qcsrc/server/w_fireball.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(FIREBALL, w_fireball, 0, 9, WEP_FLAG_SUPERWEAPON | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "fireball", "fireball", _("Fireball"));
   3 #else
   4 #ifdef SVQC
   5 .float bot_primary_fireballmooth; // whatever a mooth is
   6 .vector fireball_impactvec;
   7 .float fireball_primarytime;
   8
   9 void W_Fireball_Explode (void)
  10 {
  11         entity e;
  12         float dist;
  13         float points;
  14         vector dir;
  15         float d;
  16
  17         self.event_damage = SUB_Null;
  18         self.takedamage = DAMAGE_NO;
  19
  20         // 1. dist damage
  21         d = (self.realowner.health + self.realowner.armorvalue);
  22         RadiusDamage (self, self.realowner, autocvar_g_balance_fireball_primary_damage, autocvar_g_balance_fireball_primary_edgedamage, autocvar_g_balance_fireball_primary_radius, world, autocvar_g_balance_fireball_primary_force, self.projectiledeathtype, other);
  23         if(self.realowner.health + self.realowner.armorvalue >= d)
  24         if(!self.cnt)
  25         {
  26                 modeleffect_spawn("models/sphere/sphere.md3", 0, 0, self.origin, '0 0 0', '0 0 0', '0 0 0', 0, autocvar_g_balance_fireball_primary_bfgradius, 0.2, 0.05, 0.25);
  27
  28                 // 2. bfg effect
  29                 // NOTE: this cannot be made warpzone aware by design. So, better intentionally ignore warpzones here.
  30                 for(e = findradius(self.origin, autocvar_g_balance_fireball_primary_bfgradius); e; e = e.chain)
  31                 if(e != self.realowner) if(e.takedamage == DAMAGE_AIM) if(e.classname != "player" || !self.realowner || IsDifferentTeam(e, self))
  32                 {
  33                         // can we see fireball?
  34                         traceline(e.origin + e.view_ofs, self.origin, MOVE_NORMAL, e);
  35                         if(/* trace_startsolid || */ trace_fraction != 1) // startsolid should be never happening anyway
  36                                 continue;
  37                         // can we see player who shot fireball?
  38                         traceline(e.origin + e.view_ofs, self.realowner.origin + self.realowner.view_ofs, MOVE_NORMAL, e);
  39                         if(trace_ent != self.realowner)
  40                         if(/* trace_startsolid || */ trace_fraction != 1)
  41                                 continue;
  42                         dist = vlen(self.origin - e.origin - e.view_ofs);
  43                         points = (1 - sqrt(dist / autocvar_g_balance_fireball_primary_bfgradius));
  44                         if(points <= 0)
  45                                 continue;
  46                         dir = normalize(e.origin + e.view_ofs - self.origin);
  47
  48                         if(accuracy_isgooddamage(self.realowner, e))
  49                                 accuracy_add(self.realowner, WEP_FIREBALL, 0, autocvar_g_balance_fireball_primary_bfgdamage * points);
  50
  51                         Damage(e, self, self.realowner, autocvar_g_balance_fireball_primary_bfgdamage * points, self.projectiledeathtype | HITTYPE_BOUNCE | HITTYPE_SPLASH, e.origin + e.view_ofs, autocvar_g_balance_fireball_primary_bfgforce * dir);
  52                         pointparticles(particleeffectnum("fireball_bfgdamage"), e.origin, -1 * dir, 1);
  53                 }
  54         }
  55
  56         remove (self);
  57 }
  58
  59 void W_Fireball_TouchExplode (void)
  60 {
  61         PROJECTILE_TOUCH;
  62         W_Fireball_Explode ();
  63 }
  64
  65 void W_Fireball_LaserPlay(float dt, float dist, float damage, float edgedamage, float burntime)
  66 {
  67         entity e;
  68         float d;
  69         vector p;
  70
  71         if(damage <= 0)
  72                 return;
  73
  74         RandomSelection_Init();
  75         for(e = WarpZone_FindRadius(self.origin, dist, TRUE); e; e = e.chain)
  76         if(e != self.realowner) if(e.takedamage == DAMAGE_AIM) if(e.classname != "player" || !self.realowner || IsDifferentTeam(e, self))
  77         {
  78                 p = e.origin;
  79                 p_x += e.mins_x + random() * (e.maxs_x - e.mins_x);
  80                 p_y += e.mins_y + random() * (e.maxs_y - e.mins_y);
  81                 p_z += e.mins_z + random() * (e.maxs_z - e.mins_z);
  82                 d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
  83                 if(d < dist)
  84                 {
  85                         e.fireball_impactvec = p;
  86                         RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
  87                 }
  88         }
  89         if(RandomSelection_chosen_ent)
  90         {
  91                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
  92                 d = damage + (edgedamage - damage) * (d / dist);
  93                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
  94                 //trailparticles(self, particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
  95                 pointparticles(particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
  96         }
  97 }
  98
  99 void W_Fireball_Think()
 100 {
 101         if(time > self.pushltime)
 102         {
 103                 self.cnt = 1;
 104                 self.projectiledeathtype |= HITTYPE_SPLASH;
 105                 W_Fireball_Explode();
 106                 return;
 107         }
 108
 109         W_Fireball_LaserPlay(0.1, autocvar_g_balance_fireball_primary_laserradius, autocvar_g_balance_fireball_primary_laserdamage, autocvar_g_balance_fireball_primary_laseredgedamage, autocvar_g_balance_fireball_primary_laserburntime);
 110
 111         self.nextthink = time + 0.1;
 112 }
 113
 114 void W_Fireball_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 115 {
 116         if(self.health <= 0)
 117                 return;
 118
 119         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 120                 return; // g_projectiles_damage says to halt
 121
 122         self.health = self.health - damage;
 123         if (self.health <= 0)
 124         {
 125                 self.cnt = 1;
 126                 W_PrepareExplosionByDamage(attacker, W_Fireball_Explode);
 127         }
 128 }
 129
 130 void W_Fireball_Attack1()
 131 {
 132         entity proj;
 133
 134         W_SetupShot_ProjectileSize (self, '-16 -16 -16', '16 16 16', FALSE, 2, "weapons/fireball_fire2.wav", CH_WEAPON_A, autocvar_g_balance_fireball_primary_damage + autocvar_g_balance_fireball_primary_bfgdamage);
 135
 136         pointparticles(particleeffectnum("fireball_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 137
 138         proj = spawn ();
 139         proj.classname = "plasma_prim";
 140         proj.owner = proj.realowner = self;
 141         proj.bot_dodge = TRUE;
 142         proj.bot_dodgerating = autocvar_g_balance_fireball_primary_damage;
 143         proj.pushltime = time + autocvar_g_balance_fireball_primary_lifetime;
 144         proj.use = W_Fireball_Explode;
 145         proj.think = W_Fireball_Think;
 146         proj.nextthink = time;
 147         proj.health = autocvar_g_balance_fireball_primary_health;
 148         proj.team = self.team;
 149         proj.event_damage = W_Fireball_Damage;
 150         proj.takedamage = DAMAGE_YES;
 151         proj.damageforcescale = autocvar_g_balance_fireball_primary_damageforcescale;
 152         PROJECTILE_MAKETRIGGER(proj);
 153         proj.projectiledeathtype = WEP_FIREBALL;
 154         setorigin(proj, w_shotorg);
 155
 156         proj.movetype = MOVETYPE_FLY;
 157         W_SETUPPROJECTILEVELOCITY(proj, g_balance_fireball_primary);
 158         proj.angles = vectoangles(proj.velocity);
 159         proj.touch = W_Fireball_TouchExplode;
 160         setsize(proj, '-16 -16 -16', '16 16 16');
 161         proj.flags = FL_PROJECTILE;
 162
 163         CSQCProjectile(proj, TRUE, PROJECTILE_FIREBALL, TRUE);
 164
 165         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 166 }
 167
 168 void W_Fireball_AttackEffect(float i, vector f_diff)
 169 {
 170         W_SetupShot_ProjectileSize (self, '-16 -16 -16', '16 16 16', FALSE, 0, "", 0, 0);
 171         w_shotorg += f_diff_x * v_up + f_diff_y * v_right;
 172         pointparticles(particleeffectnum("fireball_preattack_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 173 }
 174
 175 void W_Fireball_Attack1_Frame4()
 176 {
 177         W_Fireball_Attack1();
 178         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_fireball_primary_animtime, w_ready);
 179 }
 180
 181 void W_Fireball_Attack1_Frame3()
 182 {
 183         W_Fireball_AttackEffect(0, '+1.25 +3.75 0');
 184         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_fireball_primary_animtime, W_Fireball_Attack1_Frame4);
 185 }
 186
 187 void W_Fireball_Attack1_Frame2()
 188 {
 189         W_Fireball_AttackEffect(0, '-1.25 +3.75 0');
 190         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_fireball_primary_animtime, W_Fireball_Attack1_Frame3);
 191 }
 192
 193 void W_Fireball_Attack1_Frame1()
 194 {
 195         W_Fireball_AttackEffect(1, '+1.25 -3.75 0');
 196         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_fireball_primary_animtime, W_Fireball_Attack1_Frame2);
 197 }
 198
 199 void W_Fireball_Attack1_Frame0()
 200 {
 201         W_Fireball_AttackEffect(0, '-1.25 -3.75 0');
 202         sound (self, CH_WEAPON_SINGLE, "weapons/fireball_prefire2.wav", VOL_BASE, ATTN_NORM);
 203         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_fireball_primary_animtime, W_Fireball_Attack1_Frame1);
 204 }
 205
 206 void W_Firemine_Think()
 207 {
 208         if(time > self.pushltime)
 209         {
 210                 remove(self);
 211                 return;
 212         }
 213
 214         // make it "hot" once it leaves its owner
 215         if(self.owner)
 216         {
 217                 if(vlen(self.origin - self.owner.origin - self.owner.view_ofs) > autocvar_g_balance_fireball_secondary_laserradius)
 218                 {
 219                         self.cnt += 1;
 220                         if(self.cnt == 3)
 221                                 self.owner = world;
 222                 }
 223                 else
 224                         self.cnt = 0;
 225         }
 226
 227         W_Fireball_LaserPlay(0.1, autocvar_g_balance_fireball_secondary_laserradius, autocvar_g_balance_fireball_secondary_laserdamage, autocvar_g_balance_fireball_secondary_laseredgedamage, autocvar_g_balance_fireball_secondary_laserburntime);
 228
 229         self.nextthink = time + 0.1;
 230 }
 231
 232 void W_Firemine_Touch (void)
 233 {
 234         PROJECTILE_TOUCH;
 235         if (other.takedamage == DAMAGE_AIM)
 236         if(Fire_AddDamage(other, self.realowner, autocvar_g_balance_fireball_secondary_damage, autocvar_g_balance_fireball_secondary_damagetime, self.projectiledeathtype | HITTYPE_HEADSHOT) >= 0)
 237         {
 238                 remove(self);
 239                 return;
 240         }
 241         self.projectiledeathtype |= HITTYPE_BOUNCE;
 242 }
 243
 244 void W_Fireball_Attack2()
 245 {
 246         entity proj;
 247         vector f_diff;
 248         float c;
 249
 250         c = mod(self.bulletcounter, 4);
 251         switch(c)
 252         {
 253                 case 0:
 254                         f_diff = '-1.25 -3.75 0';
 255                         break;
 256                 case 1:
 257                         f_diff = '+1.25 -3.75 0';
 258                         break;
 259                 case 2:
 260                         f_diff = '-1.25 +3.75 0';
 261                         break;
 262                 case 3:
 263                 default:
 264                         f_diff = '+1.25 +3.75 0';
 265                         break;
 266         }
 267         W_SetupShot_ProjectileSize(self, '-4 -4 -4', '4 4 4', FALSE, 2, "weapons/fireball_fire.wav", CH_WEAPON_A, autocvar_g_balance_fireball_secondary_damage);
 268         traceline(w_shotorg, w_shotorg + f_diff_x * v_up + f_diff_y * v_right, MOVE_NORMAL, self);
 269         w_shotorg = trace_endpos;
 270
 271         pointparticles(particleeffectnum("fireball_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 272
 273         proj = spawn ();
 274         proj.owner = proj.realowner = self;
 275         proj.classname = "grenade";
 276         proj.bot_dodge = TRUE;
 277         proj.bot_dodgerating = autocvar_g_balance_fireball_secondary_damage;
 278         proj.movetype = MOVETYPE_BOUNCE;
 279         proj.projectiledeathtype = WEP_FIREBALL | HITTYPE_SECONDARY;
 280         proj.touch = W_Firemine_Touch;
 281         PROJECTILE_MAKETRIGGER(proj);
 282         setsize(proj, '-4 -4 -4', '4 4 4');
 283         setorigin(proj, w_shotorg);
 284         proj.think = W_Firemine_Think;
 285         proj.nextthink = time;
 286         proj.damageforcescale = autocvar_g_balance_fireball_secondary_damageforcescale;
 287         proj.pushltime = time + autocvar_g_balance_fireball_secondary_lifetime;
 288         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_fireball_secondary);
 289
 290         proj.angles = vectoangles(proj.velocity);
 291         proj.flags = FL_PROJECTILE;
 292
 293         CSQCProjectile(proj, TRUE, PROJECTILE_FIREMINE, TRUE);
 294
 295         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 296 }
 297
 298 void spawnfunc_weapon_fireball (void)
 299 {
 300         weapon_defaultspawnfunc(WEP_FIREBALL);
 301 }
 302
 303 float w_fireball(float req)
 304 {
 305         //float ammo_amount;
 306         if (req == WR_AIM)
 307         {
 308                 self.BUTTON_ATCK = FALSE;
 309                 self.BUTTON_ATCK2 = FALSE;
 310                 if (self.bot_primary_fireballmooth == 0)
 311                 {
 312                         if(bot_aim(autocvar_g_balance_fireball_primary_speed, 0, autocvar_g_balance_fireball_primary_lifetime, FALSE))
 313                         {
 314                                 self.BUTTON_ATCK = TRUE;
 315                                 if(random() < 0.02) self.bot_primary_fireballmooth = 0;
 316                         }
 317                 }
 318                 else
 319                 {
 320                         if(bot_aim(autocvar_g_balance_fireball_secondary_speed, autocvar_g_balance_fireball_secondary_speed_up, autocvar_g_balance_fireball_secondary_lifetime, TRUE))
 321                         {
 322                                 self.BUTTON_ATCK2 = TRUE;
 323                                 if(random() < 0.01) self.bot_primary_fireballmooth = 1;
 324                         }
 325                 }
 326         }
 327         else if (req == WR_THINK)
 328         {
 329                 if (self.BUTTON_ATCK)
 330                 {
 331                         if (time >= self.fireball_primarytime)
 332                         if (weapon_prepareattack(0, autocvar_g_balance_fireball_primary_refire))
 333                         {
 334                                 W_Fireball_Attack1_Frame0();
 335                                 self.fireball_primarytime = time + autocvar_g_balance_fireball_primary_refire2 * W_WeaponRateFactor();
 336                         }
 337                 }
 338                 else if (self.BUTTON_ATCK2)
 339                 {
 340                         if (weapon_prepareattack(1, autocvar_g_balance_fireball_secondary_refire))
 341                         {
 342                                 W_Fireball_Attack2();
 343                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_fireball_secondary_animtime, w_ready);
 344                         }
 345                 }
 346         }
 347         else if (req == WR_PRECACHE)
 348         {
 349                 precache_model ("models/weapons/g_fireball.md3");
 350                 precache_model ("models/weapons/v_fireball.md3");
 351                 precache_model ("models/weapons/h_fireball.iqm");
 352                 precache_model ("models/sphere/sphere.md3");
 353                 precache_sound ("weapons/fireball_fire.wav");
 354                 precache_sound ("weapons/fireball_fire2.wav");
 355                 precache_sound ("weapons/fireball_prefire2.wav");
 356                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 357         }
 358         else if (req == WR_SETUP)
 359         {
 360                 weapon_setup(WEP_FIREBALL);
 361                 self.current_ammo = ammo_none;
 362         }
 363         else if (req == WR_CHECKAMMO1)
 364         {
 365                 return 1;
 366         }
 367         else if (req == WR_CHECKAMMO2)
 368         {
 369                 return 1;
 370         }
 371         else if (req == WR_RESETPLAYER)
 372         {
 373                 self.fireball_primarytime = time;
 374         }
 375         return TRUE;
 376 }
 377 #endif
 378 #ifdef CSQC
 379 float w_fireball(float req)
 380 {
 381         if(req == WR_IMPACTEFFECT)
 382         {
 383                 vector org2;
 384                 if(w_deathtype & HITTYPE_SECONDARY)
 385                 {
 386                         // firemine goes out silently
 387                 }
 388                 else
 389                 {
 390                         org2 = w_org + w_backoff * 16;
 391                         pointparticles(particleeffectnum("fireball_explode"), org2, '0 0 0', 1);
 392                         if(!w_issilent)
 393                                 sound(self, CH_SHOTS, "weapons/fireball_impact2.wav", VOL_BASE, ATTN_NORM * 0.25); // long range boom
 394                 }
 395         }
 396         else if(req == WR_PRECACHE)
 397         {
 398                 precache_sound("weapons/fireball_impact2.wav");
 399         }
 400         else if (req == WR_SUICIDEMESSAGE)
 401         {
 402                 if(w_deathtype & HITTYPE_SECONDARY)
 403                         w_deathtypestring = _("%s forgot about some firemine");
 404                 else
 405                         w_deathtypestring = _("%s should have used a smaller gun");
 406         }
 407         else if (req == WR_KILLMESSAGE)
 408         {
 409                 if(w_deathtype & HITTYPE_SECONDARY)
 410                 {
 411                         if(w_deathtype & HITTYPE_HEADSHOT)
 412                                 w_deathtypestring = _("%s tried to catch %s's firemine");
 413                         else
 414                                 w_deathtypestring = _("%s fatefully ignored %s's firemine");
 415                 }
 416                 else
 417                 {
 418                         if(w_deathtype & HITTYPE_BOUNCE)
 419                         {
 420                                 if(w_deathtype & HITTYPE_SPLASH) // BFG effect
 421                                         w_deathtypestring = _("%s could not hide from %s's fireball");
 422                                 else // laser
 423                                         w_deathtypestring = _("%s saw the pretty lights of %s's fireball");
 424                         }
 425                         else if(w_deathtype & HITTYPE_SPLASH)
 426                                 w_deathtypestring = _("%s got too close to %s's fireball");
 427                         else
 428                                 w_deathtypestring = _("%s tasted %s's fireball");
 429                 }
 430         }
 431         return TRUE;
 432 }
 433 #endif
 434 #endif