qcsrc/server/w_grenadelauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(GRENADE_LAUNCHER, w_glauncher, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "gl", "grenadelauncher", _("Mortar"))
   3 #else
   4 #ifdef SVQC
   5 .float gl_detonate_later;
   6 .float gl_bouncecnt;
   7
   8 void W_Grenade_Explode (void)
   9 {
  10         if(other.takedamage == DAMAGE_AIM)
  11                 if(other.classname == "player")
  12                         if(IsDifferentTeam(self.realowner, other))
  13                                 if(other.deadflag == DEAD_NO)
  14                                         if(IsFlying(other))
  15                                                 AnnounceTo(self.realowner, "airshot");
  16
  17         self.event_damage = SUB_Null;
  18         self.takedamage = DAMAGE_NO;
  19
  20         if(self.movetype == MOVETYPE_NONE)
  21                 self.velocity = self.oldvelocity;
  22
  23         RadiusDamage (self, self.realowner, autocvar_g_balance_grenadelauncher_primary_damage, autocvar_g_balance_grenadelauncher_primary_edgedamage, autocvar_g_balance_grenadelauncher_primary_radius, world, autocvar_g_balance_grenadelauncher_primary_force, self.projectiledeathtype, other);
  24
  25         remove (self);
  26 }
  27
  28 void W_Grenade_Explode2 (void)
  29 {
  30         if(other.takedamage == DAMAGE_AIM)
  31                 if(other.classname == "player")
  32                         if(IsDifferentTeam(self.realowner, other))
  33                                 if(other.deadflag == DEAD_NO)
  34                                         if(IsFlying(other))
  35                                                 AnnounceTo(self.realowner, "airshot");
  36
  37         self.event_damage = SUB_Null;
  38         self.takedamage = DAMAGE_NO;
  39
  40         if(self.movetype == MOVETYPE_NONE)
  41                 self.velocity = self.oldvelocity;
  42
  43         RadiusDamage (self, self.realowner, autocvar_g_balance_grenadelauncher_secondary_damage, autocvar_g_balance_grenadelauncher_secondary_edgedamage, autocvar_g_balance_grenadelauncher_secondary_radius, world, autocvar_g_balance_grenadelauncher_secondary_force, self.projectiledeathtype, other);
  44
  45         remove (self);
  46 }
  47
  48 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  49 {
  50         if (self.health <= 0)
  51                 return;
  52         self.health = self.health - damage;
  53         if (self.health <= 0)
  54         {
  55                 W_PrepareExplosionByDamage(attacker, self.think);
  56         }
  57 }
  58
  59 void W_Grenade_Think1 (void)
  60 {
  61         self.nextthink = time;
  62         if (time > self.cnt)
  63         {
  64                 other = world;
  65                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  66                 W_Grenade_Explode ();
  67                 return;
  68         }
  69         if(self.gl_detonate_later && self.gl_bouncecnt >= autocvar_g_balance_grenadelauncher_primary_remote_minbouncecnt)
  70                 W_Grenade_Explode();
  71 }
  72
  73 void W_Grenade_Touch1 (void)
  74 {
  75         PROJECTILE_TOUCH;
  76         if (other.takedamage == DAMAGE_AIM || autocvar_g_balance_grenadelauncher_primary_type == 0) // always explode when hitting a player, or if normal mortar projectile
  77         {
  78                 self.use ();
  79         }
  80         else if (autocvar_g_balance_grenadelauncher_primary_type == 1) // bounce
  81         {
  82                 float r;
  83                 r = random() * 6;
  84                 if(r < 1)
  85                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
  86                 else if(r < 2)
  87                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
  88                 else if(r < 3)
  89                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
  90                 else if(r < 4)
  91                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
  92                 else if(r < 5)
  93                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
  94                 else
  95                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
  96                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  97                 self.gl_bouncecnt += 1;
  98         }
  99         else if(autocvar_g_balance_grenadelauncher_primary_type == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 100         {
 101                 spamsound (self, CH_SHOTS, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
 102
 103                 // let it stick whereever it is
 104                 self.oldvelocity = self.velocity;
 105                 self.velocity = '0 0 0';
 106                 self.movetype = MOVETYPE_NONE; // also disables gravity
 107                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 108                 UpdateCSQCProjectile(self);
 109
 110                 // do not respond to any more touches
 111                 self.solid = SOLID_NOT;
 112
 113                 self.nextthink = min(self.nextthink, time + autocvar_g_balance_grenadelauncher_primary_lifetime_stick);
 114         }
 115 }
 116
 117 void W_Grenade_Touch2 (void)
 118 {
 119         PROJECTILE_TOUCH;
 120         if (other.takedamage == DAMAGE_AIM || autocvar_g_balance_grenadelauncher_secondary_type == 0) // always explode when hitting a player, or if normal mortar projectile
 121         {
 122                 self.use ();
 123         }
 124         else if (autocvar_g_balance_grenadelauncher_secondary_type == 1) // bounce
 125         {
 126                 float r;
 127                 r = random() * 6;
 128                 if(r < 1)
 129                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
 130                 else if(r < 2)
 131                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
 132                 else if(r < 3)
 133                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
 134                 else if(r < 4)
 135                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
 136                 else if(r < 5)
 137                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
 138                 else
 139                         spamsound (self, CH_SHOTS, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
 140                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 141                 self.gl_bouncecnt += 1;
 142
 143                 if (autocvar_g_balance_grenadelauncher_secondary_lifetime_bounce && self.gl_bouncecnt == 1)
 144                         self.nextthink = time + autocvar_g_balance_grenadelauncher_secondary_lifetime_bounce;
 145
 146         }
 147         else if(autocvar_g_balance_grenadelauncher_secondary_type == 2 && (!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))) // stick
 148         {
 149                 spamsound (self, CH_SHOTS, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
 150
 151                 // let it stick whereever it is
 152                 self.oldvelocity = self.velocity;
 153                 self.velocity = '0 0 0';
 154                 self.movetype = MOVETYPE_NONE; // also disables gravity
 155                 self.gravity = 0; // nope, it does NOT! maybe a bug in CSQC code? TODO
 156                 UpdateCSQCProjectile(self);
 157
 158                 // do not respond to any more touches
 159                 self.solid = SOLID_NOT;
 160
 161                 self.nextthink = min(self.nextthink, time + autocvar_g_balance_grenadelauncher_secondary_lifetime_stick);
 162         }
 163 }
 164
 165 void W_Grenade_Attack (void)
 166 {
 167         local entity gren;
 168
 169         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_grenadelauncher_primary_ammo, autocvar_g_balance_grenadelauncher_reload_ammo);
 170
 171         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CH_WEAPON_A, autocvar_g_balance_grenadelauncher_primary_damage);
 172         w_shotdir = v_forward; // no TrueAim for grenades please
 173
 174         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 175
 176         gren = spawn ();
 177         gren.owner = gren.realowner = self;
 178         gren.classname = "grenade";
 179         gren.bot_dodge = TRUE;
 180         gren.bot_dodgerating = autocvar_g_balance_grenadelauncher_primary_damage;
 181         gren.movetype = MOVETYPE_BOUNCE;
 182         gren.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 183         gren.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 184         PROJECTILE_MAKETRIGGER(gren);
 185         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER;
 186         setorigin(gren, w_shotorg);
 187         setsize(gren, '-3 -3 -3', '3 3 3');
 188
 189         gren.cnt = time + autocvar_g_balance_grenadelauncher_primary_lifetime;
 190         gren.nextthink = time;
 191         gren.think = W_Grenade_Think1;
 192         gren.use = W_Grenade_Explode;
 193         gren.touch = W_Grenade_Touch1;
 194
 195         gren.takedamage = DAMAGE_YES;
 196         gren.health = autocvar_g_balance_grenadelauncher_primary_health;
 197         gren.damageforcescale = autocvar_g_balance_grenadelauncher_primary_damageforcescale;
 198         gren.event_damage = W_Grenade_Damage;
 199         gren.damagedbycontents = TRUE;
 200         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_primary);
 201
 202         gren.angles = vectoangles (gren.velocity);
 203         gren.flags = FL_PROJECTILE;
 204
 205         if(autocvar_g_balance_grenadelauncher_primary_type == 0 || autocvar_g_balance_grenadelauncher_primary_type == 2)
 206                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 207         else
 208                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 209
 210         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 211 }
 212
 213 void W_Grenade_Attack2 (void)
 214 {
 215         local entity gren;
 216
 217         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_grenadelauncher_secondary_ammo, autocvar_g_balance_grenadelauncher_reload_ammo);
 218
 219         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 4, "weapons/grenade_fire.wav", CH_WEAPON_A, autocvar_g_balance_grenadelauncher_secondary_damage);
 220         w_shotdir = v_forward; // no TrueAim for grenades please
 221
 222         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 223
 224         gren = spawn ();
 225         gren.owner = gren.realowner = self;
 226         gren.classname = "grenade";
 227         gren.bot_dodge = TRUE;
 228         gren.bot_dodgerating = autocvar_g_balance_grenadelauncher_secondary_damage;
 229         gren.movetype = MOVETYPE_BOUNCE;
 230         gren.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 231         gren.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 232         PROJECTILE_MAKETRIGGER(gren);
 233         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER | HITTYPE_SECONDARY;
 234         setorigin(gren, w_shotorg);
 235         setsize(gren, '-3 -3 -3', '3 3 3');
 236
 237         gren.nextthink = time + autocvar_g_balance_grenadelauncher_secondary_lifetime;
 238         gren.think = adaptor_think2use_hittype_splash;
 239         gren.use = W_Grenade_Explode2;
 240         gren.touch = W_Grenade_Touch2;
 241
 242         gren.takedamage = DAMAGE_YES;
 243         gren.health = autocvar_g_balance_grenadelauncher_secondary_health;
 244         gren.damageforcescale = autocvar_g_balance_grenadelauncher_secondary_damageforcescale;
 245         gren.event_damage = W_Grenade_Damage;
 246         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_secondary);
 247
 248         gren.angles = vectoangles (gren.velocity);
 249         gren.flags = FL_PROJECTILE;
 250
 251         if(autocvar_g_balance_grenadelauncher_secondary_type == 0 || autocvar_g_balance_grenadelauncher_secondary_type == 2)
 252                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 253         else
 254                 CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 255
 256         other = gren; MUTATOR_CALLHOOK(EditProjectile);
 257 }
 258
 259 void spawnfunc_weapon_grenadelauncher (void)
 260 {
 261         weapon_defaultspawnfunc(WEP_GRENADE_LAUNCHER);
 262 }
 263
 264 .float bot_secondary_grenademooth;
 265 float w_glauncher(float req)
 266 {
 267         entity nade;
 268         float nadefound;
 269         float ammo_amount;
 270
 271         if (req == WR_AIM)
 272         {
 273                 self.BUTTON_ATCK = FALSE;
 274                 self.BUTTON_ATCK2 = FALSE;
 275                 if (self.bot_secondary_grenademooth == 0)
 276                 {
 277                         if(bot_aim(autocvar_g_balance_grenadelauncher_primary_speed, autocvar_g_balance_grenadelauncher_primary_speed_up, autocvar_g_balance_grenadelauncher_primary_lifetime, TRUE))
 278                         {
 279                                 self.BUTTON_ATCK = TRUE;
 280                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 281                         }
 282                 }
 283                 else
 284                 {
 285                         if(bot_aim(autocvar_g_balance_grenadelauncher_secondary_speed, autocvar_g_balance_grenadelauncher_secondary_speed_up, autocvar_g_balance_grenadelauncher_secondary_lifetime, TRUE))
 286                         {
 287                                 self.BUTTON_ATCK2 = TRUE;
 288                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 289                         }
 290                 }
 291         }
 292         else if (req == WR_THINK)
 293         {
 294                 if(autocvar_g_balance_grenadelauncher_reload_ammo && self.clip_load < min(autocvar_g_balance_grenadelauncher_primary_ammo, autocvar_g_balance_grenadelauncher_secondary_ammo)) // forced reload
 295                         weapon_action(self.weapon, WR_RELOAD);
 296                 else if (self.BUTTON_ATCK)
 297                 {
 298                         if (weapon_prepareattack(0, autocvar_g_balance_grenadelauncher_primary_refire))
 299                         {
 300                                 W_Grenade_Attack();
 301                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_grenadelauncher_primary_animtime, w_ready);
 302                         }
 303                 }
 304                 else if (self.BUTTON_ATCK2)
 305                 {
 306                         if (cvar("g_balance_grenadelauncher_secondary_remote_detonateprimary"))
 307                         {
 308                                 nadefound = 0;
 309                                 for(nade = world; (nade = find(nade, classname, "grenade")); ) if(nade.realowner == self)
 310                                 {
 311                                         if(!nade.gl_detonate_later)
 312                                         {
 313                                                 nade.gl_detonate_later = TRUE;
 314                                                 nadefound = 1;
 315                                         }
 316                                 }
 317                                 if(nadefound)
 318                                         sound (self, CH_WEAPON_B, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 319                         }
 320                         else if (weapon_prepareattack(1, autocvar_g_balance_grenadelauncher_secondary_refire))
 321                         {
 322                                 W_Grenade_Attack2();
 323                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_grenadelauncher_secondary_animtime, w_ready);
 324                         }
 325                 }
 326         }
 327         else if (req == WR_PRECACHE)
 328         {
 329                 precache_model ("models/weapons/g_gl.md3");
 330                 precache_model ("models/weapons/v_gl.md3");
 331                 precache_model ("models/weapons/h_gl.iqm");
 332                 precache_sound ("weapons/grenade_bounce1.wav");
 333                 precache_sound ("weapons/grenade_bounce2.wav");
 334                 precache_sound ("weapons/grenade_bounce3.wav");
 335                 precache_sound ("weapons/grenade_bounce4.wav");
 336                 precache_sound ("weapons/grenade_bounce5.wav");
 337                 precache_sound ("weapons/grenade_bounce6.wav");
 338                 precache_sound ("weapons/grenade_stick.wav");
 339                 precache_sound ("weapons/grenade_fire.wav");
 340                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 341         }
 342         else if (req == WR_SETUP)
 343         {
 344                 weapon_setup(WEP_GRENADE_LAUNCHER);
 345                 self.current_ammo = ammo_rockets;
 346         }
 347         else if (req == WR_CHECKAMMO1)
 348         {
 349                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_grenadelauncher_primary_ammo;
 350                 ammo_amount += self.weapon_load[WEP_GRENADE_LAUNCHER] >= autocvar_g_balance_grenadelauncher_primary_ammo;
 351                 return ammo_amount;
 352         }
 353         else if (req == WR_CHECKAMMO2)
 354         {
 355                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_grenadelauncher_secondary_ammo;
 356                 ammo_amount += self.weapon_load[WEP_GRENADE_LAUNCHER] >= autocvar_g_balance_grenadelauncher_secondary_ammo;
 357                 return ammo_amount;
 358         }
 359         else if (req == WR_RELOAD)
 360         {
 361                 W_Reload(min(autocvar_g_balance_grenadelauncher_primary_ammo, autocvar_g_balance_grenadelauncher_secondary_ammo), autocvar_g_balance_grenadelauncher_reload_ammo, autocvar_g_balance_grenadelauncher_reload_time, "weapons/reload.wav");
 362         }
 363         return TRUE;
 364 };
 365 #endif
 366 #ifdef CSQC
 367 float w_glauncher(float req)
 368 {
 369         if(req == WR_IMPACTEFFECT)
 370         {
 371                 vector org2;
 372                 org2 = w_org + w_backoff * 12;
 373                 pointparticles(particleeffectnum("grenade_explode"), org2, '0 0 0', 1);
 374                 if(!w_issilent)
 375                         sound(self, CH_SHOTS, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 376         }
 377         else if(req == WR_PRECACHE)
 378         {
 379                 precache_sound("weapons/grenade_impact.wav");
 380         }
 381         else if (req == WR_SUICIDEMESSAGE)
 382         {
 383                 if(w_deathtype & HITTYPE_SECONDARY)
 384                         w_deathtypestring = _("%s tried out his own grenade");
 385                 else
 386                         w_deathtypestring = _("%s detonated");
 387         }
 388         else if (req == WR_KILLMESSAGE)
 389         {
 390                 if(w_deathtype & HITTYPE_SPLASH)
 391                         if(w_deathtype & HITTYPE_BOUNCE) // (must be secondary then)
 392                                 w_deathtypestring = _("%s didn't see %s's grenade");
 393                         else // unchecked: SECONDARY
 394                                 w_deathtypestring = _("%s almost dodged %s's grenade");
 395                 else // unchecked: SECONDARY, BOUNCE
 396                         w_deathtypestring = _("%s ate %s's grenade");
 397         }
 398         return TRUE;
 399 }
 400 #endif
 401 #endif