qcsrc/server/w_grenadelauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(GRENADE_LAUNCHER, w_glauncher, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "gl", "grenadelauncher", _("Mortar"))
   3 #else
   4 #ifdef SVQC
   5 .float gl_detonate_later;
   6 .float gl_bouncecnt;
   7
   8 void W_Grenade_Explode (void)
   9 {
  10         if(other.takedamage == DAMAGE_AIM)
  11                 if(other.classname == "player")
  12                         if(IsDifferentTeam(self.realowner, other))
  13                                 if(other.deadflag == DEAD_NO)
  14                                         if(IsFlying(other))
  15                                                 AnnounceTo(self.realowner, "airshot");
  16
  17         self.event_damage = SUB_Null;
  18         self.takedamage = DAMAGE_NO;
  19
  20         if(self.movetype == MOVETYPE_NONE)
  21                 self.velocity = self.oldvelocity;
  22
  23         RadiusDamage (self, self.realowner, autocvar_g_balance_grenadelauncher_primary_damage, autocvar_g_balance_grenadelauncher_primary_edgedamage, autocvar_g_balance_grenadelauncher_primary_radius, world, autocvar_g_balance_grenadelauncher_primary_force, self.projectiledeathtype, other);
  24
  25         remove (self);
  26 }
  27
  28 void W_Grenade_Explode2 (void)
  29 {
  30         if(other.takedamage == DAMAGE_AIM)
  31                 if(other.classname == "player")
  32                         if(IsDifferentTeam(self.realowner, other))
  33                                 if(other.deadflag == DEAD_NO)
  34                                         if(IsFlying(other))
  35                                                 AnnounceTo(self.realowner, "airshot");
  36
  37         self.event_damage = SUB_Null;
  38         self.takedamage = DAMAGE_NO;
  39
  40         if(self.movetype == MOVETYPE_NONE)
  41                 self.velocity = self.oldvelocity;
  42
  43         RadiusDamage (self, self.realowner, autocvar_g_balance_grenadelauncher_secondary_damage, autocvar_g_balance_grenadelauncher_secondary_edgedamage, autocvar_g_balance_grenadelauncher_secondary_radius, world, autocvar_g_balance_grenadelauncher_secondary_force, self.projectiledeathtype, other);
  44
  45         remove (self);
  46 }
  47
  48 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  49 {
  50         if (self.health <= 0)
  51                 return;
  52
  53         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
  54                 return; // g_projectiles_damage says to halt
  55
  56         self.health = self.health - damage;
  57
  58         print(strcat("grenade health ", ftos(self.health), " after ", ftos(damage), " damage... (at time: ", ftos(time), ")\n"));
  59
  60         if (self.health <= 0)
  61                 W_PrepareExplosionByDamage(attacker, self.use);
  62 }
  63
  64 void W_Grenade_Think1 (void)
  65 {
  66         self.nextthink = time;
  67         if (time > self.cnt)
  68         {
  69                 other = world;
  70                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  71                 W_Grenade_Explode ();
  72                 return;
  73         }
  74         if(self.gl_detonate_later && self.gl_bouncecnt >= autocvar_g_balance_grenadelauncher_primary_remote_minbouncecnt)
  75                 W_Grenade_Explode();
  76 }
  77
  78 void W_Grenade_Touch1 (void)
  79 {
  80         PROJECTILE_TOUCH;
  81         if (other.takedamage == DAMAGE_AIM || autocvar_g_balance_grenadelauncher_primary_type == 0) // always explode when hitting a player, or if normal mortar projectile
  82         {
  83                 self.use ();
  84         }
  85         else if (autocvar_g_balance_grenadelauncher_primary_type == 1) // bounce
  86         {
  87                 float r;
  88                 r = random() * 6;
  89                 if(r < 1)
  90                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
  91                 else if(r < 2)
  92                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
  93                 else if(r < 3)
  94                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
  95                 else if(r < 4)
  96                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
  97                 else if(r < 5)
  98                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
  99                 else
 100                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
 101                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 102                 self.gl_bouncecnt += 1;
 103         }
 104         else if(autocvar_g_balance_grenadelauncher_primary_type == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 105         {
 106                 spamsound (self, CH_SHOTS, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
 107
 108                 // let it stick whereever it is
 109                 self.oldvelocity = self.velocity;
 110                 self.velocity = '0 0 0';
 111                 self.movetype = MOVETYPE_NONE; // also disables gravity
 112                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 113                 UpdateCSQCProjectile(self);
 114
 115                 // do not respond to any more touches
 116                 self.solid = SOLID_NOT;
 117
 118                 self.nextthink = min(self.nextthink, time + autocvar_g_balance_grenadelauncher_primary_lifetime_stick);
 119         }
 120 }
 121
 122 void W_Grenade_Touch2 (void)
 123 {
 124         PROJECTILE_TOUCH;
 125         if (other.takedamage == DAMAGE_AIM || autocvar_g_balance_grenadelauncher_secondary_type == 0) // always explode when hitting a player, or if normal mortar projectile
 126         {
 127                 self.use ();
 128         }
 129         else if (autocvar_g_balance_grenadelauncher_secondary_type == 1) // bounce
 130         {
 131                 float r;
 132                 r = random() * 6;
 133                 if(r < 1)
 134                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
 135                 else if(r < 2)
 136                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
 137                 else if(r < 3)
 138                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
 139                 else if(r < 4)
 140                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
 141                 else if(r < 5)
 142                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
 143                 else
 144                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
 145                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 146                 self.gl_bouncecnt += 1;
 147
 148                 if (autocvar_g_balance_grenadelauncher_secondary_lifetime_bounce && self.gl_bouncecnt == 1)
 149                         self.nextthink = time + autocvar_g_balance_grenadelauncher_secondary_lifetime_bounce;
 150
 151         }
 152         else if(autocvar_g_balance_grenadelauncher_secondary_type == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 153         {
 154                 spamsound (self, CH_SHOTS, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
 155
 156                 // let it stick whereever it is
 157                 self.oldvelocity = self.velocity;
 158                 self.velocity = '0 0 0';
 159                 self.movetype = MOVETYPE_NONE; // also disables gravity
 160                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 161                 UpdateCSQCProjectile(self);
 162
 163                 // do not respond to any more touches
 164                 self.solid = SOLID_NOT;
 165
 166                 self.nextthink = min(self.nextthink, time + autocvar_g_balance_grenadelauncher_secondary_lifetime_stick);
 167         }
 168 }
 169
 170 void W_Grenade_Attack (void)
 171 {
 172         local entity gren;
 173
 174         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_grenadelauncher_primary_ammo, autocvar_g_balance_grenadelauncher_reload_ammo);
 175
 176         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CH_WEAPON_A, autocvar_g_balance_grenadelauncher_primary_damage);
 177         w_shotdir = v_forward; // no TrueAim for grenades please
 178
 179         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 180
 181         gren = spawn ();
 182         gren.owner = gren.realowner = self;
 183         gren.classname = "grenade";
 184         gren.bot_dodge = TRUE;
 185         gren.bot_dodgerating = autocvar_g_balance_grenadelauncher_primary_damage;
 186         gren.movetype = MOVETYPE_BOUNCE;
 187         gren.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 188         gren.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 189         PROJECTILE_MAKETRIGGER(gren);
 190         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER;
 191         setorigin(gren, w_shotorg);
 192         setsize(gren, '-3 -3 -3', '3 3 3');
 193
 194         gren.cnt = time + autocvar_g_balance_grenadelauncher_primary_lifetime;
 195         gren.nextthink = time;
 196         gren.think = W_Grenade_Think1;
 197         gren.use = W_Grenade_Explode;
 198         gren.touch = W_Grenade_Touch1;
 199
 200         gren.takedamage = DAMAGE_YES;
 201         gren.health = autocvar_g_balance_grenadelauncher_primary_health;
 202         gren.damageforcescale = autocvar_g_balance_grenadelauncher_primary_damageforcescale;
 203         gren.event_damage = W_Grenade_Damage;
 204         gren.damagedbycontents = TRUE;
 205         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_primary);
 206
 207         gren.angles = vectoangles (gren.velocity);
 208         gren.flags = FL_PROJECTILE;
 209
 210         if(autocvar_g_balance_grenadelauncher_primary_type == 0 || autocvar_g_balance_grenadelauncher_primary_type == 2)
 211                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 212         else
 213                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 214
 215         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 216 }
 217
 218 void W_Grenade_Attack2 (void)
 219 {
 220         local entity gren;
 221
 222         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_grenadelauncher_secondary_ammo, autocvar_g_balance_grenadelauncher_reload_ammo);
 223
 224         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CH_WEAPON_A, autocvar_g_balance_grenadelauncher_secondary_damage);
 225         w_shotdir = v_forward; // no TrueAim for grenades please
 226
 227         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 228
 229         gren = spawn ();
 230         gren.owner = gren.realowner = self;
 231         gren.classname = "grenade";
 232         gren.bot_dodge = TRUE;
 233         gren.bot_dodgerating = autocvar_g_balance_grenadelauncher_secondary_damage;
 234         gren.movetype = MOVETYPE_BOUNCE;
 235         gren.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 236         gren.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 237         PROJECTILE_MAKETRIGGER(gren);
 238         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER | HITTYPE_SECONDARY;
 239         setorigin(gren, w_shotorg);
 240         setsize(gren, '-3 -3 -3', '3 3 3');
 241
 242         gren.nextthink = time + autocvar_g_balance_grenadelauncher_secondary_lifetime;
 243         gren.think = adaptor_think2use_hittype_splash;
 244         gren.use = W_Grenade_Explode2;
 245         gren.touch = W_Grenade_Touch2;
 246
 247         gren.takedamage = DAMAGE_YES;
 248         gren.health = autocvar_g_balance_grenadelauncher_secondary_health;
 249         gren.damageforcescale = autocvar_g_balance_grenadelauncher_secondary_damageforcescale;
 250         gren.event_damage = W_Grenade_Damage;
 251         gren.damagedbycontents = TRUE;
 252         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_secondary);
 253
 254         gren.angles = vectoangles (gren.velocity);
 255         gren.flags = FL_PROJECTILE;
 256
 257         if(autocvar_g_balance_grenadelauncher_secondary_type == 0 || autocvar_g_balance_grenadelauncher_secondary_type == 2)
 258                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 259         else
 260                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 261
 262         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 263 }
 264
 265 void spawnfunc_weapon_grenadelauncher (void)
 266 {
 267         weapon_defaultspawnfunc(WEP_GRENADE_LAUNCHER);
 268 }
 269
 270 .float bot_secondary_grenademooth;
 271 float w_glauncher(float req)
 272 {
 273         entity nade;
 274         float nadefound;
 275         float ammo_amount;
 276
 277         if (req == WR_AIM)
 278         {
 279                 self.BUTTON_ATCK = FALSE;
 280                 self.BUTTON_ATCK2 = FALSE;
 281                 if (self.bot_secondary_grenademooth == 0)
 282                 {
 283                         if(bot_aim(autocvar_g_balance_grenadelauncher_primary_speed, autocvar_g_balance_grenadelauncher_primary_speed_up, autocvar_g_balance_grenadelauncher_primary_lifetime, TRUE))
 284                         {
 285                                 self.BUTTON_ATCK = TRUE;
 286                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 287                         }
 288                 }
 289                 else
 290                 {
 291                         if(bot_aim(autocvar_g_balance_grenadelauncher_secondary_speed, autocvar_g_balance_grenadelauncher_secondary_speed_up, autocvar_g_balance_grenadelauncher_secondary_lifetime, TRUE))
 292                         {
 293                                 self.BUTTON_ATCK2 = TRUE;
 294                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 295                         }
 296                 }
 297         }
 298         else if (req == WR_THINK)
 299         {
 300                 if(autocvar_g_balance_grenadelauncher_reload_ammo && self.clip_load < min(autocvar_g_balance_grenadelauncher_primary_ammo, autocvar_g_balance_grenadelauncher_secondary_ammo)) // forced reload
 301                         weapon_action(self.weapon, WR_RELOAD);
 302                 else if (self.BUTTON_ATCK)
 303                 {
 304                         if (weapon_prepareattack(0, autocvar_g_balance_grenadelauncher_primary_refire))
 305                         {
 306                                 W_Grenade_Attack();
 307                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_grenadelauncher_primary_animtime, w_ready);
 308                         }
 309                 }
 310                 else if (self.BUTTON_ATCK2)
 311                 {
 312                         if (cvar("g_balance_grenadelauncher_secondary_remote_detonateprimary"))
 313                         {
 314                                 nadefound = 0;
 315                                 for(nade = world; (nade = find(nade, classname, "grenade")); ) if(nade.realowner == self)
 316                                 {
 317                                         if(!nade.gl_detonate_later)
 318                                         {
 319                                                 nade.gl_detonate_later = TRUE;
 320                                                 nadefound = 1;
 321                                         }
 322                                 }
 323                                 if(nadefound)
 324                                         sound (self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 325                         }
 326                         else if (weapon_prepareattack(1, autocvar_g_balance_grenadelauncher_secondary_refire))
 327                         {
 328                                 W_Grenade_Attack2();
 329                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_grenadelauncher_secondary_animtime, w_ready);
 330                         }
 331                 }
 332         }
 333         else if (req == WR_PRECACHE)
 334         {
 335                 precache_model ("models/weapons/g_gl.md3");
 336                 precache_model ("models/weapons/v_gl.md3");
 337                 precache_model ("models/weapons/h_gl.iqm");
 338                 precache_sound ("weapons/grenade_bounce1.wav");
 339                 precache_sound ("weapons/grenade_bounce2.wav");
 340                 precache_sound ("weapons/grenade_bounce3.wav");
 341                 precache_sound ("weapons/grenade_bounce4.wav");
 342                 precache_sound ("weapons/grenade_bounce5.wav");
 343                 precache_sound ("weapons/grenade_bounce6.wav");
 344                 precache_sound ("weapons/grenade_stick.wav");
 345                 precache_sound ("weapons/grenade_fire.wav");
 346                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 347         }
 348         else if (req == WR_SETUP)
 349         {
 350                 weapon_setup(WEP_GRENADE_LAUNCHER);
 351                 self.current_ammo = ammo_rockets;
 352         }
 353         else if (req == WR_CHECKAMMO1)
 354         {
 355                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_grenadelauncher_primary_ammo;
 356                 ammo_amount += self.weapon_load[WEP_GRENADE_LAUNCHER] >= autocvar_g_balance_grenadelauncher_primary_ammo;
 357                 return ammo_amount;
 358         }
 359         else if (req == WR_CHECKAMMO2)
 360         {
 361                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_grenadelauncher_secondary_ammo;
 362                 ammo_amount += self.weapon_load[WEP_GRENADE_LAUNCHER] >= autocvar_g_balance_grenadelauncher_secondary_ammo;
 363                 return ammo_amount;
 364         }
 365         else if (req == WR_RELOAD)
 366         {
 367                 W_Reload(min(autocvar_g_balance_grenadelauncher_primary_ammo, autocvar_g_balance_grenadelauncher_secondary_ammo), autocvar_g_balance_grenadelauncher_reload_ammo, autocvar_g_balance_grenadelauncher_reload_time, "weapons/reload.wav");
 368         }
 369         return TRUE;
 370 };
 371 #endif
 372 #ifdef CSQC
 373 float w_glauncher(float req)
 374 {
 375         if(req == WR_IMPACTEFFECT)
 376         {
 377                 vector org2;
 378                 org2 = w_org + w_backoff * 12;
 379                 pointparticles(particleeffectnum("grenade_explode"), org2, '0 0 0', 1);
 380                 if(!w_issilent)
 381                         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 382         }
 383         else if(req == WR_PRECACHE)
 384         {
 385                 precache_sound("weapons/grenade_impact.wav");
 386         }
 387         else if (req == WR_SUICIDEMESSAGE)
 388         {
 389                 if(w_deathtype & HITTYPE_SECONDARY)
 390                         w_deathtypestring = _("%s tried out his own grenade");
 391                 else
 392                         w_deathtypestring = _("%s detonated");
 393         }
 394         else if (req == WR_KILLMESSAGE)
 395         {
 396                 if(w_deathtype & HITTYPE_SPLASH)
 397                         if(w_deathtype & HITTYPE_BOUNCE) // (must be secondary then)
 398                                 w_deathtypestring = _("%s didn't see %s's grenade");
 399                         else // unchecked: SECONDARY
 400                                 w_deathtypestring = _("%s almost dodged %s's grenade");
 401                 else // unchecked: SECONDARY, BOUNCE
 402                         w_deathtypestring = _("%s ate %s's grenade");
 403         }
 404         return TRUE;
 405 }
 406 #endif
 407 #endif