qcsrc/server/w_hlac.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HLAC, w_hlac, IT_CELLS, 6, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hlac", "hlac", "Heavy Laser Assault Cannon");
   3 #else
   4 #ifdef SVQC
   5 .float HLAC_bulletcounter;
   6 void W_HLAC_Touch (void)
   7 {
   8         PROJECTILE_TOUCH;
   9
  10         self.event_damage = SUB_Null;
  11
  12     RadiusDamage (self, self.owner, cvar("g_balance_hlac_primary_damage"), cvar("g_balance_hlac_primary_edgedamage"), cvar("g_balance_hlac_primary_radius"), world, cvar("g_balance_hlac_primary_force"), self.projectiledeathtype, other);
  13
  14         remove (self);
  15 }
  16
  17 void W_HLAC_Touch2 (void)
  18 {
  19         PROJECTILE_TOUCH;
  20
  21         self.event_damage = SUB_Null;
  22
  23     RadiusDamage (self, self.owner, cvar("g_balance_hlac_secondary_damage"), cvar("g_balance_hlac_secondary_edgedamage"), cvar("g_balance_hlac_secondary_radius"), world, cvar("g_balance_hlac_secondary_force"), self.projectiledeathtype, other);
  24
  25         remove (self);
  26 }
  27
  28 void W_HLAC_Attack (void)
  29 {
  30         local entity missile;
  31     float spread;
  32
  33     if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  34     {
  35         self.ammo_cells = self.ammo_cells - cvar("g_balance_hlac_primary_ammo");
  36     }
  37
  38     spread = cvar("g_balance_hlac_primary_spread_min") + (cvar("g_balance_hlac_primary_spread_add") * self.HLAC_bulletcounter);
  39     spread = min(spread,cvar("g_balance_hlac_primary_spread_max"));
  40     if(self.crouch)
  41         spread = spread * cvar("g_balance_hlac_primary_spread_crouchmod");
  42
  43         W_SetupShot (self, FALSE, 3, "weapons/lasergun_fire.wav", cvar("g_balance_hlac_primary_damage"));
  44         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  45         if (!g_norecoil)
  46         {
  47                 self.punchangle_x = random () - 0.5;
  48                 self.punchangle_y = random () - 0.5;
  49         }
  50
  51         missile = spawn ();
  52         missile.owner = self;
  53         missile.classname = "hlacbolt";
  54         // missile.dmg = issecondary;
  55         missile.bot_dodge = TRUE;
  56
  57     missile.bot_dodgerating = cvar("g_balance_hlac_primary_damage");
  58
  59         missile.movetype = MOVETYPE_FLY;
  60         PROJECTILE_MAKETRIGGER(missile);
  61
  62         setorigin (missile, w_shotorg);
  63         setsize(missile, '0 0 0', '0 0 0');
  64
  65         W_SetupProjectileVelocity(missile, cvar("g_balance_hlac_primary_speed"), spread);
  66         missile.angles = vectoangles (missile.velocity);
  67
  68         missile.touch = W_HLAC_Touch;
  69         missile.think = SUB_Remove;
  70
  71     missile.nextthink = time + cvar("g_balance_hlac_primary_lifetime");
  72
  73         missile.flags = FL_PROJECTILE;
  74         missile.projectiledeathtype = WEP_HLAC;
  75
  76         CSQCProjectile(missile, TRUE, PROJECTILE_HLAC, TRUE);
  77 }
  78
  79 void W_HLAC_Attack2f (void)
  80 {
  81         local entity missile;
  82     float spread;
  83
  84     spread = cvar("g_balance_hlac_secondary_spread");
  85
  86
  87     if(self.crouch)
  88         spread = spread * cvar("g_balance_hlac_secondary_spread_crouchmod");
  89
  90         W_SetupShot (self, FALSE, 3, "weapons/lasergun_fire.wav", cvar("g_balance_hlac_secondary_damage"));
  91         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  92
  93         missile = spawn ();
  94         missile.owner = self;
  95         missile.classname = "hlacbolt";
  96         // missile.dmg = issecondary;
  97         missile.bot_dodge = TRUE;
  98
  99     missile.bot_dodgerating = cvar("g_balance_hlac_secondary_damage");
 100
 101         missile.movetype = MOVETYPE_FLY;
 102         PROJECTILE_MAKETRIGGER(missile);
 103
 104         setorigin (missile, w_shotorg);
 105         setsize(missile, '0 0 0', '0 0 0');
 106
 107         W_SetupProjectileVelocity(missile, cvar("g_balance_hlac_secondary_speed"), spread);
 108         missile.angles = vectoangles (missile.velocity);
 109
 110         missile.touch = W_HLAC_Touch2;
 111         missile.think = SUB_Remove;
 112
 113     missile.nextthink = time + cvar("g_balance_hlac_secondary_lifetime");
 114
 115         missile.flags = FL_PROJECTILE;
 116         missile.projectiledeathtype = WEP_HLAC | HITTYPE_SECONDARY;
 117
 118         CSQCProjectile(missile, TRUE, PROJECTILE_HLAC, TRUE);
 119 }
 120
 121 void W_HLAC_Attack2 (void)
 122 {
 123     float i;
 124
 125     if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 126     {
 127         self.ammo_cells = self.ammo_cells - cvar("g_balance_hlac_secondary_ammo");
 128     }
 129
 130     for(i=cvar("g_balance_hlac_secondary_shots");i>0;--i)
 131         W_HLAC_Attack2f();
 132
 133         if (!g_norecoil)
 134         {
 135                 self.punchangle_x = random () - 0.5;
 136                 self.punchangle_y = random () - 0.5;
 137         }
 138 }
 139
 140 // weapon frames
 141 void HLAC_fire1_02()
 142 {
 143         if(self.weapon != self.switchweapon) // abort immediately if switching
 144         {
 145                 w_ready();
 146                 return;
 147         }
 148
 149         if (self.BUTTON_ATCK)
 150         {
 151                 if (!weapon_action(self.weapon, WR_CHECKAMMO1))
 152                 {
 153                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 154                         w_ready();
 155                         return;
 156                 }
 157
 158                 ATTACK_FINISHED(self) = time + cvar("g_balance_hlac_primary_refire") * W_WeaponRateFactor();
 159                 W_HLAC_Attack();
 160                 self.HLAC_bulletcounter = self.HLAC_bulletcounter + 1;
 161         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_hlac_primary_refire"), HLAC_fire1_02);
 162         }
 163         else
 164         {
 165                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_hlac_primary_animtime"), w_ready);
 166         }
 167 };
 168
 169 void spawnfunc_weapon_hlac (void)
 170 {
 171         weapon_defaultspawnfunc(WEP_HLAC);
 172 }
 173
 174 float w_hlac(float req)
 175 {
 176         if (req == WR_AIM)
 177         self.BUTTON_ATCK = bot_aim(cvar("g_balance_hlac_primary_speed"), 0, cvar("g_balance_hlac_primary_lifetime"), FALSE);
 178         else if (req == WR_THINK)
 179         {
 180                 if (self.BUTTON_ATCK)
 181                 if (weapon_prepareattack(0, cvar("g_balance_hlac_primary_refire")))
 182                 {
 183                         self.HLAC_bulletcounter = 0;
 184                         W_HLAC_Attack();
 185                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_hlac_primary_refire"), HLAC_fire1_02);
 186                 }
 187
 188                 if (self.BUTTON_ATCK2 && cvar("g_balance_hlac_secondary"))
 189                 if (weapon_prepareattack(1, cvar("g_balance_hlac_secondary_refire")))
 190                 {
 191                         W_HLAC_Attack2();
 192                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_hlac_secondary_animtime"), w_ready);
 193                 }
 194
 195         }
 196         else if (req == WR_PRECACHE)
 197         {
 198         precache_model ("models/weapons/g_hlac.md3");
 199                 precache_model ("models/weapons/v_hlac.md3");
 200                 precache_model ("models/weapons/h_hlac.iqm");
 201                 precache_sound ("weapons/lasergun_fire.wav");
 202
 203         }
 204         else if (req == WR_SETUP)
 205                 weapon_setup(WEP_HLAC);
 206         else if (req == WR_CHECKAMMO1)
 207                 return self.ammo_cells >= cvar("g_balance_hlac_primary_ammo");
 208         else if (req == WR_CHECKAMMO2)
 209                 return self.ammo_cells >= cvar("g_balance_hlac_secondary_ammo");
 210         return TRUE;
 211 };
 212 #endif
 213 #ifdef CSQC
 214 float w_hlac(float req)
 215 {
 216         if(req == WR_IMPACTEFFECT)
 217         {
 218                 vector org2;
 219                 org2 = w_org + w_backoff * 6;
 220                 pointparticles(particleeffectnum("laser_impact"), org2, w_backoff * 1000, 1);
 221                 if(!w_issilent)
 222                         sound(self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 223         }
 224         else if(req == WR_PRECACHE)
 225         {
 226                 precache_sound("weapons/laserimpact.wav");
 227         }
 228         else if (req == WR_SUICIDEMESSAGE)
 229                 w_deathtypestring = "should have used a smaller gun";
 230         else if (req == WR_KILLMESSAGE)
 231                 w_deathtypestring = "was cut down by";
 232         return TRUE;
 233 }
 234 #endif
 235 #endif