qcsrc/server/w_nex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", "Nex");
   3 #else
   4 #ifdef SVQC
   5 void SendCSQCNexBeamParticle(float charge) {
   6         vector v;
   7         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
   8         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   9         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
  10         WriteCoord(MSG_BROADCAST, w_shotorg_x);
  11         WriteCoord(MSG_BROADCAST, w_shotorg_y);
  12         WriteCoord(MSG_BROADCAST, w_shotorg_z);
  13         WriteCoord(MSG_BROADCAST, v_x);
  14         WriteCoord(MSG_BROADCAST, v_y);
  15         WriteCoord(MSG_BROADCAST, v_z);
  16         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  17 }
  18
  19 void W_Nex_Attack (float issecondary)
  20 {
  21         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
  22         if(issecondary)
  23         {
  24                 mydmg = autocvar_g_balance_nex_secondary_damage;
  25                 myforce = autocvar_g_balance_nex_secondary_force;
  26                 mymindist = autocvar_g_balance_nex_secondary_damagefalloff_mindist;
  27                 mymaxdist = autocvar_g_balance_nex_secondary_damagefalloff_maxdist;
  28                 myhalflife = autocvar_g_balance_nex_secondary_damagefalloff_halflife;
  29                 myforcehalflife = autocvar_g_balance_nex_secondary_damagefalloff_forcehalflife;
  30                 myammo = autocvar_g_balance_nex_secondary_ammo;
  31         }
  32         else
  33         {
  34                 mydmg = autocvar_g_balance_nex_primary_damage;
  35                 myforce = autocvar_g_balance_nex_primary_force;
  36                 mymindist = autocvar_g_balance_nex_primary_damagefalloff_mindist;
  37                 mymaxdist = autocvar_g_balance_nex_primary_damagefalloff_maxdist;
  38                 myhalflife = autocvar_g_balance_nex_primary_damagefalloff_halflife;
  39                 myforcehalflife = autocvar_g_balance_nex_primary_damagefalloff_forcehalflife;
  40                 myammo = autocvar_g_balance_nex_primary_ammo;
  41         }
  42
  43         float flying;
  44         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  45
  46         if(autocvar_g_balance_nex_charge)
  47         {
  48                 charge = autocvar_g_balance_nex_charge_mindmg / mydmg + (1 - autocvar_g_balance_nex_charge_mindmg / mydmg) * self.nex_charge;
  49                 self.nex_charge *= autocvar_g_balance_nex_charge_shot_multiplier; // do this AFTER setting mydmg/myforce
  50                 // O RLY? -- divVerent
  51                 // YA RLY -- FruitieX
  52         }
  53         else
  54                 charge = 1;
  55         mydmg *= charge;
  56         myforce *= charge;
  57
  58         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", CHAN_WEAPON, mydmg);
  59         if(charge > autocvar_g_balance_nex_charge_limit && autocvar_g_balance_nex_charge_limit) // if the Nex is overcharged, we play an extra sound
  60         {
  61                 sound (self, CHAN_WEAPON2, "weapons/nexcharge.wav", VOL_BASE * (charge - 0.5 * autocvar_g_balance_nex_charge_limit) / (1 - 0.5 * autocvar_g_balance_nex_charge_limit), ATTN_NORM);
  62         }
  63
  64         yoda = 0;
  65         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
  66
  67         if(yoda && flying)
  68                 AnnounceTo(self, "yoda");
  69
  70         //beam and muzzle flash done on client
  71         SendCSQCNexBeamParticle(charge);
  72
  73         // flash and burn the wall
  74         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  75                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
  76
  77         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  78                 self.ammo_cells = self.ammo_cells - myammo;
  79 }
  80
  81 void spawnfunc_weapon_nex (void); // defined in t_items.qc
  82
  83 .float nex_chargepool_pauseregen_finished;
  84 float w_nex(float req)
  85 {
  86         float dt;
  87         if (req == WR_AIM)
  88         {
  89                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
  90                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
  91         }
  92         else if (req == WR_THINK)
  93         {
  94                 if(autocvar_g_balance_nex_charge && self.nex_charge < autocvar_g_balance_nex_charge_limit)
  95                         self.nex_charge = min(1, self.nex_charge + autocvar_g_balance_nex_charge_rate * frametime / W_TICSPERFRAME);
  96
  97                 if(autocvar_g_balance_nex_secondary_chargepool)
  98                         if(self.nex_chargepool_ammo < 1)
  99                         {
 100                                 if(self.nex_chargepool_pauseregen_finished < time)
 101                                         self.nex_chargepool_ammo = min(1, self.nex_chargepool_ammo + autocvar_g_balance_nex_secondary_chargepool_regen * frametime / W_TICSPERFRAME);
 102                                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_nex_secondary_chargepool_pause_health_regen);
 103                         }
 104
 105                 if (self.BUTTON_ATCK)
 106                 {
 107                         if (weapon_prepareattack(0, autocvar_g_balance_nex_primary_refire))
 108                         {
 109                                 W_Nex_Attack(0);
 110                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_nex_primary_animtime, w_ready);
 111                         }
 112                 }
 113                 if ((autocvar_g_balance_nex_secondary_charge && !autocvar_g_balance_nex_secondary) ? self.BUTTON_ZOOM : self.BUTTON_ATCK2)
 114                 {
 115                         if(autocvar_g_balance_nex_secondary_charge)
 116                         {
 117                                 self.nex_charge_rottime = time + autocvar_g_balance_nex_charge_rot_pause;
 118                                 dt = frametime / W_TICSPERFRAME;
 119
 120                                 if(self.nex_charge < 1)
 121                                 {
 122                                         if(autocvar_g_balance_nex_secondary_chargepool)
 123                                         {
 124                                                 if(autocvar_g_balance_nex_secondary_ammo)
 125                                                 {
 126                                                         // always deplete if secondary is held
 127                                                         self.nex_chargepool_ammo = max(0, self.nex_chargepool_ammo - autocvar_g_balance_nex_secondary_ammo * dt);
 128
 129                                                         dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 130                                                         self.nex_chargepool_pauseregen_finished = time + autocvar_g_balance_nex_secondary_chargepool_pause_regen;
 131                                                         dt = min(dt, self.nex_chargepool_ammo);
 132                                                         dt = max(0, dt);
 133
 134                                                         self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 135                                                 }
 136                                         }
 137
 138                                         else if(autocvar_g_balance_nex_secondary_ammo)
 139                                         {
 140                                                 if(self.BUTTON_ATCK2) // only eat ammo when the button is pressed
 141                                                 {
 142                                                         dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 143                                                         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 144                                                         {
 145                                                                 dt = min(dt, (self.ammo_cells - autocvar_g_balance_nex_primary_ammo) / autocvar_g_balance_nex_secondary_ammo);
 146                                                                 dt = max(0, dt);
 147                                                                 if(dt > 0)
 148                                                                 {
 149                                                                         self.ammo_cells = max(autocvar_g_balance_nex_secondary_ammo, self.ammo_cells - autocvar_g_balance_nex_secondary_ammo * dt);
 150                                                                 }
 151                                                         }
 152                                                         self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 153                                                 }
 154                                         }
 155
 156                                         else
 157                                         {
 158                                                 dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 159                                                 self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 160                                         }
 161                                 }
 162                         }
 163                         else if(autocvar_g_balance_nex_secondary)
 164                         {
 165                                 if (weapon_prepareattack(0, autocvar_g_balance_nex_secondary_refire))
 166                                 {
 167                                         W_Nex_Attack(1);
 168                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_nex_secondary_animtime, w_ready);
 169                                 }
 170                         }
 171                 }
 172
 173                 if(autocvar_g_balance_nex_charge)
 174                 {
 175                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_limit);
 176                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_limit);
 177                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_limit);
 178
 179                         if(self.nex_charge > autocvar_g_balance_nex_charge_limit)
 180                         {
 181                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_limit) / (1 - autocvar_g_balance_nex_charge_limit);
 182                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_limit) / (1 - autocvar_g_balance_nex_charge_limit);
 183                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_limit) / (1 - autocvar_g_balance_nex_charge_limit);
 184                         }
 185                 }
 186         }
 187         else if (req == WR_PRECACHE)
 188         {
 189                 precache_model ("models/nexflash.md3");
 190                 precache_model ("models/weapons/g_nex.md3");
 191                 precache_model ("models/weapons/v_nex.md3");
 192                 precache_model ("models/weapons/h_nex.iqm");
 193                 precache_sound ("weapons/nexfire.wav");
 194                 precache_sound ("weapons/nexcharge.wav");
 195                 precache_sound ("weapons/nexwhoosh1.wav");
 196                 precache_sound ("weapons/nexwhoosh2.wav");
 197                 precache_sound ("weapons/nexwhoosh3.wav");
 198         }
 199         else if (req == WR_SETUP)
 200                 weapon_setup(WEP_NEX);
 201         else if (req == WR_CHECKAMMO1)
 202                 return self.ammo_cells >= autocvar_g_balance_nex_primary_ammo;
 203         else if (req == WR_CHECKAMMO2)
 204                 return self.ammo_cells >= autocvar_g_balance_nex_primary_ammo; // don't allow charging if we don't have enough ammo
 205         return TRUE;
 206 };
 207 #endif
 208 #ifdef CSQC
 209 float w_nex(float req)
 210 {
 211         if(req == WR_IMPACTEFFECT)
 212         {
 213                 vector org2;
 214                 org2 = w_org + w_backoff * 6;
 215                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 216                 if(!w_issilent)
 217                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 218         }
 219         else if(req == WR_PRECACHE)
 220         {
 221                 precache_sound("weapons/neximpact.wav");
 222         }
 223         else if (req == WR_SUICIDEMESSAGE)
 224                 w_deathtypestring = "%s did the impossible";
 225         else if (req == WR_KILLMESSAGE)
 226                 w_deathtypestring = "%s has been vaporized by %s";
 227         return TRUE;
 228 }
 229 #endif
 230 #endif