Update the hold cvar so that it now actually represents the amount of time you can...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / w_hagar.qc
1 #ifdef REGISTER_WEAPON
2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
3 #else
4 #ifdef SVQC
5 // NO bounce protection, as bounces are limited!
6
7 void W_Hagar_Explode (void)
8 {
9         self.event_damage = SUB_Null;
10         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
11
12         remove (self);
13 }
14
15 void W_Hagar_Explode2 (void)
16 {
17         self.event_damage = SUB_Null;
18         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
19
20         remove (self);
21 }
22
23 void W_Hagar_Touch (void)
24 {
25         PROJECTILE_TOUCH;
26         self.use ();
27 }
28
29 void W_Hagar_Touch2 (void)
30 {
31         PROJECTILE_TOUCH;
32
33         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
34                 self.use();
35         } else {
36                 self.cnt++;
37                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
38                 self.angles = vectoangles (self.velocity);
39                 self.owner = world;
40                 self.projectiledeathtype |= HITTYPE_BOUNCE;
41         }
42 }
43
44 void W_Hagar_Attack (void)
45 {
46         local entity missile;
47
48         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
49
50         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_primary_damage);
51
52         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
53
54         missile = spawn ();
55         missile.owner = missile.realowner = self;
56         missile.classname = "missile";
57         missile.bot_dodge = TRUE;
58         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
59         missile.touch = W_Hagar_Touch;
60         missile.use = W_Hagar_Explode;
61         missile.think = adaptor_think2use_hittype_splash;
62         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
63         PROJECTILE_MAKETRIGGER(missile);
64         missile.projectiledeathtype = WEP_HAGAR;
65         setorigin (missile, w_shotorg);
66         setsize(missile, '0 0 0', '0 0 0');
67
68         missile.movetype = MOVETYPE_FLY;
69         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
70
71         missile.angles = vectoangles (missile.velocity);
72         missile.flags = FL_PROJECTILE;
73
74         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
75
76         other = missile; MUTATOR_CALLHOOK(EditProjectile);
77 }
78
79 void W_Hagar_Attack2 (void)
80 {
81         local entity missile;
82
83         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
84
85         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
86
87         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
88
89         missile = spawn ();
90         missile.owner = missile.realowner = self;
91         missile.classname = "missile";
92         missile.bot_dodge = TRUE;
93         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
94         missile.touch = W_Hagar_Touch2;
95         missile.cnt = 0;
96         missile.use = W_Hagar_Explode2;
97         missile.think = adaptor_think2use_hittype_splash;
98         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
99         PROJECTILE_MAKETRIGGER(missile);
100         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
101         setorigin (missile, w_shotorg);
102         setsize(missile, '0 0 0', '0 0 0');
103
104         missile.movetype = MOVETYPE_BOUNCEMISSILE;
105         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
106
107         missile.angles = vectoangles (missile.velocity);
108         missile.flags = FL_PROJECTILE;
109
110         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
111
112         other = missile; MUTATOR_CALLHOOK(EditProjectile);
113 }
114
115 .float hagar_loadstep, hagar_loadblock, hagar_loadbeep;
116 void W_Hagar_Attack2_Load_Release (void)
117 {
118         // time to release the rockets we've loaded
119
120         local entity missile;
121         local float counter, shots;
122         local vector s;
123         vector forward, right, up;
124
125         if(!self.hagar_load)
126                 return;
127
128         weapon_prepareattack_do(1, autocvar_g_balance_hagar_secondary_refire);
129
130         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
131         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
132
133         forward = v_forward;
134         right = v_right;
135         up = v_up;
136
137         shots = self.hagar_load;
138         missile = world;
139         while (counter < shots)
140         {
141                 missile = spawn ();
142                 missile.owner = missile.realowner = self;
143                 missile.classname = "missile";
144                 missile.bot_dodge = TRUE;
145                 missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
146
147                 missile.touch = W_Hagar_Touch; // not bouncy
148                 missile.use = W_Hagar_Explode2;
149                 missile.think = adaptor_think2use_hittype_splash;
150                 missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
151                 PROJECTILE_MAKETRIGGER(missile);
152                 missile.projectiledeathtype = WEP_HAGAR;
153                 setorigin (missile, w_shotorg);
154                 setsize(missile, '0 0 0', '0 0 0');
155                 missile.movetype = MOVETYPE_FLY;
156
157                 s = '0 0 0';
158                 if (counter == 0)
159                         s = '0 0 0';
160                 else
161                 {
162                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
163                         s_y = v_forward_x;
164                         s_z = v_forward_y;
165                 }
166                 s = s * cvar("g_balance_hagar_secondary_spread") * g_weaponspreadfactor;
167                 W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_hagar_secondary_speed"), 0, 0, 0, FALSE);
168
169                 missile.angles = vectoangles (missile.velocity);
170                 missile.flags = FL_PROJECTILE;
171
172                 CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
173
174                 other = missile; MUTATOR_CALLHOOK(EditProjectile);
175
176                 counter = counter + 1;
177         }
178
179         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
180         self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_refire;
181         self.hagar_load = 0;
182 }
183
184 void W_Hagar_Attack2_Load (void)
185 {
186         // loadable hagar secondary attack, must always run each frame
187
188         local float loaded, enough_ammo;
189         loaded = self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max;
190
191         // this is different than WR_CHECKAMMO when it comes to reloading
192         if(autocvar_g_balance_hagar_reload_ammo)
193                 enough_ammo = self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
194         else
195                 enough_ammo = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
196
197         if(self.BUTTON_ATCK2)
198         {
199                 if(self.BUTTON_ATCK && autocvar_g_balance_hagar_secondary_load_abort)
200                 {
201                         if(self.hagar_load)
202                         {
203                                 // if we pressed primary fire while loading, unload all rockets and abort
204                                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load * -1, autocvar_g_balance_hagar_reload_ammo); // give back ammo
205                                 self.hagar_load = 0;
206                                 sound(self, CHAN_WEAPON, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
207
208                                 // pause until we can load rockets again, once we re-press the alt fire button
209                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed;
210
211                                 // require letting go of the alt fire button before we can load again
212                                 self.hagar_loadblock = TRUE;
213                         }
214                 }
215                 else
216                 {
217                         // check if we can attempt to load another rocket
218                         if(!loaded && enough_ammo)
219                         {
220                                 if(!self.hagar_loadblock && self.hagar_loadstep < time)
221                                 {
222                                         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
223                                         self.hagar_load += 1;
224                                         sound(self, CHAN_WEAPON2, "weapons/hagar_load.wav", VOL_BASE * 0.8, ATTN_NORM); // sound is too loud according to most
225
226                                         if (self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max)
227                                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_hold;
228                                         else
229                                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed;
230                                 }
231                         }
232                         else if(!self.hagar_loadbeep && self.hagar_load) // prevents the beep from playing each frame
233                         {
234                                 // if this is the last rocket we can load, play a beep sound to notify the player
235                                 sound(self, CHAN_WEAPON, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
236                                 self.hagar_loadbeep = TRUE;
237                         }
238                 }
239         }
240         else if(self.hagar_loadblock)
241         {
242                 // the alt fire button has been released, so re-enable loading if blocked
243                 self.hagar_loadblock = FALSE;
244         }
245
246         if(self.hagar_load)
247         {
248                 self.weapon_forbidchange = TRUE;
249                 if(!self.BUTTON_ATCK2 || ((loaded || !enough_ammo) && self.hagar_loadstep < time && autocvar_g_balance_hagar_secondary_load_hold >= 0))
250                         W_Hagar_Attack2_Load_Release();
251         }
252         else
253         {
254                 self.weapon_forbidchange = FALSE;
255                 self.hagar_loadbeep = FALSE;
256         }
257
258         // we aren't checking ammo during an attack, so we must do it here
259         if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
260         {
261                 W_SwitchToOtherWeapon(self);
262                 return;
263         }
264 }
265
266 void spawnfunc_weapon_hagar (void)
267 {
268         weapon_defaultspawnfunc(WEP_HAGAR);
269 }
270
271 float w_hagar(float req)
272 {
273         float ammo_amount;
274         if (req == WR_AIM)
275                 if (random()>0.15)
276                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
277                 else
278                 {
279                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
280                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
281                 }
282         else if (req == WR_THINK)
283         {
284                 local float loadable_secondary;
285                 loadable_secondary = autocvar_g_balance_hagar_secondary_load && autocvar_g_balance_hagar_secondary;
286
287                 if (loadable_secondary)
288                         W_Hagar_Attack2_Load(); // must always run each frame
289                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
290                         weapon_action(self.weapon, WR_RELOAD);
291                 else if (self.BUTTON_ATCK && !self.hagar_load && !self.hagar_loadblock) // not while secondary is loaded or awaiting reset
292                 {
293                         if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
294                         {
295                                 W_Hagar_Attack();
296                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
297                         }
298                 }
299                 else if (self.BUTTON_ATCK2 && !loadable_secondary && autocvar_g_balance_hagar_secondary)
300                 {
301                         if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
302                         {
303                                 W_Hagar_Attack2();
304                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
305                         }
306                 }
307         }
308         else if (req == WR_PRECACHE)
309         {
310                 precache_model ("models/weapons/g_hagar.md3");
311                 precache_model ("models/weapons/v_hagar.md3");
312                 precache_model ("models/weapons/h_hagar.iqm");
313                 precache_sound ("weapons/hagar_fire.wav");
314                 precache_sound ("weapons/hagar_load.wav");
315                 precache_sound ("weapons/hagar_beep.wav");
316                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
317         }
318         else if (req == WR_SETUP)
319         {
320                 weapon_setup(WEP_HAGAR);
321                 self.current_ammo = ammo_rockets;
322                 self.hagar_loadblock = FALSE;
323
324                 if(self.hagar_load)
325                 {
326                         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load * -1, autocvar_g_balance_hagar_reload_ammo); // give back ammo if necessary
327                         self.hagar_load = 0;
328                 }
329         }
330         else if (req == WR_CHECKAMMO1)
331         {
332                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
333                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
334                 return ammo_amount;
335         }
336         else if (req == WR_CHECKAMMO2)
337         {
338                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
339                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
340                 return ammo_amount;
341         }
342         else if (req == WR_RESETPLAYER)
343         {
344                 self.hagar_load = 0;
345         }
346         else if (req == WR_PLAYERDEATH)
347         {
348                 // if we have any rockets loaded when we die, release them
349                 if(self.hagar_load && autocvar_g_balance_hagar_secondary_load_releasedeath)
350                         W_Hagar_Attack2_Load_Release();
351         }
352         else if (req == WR_RELOAD)
353         {
354                 if not(self.hagar_load) // require releasing loaded rockets first
355                         W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
356         }
357         return TRUE;
358 };
359 #endif
360 #ifdef CSQC
361 float w_hagar(float req)
362 {
363         if(req == WR_IMPACTEFFECT)
364         {
365                 vector org2;
366                 org2 = w_org + w_backoff * 6;
367                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
368                 if(!w_issilent)
369                 {
370                         if (w_random<0.15)
371                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
372                         else if (w_random<0.7)
373                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
374                         else
375                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
376                 }
377         }
378         else if(req == WR_PRECACHE)
379         {
380                 precache_sound("weapons/hagexp1.wav");
381                 precache_sound("weapons/hagexp2.wav");
382                 precache_sound("weapons/hagexp3.wav");
383         }
384         else if (req == WR_SUICIDEMESSAGE)
385                 w_deathtypestring = _("%s played with tiny rockets");
386         else if (req == WR_KILLMESSAGE)
387         {
388                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
389                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
390                 else // unchecked: SPLASH, SECONDARY
391                         w_deathtypestring = _("%s was pummeled by %s");
392         }
393         return TRUE;
394 }
395 #endif
396 #endif