qcsrc/server/w_laser.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(LASER, w_laser, 0, 1, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, 0, "laser", "laser", _("Laser"))
   3 #else
   4 #ifdef SVQC
   5 void(float imp) W_SwitchWeapon;
   6
   7 void W_Laser_Touch (void)
   8 {
   9         PROJECTILE_TOUCH;
  10
  11         self.event_damage = SUB_Null;
  12         if (self.dmg)
  13                 RadiusDamage (self, self.owner, autocvar_g_balance_laser_secondary_damage, autocvar_g_balance_laser_secondary_edgedamage, autocvar_g_balance_laser_secondary_radius, world, autocvar_g_balance_laser_secondary_force, self.projectiledeathtype, other);
  14         else
  15                 RadiusDamage (self, self.owner, autocvar_g_balance_laser_primary_damage, autocvar_g_balance_laser_primary_edgedamage, autocvar_g_balance_laser_primary_radius, world, autocvar_g_balance_laser_primary_force, self.projectiledeathtype, other);
  16
  17         remove (self);
  18 }
  19
  20 void W_Laser_Think()
  21 {
  22         self.movetype = MOVETYPE_FLY;
  23         self.think = SUB_Remove;
  24         if (self.dmg)
  25                 self.nextthink = time + autocvar_g_balance_laser_secondary_lifetime;
  26         else
  27                 self.nextthink = time + autocvar_g_balance_laser_primary_lifetime;
  28         CSQCProjectile(self, TRUE, PROJECTILE_LASER, TRUE);
  29 }
  30
  31 void W_Laser_Attack (float issecondary)
  32 {
  33         local entity missile;
  34         vector s_forward;
  35         float a;
  36         float nodamage;
  37
  38         if(issecondary == 2) // minstanex shot
  39                 nodamage = g_minstagib;
  40         else
  41                 nodamage = FALSE;
  42
  43         a = autocvar_g_balance_laser_primary_shotangle;
  44         s_forward = v_forward * cos(a * DEG2RAD) + v_up * sin(a * DEG2RAD);
  45
  46         if(nodamage)
  47                 W_SetupShot_Dir (self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", CHAN_WEAPON2, 0);
  48         else if(issecondary == 1)
  49                 W_SetupShot_Dir (self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", CHAN_WEAPON2, autocvar_g_balance_laser_secondary_damage);
  50         else
  51                 W_SetupShot_Dir (self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", CHAN_WEAPON2, autocvar_g_balance_laser_primary_damage);
  52         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  53
  54         missile = spawn ();
  55         missile.owner = self;
  56         missile.classname = "laserbolt";
  57         missile.dmg = 0;
  58         if(!nodamage)
  59         {
  60                 missile.bot_dodge = TRUE;
  61                 missile.bot_dodgerating = autocvar_g_balance_laser_primary_damage;
  62         }
  63
  64         PROJECTILE_MAKETRIGGER(missile);
  65         missile.projectiledeathtype = WEP_LASER;
  66
  67         setorigin (missile, w_shotorg);
  68         setsize(missile, '0 0 0', '0 0 0');
  69
  70         W_SETUPPROJECTILEVELOCITY(missile, g_balance_laser_primary);
  71         missile.angles = vectoangles (missile.velocity);
  72         //missile.glow_color = 250; // 244, 250
  73         //missile.glow_size = 120;
  74         missile.touch = W_Laser_Touch;
  75
  76         missile.flags = FL_PROJECTILE;
  77
  78         missile.think = W_Laser_Think;
  79         missile.nextthink = time + autocvar_g_balance_laser_primary_delay;
  80
  81         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  82
  83         if(time >= missile.nextthink)
  84         {
  85                 entity oldself;
  86                 oldself = self;
  87                 self = missile;
  88                 self.think();
  89                 self = oldself;
  90         }
  91 }
  92
  93 .vector hook_start, hook_end;
  94 float gauntletbeam_send(entity to, float sf)
  95 {
  96         WriteByte(MSG_ENTITY, ENT_CLIENT_GAUNTLET);
  97         sf = sf & 0x7F;
  98         if(sound_allowed(MSG_BROADCAST, self.owner))
  99                 sf |= 0x80;
 100         WriteByte(MSG_ENTITY, sf);
 101         if(sf & 1)
 102         {
 103                 WriteByte(MSG_ENTITY, num_for_edict(self.owner));
 104         }
 105         if(sf & 2)
 106         {
 107                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 108                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 109                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 110         }
 111         if(sf & 4)
 112         {
 113                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 114                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 115                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 116         }
 117         return TRUE;
 118 }
 119 .entity gauntletbeam;
 120 .float prevgauntletfire;
 121 void gauntletbeam_think()
 122 {
 123         float damage, myforce, myradius;
 124         damage = autocvar_g_balance_laser_secondary_damage;
 125         myforce = autocvar_g_balance_laser_secondary_force;
 126         myradius = autocvar_g_balance_laser_secondary_radius;
 127
 128         self.owner.prevgauntletfire = time;
 129         if (self.owner.weaponentity.state != WS_INUSE || self != self.owner.gauntletbeam || self.owner.deadflag != DEAD_NO || !self.owner.BUTTON_ATCK2)
 130         {
 131                 remove(self);
 132                 return;
 133         }
 134
 135         self.nextthink = time;
 136
 137         makevectors(self.owner.v_angle);
 138
 139         float dt;
 140         dt = frametime;
 141
 142         W_SetupShot_Range(self.owner, TRUE, 0, "", 0, damage * dt, myradius);
 143         WarpZone_traceline_antilag(self.owner, w_shotorg, w_shotend, MOVE_NORMAL, self.owner, ANTILAG_LATENCY(self.owner));
 144
 145         // apply the damage
 146         if(trace_ent)
 147         {
 148                 vector force;
 149                 force = w_shotdir * myforce;
 150                 if(accuracy_isgooddamage(self.owner, trace_ent))
 151                         accuracy_add(self.owner, WEP_LASER, 0, damage * dt);
 152                 Damage (trace_ent, self.owner, self.owner, damage * dt, WEP_LASER | HITTYPE_SECONDARY, trace_endpos, force * dt);
 153         }
 154
 155         // draw effect
 156         if(w_shotorg != self.hook_start)
 157         {
 158                 self.SendFlags |= 2;
 159                 self.hook_start = w_shotorg;
 160         }
 161         if(w_shotend != self.hook_end)
 162         {
 163                 self.SendFlags |= 4;
 164                 self.hook_end = w_shotend;
 165         }
 166 }
 167
 168 // experimental gauntlet
 169 void W_Laser_Attack2 ()
 170 {
 171         // only play fire sound if 0.5 sec has passed since player let go the fire button
 172         if(time - self.prevgauntletfire > 0.5)
 173         {
 174                 sound (self, CHAN_WEAPON, "weapons/gauntlet_fire.wav", VOL_BASE, ATTN_NORM);
 175         }
 176
 177         entity beam, oldself;
 178
 179         self.gauntletbeam = beam = spawn();
 180         beam.solid = SOLID_NOT;
 181         beam.think = gauntletbeam_think;
 182         beam.owner = self;
 183         beam.movetype = MOVETYPE_NONE;
 184         beam.shot_spread = 0;
 185         beam.bot_dodge = TRUE;
 186         beam.bot_dodgerating = autocvar_g_balance_laser_primary_damage;
 187         Net_LinkEntity(beam, FALSE, 0, gauntletbeam_send);
 188
 189         oldself = self;
 190         self = beam;
 191         self.think();
 192         self = oldself;
 193 }
 194
 195 void LaserInit()
 196 {
 197         weapon_action(WEP_LASER, WR_PRECACHE);
 198         gauntlet_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_LASER), FALSE, FALSE, 1);
 199         gauntlet_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_LASER), FALSE, FALSE, 2);
 200         gauntlet_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_LASER), FALSE, FALSE, 3);
 201         gauntlet_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_LASER), FALSE, FALSE, 4);
 202 }
 203
 204 void spawnfunc_weapon_laser (void)
 205 {
 206         weapon_defaultspawnfunc(WEP_LASER);
 207 }
 208
 209 float w_laser(float req)
 210 {
 211         local float r1;
 212         local float r2;
 213         if (req == WR_AIM)
 214         {
 215                 if(autocvar_g_balance_laser_secondary)
 216                 {
 217                         r1 = autocvar_g_balance_laser_primary_damage;
 218                         r2 = autocvar_g_balance_laser_secondary_damage;
 219                         if (random() * (r2 + r1) > r1)
 220                                 self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_laser_secondary_speed, 0, autocvar_g_balance_laser_secondary_lifetime, FALSE);
 221                         else
 222                                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_laser_primary_speed, 0, autocvar_g_balance_laser_primary_lifetime, FALSE);
 223                 }
 224                 else
 225                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_laser_primary_speed, 0, autocvar_g_balance_laser_primary_lifetime, FALSE);
 226         }
 227         else if (req == WR_THINK)
 228         {
 229                 if(autocvar_g_balance_laser_reload_ammo && self.clip_load < 1) // forced reload
 230                         weapon_action(self.weapon, WR_RELOAD);
 231                 else if (self.BUTTON_ATCK)
 232                 {
 233                         if (weapon_prepareattack(0, autocvar_g_balance_laser_primary_refire))
 234                         {
 235                                 W_DecreaseAmmo(ammo_none, 1, TRUE);
 236
 237                                 W_Laser_Attack(0);
 238                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_laser_primary_animtime, w_ready);
 239                         }
 240                 }
 241                 else if (self.BUTTON_ATCK2)
 242                 {
 243                         if(autocvar_g_balance_laser_secondary)
 244                         {
 245                                 W_DecreaseAmmo(ammo_none, 1, TRUE);
 246
 247                                 if (weapon_prepareattack(0, 0))
 248                                 {
 249                                         W_Laser_Attack2();
 250                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_laser_secondary_animtime, w_ready);
 251                                 }
 252                         }
 253                         else
 254                         {
 255                                 if(self.switchweapon == WEP_LASER) // don't do this if already switching
 256                                         W_SwitchWeapon (self.cnt);
 257                         }
 258                 }
 259         }
 260         else if (req == WR_PRECACHE)
 261         {
 262                 precache_model ("models/weapons/g_laser.md3");
 263                 precache_model ("models/weapons/v_laser.md3");
 264                 precache_model ("models/weapons/h_laser.iqm");
 265                 precache_sound ("weapons/lasergun_fire.wav");
 266                 precache_sound ("weapons/gauntlet_fire.wav");
 267                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 268         }
 269         else if (req == WR_SETUP)
 270         {
 271                 weapon_setup(WEP_LASER);
 272                 self.current_ammo = ammo_none;
 273         }
 274         else if (req == WR_CHECKAMMO1)
 275         {
 276                 return TRUE;
 277         }
 278         else if (req == WR_CHECKAMMO2)
 279         {
 280                 return TRUE;
 281         }
 282         else if (req == WR_RELOAD)
 283         {
 284                 W_Reload(0, autocvar_g_balance_laser_reload_ammo, autocvar_g_balance_laser_reload_time, "weapons/reload.wav");
 285         }
 286         return TRUE;
 287 };
 288 #endif
 289 #ifdef CSQC
 290 float w_laser(float req)
 291 {
 292         if(req == WR_IMPACTEFFECT)
 293         {
 294                 vector org2;
 295                 org2 = w_org + w_backoff * 6;
 296                 pointparticles(particleeffectnum("laser_impact"), org2, w_backoff * 1000, 1);
 297                 if(!w_issilent)
 298                         sound(self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 299         }
 300         else if(req == WR_PRECACHE)
 301         {
 302                 precache_sound("weapons/laserimpact.wav");
 303         }
 304         else if (req == WR_SUICIDEMESSAGE)
 305                 w_deathtypestring = _("%s lasered themself to hell");
 306         else if (req == WR_KILLMESSAGE)
 307         {
 308                 if(w_deathtype & HITTYPE_SECONDARY)
 309                         w_deathtypestring = _("%s was cut in half by %s's gauntlet"); // unchecked: SPLASH
 310                 else
 311                         w_deathtypestring = _("%s was lasered to death by %s"); // unchecked: SPLASH
 312         }
 313         return TRUE;
 314 }
 315 #endif
 316 #endif