qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 void W_Hagar_Explode (void)
   8 {
   9         self.event_damage = SUB_Null;
  10         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  11
  12         remove (self);
  13 }
  14
  15 void W_Hagar_Explode2 (void)
  16 {
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  19
  20         remove (self);
  21 }
  22
  23 void W_Hagar_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  24 {
  25         if (self.health <= 0)
  26                 return;
  27
  28         if ((inflictor.realowner == self.realowner) && !autocvar_g_balance_hagar_secondary_load_linkexplode)
  29                 return;
  30
  31         self.health = self.health - damage;
  32         self.angles = vectoangles(self.velocity);
  33
  34         print(strcat("hagar rocket health ", ftos(self.health), " after ", ftos(damage), " damage... (at time: ", ftos(time), ")\n"));
  35
  36         if (self.health <= 0)
  37                 W_PrepareExplosionByDamage(attacker, self.think);
  38 }
  39
  40 void W_Hagar_Touch (void)
  41 {
  42         PROJECTILE_TOUCH;
  43         self.use ();
  44 }
  45
  46 void W_Hagar_Touch2 (void)
  47 {
  48         PROJECTILE_TOUCH;
  49
  50         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  51                 self.use();
  52         } else {
  53                 self.cnt++;
  54                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  55                 self.angles = vectoangles (self.velocity);
  56                 self.owner = world;
  57                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  58         }
  59 }
  60
  61 void W_Hagar_Attack (void)
  62 {
  63         local entity missile;
  64
  65         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  66
  67         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, autocvar_g_balance_hagar_primary_damage);
  68
  69         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  70
  71         missile = spawn ();
  72         missile.owner = missile.realowner = self;
  73         missile.classname = "missile";
  74         missile.bot_dodge = TRUE;
  75         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  76
  77         missile.takedamage = DAMAGE_YES;
  78         missile.health = autocvar_g_balance_hagar_primary_health;
  79         missile.damageforcescale = autocvar_g_balance_hagar_primary_damageforcescale;
  80         missile.event_damage = W_Hagar_Damage;
  81         missile.damagedbycontents = TRUE;
  82
  83         missile.touch = W_Hagar_Touch;
  84         missile.use = W_Hagar_Explode;
  85         missile.think = adaptor_think2use_hittype_splash;
  86         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  87         PROJECTILE_MAKETRIGGER(missile);
  88         missile.projectiledeathtype = WEP_HAGAR;
  89         setorigin (missile, w_shotorg);
  90         setsize(missile, '0 0 0', '0 0 0');
  91
  92         missile.movetype = MOVETYPE_FLY;
  93         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  94
  95         missile.angles = vectoangles (missile.velocity);
  96         missile.flags = FL_PROJECTILE;
  97
  98         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  99
 100         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 101 }
 102
 103 void W_Hagar_Attack2 (void)
 104 {
 105         local entity missile;
 106
 107         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
 108
 109         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, autocvar_g_balance_hagar_secondary_damage);
 110
 111         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 112
 113         missile = spawn ();
 114         missile.owner = missile.realowner = self;
 115         missile.classname = "missile";
 116         missile.bot_dodge = TRUE;
 117         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 118
 119         missile.takedamage = DAMAGE_YES;
 120         missile.health = autocvar_g_balance_hagar_secondary_health;
 121         missile.damageforcescale = autocvar_g_balance_hagar_secondary_damageforcescale;
 122         missile.event_damage = W_Hagar_Damage;
 123         missile.damagedbycontents = TRUE;
 124
 125         missile.touch = W_Hagar_Touch2;
 126         missile.cnt = 0;
 127         missile.use = W_Hagar_Explode2;
 128         missile.think = adaptor_think2use_hittype_splash;
 129         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 130         PROJECTILE_MAKETRIGGER(missile);
 131         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 132         setorigin (missile, w_shotorg);
 133         setsize(missile, '0 0 0', '0 0 0');
 134
 135         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 136         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 137
 138         missile.angles = vectoangles (missile.velocity);
 139         missile.flags = FL_PROJECTILE;
 140
 141         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 142
 143         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 144 }
 145
 146 .float hagar_loadstep, hagar_loadblock, hagar_loadbeep;
 147 void W_Hagar_Attack2_Load_Release (void)
 148 {
 149         // time to release the rockets we've loaded
 150
 151         local entity missile;
 152         local float counter, shots, spread_pershot;
 153         local vector s;
 154         vector forward, right, up;
 155
 156         if(!self.hagar_load)
 157                 return;
 158
 159         weapon_prepareattack_do(1, autocvar_g_balance_hagar_secondary_refire);
 160
 161         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, autocvar_g_balance_hagar_secondary_damage);
 162         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 163
 164         forward = v_forward;
 165         right = v_right;
 166         up = v_up;
 167
 168         shots = self.hagar_load;
 169         missile = world;
 170         while (counter < shots)
 171         {
 172                 missile = spawn ();
 173                 missile.owner = missile.realowner = self;
 174                 missile.classname = "missile";
 175                 missile.bot_dodge = TRUE;
 176                 missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 177
 178                 missile.takedamage = DAMAGE_YES;
 179                 missile.health = autocvar_g_balance_hagar_secondary_health;
 180                 missile.damageforcescale = autocvar_g_balance_hagar_secondary_damageforcescale;
 181                 missile.event_damage = W_Hagar_Damage;
 182                 missile.damagedbycontents = TRUE;
 183
 184                 missile.touch = W_Hagar_Touch; // not bouncy
 185                 missile.use = W_Hagar_Explode2;
 186                 missile.think = adaptor_think2use_hittype_splash;
 187                 missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 188                 PROJECTILE_MAKETRIGGER(missile);
 189                 missile.projectiledeathtype = WEP_HAGAR;
 190                 setorigin (missile, w_shotorg);
 191                 setsize(missile, '0 0 0', '0 0 0');
 192                 missile.movetype = MOVETYPE_FLY;
 193
 194                 // per-shot spread calculation: the more shots there are, the less spread is applied (based on the bias cvar)
 195                 spread_pershot = ((shots - 1) / (autocvar_g_balance_hagar_secondary_load_max - 1));
 196                 spread_pershot = (1 - (spread_pershot * autocvar_g_balance_hagar_secondary_load_spread_bias));
 197                 spread_pershot = (autocvar_g_balance_hagar_secondary_spread * spread_pershot * g_weaponspreadfactor);
 198
 199                 // pattern spread calculation
 200                 s = '0 0 0';
 201                 if (counter == 0)
 202                         s = '0 0 0';
 203                 else
 204                 {
 205                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 206                         s_y = v_forward_x;
 207                         s_z = v_forward_y;
 208                 }
 209                 s = s * autocvar_g_balance_hagar_secondary_load_spread * g_weaponspreadfactor;
 210
 211                 W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, autocvar_g_balance_hagar_secondary_speed, 0, 0, spread_pershot, FALSE);
 212
 213                 missile.angles = vectoangles (missile.velocity);
 214                 missile.flags = FL_PROJECTILE;
 215
 216                 CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 217
 218                 other = missile; MUTATOR_CALLHOOK(EditProjectile);
 219
 220                 counter = counter + 1;
 221         }
 222
 223         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 224         self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_refire * W_WeaponRateFactor();
 225         self.hagar_load = 0;
 226 }
 227
 228 void W_Hagar_Attack2_Load (void)
 229 {
 230         // loadable hagar secondary attack, must always run each frame
 231
 232         local float loaded, enough_ammo;
 233         loaded = self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max;
 234
 235         // this is different than WR_CHECKAMMO when it comes to reloading
 236         if(autocvar_g_balance_hagar_reload_ammo)
 237                 enough_ammo = self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 238         else
 239                 enough_ammo = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 240
 241         if(self.BUTTON_ATCK2)
 242         {
 243                 if(self.BUTTON_ATCK && autocvar_g_balance_hagar_secondary_load_abort)
 244                 {
 245                         if(self.hagar_load)
 246                         {
 247                                 // if we pressed primary fire while loading, unload all rockets and abort
 248                                 self.weaponentity.state = WS_READY;
 249                                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load * -1, autocvar_g_balance_hagar_reload_ammo); // give back ammo
 250                                 self.hagar_load = 0;
 251                                 sound(self, CH_WEAPON_A, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 252
 253                                 // pause until we can load rockets again, once we re-press the alt fire button
 254                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed * W_WeaponRateFactor();
 255
 256                                 // require letting go of the alt fire button before we can load again
 257                                 self.hagar_loadblock = TRUE;
 258                         }
 259                 }
 260                 else
 261                 {
 262                         // check if we can attempt to load another rocket
 263                         if(!loaded && enough_ammo)
 264                         {
 265                                 if(!self.hagar_loadblock && self.hagar_loadstep < time)
 266                                 {
 267                                         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
 268                                         self.weaponentity.state = WS_INUSE;
 269                                         self.hagar_load += 1;
 270                                         sound(self, CH_WEAPON_B, "weapons/hagar_load.wav", VOL_BASE * 0.8, ATTN_NORM); // sound is too loud according to most
 271
 272                                         if (self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max)
 273                                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_hold * W_WeaponRateFactor();
 274                                         else
 275                                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed * W_WeaponRateFactor();
 276                                 }
 277                         }
 278                         else if(!self.hagar_loadbeep && self.hagar_load) // prevents the beep from playing each frame
 279                         {
 280                                 // if this is the last rocket we can load, play a beep sound to notify the player
 281                                 sound(self, CH_WEAPON_A, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 282                                 self.hagar_loadbeep = TRUE;
 283                         }
 284                 }
 285         }
 286         else if(self.hagar_loadblock)
 287         {
 288                 // the alt fire button has been released, so re-enable loading if blocked
 289                 self.hagar_loadblock = FALSE;
 290         }
 291
 292         if(self.hagar_load)
 293         {
 294                 if(!self.BUTTON_ATCK2 || ((loaded || !enough_ammo) && self.hagar_loadstep < time && autocvar_g_balance_hagar_secondary_load_hold >= 0))
 295                 {
 296                         self.weaponentity.state = WS_READY;
 297                         W_Hagar_Attack2_Load_Release();
 298                 }
 299         }
 300         else
 301         {
 302                 self.hagar_loadbeep = FALSE;
 303         }
 304
 305         // we aren't checking ammo during an attack, so we must do it here
 306         if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
 307         {
 308                 // note: this doesn't force the switch
 309                 W_SwitchToOtherWeapon(self);
 310                 return;
 311         }
 312 }
 313
 314 void spawnfunc_weapon_hagar (void)
 315 {
 316         weapon_defaultspawnfunc(WEP_HAGAR);
 317 }
 318
 319 float w_hagar(float req)
 320 {
 321         float ammo_amount;
 322         if (req == WR_AIM)
 323                 if (random()>0.15)
 324                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 325                 else
 326                 {
 327                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 328                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 329                 }
 330         else if (req == WR_THINK)
 331         {
 332                 local float loadable_secondary;
 333                 loadable_secondary = autocvar_g_balance_hagar_secondary_load && autocvar_g_balance_hagar_secondary;
 334
 335                 if (loadable_secondary)
 336                         W_Hagar_Attack2_Load(); // must always run each frame
 337                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 338                         weapon_action(self.weapon, WR_RELOAD);
 339                 else if (self.BUTTON_ATCK && !self.hagar_load && !self.hagar_loadblock) // not while secondary is loaded or awaiting reset
 340                 {
 341                         if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 342                         {
 343                                 W_Hagar_Attack();
 344                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 345                         }
 346                 }
 347                 else if (self.BUTTON_ATCK2 && !loadable_secondary && autocvar_g_balance_hagar_secondary)
 348                 {
 349                         if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 350                         {
 351                                 W_Hagar_Attack2();
 352                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 353                         }
 354                 }
 355         }
 356         else if (req == WR_GONETHINK)
 357         {
 358                 // we lost the weapon and want to prepare switching away
 359                 if(self.hagar_load)
 360                 {
 361                         self.weaponentity.state = WS_READY;
 362                         W_Hagar_Attack2_Load_Release();
 363                 }
 364         }
 365         else if (req == WR_PRECACHE)
 366         {
 367                 precache_model ("models/weapons/g_hagar.md3");
 368                 precache_model ("models/weapons/v_hagar.md3");
 369                 precache_model ("models/weapons/h_hagar.iqm");
 370                 precache_sound ("weapons/hagar_fire.wav");
 371                 precache_sound ("weapons/hagar_load.wav");
 372                 precache_sound ("weapons/hagar_beep.wav");
 373                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 374         }
 375         else if (req == WR_SETUP)
 376         {
 377                 weapon_setup(WEP_HAGAR);
 378                 self.current_ammo = ammo_rockets;
 379                 self.hagar_loadblock = FALSE;
 380
 381                 if(self.hagar_load)
 382                 {
 383                         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load * -1, autocvar_g_balance_hagar_reload_ammo); // give back ammo if necessary
 384                         self.hagar_load = 0;
 385                 }
 386         }
 387         else if (req == WR_CHECKAMMO1)
 388         {
 389                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 390                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 391                 return ammo_amount;
 392         }
 393         else if (req == WR_CHECKAMMO2)
 394         {
 395                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 396                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 397                 return ammo_amount;
 398         }
 399         else if (req == WR_RESETPLAYER)
 400         {
 401                 self.hagar_load = 0;
 402         }
 403         else if (req == WR_PLAYERDEATH)
 404         {
 405                 // if we have any rockets loaded when we die, release them
 406                 if(self.hagar_load && autocvar_g_balance_hagar_secondary_load_releasedeath)
 407                         W_Hagar_Attack2_Load_Release();
 408         }
 409         else if (req == WR_RELOAD)
 410         {
 411                 if not(self.hagar_load) // require releasing loaded rockets first
 412                         W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 413         }
 414         return TRUE;
 415 };
 416 #endif
 417 #ifdef CSQC
 418 float w_hagar(float req)
 419 {
 420         if(req == WR_IMPACTEFFECT)
 421         {
 422                 vector org2;
 423                 org2 = w_org + w_backoff * 6;
 424                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 425                 if(!w_issilent)
 426                 {
 427                         if (w_random<0.15)
 428                                 sound(self, CH_SHOTS, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 429                         else if (w_random<0.7)
 430                                 sound(self, CH_SHOTS, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 431                         else
 432                                 sound(self, CH_SHOTS, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 433                 }
 434         }
 435         else if(req == WR_PRECACHE)
 436         {
 437                 precache_sound("weapons/hagexp1.wav");
 438                 precache_sound("weapons/hagexp2.wav");
 439                 precache_sound("weapons/hagexp3.wav");
 440         }
 441         else if (req == WR_SUICIDEMESSAGE)
 442                 w_deathtypestring = _("%s played with tiny rockets");
 443         else if (req == WR_KILLMESSAGE)
 444         {
 445                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 446                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 447                 else // unchecked: SPLASH, SECONDARY
 448                         w_deathtypestring = _("%s was pummeled by %s");
 449         }
 450         return TRUE;
 451 }
 452 #endif
 453 #endif