qcsrc/server/w_fireball.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(FIREBALL, w_fireball, IT_FUEL, 9, WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "fireball", "fireball", _("Fireball"));
   3 #else
   4 #ifdef SVQC
   5 .float bot_primary_fireballmooth; // whatever a mooth is
   6 .vector fireball_impactvec;
   7 .float fireball_primarytime;
   8
   9 void W_Fireball_Explode (void)
  10 {
  11         entity e;
  12         float dist;
  13         float points;
  14         vector dir;
  15         float d;
  16
  17         self.event_damage = SUB_Null;
  18         self.takedamage = DAMAGE_NO;
  19
  20         // 1. dist damage
  21         d = (self.realowner.health + self.realowner.armorvalue);
  22         RadiusDamage (self, self.realowner, autocvar_g_balance_fireball_primary_damage, autocvar_g_balance_fireball_primary_edgedamage, autocvar_g_balance_fireball_primary_radius, world, autocvar_g_balance_fireball_primary_force, self.projectiledeathtype, other);
  23         if(self.realowner.health + self.realowner.armorvalue >= d)
  24         if(!self.cnt)
  25         {
  26                 modeleffect_spawn("models/sphere/sphere.md3", 0, 0, self.origin, '0 0 0', '0 0 0', '0 0 0', 0, autocvar_g_balance_fireball_primary_bfgradius, 0.2, 0.05, 0.25);
  27
  28                 // 2. bfg effect
  29                 // NOTE: this cannot be made warpzone aware by design. So, better intentionally ignore warpzones here.
  30                 for(e = findradius(self.origin, autocvar_g_balance_fireball_primary_bfgradius); e; e = e.chain)
  31                 if(e != self.realowner) if(e.takedamage == DAMAGE_AIM) if(e.classname != "player" || !self.realowner || IsDifferentTeam(e, self))
  32                 {
  33                         // can we see fireball?
  34                         traceline(e.origin + e.view_ofs, self.origin, MOVE_NORMAL, e);
  35                         if(/* trace_startsolid || */ trace_fraction != 1) // startsolid should be never happening anyway
  36                                 continue;
  37                         // can we see player who shot fireball?
  38                         traceline(e.origin + e.view_ofs, self.realowner.origin + self.realowner.view_ofs, MOVE_NORMAL, e);
  39                         if(trace_ent != self.realowner)
  40                         if(/* trace_startsolid || */ trace_fraction != 1)
  41                                 continue;
  42                         dist = vlen(self.origin - e.origin - e.view_ofs);
  43                         points = (1 - sqrt(dist / autocvar_g_balance_fireball_primary_bfgradius));
  44                         if(points <= 0)
  45                                 continue;
  46                         dir = normalize(e.origin + e.view_ofs - self.origin);
  47
  48                         if(accuracy_isgooddamage(self.realowner, e))
  49                                 accuracy_add(self.realowner, WEP_FIREBALL, 0, autocvar_g_balance_fireball_primary_bfgdamage * points);
  50
  51                         Damage(e, self, self.realowner, autocvar_g_balance_fireball_primary_bfgdamage * points, self.projectiledeathtype | HITTYPE_BOUNCE | HITTYPE_SPLASH, e.origin + e.view_ofs, autocvar_g_balance_fireball_primary_bfgforce * dir);
  52                         pointparticles(particleeffectnum("fireball_bfgdamage"), e.origin, -1 * dir, 1);
  53                 }
  54         }
  55
  56         remove (self);
  57 }
  58
  59 void W_Fireball_TouchExplode (void)
  60 {
  61         PROJECTILE_TOUCH;
  62         W_Fireball_Explode ();
  63 }
  64
  65 void W_Fireball_LaserPlay(float dt, float dist, float damage, float edgedamage, float burntime)
  66 {
  67         entity e;
  68         float d;
  69         vector p;
  70
  71         if(damage <= 0)
  72                 return;
  73
  74         RandomSelection_Init();
  75         for(e = WarpZone_FindRadius(self.origin, dist, TRUE); e; e = e.chain)
  76         if(e != self.realowner) if(e.takedamage == DAMAGE_AIM) if(e.classname != "player" || !self.realowner || IsDifferentTeam(e, self))
  77         {
  78                 p = e.origin;
  79                 p_x += e.mins_x + random() * (e.maxs_x - e.mins_x);
  80                 p_y += e.mins_y + random() * (e.maxs_y - e.mins_y);
  81                 p_z += e.mins_z + random() * (e.maxs_z - e.mins_z);
  82                 d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
  83                 if(d < dist)
  84                 {
  85                         e.fireball_impactvec = p;
  86                         RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
  87                 }
  88         }
  89         if(RandomSelection_chosen_ent)
  90         {
  91                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
  92                 d = damage + (edgedamage - damage) * (d / dist);
  93                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
  94                 //trailparticles(self, particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
  95                 pointparticles(particleeffectnum("fireball_laser"), self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
  96         }
  97 }
  98
  99 void W_Fireball_Think()
 100 {
 101         if(time > self.pushltime)
 102         {
 103                 self.cnt = 1;
 104                 self.projectiledeathtype |= HITTYPE_SPLASH;
 105                 W_Fireball_Explode();
 106                 return;
 107         }
 108
 109         W_Fireball_LaserPlay(0.1, autocvar_g_balance_fireball_primary_laserradius, autocvar_g_balance_fireball_primary_laserdamage, autocvar_g_balance_fireball_primary_laseredgedamage, autocvar_g_balance_fireball_primary_laserburntime);
 110
 111         self.nextthink = time + 0.1;
 112 }
 113
 114 void W_Fireball_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 115 {
 116         if(self.health <= 0)
 117                 return;
 118         self.health = self.health - damage;
 119         if (self.health <= 0)
 120         {
 121                 self.cnt = 1;
 122                 W_PrepareExplosionByDamage(attacker, W_Fireball_Explode);
 123         }
 124 }
 125
 126 void W_Fireball_Attack1()
 127 {
 128         local entity proj;
 129
 130         W_SetupShot_ProjectileSize (self, '-16 -16 -16', '16 16 16', FALSE, 2, "weapons/fireball_fire2.wav", CH_WEAPON_A, autocvar_g_balance_fireball_primary_damage + autocvar_g_balance_fireball_primary_bfgdamage);
 131
 132         pointparticles(particleeffectnum("fireball_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 133
 134         proj = spawn ();
 135         proj.classname = "plasma_prim";
 136         proj.owner = proj.realowner = self;
 137         proj.bot_dodge = TRUE;
 138         proj.bot_dodgerating = autocvar_g_balance_fireball_primary_damage;
 139         proj.pushltime = time + autocvar_g_balance_fireball_primary_lifetime;
 140         proj.use = W_Fireball_Explode;
 141         proj.think = W_Fireball_Think;
 142         proj.nextthink = time;
 143         proj.health = autocvar_g_balance_fireball_primary_health;
 144         proj.team = self.team;
 145         proj.event_damage = W_Fireball_Damage;
 146         proj.takedamage = DAMAGE_YES;
 147         proj.damageforcescale = autocvar_g_balance_fireball_primary_damageforcescale;
 148         PROJECTILE_MAKETRIGGER(proj);
 149         proj.projectiledeathtype = WEP_FIREBALL;
 150         setorigin(proj, w_shotorg);
 151
 152         proj.movetype = MOVETYPE_FLY;
 153         W_SETUPPROJECTILEVELOCITY(proj, g_balance_fireball_primary);
 154         proj.angles = vectoangles(proj.velocity);
 155         proj.touch = W_Fireball_TouchExplode;
 156         setsize(proj, '-16 -16 -16', '16 16 16');
 157         proj.flags = FL_PROJECTILE;
 158
 159         CSQCProjectile(proj, TRUE, PROJECTILE_FIREBALL, TRUE);
 160
 161         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 162 }
 163
 164 void W_Fireball_AttackEffect(float i, vector f_diff)
 165 {
 166         W_SetupShot_ProjectileSize (self, '-16 -16 -16', '16 16 16', FALSE, 0, "", 0, 0);
 167         w_shotorg += f_diff_x * v_up + f_diff_y * v_right;
 168         pointparticles(particleeffectnum("fireball_preattack_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 169 }
 170
 171 void W_Fireball_Attack1_Frame4()
 172 {
 173         W_Fireball_Attack1();
 174         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_fireball_primary_animtime, w_ready);
 175 }
 176
 177 void W_Fireball_Attack1_Frame3()
 178 {
 179         W_Fireball_AttackEffect(0, '+1.25 +3.75 0');
 180         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_fireball_primary_animtime, W_Fireball_Attack1_Frame4);
 181 }
 182
 183 void W_Fireball_Attack1_Frame2()
 184 {
 185         W_Fireball_AttackEffect(0, '-1.25 +3.75 0');
 186         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_fireball_primary_animtime, W_Fireball_Attack1_Frame3);
 187 }
 188
 189 void W_Fireball_Attack1_Frame1()
 190 {
 191         W_Fireball_AttackEffect(1, '+1.25 -3.75 0');
 192         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_fireball_primary_animtime, W_Fireball_Attack1_Frame2);
 193 }
 194
 195 void W_Fireball_Attack1_Frame0()
 196 {
 197         W_DecreaseAmmo(ammo_fuel, autocvar_g_balance_fireball_primary_ammo, autocvar_g_balance_fireball_reload_ammo);
 198
 199         W_Fireball_AttackEffect(0, '-1.25 -3.75 0');
 200         sound (self, CH_WEAPON_SINGLE, "weapons/fireball_prefire2.wav", VOL_BASE, ATTN_NORM);
 201         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_fireball_primary_animtime, W_Fireball_Attack1_Frame1);
 202 }
 203
 204 void W_Firemine_Think()
 205 {
 206         if(time > self.pushltime)
 207         {
 208                 remove(self);
 209                 return;
 210         }
 211
 212         // make it "hot" once it leaves its owner
 213         if(self.owner)
 214         {
 215                 if(vlen(self.origin - self.owner.origin - self.owner.view_ofs) > autocvar_g_balance_fireball_secondary_laserradius)
 216                 {
 217                         self.cnt += 1;
 218                         if(self.cnt == 3)
 219                                 self.owner = world;
 220                 }
 221                 else
 222                         self.cnt = 0;
 223         }
 224
 225         W_Fireball_LaserPlay(0.1, autocvar_g_balance_fireball_secondary_laserradius, autocvar_g_balance_fireball_secondary_laserdamage, autocvar_g_balance_fireball_secondary_laseredgedamage, autocvar_g_balance_fireball_secondary_laserburntime);
 226
 227         self.nextthink = time + 0.1;
 228 }
 229
 230 void W_Firemine_Touch (void)
 231 {
 232         PROJECTILE_TOUCH;
 233         if (other.takedamage == DAMAGE_AIM)
 234         if(Fire_AddDamage(other, self.realowner, autocvar_g_balance_fireball_secondary_damage, autocvar_g_balance_fireball_secondary_damagetime, self.projectiledeathtype | HITTYPE_HEADSHOT) >= 0)
 235         {
 236                 remove(self);
 237                 return;
 238         }
 239         self.projectiledeathtype |= HITTYPE_BOUNCE;
 240 }
 241
 242 void W_Fireball_Attack2()
 243 {
 244         local entity proj;
 245         vector f_diff;
 246         float c;
 247
 248         W_DecreaseAmmo(ammo_fuel, autocvar_g_balance_fireball_secondary_ammo, autocvar_g_balance_fireball_reload_ammo);
 249
 250         c = mod(self.bulletcounter, 4);
 251         switch(c)
 252         {
 253                 case 0:
 254                         f_diff = '-1.25 -3.75 0';
 255                         break;
 256                 case 1:
 257                         f_diff = '+1.25 -3.75 0';
 258                         break;
 259                 case 2:
 260                         f_diff = '-1.25 +3.75 0';
 261                         break;
 262                 case 3:
 263                 default:
 264                         f_diff = '+1.25 +3.75 0';
 265                         break;
 266         }
 267         W_SetupShot_ProjectileSize(self, '-4 -4 -4', '4 4 4', FALSE, 2, "weapons/fireball_fire.wav", CH_WEAPON_A, autocvar_g_balance_fireball_secondary_damage);
 268         traceline(w_shotorg, w_shotorg + f_diff_x * v_up + f_diff_y * v_right, MOVE_NORMAL, self);
 269         w_shotorg = trace_endpos;
 270
 271         pointparticles(particleeffectnum("fireball_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 272
 273         proj = spawn ();
 274         proj.owner = proj.realowner = self;
 275         proj.classname = "grenade";
 276         proj.bot_dodge = TRUE;
 277         proj.bot_dodgerating = autocvar_g_balance_fireball_secondary_damage;
 278         proj.movetype = MOVETYPE_BOUNCE;
 279         proj.projectiledeathtype = WEP_FIREBALL | HITTYPE_SECONDARY;
 280         proj.touch = W_Firemine_Touch;
 281         PROJECTILE_MAKETRIGGER(proj);
 282         setsize(proj, '-4 -4 -4', '4 4 4');
 283         setorigin(proj, w_shotorg);
 284         proj.think = W_Firemine_Think;
 285         proj.nextthink = time;
 286         proj.damageforcescale = autocvar_g_balance_fireball_secondary_damageforcescale;
 287         proj.pushltime = time + autocvar_g_balance_fireball_secondary_lifetime;
 288         W_SETUPPROJECTILEVELOCITY_UP(proj, g_balance_fireball_secondary);
 289
 290         proj.angles = vectoangles(proj.velocity);
 291         proj.flags = FL_PROJECTILE;
 292
 293         CSQCProjectile(proj, TRUE, PROJECTILE_FIREMINE, TRUE);
 294
 295         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 296 }
 297
 298 void spawnfunc_weapon_fireball (void)
 299 {
 300         weapon_defaultspawnfunc(WEP_FIREBALL);
 301 }
 302
 303 float w_fireball(float req)
 304 {
 305         float ammo_amount;
 306         if (req == WR_AIM)
 307         {
 308                 self.BUTTON_ATCK = FALSE;
 309                 self.BUTTON_ATCK2 = FALSE;
 310                 if (self.bot_primary_fireballmooth == 0)
 311                 {
 312                         if(bot_aim(autocvar_g_balance_fireball_primary_speed, 0, autocvar_g_balance_fireball_primary_lifetime, FALSE))
 313                         {
 314                                 self.BUTTON_ATCK = TRUE;
 315                                 if(random() < 0.02) self.bot_primary_fireballmooth = 0;
 316                         }
 317                 }
 318                 else
 319                 {
 320                         if(bot_aim(autocvar_g_balance_fireball_secondary_speed, autocvar_g_balance_fireball_secondary_speed_up, autocvar_g_balance_fireball_secondary_lifetime, TRUE))
 321                         {
 322                                 self.BUTTON_ATCK2 = TRUE;
 323                                 if(random() < 0.01) self.bot_primary_fireballmooth = 1;
 324                         }
 325                 }
 326         }
 327         else if (req == WR_THINK)
 328         {
 329                 if(autocvar_g_balance_fireball_reload_ammo && self.clip_load < min(autocvar_g_balance_fireball_primary_ammo, autocvar_g_balance_fireball_secondary_ammo)) // forced reload
 330                         weapon_action(self.weapon, WR_RELOAD);
 331                 else if (self.BUTTON_ATCK)
 332                 {
 333                         if (time >= self.fireball_primarytime)
 334                         if (weapon_prepareattack(0, autocvar_g_balance_fireball_primary_refire))
 335                         {
 336                                 W_Fireball_Attack1_Frame0();
 337                                 self.fireball_primarytime = time + autocvar_g_balance_fireball_primary_refire2 * W_WeaponRateFactor();
 338                         }
 339                 }
 340                 else if (self.BUTTON_ATCK2)
 341                 {
 342                         if (weapon_prepareattack(1, autocvar_g_balance_fireball_secondary_refire))
 343                         {
 344                                 W_Fireball_Attack2();
 345                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_fireball_secondary_animtime, w_ready);
 346                         }
 347                 }
 348         }
 349         else if (req == WR_PRECACHE)
 350         {
 351                 precache_model ("models/weapons/g_fireball.md3");
 352                 precache_model ("models/weapons/v_fireball.md3");
 353                 precache_model ("models/weapons/h_fireball.iqm");
 354                 precache_model ("models/sphere/sphere.md3");
 355                 precache_sound ("weapons/fireball_fire.wav");
 356                 precache_sound ("weapons/fireball_fire2.wav");
 357                 precache_sound ("weapons/fireball_prefire2.wav");
 358                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 359         }
 360         else if (req == WR_SETUP)
 361         {
 362                 weapon_setup(WEP_FIREBALL);
 363                 self.current_ammo = ammo_fuel;
 364         }
 365         else if (req == WR_CHECKAMMO1)
 366         {
 367                 ammo_amount = self.ammo_fuel >= autocvar_g_balance_fireball_primary_ammo;
 368                 ammo_amount += self.(weapon_load[WEP_FIREBALL]) >= autocvar_g_balance_fireball_primary_ammo;
 369                 return ammo_amount;
 370         }
 371         else if (req == WR_CHECKAMMO2)
 372         {
 373                 ammo_amount = self.ammo_fuel >= autocvar_g_balance_fireball_secondary_ammo;
 374                 ammo_amount += self.(weapon_load[WEP_FIREBALL]) >= autocvar_g_balance_fireball_secondary_ammo;
 375                 return ammo_amount;
 376         }
 377         else if (req == WR_RESETPLAYER)
 378         {
 379                 self.fireball_primarytime = time;
 380         }
 381         else if (req == WR_RELOAD)
 382         {
 383                 // fuel can be a non-whole number, which brakes stuff here when between 0 and 1
 384                 if(self.ammo_fuel < 1)
 385                         self.ammo_fuel = 0;
 386
 387                 W_Reload(min(autocvar_g_balance_fireball_primary_ammo, autocvar_g_balance_fireball_secondary_ammo), autocvar_g_balance_fireball_reload_ammo, autocvar_g_balance_fireball_reload_time, "weapons/reload.wav");
 388         }
 389         return TRUE;
 390 };
 391 #endif
 392 #ifdef CSQC
 393 float w_fireball(float req)
 394 {
 395         if(req == WR_IMPACTEFFECT)
 396         {
 397                 vector org2;
 398                 if(w_deathtype & HITTYPE_SECONDARY)
 399                 {
 400                         // firemine goes out silently
 401                 }
 402                 else
 403                 {
 404                         org2 = w_org + w_backoff * 16;
 405                         pointparticles(particleeffectnum("fireball_explode"), org2, '0 0 0', 1);
 406                         if(!w_issilent)
 407                                 sound(self, CH_SHOTS, "weapons/fireball_impact2.wav", VOL_BASE, ATTN_NORM * 0.25); // long range boom
 408                 }
 409         }
 410         else if(req == WR_PRECACHE)
 411         {
 412                 precache_sound("weapons/fireball_impact2.wav");
 413         }
 414         else if (req == WR_SUICIDEMESSAGE)
 415         {
 416                 if(w_deathtype & HITTYPE_SECONDARY)
 417                         w_deathtypestring = _("%s forgot about some firemine");
 418                 else
 419                         w_deathtypestring = _("%s should have used a smaller gun");
 420         }
 421         else if (req == WR_KILLMESSAGE)
 422         {
 423                 if(w_deathtype & HITTYPE_SECONDARY)
 424                 {
 425                         if(w_deathtype & HITTYPE_HEADSHOT)
 426                                 w_deathtypestring = _("%s tried to catch %s's firemine");
 427                         else
 428                                 w_deathtypestring = _("%s fatefully ignored %s's firemine");
 429                 }
 430                 else
 431                 {
 432                         if(w_deathtype & HITTYPE_BOUNCE)
 433                         {
 434                                 if(w_deathtype & HITTYPE_SPLASH) // BFG effect
 435                                         w_deathtypestring = _("%s could not hide from %s's fireball");
 436                                 else // laser
 437                                         w_deathtypestring = _("%s saw the pretty lights of %s's fireball");
 438                         }
 439                         else if(w_deathtype & HITTYPE_SPLASH)
 440                                 w_deathtypestring = _("%s got too close to %s's fireball");
 441                         else
 442                                 w_deathtypestring = _("%s tasted %s's fireball");
 443                 }
 444         }
 445         return TRUE;
 446 }
 447 #endif
 448 #endif