qcsrc/server/w_electro.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ELECTRO, w_electro, IT_CELLS, 5, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "electro", "electro", "Electro");
   3 #else
   4 #ifdef SVQC
   5 .float electro_count;
   6 .float electro_secondarytime;
   7
   8 void W_Plasma_Explode_Combo (void);
   9
  10 void W_Plasma_TriggerCombo(vector org, float rad, entity own)
  11 {
  12         local entity e;
  13         e = WarpZone_FindRadius(org, rad, TRUE);
  14         while (e)
  15         {
  16                 if (e.classname == "plasma")
  17                 {
  18                         // change owner to whoever caused the combo explosion
  19                         e.owner = own;
  20                         e.takedamage = DAMAGE_NO;
  21                         e.classname = "plasma_chain";
  22                         e.think = W_Plasma_Explode_Combo;
  23                         e.nextthink = time + vlen(e.WarpZone_findradius_dist) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  24                 }
  25                 e = e.chain;
  26         }
  27 }
  28
  29 void W_Plasma_Explode (void)
  30 {
  31         if(other.takedamage == DAMAGE_AIM)
  32                 if(other.classname == "player")
  33                         if(IsDifferentTeam(self.owner, other))
  34                                 if(other.deadflag == DEAD_NO)
  35                                         if(IsFlying(other))
  36                                                 AnnounceTo(self.owner, "electrobitch");
  37
  38         self.event_damage = SUB_Null;
  39         self.takedamage = DAMAGE_NO;
  40         if (self.movetype == MOVETYPE_BOUNCE)
  41         {
  42                 RadiusDamage (self, self.owner, cvar("g_balance_electro_secondary_damage"), cvar("g_balance_electro_secondary_edgedamage"), cvar("g_balance_electro_secondary_radius"), world, cvar("g_balance_electro_secondary_force"), self.projectiledeathtype, other);
  43         }
  44         else
  45         {
  46                 W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_primary_comboradius"), self.owner);
  47                 RadiusDamage (self, self.owner, cvar("g_balance_electro_primary_damage"), cvar("g_balance_electro_primary_edgedamage"), cvar("g_balance_electro_primary_radius"), world, cvar("g_balance_electro_primary_force"), self.projectiledeathtype, other);
  48         }
  49
  50         remove (self);
  51 }
  52
  53 void W_Plasma_Explode_Combo (void)
  54 {
  55         W_Plasma_TriggerCombo(self.origin, cvar("g_balance_electro_combo_comboradius"), self.owner);
  56
  57         self.event_damage = SUB_Null;
  58         RadiusDamage (self, self.owner, cvar("g_balance_electro_combo_damage"), cvar("g_balance_electro_combo_edgedamage"), cvar("g_balance_electro_combo_radius"), world, cvar("g_balance_electro_combo_force"), WEP_ELECTRO | HITTYPE_BOUNCE, world); // use THIS type for a combo because primary can't bounce
  59         remove (self);
  60 }
  61
  62 void W_Plasma_Touch (void)
  63 {
  64         PROJECTILE_TOUCH;
  65         if (other.takedamage == DAMAGE_AIM) {
  66                 W_Plasma_Explode ();
  67         } else {
  68                 spamsound (self, CHAN_PROJECTILE, "weapons/electro_bounce.wav", VOL_BASE, ATTN_NORM);
  69                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  70         }
  71 }
  72
  73 void W_Plasma_TouchExplode (void)
  74 {
  75         PROJECTILE_TOUCH;
  76         W_Plasma_Explode ();
  77 }
  78
  79 void W_Plasma_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  80 {
  81         if(self.health <= 0)
  82                 return;
  83         // note: combos are usually triggered by W_Plasma_TriggerCombo, not damage
  84         self.health = self.health - damage;
  85         if (self.health <= 0)
  86         {
  87                 self.takedamage = DAMAGE_NO;
  88                 self.nextthink = time;
  89                 if (inflictor.classname == "plasma_chain" || inflictor.classname == "plasma_prim")
  90                 {
  91                         // change owner to whoever caused the combo explosion
  92                         self.owner = inflictor.owner;
  93                         self.classname = "plasma_chain";
  94                         self.think = W_Plasma_Explode_Combo;
  95                         self.nextthink = time + min(cvar("g_balance_electro_combo_radius"), vlen(self.origin - inflictor.origin)) / cvar("g_balance_electro_combo_speed"); // delay combo chains, looks cooler
  96                                 //                  ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ bounding the length, because inflictor may be in a galaxy far far away (warpzones)
  97                 }
  98                 else
  99                 {
 100                         self.use = W_Plasma_Explode;
 101                         self.think = adaptor_think2use; // not _hittype_splash, as this runs "immediately"
 102                 }
 103         }
 104 }
 105
 106 void W_Electro_Attack()
 107 {
 108         local entity proj;
 109
 110         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 2, "weapons/electro_fire.wav", cvar("g_balance_electro_primary_damage"));
 111
 112         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 113
 114         proj = spawn ();
 115         proj.classname = "plasma_prim";
 116         proj.owner = self;
 117         proj.bot_dodge = TRUE;
 118         proj.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 119         proj.use = W_Plasma_Explode;
 120         proj.think = adaptor_think2use_hittype_splash;
 121         proj.nextthink = time + cvar("g_balance_electro_primary_lifetime");
 122         PROJECTILE_MAKETRIGGER(proj);
 123         proj.projectiledeathtype = WEP_ELECTRO;
 124         setorigin(proj, w_shotorg);
 125
 126         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 127                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_primary_ammo");
 128         proj.movetype = MOVETYPE_FLY;
 129         W_SETUPPROJECTILEVELOCITY(proj, g_balance_electro_primary);
 130         proj.angles = vectoangles(proj.velocity);
 131         proj.touch = W_Plasma_TouchExplode;
 132         setsize(proj, '0 0 -3', '0 0 -3');
 133         proj.flags = FL_PROJECTILE;
 134
 135         //sound (proj, CHAN_PAIN, "weapons/electro_fly.wav", VOL_BASE, ATTN_NORM);
 136         //sounds bad
 137
 138         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO_BEAM, TRUE);
 139 }
 140
 141 void W_Electro_Attack2()
 142 {
 143         local entity proj;
 144
 145         W_SetupShot_ProjectileSize (self, '0 0 -4', '0 0 -4', FALSE, 2, "weapons/electro_fire2.wav", cvar("g_balance_electro_secondary_damage"));
 146         w_shotdir = v_forward; // no TrueAim for grenades please
 147
 148         pointparticles(particleeffectnum("electro_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 149
 150         proj = spawn ();
 151         proj.classname = "plasma";
 152         proj.owner = self;
 153         proj.use = W_Plasma_Explode;
 154         proj.think = adaptor_think2use_hittype_splash;
 155         proj.bot_dodge = TRUE;
 156         proj.bot_dodgerating = cvar("g_balance_electro_secondary_damage");
 157         proj.nextthink = time + cvar("g_balance_electro_secondary_lifetime");
 158         PROJECTILE_MAKETRIGGER(proj);
 159         proj.projectiledeathtype = WEP_ELECTRO | HITTYPE_SECONDARY;
 160         setorigin(proj, w_shotorg);
 161
 162         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 163                 self.ammo_cells = self.ammo_cells - cvar("g_balance_electro_secondary_ammo");
 164         //proj.glow_size = 50;
 165         //proj.glow_color = 45;
 166         proj.movetype = MOVETYPE_BOUNCE;
 167         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_electro_secondary);
 168         proj.touch = W_Plasma_Touch;
 169         setsize(proj, '0 0 -4', '0 0 -4');
 170         proj.takedamage = DAMAGE_YES;
 171         proj.damageforcescale = cvar("g_balance_electro_secondary_damageforcescale");
 172         proj.health = cvar("g_balance_electro_secondary_health");
 173         proj.event_damage = W_Plasma_Damage;
 174         proj.flags = FL_PROJECTILE;
 175
 176 #if 0
 177         entity p2;
 178         p2 = spawn();
 179         copyentity(proj, p2);
 180         setmodel(p2, "models/ebomb.mdl");
 181         setsize(p2, proj.mins, proj.maxs);
 182 #endif
 183
 184         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, FALSE); // no culling, it has sound
 185 }
 186
 187 .entity lgbeam, exteriorlgbeam;
 188 .float nextdamagethink;
 189 void lgbeam_think()
 190 {
 191         if (self.owner.weaponentity.state != WS_INUSE || (self.owner.ammo_cells <= 0 && !(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)) || self != self.owner.lgbeam || self.owner.deadflag != DEAD_NO || !self.owner.BUTTON_ATCK)
 192         {
 193                 remove(self);
 194                 return;
 195         }
 196
 197         self.nextthink = time;
 198
 199         makevectors(self.owner.v_angle);
 200         vector angle;
 201         angle = v_forward;
 202
 203         traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_electro_primary_range"), FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 204
 205         if not(self.owner.items & IT_UNLIMITED_WEAPON_AMMO)
 206                 self.owner.ammo_cells = max(0, self.owner.ammo_cells - cvar("g_balance_electro_primary_ammo") * frametime);
 207
 208         // apply the damage
 209         if(trace_fraction < 1)
 210         {
 211                 vector force;
 212                 force = angle * cvar("g_balance_electro_primary_force") + '0 0 1' * cvar("g_balance_electro_primary_force_up");
 213                 Damage (trace_ent, self.owner, self.owner, cvar("g_balance_electro_primary_damage") * frametime, WEP_ELECTRO, trace_endpos, force * frametime);
 214                 W_Plasma_TriggerCombo(trace_endpos, cvar("g_balance_electro_primary_comboradius"), self.owner);
 215         }
 216
 217         // draw effect
 218         vector vecs, org;
 219         if(self.owner.weaponentity.movedir_x > 0)
 220         {
 221                 vecs = self.owner.weaponentity.movedir;
 222                 vecs_y = -vecs_y;
 223         }
 224         else
 225                 vecs = '0 0 0';
 226         org = self.owner.origin + self.owner.view_ofs + v_forward * vecs_x + v_right * vecs_y + v_up * vecs_z;
 227
 228         // TODO turn into a csqc entity
 229         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
 230         WriteByte(MSG_BROADCAST, TE_CSQC_BEAM);
 231         WriteByte(MSG_BROADCAST, num_for_edict(self.owner));
 232         WriteByte(MSG_BROADCAST, sound_allowed(MSG_BROADCAST, self.owner) ? 1 : 2);
 233         WriteCoord(MSG_BROADCAST, trace_endpos_x);
 234         WriteCoord(MSG_BROADCAST, trace_endpos_y);
 235         WriteCoord(MSG_BROADCAST, trace_endpos_z);
 236         WriteCoord(MSG_BROADCAST, org_x);
 237         WriteCoord(MSG_BROADCAST, org_y);
 238         WriteCoord(MSG_BROADCAST, org_z);
 239 }
 240
 241 // experimental lightning gun
 242 void W_Electro_Attack3 (void)
 243 {
 244         entity beam, oldself;
 245
 246         self.lgbeam = beam = spawn();
 247         setmodel(beam,"models/turrets/phaser_beam.md3");
 248         beam.effects = EF_LOWPRECISION;
 249         beam.solid = SOLID_NOT;
 250         beam.think = lgbeam_think;
 251         beam.owner = self;
 252         beam.movetype = MOVETYPE_NONE;
 253         beam.shot_spread = 0;
 254         beam.bot_dodge = TRUE;
 255         beam.bot_dodgerating = cvar("g_balance_electro_primary_damage");
 256
 257         oldself = self;
 258         self = beam;
 259         self.think();
 260         self = oldself;
 261 }
 262
 263 void ElectroInit()
 264 {
 265         weapon_action(WEP_ELECTRO, WR_PRECACHE);
 266         electro_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), TRUE, FALSE, 1);
 267         electro_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), TRUE, FALSE, 2);
 268         electro_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), TRUE, FALSE, 3);
 269         electro_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_ELECTRO), TRUE, FALSE, 4);
 270 }
 271
 272 void spawnfunc_weapon_electro (void)
 273 {
 274         weapon_defaultspawnfunc(WEP_ELECTRO);
 275 }
 276
 277 void w_electro_checkattack()
 278 {
 279         if(self.electro_count > 1)
 280         if(self.BUTTON_ATCK2)
 281         if(weapon_prepareattack(1, -1))
 282         {
 283                 W_Electro_Attack2();
 284                 self.electro_count -= 1;
 285                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 286                 return;
 287         }
 288
 289         w_ready();
 290 }
 291
 292 .float bot_secondary_electromooth;
 293 .float BUTTON_ATCK_prev;
 294 float w_electro(float req)
 295 {
 296         if (req == WR_AIM)
 297         {
 298                 self.BUTTON_ATCK=FALSE;
 299                 self.BUTTON_ATCK2=FALSE;
 300                 if(vlen(self.origin-self.enemy.origin) > 1000)
 301                         self.bot_secondary_electromooth = 0;
 302                 if(self.bot_secondary_electromooth == 0)
 303                 {
 304                         if(bot_aim(cvar("g_balance_electro_primary_speed"), 0, cvar("g_balance_electro_primary_lifetime"), FALSE))
 305                         {
 306                                 self.BUTTON_ATCK = TRUE;
 307                                 if(random() < 0.01) self.bot_secondary_electromooth = 1;
 308                         }
 309                 }
 310                 else
 311                 {
 312                         if(bot_aim(cvar("g_balance_electro_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_electro_secondary_lifetime"), TRUE))
 313                         {
 314                                 self.BUTTON_ATCK2 = TRUE;
 315                                 if(random() < 0.03) self.bot_secondary_electromooth = 0;
 316                         }
 317                 }
 318         }
 319         else if (req == WR_THINK)
 320         {
 321                 if (self.BUTTON_ATCK)
 322                 {
 323                         if (weapon_prepareattack(0, cvar("g_balance_electro_primary_refire")))
 324                         {
 325                                 if(cvar("g_balance_electro_lightning"))
 326                                 {
 327                                         if (self.BUTTON_ATCK_prev == 0)
 328                                         {
 329                                                 W_Electro_Attack3();
 330                                         }
 331                                         self.BUTTON_ATCK_prev = 1;
 332                                 }
 333                                 else
 334                                 {
 335                                         W_Electro_Attack();
 336                                 }
 337                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_electro_primary_animtime"), w_ready);
 338                         }
 339                 } else {
 340                         self.BUTTON_ATCK_prev = 0;
 341                 }
 342
 343                 if (self.BUTTON_ATCK2)
 344                 if (time >= self.electro_secondarytime)
 345                 if (weapon_prepareattack(1, cvar("g_balance_electro_secondary_refire")))
 346                 {
 347                         W_Electro_Attack2();
 348                         self.electro_count = cvar("g_balance_electro_secondary_count");
 349                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_electro_secondary_animtime"), w_electro_checkattack);
 350                         self.electro_secondarytime = time + cvar("g_balance_electro_secondary_refire2");
 351                 }
 352         }
 353         else if (req == WR_PRECACHE)
 354         {
 355                 precache_model ("models/weapons/g_electro.md3");
 356                 precache_model ("models/weapons/v_electro.md3");
 357                 precache_model ("models/weapons/h_electro.iqm");
 358                 precache_sound ("weapons/electro_bounce.wav");
 359                 precache_sound ("weapons/electro_fire.wav");
 360                 precache_sound ("weapons/electro_fire2.wav");
 361                 precache_sound ("weapons/electro_impact.wav");
 362                 precache_sound ("weapons/electro_impact_combo.wav");
 363                 if(cvar("g_balance_electro_lightning"))
 364                         precache_sound ("weapons/crylink_fire2.wav");
 365         }
 366         else if (req == WR_SETUP)
 367                 weapon_setup(WEP_ELECTRO);
 368         else if (req == WR_CHECKAMMO1)
 369         {
 370                 if(cvar("g_balance_electro_lightning"))
 371                         return self.ammo_cells >= cvar("g_balance_electro_primary_ammo") * cvar("g_balance_electro_primary_refire");
 372                 else
 373                         return self.ammo_cells >= cvar("g_balance_electro_primary_ammo");
 374         }
 375         else if (req == WR_CHECKAMMO2)
 376                 return self.ammo_cells >= cvar("g_balance_electro_secondary_ammo");
 377         else if (req == WR_RESETPLAYER)
 378         {
 379                 self.electro_secondarytime = time;
 380         }
 381         return TRUE;
 382 };
 383 #endif
 384 #ifdef CSQC
 385 float w_electro(float req)
 386 {
 387         if(req == WR_IMPACTEFFECT)
 388         {
 389                 vector org2;
 390                 org2 = w_org + w_backoff * 6;
 391                 if(w_deathtype & HITTYPE_SECONDARY)
 392                 {
 393                         pointparticles(particleeffectnum("electro_ballexplode"), org2, '0 0 0', 1);
 394                         if(!w_issilent)
 395                                 sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 396                 }
 397                 else
 398                 {
 399                         if(w_deathtype & HITTYPE_BOUNCE)
 400                         {
 401                                 // this is sent as "primary (w_deathtype & HITTYPE_BOUNCE)" to distinguish it from (w_deathtype & HITTYPE_SECONDARY) bounced balls
 402                                 pointparticles(particleeffectnum("electro_combo"), org2, '0 0 0', 1);
 403                                 if(!w_issilent)
 404                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact_combo.wav", VOL_BASE, ATTN_NORM);
 405                         }
 406                         else
 407                         {
 408                                 pointparticles(particleeffectnum("electro_impact"), org2, '0 0 0', 1);
 409                                 if(!w_issilent)
 410                                         sound(self, CHAN_PROJECTILE, "weapons/electro_impact.wav", VOL_BASE, ATTN_NORM);
 411                         }
 412                 }
 413         }
 414         else if(req == WR_PRECACHE)
 415         {
 416                 precache_sound("weapons/electro_impact.wav");
 417                 precache_sound("weapons/electro_impact_combo.wav");
 418         }
 419         else if (req == WR_SUICIDEMESSAGE)
 420         {
 421                 if(w_deathtype & HITTYPE_SECONDARY)
 422                         w_deathtypestring = "could not remember where they put plasma";
 423                 else
 424                         w_deathtypestring = "played with plasma";
 425         }
 426         else if (req == WR_KILLMESSAGE)
 427         {
 428                 if(w_deathtype & HITTYPE_SECONDARY)
 429                 {
 430                         if(w_deathtype & HITTYPE_SPLASH) // unchecked: BOUNCE
 431                                 w_deathtypestring = "just noticed #'s blue ball";
 432                         else // unchecked: BOUNCE
 433                                 w_deathtypestring = "got in touch with #'s blue ball";
 434                 }
 435                 else
 436                 {
 437                         if(w_deathtype & HITTYPE_BOUNCE) // combo
 438                                 w_deathtypestring = "felt the electrifying air of #'s combo";
 439                         else if(w_deathtype & HITTYPE_SPLASH)
 440                                 w_deathtypestring = "got too close to #'s blue beam";
 441                         else
 442                                 w_deathtypestring = "was blasted by #'s blue beam";
 443                 }
 444         }
 445         return TRUE;
 446 }
 447 #endif
 448 #endif