qcsrc/server/w_nex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", "Nex");
   3 #else
   4 #ifdef SVQC
   5 void SendCSQCNexBeamParticle() {
   6         vector v;
   7         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
   8         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   9         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
  10
  11         WriteCoord(MSG_BROADCAST, w_shotorg_x);
  12         WriteCoord(MSG_BROADCAST, w_shotorg_y);
  13         WriteCoord(MSG_BROADCAST, w_shotorg_z);
  14         WriteCoord(MSG_BROADCAST, v_x);
  15         WriteCoord(MSG_BROADCAST, v_y);
  16         WriteCoord(MSG_BROADCAST, v_z);
  17 }
  18
  19 void W_Nex_Attack (float issecondary)
  20 {
  21         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo;
  22         if(issecondary)
  23         {
  24                 mydmg = cvar("g_balance_nex_secondary_damage");
  25                 myforce = cvar("g_balance_nex_secondary_force");
  26                 mymindist = cvar("g_balance_nex_secondary_damagefalloff_mindist");
  27                 mymaxdist = cvar("g_balance_nex_secondary_damagefalloff_maxdist");
  28                 myhalflife = cvar("g_balance_nex_secondary_damagefalloff_halflife");
  29                 myforcehalflife = cvar("g_balance_nex_secondary_damagefalloff_forcehalflife");
  30                 myammo = cvar("g_balance_nex_secondary_ammo");
  31         }
  32         else
  33         {
  34                 mydmg = cvar("g_balance_nex_primary_damage");
  35                 myforce = cvar("g_balance_nex_primary_force");
  36                 mymindist = cvar("g_balance_nex_primary_damagefalloff_mindist");
  37                 mymaxdist = cvar("g_balance_nex_primary_damagefalloff_maxdist");
  38                 myhalflife = cvar("g_balance_nex_primary_damagefalloff_halflife");
  39                 myforcehalflife = cvar("g_balance_nex_primary_damagefalloff_forcehalflife");
  40                 myammo = cvar("g_balance_nex_primary_ammo");
  41         }
  42
  43         float flying;
  44         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  45
  46         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", mydmg);
  47
  48         yoda = 0;
  49         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
  50
  51         if(yoda && flying)
  52                 AnnounceTo(self, "yoda");
  53
  54         //beam and muzzle flash done on client
  55         SendCSQCNexBeamParticle();
  56
  57         // flash and burn the wall
  58         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  59                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
  60
  61         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  62                 self.ammo_cells = self.ammo_cells - myammo;
  63 }
  64
  65 void spawnfunc_weapon_nex (void); // defined in t_items.qc
  66
  67 float w_nex(float req)
  68 {
  69         if (req == WR_AIM)
  70         {
  71                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
  72                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
  73         }
  74         else if (req == WR_THINK)
  75         {
  76                 if (self.BUTTON_ATCK)
  77                 {
  78                         if (weapon_prepareattack(0, cvar("g_balance_nex_primary_refire")))
  79                         {
  80                                 W_Nex_Attack(0);
  81                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_primary_animtime"), w_ready);
  82                         }
  83                 }
  84                 if (self.BUTTON_ATCK2)
  85                 {
  86                         if(cvar("g_balance_nex_secondary"))
  87                         {
  88                                 if (weapon_prepareattack(0, cvar("g_balance_nex_secondary_refire")))
  89                                 {
  90                                         W_Nex_Attack(1);
  91                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nex_secondary_animtime"), w_ready);
  92                                 }
  93                         }
  94                 }
  95         }
  96         else if (req == WR_PRECACHE)
  97         {
  98                 precache_model ("models/nexflash.md3");
  99                 precache_model ("models/weapons/g_nex.md3");
 100                 precache_model ("models/weapons/v_nex.md3");
 101                 precache_model ("models/weapons/h_nex.iqm");
 102                 precache_sound ("weapons/nexfire.wav");
 103                 precache_sound ("weapons/nexwhoosh1.wav");
 104                 precache_sound ("weapons/nexwhoosh2.wav");
 105                 precache_sound ("weapons/nexwhoosh3.wav");
 106         }
 107         else if (req == WR_SETUP)
 108                 weapon_setup(WEP_NEX);
 109         else if (req == WR_CHECKAMMO1)
 110                 return self.ammo_cells >= cvar("g_balance_nex_primary_ammo");
 111         else if (req == WR_CHECKAMMO2)
 112                 return self.ammo_cells >= cvar("g_balance_nex_secondary_ammo");
 113         return TRUE;
 114 };
 115 #endif
 116 #ifdef CSQC
 117 float w_nex(float req)
 118 {
 119         if(req == WR_IMPACTEFFECT)
 120         {
 121                 vector org2;
 122                 org2 = w_org + w_backoff * 6;
 123                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 124                 if(!w_issilent)
 125                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 126         }
 127         else if(req == WR_PRECACHE)
 128         {
 129                 precache_sound("weapons/neximpact.wav");
 130         }
 131         else if (req == WR_SUICIDEMESSAGE)
 132                 w_deathtypestring = "%s did the impossible";
 133         else if (req == WR_KILLMESSAGE)
 134                 w_deathtypestring = "%s has been vaporized by %s";
 135         return TRUE;
 136 }
 137 #endif
 138 #endif