qcsrc/server/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ELECTRO, w_electro, IT_CELLS, 5, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "electro", "electro", _("Electro"));
   3 #else
   4 #ifdef SVQC
   5 .float electro_count;
   6 .float electro_secondarytime;
   7
   8 void W_Plasma_Explode_Combo (void);
   9
  10 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  11 {
  12         local entity e;
  13         e = WarpZone_FindRadius(org, rad, TRUE);
  14         while (e)
  15         {
  16                 if (e.classname == "plasma")
  17                 {
  18                         // change owner to whoever caused the combo explosion
  19                         e.realowner = own;
  20                         e.takedamage = DAMAGE_NO;
  21                         e.classname = "plasma_chain";
  22                         e.think = W_Plasma_Explode_Combo;
  23                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / autocvar_g_balance_electro_combo_speed; // delay combo chains, looks cooler
  24                 }
  25                 e = e.chain;
  26         }
  27 }
  28
  29 void W_Plasma_Explode (void)
  30 {
  31         if(other.takedamage == DAMAGE_AIM)
  32                 if(other.classname == "player")
  33                         if(IsDifferentTeam(self.realowner, other))
  34                                 if(other.deadflag == DEAD_NO)
  35                                         if(IsFlying(other))
  36                                                 AnnounceTo(self.realowner, "electrobitch");
  37
  38         self.event_damage = SUB_Null;
  39         self.takedamage = DAMAGE_NO;
  40         if (self.movetype == MOVETYPE_BOUNCE)
  41         {
  42                 RadiusDamage (self, self.realowner, autocvar_g_balance_electro_secondary_damage, autocvar_g_balance_electro_secondary_edgedamage, autocvar_g_balance_electro_secondary_radius, world, autocvar_g_balance_electro_secondary_force, self.projectiledeathtype, other);
  43         }
  44         else
  45         {
  46                 W_Plasma_TriggerCombo(self.origin, autocvar_g_balance_electro_primary_comboradius, self.realowner);
  47                 RadiusDamage (self, self.realowner, autocvar_g_balance_electro_primary_damage, autocvar_g_balance_electro_primary_edgedamage, autocvar_g_balance_electro_primary_radius, world, autocvar_g_balance_electro_primary_force, self.projectiledeathtype, other);
  48         }
  49
  50         remove (self);
  51 }
  52
  53 void W_Plasma_Explode_Combo (void)
  54 {
  55         W_Plasma_TriggerCombo(self.origin, autocvar_g_balance_electro_combo_comboradius, self.realowner);
  56
  57         self.event_damage = SUB_Null;
  58         RadiusDamage (self, self.realowner, autocvar_g_balance_electro_combo_damage, autocvar_g_balance_electro_combo_edgedamage, autocvar_g_balance_electro_combo_radius, world, autocvar_g_balance_electro_combo_force, WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
  59         remove (self);
  60 }
  61
  62 void W_Plasma_Touch (void)
  63 {
  64         //self.velocity = self.velocity  * 0.1;
  65
  66         PROJECTILE_TOUCH;
  67         if (other.takedamage == DAMAGE_AIM) {
  68                 W_Plasma_Explode ();
  69         } else {
  70                 //UpdateCSQCProjectile(self);
  71                 spamsound (self, CH_SHOTS, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
  72                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  73         }
  74 }
  75
  76 void W_Plasma_TouchExplode (void)
  77 {
  78         PROJECTILE_TOUCH;
  79         W_Plasma_Explode ();
  80 }
  81
  82 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  83 {
  84         if(self.health <= 0)
  85                 return;
  86         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
  87         self.health = self.health - damage;
  88         if (self.health <= 0)
  89         {
  90                 self.takedamage = DAMAGE_NO;
  91                 self.nextthink = time;
  92                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
  93                 {
  94                         // change owner to whoever caused the combo explosion
  95                         self.realowner = inflictor.realowner;
  96                         self.classname = "plasma_chain";
  97                         self.think = W_Plasma_Explode_Combo;
  98                         self.nextthink = time + min(autocvar_g_balance_electro_combo_radius, vlen(self.origin - inflictor.origin)) / autocvar_g_balance_electro_combo_speed; // delay combo chains, looks cooler
  99                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
 100                 }
 101                 else
 102                 {
 103                         self.use = W_Plasma_Explode;
 104                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 105                 }
 106         }
 107 }
 108
 109 void W_Electro_Attack()
 110 {
 111         local entity proj;
 112
 113         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_electro_primary_ammo, autocvar_g_balance_electro_reload_ammo);
 114
 115         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", CH_WEAPON_A, autocvar_g_balance_electro_primary_damage);
 116
 117         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 118
 119         proj = spawn ();
 120         proj.classname = "plasma_prim";
 121         proj.owner = proj.realowner = self;
 122         proj.bot_dodge = TRUE;
 123         proj.bot_dodgerating = autocvar_g_balance_electro_primary_damage;
 124         proj.use = W_Plasma_Explode;
 125         proj.think = adaptor_think2use_hittype_splash;
 126         proj.nextthink = time + autocvar_g_balance_electro_primary_lifetime;
 127         PROJECTILE_MAKETRIGGER(proj);
 128         proj.projectiledeathtype = WEP_ELECTRO;
 129         setorigin(proj, w_shotorg);
 130
 131         proj.movetype = MOVETYPE_FLY;
 132         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
 133         proj.angles = vectoangles(proj.velocity);
 134         proj.touch = W_Plasma_TouchExplode;
 135         setsize(proj, '0 0 -3', '0 0 -3');
 136         proj.flags = FL_PROJECTILE;
 137
 138         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 139
 140         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 141 }
 142
 143 void W_Electro_Attack2()
 144 {
 145         local entity proj;
 146
 147         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_electro_secondary_ammo, autocvar_g_balance_electro_reload_ammo);
 148
 149         W_SetupShot_ProjectileSize (self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", CH_WEAPON_A, autocvar_g_balance_electro_secondary_damage);
 150
 151         w_shotdir = v_forward; // no TrueAim for grenades please
 152
 153         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 154
 155         proj = spawn ();
 156         proj.classname = "plasma";
 157         proj.owner = proj.realowner = self;
 158         proj.use = W_Plasma_Explode;
 159         proj.think = adaptor_think2use_hittype_splash;
 160         proj.bot_dodge = TRUE;
 161         proj.bot_dodgerating = autocvar_g_balance_electro_secondary_damage;
 162         proj.nextthink = time + autocvar_g_balance_electro_secondary_lifetime;
 163         PROJECTILE_MAKETRIGGER(proj);
 164         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 165         setorigin(proj, w_shotorg);
 166
 167         //proj.glow_size = 50;
 168         //proj.glow_color = 45;
 169         proj.movetype = MOVETYPE_BOUNCE;
 170         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 171         proj.touch = W_Plasma_Touch;
 172         setsize(proj, '0 0 -4', '0 0 -4');
 173         proj.takedamage = DAMAGE_YES;
 174         proj.damageforcescale = autocvar_g_balance_electro_secondary_damageforcescale;
 175         proj.health = autocvar_g_balance_electro_secondary_health;
 176         proj.event_damage = W_Plasma_Damage;
 177         proj.flags = FL_PROJECTILE;
 178
 179         proj.bouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 180         proj.bouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 181
 182 #if 0
 183         entity p2;
 184         p2 = spawn();
 185         copyentity(proj, p2);
 186         setmodel(p2, "models/ebomb.mdl");
 187         setsize(p2, proj.mins, proj.maxs);
 188 #endif
 189
 190         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 191
 192         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 193 }
 194
 195 .vector hook_start, hook_end;
 196 float lgbeam_send(entity to, float sf)
 197 {
 198         WriteByte(MSG_ENTITY, ENT_CLIENT_LGBEAM);
 199         sf = sf & 0x7F;
 200         if(sound_allowed(MSG_BROADCAST, self.realowner))
 201                 sf |= 0x80;
 202         WriteByte(MSG_ENTITY, sf);
 203         if(sf & 1)
 204         {
 205                 WriteByte(MSG_ENTITY, num_for_edict(self.realowner));
 206                 WriteCoord(MSG_ENTITY, autocvar_g_balance_electro_primary_range);
 207         }
 208         if(sf & 2)
 209         {
 210                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 211                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 212                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 213         }
 214         if(sf & 4)
 215         {
 216                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 217                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 218                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 219         }
 220         return TRUE;
 221 }
 222 .entity lgbeam;
 223 .float prevlgfire;
 224 float lgbeam_checkammo()
 225 {
 226         if(self.realowner.items & IT_UNLIMITED_WEAPON_AMMO)
 227                 return TRUE;
 228         else if(autocvar_g_balance_electro_reload_ammo)
 229                 return self.realowner.clip_load > 0;
 230         else
 231                 return self.realowner.ammo_cells > 0;
 232 }
 233
 234 entity lgbeam_owner_ent;
 235 void lgbeam_think()
 236 {
 237         entity owner_player;
 238         owner_player = self.realowner;
 239
 240         owner_player.prevlgfire = time;
 241         if (self != owner_player.lgbeam)
 242         {
 243                 remove(self);
 244                 return;
 245         }
 246
 247         if (owner_player.weaponentity.state != WS_INUSE || !lgbeam_checkammo() || owner_player.deadflag != DEAD_NO || !owner_player.BUTTON_ATCK || owner_player.freezetag_frozen)
 248         {
 249                 if(self == owner_player.lgbeam)
 250                         owner_player.lgbeam = world;
 251                 remove(self);
 252                 return;
 253         }
 254
 255         self.nextthink = time;
 256
 257         makevectors(owner_player.v_angle);
 258
 259         float dt, f;
 260         dt = frametime;
 261
 262         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 263         if not(owner_player.items & IT_UNLIMITED_WEAPON_AMMO)
 264         {
 265                 if(autocvar_g_balance_electro_primary_ammo)
 266                 {
 267                         if(autocvar_g_balance_electro_reload_ammo)
 268                         {
 269                                 dt = min(dt, owner_player.clip_load / autocvar_g_balance_electro_primary_ammo);
 270                                 owner_player.clip_load = max(0, owner_player.clip_load - autocvar_g_balance_electro_primary_ammo * frametime);
 271                                 owner_player.weapon_load[WEP_ELECTRO] = owner_player.clip_load;
 272                         }
 273                         else
 274                         {
 275                                 dt = min(dt, owner_player.ammo_cells / autocvar_g_balance_electro_primary_ammo);
 276                                 owner_player.ammo_cells = max(0, owner_player.ammo_cells - autocvar_g_balance_electro_primary_ammo * frametime);
 277                         }
 278                 }
 279         }
 280
 281         W_SetupShot_Range(owner_player, TRUE, 0, "", 0, autocvar_g_balance_electro_primary_damage * dt, autocvar_g_balance_electro_primary_range);
 282         if(!lgbeam_owner_ent)
 283         {
 284                 lgbeam_owner_ent = spawn();
 285                 lgbeam_owner_ent.classname = "lgbeam_owner_ent";
 286         }
 287         WarpZone_traceline_antilag(lgbeam_owner_ent, w_shotorg, w_shotend, MOVE_NORMAL, lgbeam_owner_ent, ANTILAG_LATENCY(owner_player));
 288
 289         // apply the damage
 290         if(trace_ent)
 291         {
 292                 vector force;
 293                 force = w_shotdir * autocvar_g_balance_electro_primary_force + '0 0 1' * autocvar_g_balance_electro_primary_force_up;
 294
 295                 f = ExponentialFalloff(autocvar_g_balance_electro_primary_falloff_mindist, autocvar_g_balance_electro_primary_falloff_maxdist, autocvar_g_balance_electro_primary_falloff_halflifedist, vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - w_shotorg));
 296
 297                 if(accuracy_isgooddamage(owner_player, trace_ent))
 298                         accuracy_add(owner_player, WEP_ELECTRO, 0, autocvar_g_balance_electro_primary_damage * dt * f);
 299                 Damage (trace_ent, owner_player, owner_player, autocvar_g_balance_electro_primary_damage * dt * f, WEP_ELECTRO, trace_endpos, force * dt);
 300         }
 301         W_Plasma_TriggerCombo(trace_endpos, autocvar_g_balance_electro_primary_comboradius, owner_player);
 302
 303         // draw effect
 304         if(w_shotorg != self.hook_start)
 305         {
 306                 self.SendFlags |= 2;
 307                 self.hook_start = w_shotorg;
 308         }
 309         if(w_shotend != self.hook_end)
 310         {
 311                 self.SendFlags |= 4;
 312                 self.hook_end = w_shotend;
 313         }
 314 }
 315
 316 // experimental lightning gun
 317 void W_Electro_Attack3 (void)
 318 {
 319         // only play fire sound if 0.5 sec has passed since player let go the fire button
 320         if(time - self.prevlgfire > 0.5)
 321                 sound (self, CH_WEAPON_A, "weapons/lgbeam_fire.wav", VOL_BASE, ATTN_NORM);
 322
 323         entity beam, oldself;
 324
 325         self.lgbeam = beam = spawn();
 326         beam.classname = "lgbeam";
 327         beam.solid = SOLID_NOT;
 328         beam.think = lgbeam_think;
 329         beam.owner = beam.realowner = self;
 330         beam.movetype = MOVETYPE_NONE;
 331         beam.shot_spread = 0;
 332         beam.bot_dodge = TRUE;
 333         beam.bot_dodgerating = autocvar_g_balance_electro_primary_damage;
 334         Net_LinkEntity(beam, FALSE, 0, lgbeam_send);
 335
 336         oldself = self;
 337         self = beam;
 338         self.think();
 339         self = oldself;
 340 }
 341
 342 void ElectroInit()
 343 {
 344         weapon_action(WEP_ELECTRO, WR_PRECACHE);
 345         electro_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 1);
 346         electro_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 2);
 347         electro_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 3);
 348         electro_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), FALSE, FALSE, 4);
 349 }
 350
 351 void spawnfunc_weapon_electro (void)
 352 {
 353         weapon_defaultspawnfunc(WEP_ELECTRO);
 354 }
 355
 356 void w_electro_checkattack()
 357 {
 358         if(self.electro_count > 1)
 359         if(self.BUTTON_ATCK2)
 360         if(weapon_prepareattack(1, -1))
 361         {
 362                 W_Electro_Attack2();
 363                 self.electro_count -= 1;
 364                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_electro_secondary_animtime, w_electro_checkattack);
 365                 return;
 366         }
 367
 368         w_ready();
 369 }
 370
 371 .float bot_secondary_electromooth;
 372 .float BUTTON_ATCK_prev;
 373 float w_electro(float req)
 374 {
 375         float ammo_amount;
 376         if (req == WR_AIM)
 377         {
 378                 self.BUTTON_ATCK=FALSE;
 379                 self.BUTTON_ATCK2=FALSE;
 380                 if(vlen(self.origin-self.enemy.origin) > 1000)
 381                         self.bot_secondary_electromooth = 0;
 382                 if(self.bot_secondary_electromooth == 0)
 383                 {
 384                         float shoot;
 385
 386                         if(autocvar_g_balance_electro_primary_speed)
 387                                 shoot = bot_aim(autocvar_g_balance_electro_primary_speed, 0, autocvar_g_balance_electro_primary_lifetime, FALSE);
 388                         else
 389                                 shoot = bot_aim(1000000, 0, 0.001, FALSE);
 390
 391                         if(shoot)
 392                         {
 393                                 self.BUTTON_ATCK = TRUE;
 394                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 395                         }
 396                 }
 397                 else
 398                 {
 399                         if(bot_aim(autocvar_g_balance_electro_secondary_speed, autocvar_g_balance_grenadelauncher_secondary_speed_up, autocvar_g_balance_electro_secondary_lifetime, TRUE))
 400                         {
 401                                 self.BUTTON_ATCK2 = TRUE;
 402                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 403                         }
 404                 }
 405         }
 406         else if (req == WR_THINK)
 407         {
 408                 if(autocvar_g_balance_electro_reload_ammo) // forced reload
 409                 {
 410                         if(autocvar_g_balance_electro_lightning)
 411                         {
 412                                 if(self.clip_load > 0)
 413                                         ammo_amount = 1;
 414                         }
 415                         else if(self.clip_load >= autocvar_g_balance_electro_primary_ammo)
 416                                 ammo_amount = 1;
 417                         if(self.clip_load >= autocvar_g_balance_electro_secondary_ammo)
 418                                 ammo_amount += 1;
 419
 420                         if(!ammo_amount)
 421                         {
 422                                 weapon_action(self.weapon, WR_RELOAD);
 423                                 return FALSE;
 424                         }
 425                 }
 426                 if (self.BUTTON_ATCK)
 427                 {
 428                         if(autocvar_g_balance_electro_lightning)
 429                                 if(self.BUTTON_ATCK_prev)
 430                                 {
 431                                         // prolong the animtime while the gun is being fired
 432                                         if(self.animstate_startframe == self.anim_shoot_x && self.animstate_numframes == self.anim_shoot_y)
 433                                                 weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_electro_primary_animtime, w_ready);
 434                                         else
 435                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 436                                 }
 437                         if (weapon_prepareattack(0, (autocvar_g_balance_electro_lightning ? 0 : autocvar_g_balance_electro_primary_refire)))
 438                         {
 439                                 if(autocvar_g_balance_electro_lightning)
 440                                 {
 441                                         if ((!self.lgbeam) || wasfreed(self.lgbeam))
 442                                         {
 443                                                 W_Electro_Attack3();
 444                                         }
 445                                         if(!self.BUTTON_ATCK_prev)
 446                                         {
 447                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 448                                                 self.BUTTON_ATCK_prev = 1;
 449                                         }
 450                                 }
 451                                 else
 452                                 {
 453                                         W_Electro_Attack();
 454                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 455                                 }
 456                         }
 457                 } else {
 458                         if(autocvar_g_balance_electro_lightning)
 459                         {
 460                                 if (self.BUTTON_ATCK_prev != 0)
 461                                 {
 462                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_electro_primary_animtime, w_ready);
 463                                         ATTACK_FINISHED(self) = time + autocvar_g_balance_electro_primary_refire * W_WeaponRateFactor();
 464                                 }
 465                                 self.BUTTON_ATCK_prev = 0;
 466                         }
 467
 468                         if (self.BUTTON_ATCK2)
 469                         {
 470                                 if (time >= self.electro_secondarytime)
 471                                 if (weapon_prepareattack(1, autocvar_g_balance_electro_secondary_refire))
 472                                 {
 473                                         W_Electro_Attack2();
 474                                         self.electro_count = autocvar_g_balance_electro_secondary_count;
 475                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_electro_secondary_animtime, w_electro_checkattack);
 476                                         self.electro_secondarytime = time + autocvar_g_balance_electro_secondary_refire2 * W_WeaponRateFactor();
 477                                 }
 478                         }
 479                 }
 480         }
 481         else if (req == WR_PRECACHE)
 482         {
 483                 precache_model ("models/weapons/g_electro.md3");
 484                 precache_model ("models/weapons/v_electro.md3");
 485                 precache_model ("models/weapons/h_electro.iqm");
 486                 precache_sound ("weapons/electro_bounce.wav");
 487                 precache_sound ("weapons/electro_fire.wav");
 488                 precache_sound ("weapons/electro_fire2.wav");
 489                 precache_sound ("weapons/electro_impact.wav");
 490                 precache_sound ("weapons/electro_impact_combo.wav");
 491                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 492                 if(autocvar_g_balance_electro_lightning)
 493                 {
 494                         precache_sound ("weapons/lgbeam_fire.wav");
 495                 }
 496         }
 497         else if (req == WR_SETUP)
 498         {
 499                 weapon_setup(WEP_ELECTRO);
 500                 self.current_ammo = ammo_cells;
 501         }
 502         else if (req == WR_CHECKAMMO1)
 503         {
 504                 if(autocvar_g_balance_electro_lightning)
 505                 {
 506                         if(!autocvar_g_balance_electro_primary_ammo)
 507                                 ammo_amount = 1;
 508                         else
 509                                 ammo_amount = self.ammo_cells > 0;
 510                         ammo_amount += self.weapon_load[WEP_ELECTRO] > 0;
 511                 }
 512                 else
 513                 {
 514                         ammo_amount = self.ammo_cells >= autocvar_g_balance_electro_primary_ammo;
 515                         ammo_amount += self.weapon_load[WEP_ELECTRO] >= autocvar_g_balance_electro_primary_ammo;
 516                 }
 517                 return ammo_amount;
 518         }
 519         else if (req == WR_CHECKAMMO2)
 520         {
 521                 ammo_amount = self.ammo_cells >= autocvar_g_balance_electro_secondary_ammo;
 522                 ammo_amount += self.weapon_load[WEP_ELECTRO] >= autocvar_g_balance_electro_secondary_ammo;
 523                 return ammo_amount;
 524         }
 525         else if (req == WR_RESETPLAYER)
 526         {
 527                 self.electro_secondarytime = time;
 528         }
 529         else if (req == WR_RELOAD)
 530         {
 531                 W_Reload(min(autocvar_g_balance_electro_primary_ammo, autocvar_g_balance_electro_secondary_ammo), autocvar_g_balance_electro_reload_ammo, autocvar_g_balance_electro_reload_time, "weapons/reload.wav");
 532         }
 533         return TRUE;
 534 };
 535 #endif
 536 #ifdef CSQC
 537 float w_electro(float req)
 538 {
 539         if(req == WR_IMPACTEFFECT)
 540         {
 541                 vector org2;
 542                 org2 = w_org + w_backoff * 6;
 543                 if(w_deathtype & HITTYPE_SECONDARY)
 544                 {
 545                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 546                         if(!w_issilent)
 547                                 sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 548                 }
 549                 else
 550                 {
 551                         if(w_deathtype & HITTYPE_BOUNCE)
 552                         {
 553                                 // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 554                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 555                                 if(!w_issilent)
 556                                         sound(self, CH_SHOTS, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 557                         }
 558                         else
 559                         {
 560                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 561                                 if(!w_issilent)
 562                                         sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 563                         }
 564                 }
 565         }
 566         else if(req == WR_PRECACHE)
 567         {
 568                 precache_sound("weapons/electro_impact.wav");
 569                 precache_sound("weapons/electro_impact_combo.wav");
 570         }
 571         else if (req == WR_SUICIDEMESSAGE)
 572         {
 573                 if(w_deathtype & HITTYPE_SECONDARY)
 574                         w_deathtypestring = _("%s could not remember where they put plasma");
 575                 else
 576                         w_deathtypestring = _("%s played with plasma");
 577         }
 578         else if (req == WR_KILLMESSAGE)
 579         {
 580                 if(w_deathtype & HITTYPE_SECONDARY)
 581                 {
 582                         if(w_deathtype & HITTYPE_SPLASH) // unchecked: BOUNCE
 583                                 w_deathtypestring = _("%s just noticed %s's blue ball");
 584                         else // unchecked: BOUNCE
 585                                 w_deathtypestring = _("%s got in touch with %s's blue ball");
 586                 }
 587                 else
 588                 {
 589                         if(w_deathtype & HITTYPE_BOUNCE) // combo
 590                                 w_deathtypestring = _("%s felt the electrifying air of %s's combo");
 591                         else if(w_deathtype & HITTYPE_SPLASH)
 592                                 w_deathtypestring = _("%s got too close to %s's blue beam");
 593                         else
 594                                 w_deathtypestring = _("%s was blasted by %s's blue beam");
 595                 }
 596         }
 597         return TRUE;
 598 }
 599 #endif
 600 #endif