qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 void W_Hagar_Explode (void)
   8 {
   9         self.event_damage = SUB_Null;
  10         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  11
  12         remove (self);
  13 }
  14
  15 void W_Hagar_Explode2 (void)
  16 {
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  19
  20         remove (self);
  21 }
  22
  23 void W_Hagar_Touch (void)
  24 {
  25         PROJECTILE_TOUCH;
  26         self.use ();
  27 }
  28
  29 void W_Hagar_Touch2 (void)
  30 {
  31         PROJECTILE_TOUCH;
  32
  33         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  34                 self.use();
  35         } else {
  36                 self.cnt++;
  37                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  38                 self.angles = vectoangles (self.velocity);
  39                 self.owner = world;
  40                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  41         }
  42 }
  43
  44 void W_Hagar_Attack (void)
  45 {
  46         local entity missile;
  47
  48         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  49
  50         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_primary_damage);
  51
  52         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  53
  54         missile = spawn ();
  55         missile.owner = missile.realowner = self;
  56         missile.classname = "missile";
  57         missile.bot_dodge = TRUE;
  58         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  59         missile.touch = W_Hagar_Touch;
  60         missile.use = W_Hagar_Explode;
  61         missile.think = adaptor_think2use_hittype_splash;
  62         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  63         PROJECTILE_MAKETRIGGER(missile);
  64         missile.projectiledeathtype = WEP_HAGAR;
  65         setorigin (missile, w_shotorg);
  66         setsize(missile, '0 0 0', '0 0 0');
  67
  68         missile.movetype = MOVETYPE_FLY;
  69         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  70
  71         missile.angles = vectoangles (missile.velocity);
  72         missile.flags = FL_PROJECTILE;
  73
  74         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  75
  76         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  77 }
  78
  79 void W_Hagar_Attack2 (void)
  80 {
  81         local entity missile;
  82
  83         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
  84
  85         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CHAN_WEAPON, autocvar_g_balance_hagar_secondary_damage);
  86
  87         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  88
  89         missile = spawn ();
  90         missile.owner = missile.realowner = self;
  91         missile.classname = "missile";
  92         missile.bot_dodge = TRUE;
  93         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
  94         missile.touch = W_Hagar_Touch2;
  95         missile.cnt = 0;
  96         missile.use = W_Hagar_Explode2;
  97         missile.think = adaptor_think2use_hittype_splash;
  98         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
  99         PROJECTILE_MAKETRIGGER(missile);
 100         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 101         setorigin (missile, w_shotorg);
 102         setsize(missile, '0 0 0', '0 0 0');
 103
 104         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 105         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 106
 107         missile.angles = vectoangles (missile.velocity);
 108         missile.flags = FL_PROJECTILE;
 109
 110         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 111
 112         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 113 }
 114
 115 void spawnfunc_weapon_hagar (void)
 116 {
 117         weapon_defaultspawnfunc(WEP_HAGAR);
 118 }
 119
 120 float w_hagar(float req)
 121 {
 122         float ammo_amount;
 123         if (req == WR_AIM)
 124                 if (random()>0.15)
 125                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 126                 else
 127                 {
 128                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 129                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 130                 }
 131         else if (req == WR_THINK)
 132         {
 133                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 134                         weapon_action(self.weapon, WR_RELOAD);
 135                 else if (self.BUTTON_ATCK)
 136                 {
 137                         if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 138                         {
 139                                 W_Hagar_Attack();
 140                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 141                         }
 142                 }
 143                 else if (self.BUTTON_ATCK2 && autocvar_g_balance_hagar_secondary)
 144                 {
 145                         if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 146                         {
 147                                 W_Hagar_Attack2();
 148                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 149                         }
 150                 }
 151         }
 152         else if (req == WR_PRECACHE)
 153         {
 154                 precache_model ("models/weapons/g_hagar.md3");
 155                 precache_model ("models/weapons/v_hagar.md3");
 156                 precache_model ("models/weapons/h_hagar.iqm");
 157                 precache_sound ("weapons/hagar_fire.wav");
 158                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 159         }
 160         else if (req == WR_SETUP)
 161         {
 162                 weapon_setup(WEP_HAGAR);
 163                 self.current_ammo = ammo_rockets;
 164         }
 165         else if (req == WR_CHECKAMMO1)
 166         {
 167                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 168                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 169                 return ammo_amount;
 170         }
 171         else if (req == WR_CHECKAMMO2)
 172         {
 173                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 174                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 175                 return ammo_amount;
 176         }
 177         else if (req == WR_RELOAD)
 178         {
 179                 W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 180         }
 181         return TRUE;
 182 };
 183 #endif
 184 #ifdef CSQC
 185 float w_hagar(float req)
 186 {
 187         if(req == WR_IMPACTEFFECT)
 188         {
 189                 vector org2;
 190                 org2 = w_org + w_backoff * 6;
 191                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 192                 if(!w_issilent)
 193                 {
 194                         if (w_random<0.15)
 195                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 196                         else if (w_random<0.7)
 197                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 198                         else
 199                                 sound(self, CHAN_PROJECTILE, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 200                 }
 201         }
 202         else if(req == WR_PRECACHE)
 203         {
 204                 precache_sound("weapons/hagexp1.wav");
 205                 precache_sound("weapons/hagexp2.wav");
 206                 precache_sound("weapons/hagexp3.wav");
 207         }
 208         else if (req == WR_SUICIDEMESSAGE)
 209                 w_deathtypestring = _("%s played with tiny rockets");
 210         else if (req == WR_KILLMESSAGE)
 211         {
 212                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 213                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 214                 else // unchecked: SPLASH, SECONDARY
 215                         w_deathtypestring = _("%s was pummeled by %s");
 216         }
 217         return TRUE;
 218 }
 219 #endif
 220 #endif