qcsrc/server/w_nex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", "Nex");
   3 #else
   4 #ifdef SVQC
   5 void SendCSQCNexBeamParticle(float charge) {
   6         vector v;
   7         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
   8         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   9         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
  10         WriteCoord(MSG_BROADCAST, w_shotorg_x);
  11         WriteCoord(MSG_BROADCAST, w_shotorg_y);
  12         WriteCoord(MSG_BROADCAST, w_shotorg_z);
  13         WriteCoord(MSG_BROADCAST, v_x);
  14         WriteCoord(MSG_BROADCAST, v_y);
  15         WriteCoord(MSG_BROADCAST, v_z);
  16         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  17 }
  18
  19 void W_Nex_Attack (float issecondary)
  20 {
  21         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
  22         if(issecondary)
  23         {
  24                 mydmg = cvar("g_balance_nex_secondary_damage");
  25                 myforce = cvar("g_balance_nex_secondary_force");
  26                 mymindist = cvar("g_balance_nex_secondary_damagefalloff_mindist");
  27                 mymaxdist = cvar("g_balance_nex_secondary_damagefalloff_maxdist");
  28                 myhalflife = cvar("g_balance_nex_secondary_damagefalloff_halflife");
  29                 myforcehalflife = cvar("g_balance_nex_secondary_damagefalloff_forcehalflife");
  30                 myammo = cvar("g_balance_nex_secondary_ammo");
  31         }
  32         else
  33         {
  34                 mydmg = cvar("g_balance_nex_primary_damage");
  35                 myforce = cvar("g_balance_nex_primary_force");
  36                 mymindist = cvar("g_balance_nex_primary_damagefalloff_mindist");
  37                 mymaxdist = cvar("g_balance_nex_primary_damagefalloff_maxdist");
  38                 myhalflife = cvar("g_balance_nex_primary_damagefalloff_halflife");
  39                 myforcehalflife = cvar("g_balance_nex_primary_damagefalloff_forcehalflife");
  40                 myammo = cvar("g_balance_nex_primary_ammo");
  41         }
  42
  43         float flying;
  44         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  45
  46         if(cvar("g_balance_nex_charge"))
  47         {
  48                 charge = cvar("g_balance_nex_charge_mindmg") / mydmg + (1 - cvar("g_balance_nex_charge_mindmg") / mydmg) * self.nex_charge;
  49                 self.nex_charge *= cvar("g_balance_nex_charge_shot_multiplier"); // do this AFTER setting mydmg/myforce
  50         }
  51         else
  52                 charge = 1;
  53         mydmg = mydmg * charge;
  54         myforce = myforce * charge;
  55
  56         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", mydmg);
  57
  58         yoda = 0;
  59         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
  60
  61         if(yoda && flying)
  62                 AnnounceTo(self, "yoda");
  63
  64         //beam and muzzle flash done on client
  65         SendCSQCNexBeamParticle(charge);
  66
  67         // flash and burn the wall
  68         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  69                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
  70
  71         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  72                 self.ammo_cells = self.ammo_cells - myammo;
  73 }
  74
  75 void spawnfunc_weapon_nex (void); // defined in t_items.qc
  76
  77 float w_nex(float req)
  78 {
  79         float dt;
  80         if (req == WR_AIM)
  81         {
  82                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
  83                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
  84         }
  85         else if (req == WR_THINK)
  86         {
  87                 if(cvar("g_balance_nex_charge") && self.nex_charge < cvar("g_balance_nex_charge_limit"))
  88                         self.nex_charge = min(1, self.nex_charge + cvar("g_balance_nex_charge_rate") * frametime / W_TICSPERFRAME);
  89                 if (self.BUTTON_ATCK)
  90                 {
  91                         if (weapon_prepareattack(0, cvar("g_balance_nex_primary_refire")))
  92                         {
  93                                 W_Nex_Attack(0);
  94                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_primary_animtime"), w_ready);
  95                         }
  96                 }
  97                 if (self.BUTTON_ATCK2)
  98                 {
  99                         if(cvar("g_balance_nex_secondary_charge"))
 100                         {
 101                                 dt = frametime / W_TICSPERFRAME;
 102                                 if(self.nex_charge < 1)
 103                                 {
 104                                         dt = min(dt, (1 - self.nex_charge) / cvar("g_balance_nex_secondary_charge_rate"));
 105                                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 106                                         {
 107                                                 if(cvar("g_balance_nex_secondary_ammo"))
 108                                                 {
 109                                                         dt = min(dt, (self.ammo_cells - cvar("g_balance_nex_primary_ammo")) / cvar("g_balance_nex_secondary_ammo"));
 110                                                         dt = max(0, dt);
 111                                                         if(dt > 0)
 112                                                         {
 113                                                                 self.ammo_cells = max(cvar("g_balance_nex_secondary_ammo"), self.ammo_cells - cvar("g_balance_nex_secondary_ammo") * dt);
 114                                                         }
 115                                                 }
 116                                         }
 117                                         self.nex_charge += dt * cvar("g_balance_nex_secondary_charge_rate");
 118                                 }
 119                         }
 120                         else if(cvar("g_balance_nex_secondary"))
 121                         {
 122                                 if (weapon_prepareattack(0, cvar("g_balance_nex_secondary_refire")))
 123                                 {
 124                                         W_Nex_Attack(1);
 125                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_secondary_animtime"), w_ready);
 126                                 }
 127                         }
 128                 }
 129         }
 130         else if (req == WR_PRECACHE)
 131         {
 132                 precache_model ("models/nexflash.md3");
 133                 precache_model ("models/weapons/g_nex.md3");
 134                 precache_model ("models/weapons/v_nex.md3");
 135                 precache_model ("models/weapons/h_nex.iqm");
 136                 precache_sound ("weapons/nexfire.wav");
 137                 precache_sound ("weapons/nexwhoosh1.wav");
 138                 precache_sound ("weapons/nexwhoosh2.wav");
 139                 precache_sound ("weapons/nexwhoosh3.wav");
 140         }
 141         else if (req == WR_SETUP)
 142                 weapon_setup(WEP_NEX);
 143         else if (req == WR_CHECKAMMO1)
 144                 return self.ammo_cells >= cvar("g_balance_nex_primary_ammo");
 145         else if (req == WR_CHECKAMMO2)
 146         {
 147                 if(cvar("g_balance_nex_secondary_charge"))
 148                         return self.ammo_cells >= cvar("g_balance_nex_primary_ammo");
 149                 return self.ammo_cells >= cvar("g_balance_nex_secondary_ammo");
 150         }
 151         return TRUE;
 152 };
 153 #endif
 154 #ifdef CSQC
 155 float w_nex(float req)
 156 {
 157         if(req == WR_IMPACTEFFECT)
 158         {
 159                 vector org2;
 160                 org2 = w_org + w_backoff * 6;
 161                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 162                 if(!w_issilent)
 163                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 164         }
 165         else if(req == WR_PRECACHE)
 166         {
 167                 precache_sound("weapons/neximpact.wav");
 168         }
 169         else if (req == WR_SUICIDEMESSAGE)
 170                 w_deathtypestring = "%s did the impossible";
 171         else if (req == WR_KILLMESSAGE)
 172                 w_deathtypestring = "%s has been vaporized by %s";
 173         return TRUE;
 174 }
 175 #endif
 176 #endif