qcsrc/server/w_rocketlauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ROCKET_LAUNCHER, w_rlauncher, IT_ROCKETS, 9, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "rl", "rocketlauncher", "Rocket Launcher");
   3 #else
   4 #ifdef SVQC
   5 .float rl_release;
   6 .float rl_detonate_later;
   7
   8 void W_Rocket_Unregister()
   9 {
  10         if(self.owner && self.owner.lastrocket == self)
  11         {
  12                 self.owner.lastrocket = world;
  13                 // self.owner.rl_release = 1;
  14         }
  15 }
  16
  17 void W_Rocket_Explode ()
  18 {
  19         W_Rocket_Unregister();
  20
  21         if(other.takedamage == DAMAGE_AIM)
  22                 if(other.classname == "player")
  23                         if(IsDifferentTeam(self.owner, other))
  24                                 if(IsFlying(other))
  25                                         AnnounceTo(self.owner, "airshot");
  26
  27         self.event_damage = SUB_Null;
  28         self.takedamage = DAMAGE_NO;
  29
  30         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  31
  32         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  33         {
  34                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  35                 {
  36                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  37                         ATTACK_FINISHED(self.owner) = time;
  38                         self.owner.switchweapon = w_getbestweapon(self.owner);
  39                 }
  40                 if(g_laserguided_missile)
  41                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire") * W_WeaponRateFactor();
  42         }
  43         remove (self);
  44 }
  45
  46 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  47 {
  48         entity head, selected;
  49         vector dir;
  50         float dist, maxdist,// bestdist,
  51                 dot,// bestdot,
  52                 points, bestpoints;
  53         //bestdist = 9999;
  54         //bestdot = -2;
  55         bestpoints = 0;
  56         maxdist = 800;
  57         selected = world;
  58
  59         makevectors(e.angles);
  60
  61         head = find(world, classname, "laser_target");
  62         while(head)
  63         {
  64                 points = 0;
  65                 dir = normalize(head.origin - self.origin);
  66                 dot = dir * v_forward;
  67                 dist = vlen(head.origin - self.origin);
  68                 if(dist > maxdist)
  69                         dist = maxdist;
  70
  71                 // gain points for being in front
  72                 points = points + ((dot+1)*0.5) * 500
  73                         * (1 + crandom()*dot_variance);
  74                 // gain points for being close away
  75                 points = points + (1 - dist/maxdist) * 1000
  76                         * (1 + crandom()*dot_variance);
  77
  78                 traceline(e.origin, head.origin, TRUE, self);
  79                 if(trace_fraction < 1)
  80                 {
  81                         points = 0;
  82                 }
  83
  84                 if(points > bestpoints)//random() > 0.5)//
  85                 {
  86                         bestpoints = points;
  87                         selected = head;
  88                 }
  89
  90                 head = find(head, classname, "laser_target");
  91         }
  92
  93         //bprint(selected.owner.netname);
  94         //bprint("\n");
  95         return selected;
  96 }
  97
  98 void W_Rocket_RemoteExplode()
  99 {
 100         if(self.owner.deadflag == DEAD_NO)
 101         if(self.owner.lastrocket)
 102         {
 103                 if((self.spawnshieldtime >= 0)
 104                         ? (time >= self.spawnshieldtime) // timer
 105                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_radius")) // safety device
 106                 )
 107                 {
 108                         other = world;
 109                         self.projectiledeathtype |= HITTYPE_BOUNCE;
 110                 }
 111                 else
 112                 {
 113                         W_Rocket_Unregister();
 114
 115                         if(other.takedamage == DAMAGE_AIM)
 116                                 if(other.classname == "player")
 117                                         if(IsDifferentTeam(self.owner, other))
 118                                                 if(IsFlying(other))
 119                                                         AnnounceTo(self.owner, "airshot");
 120
 121                         self.event_damage = SUB_Null;
 122                         self.takedamage = DAMAGE_NO;
 123
 124                         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_remote_damage"), cvar("g_balance_rocketlauncher_remote_edgedamage"), cvar("g_balance_rocketlauncher_remote_radius"), world, cvar("g_balance_rocketlauncher_remote_force"), self.projectiledeathtype, other);
 125
 126                         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 127                         {
 128                                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 129                                 {
 130                                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
 131                                         ATTACK_FINISHED(self.owner) = time;
 132                                         self.owner.switchweapon = w_getbestweapon(self.owner);
 133                                 }
 134                                 if(g_laserguided_missile)
 135                                         ATTACK_FINISHED(self.owner) = time + cvar("g_balance_rocketlauncher_refire") * W_WeaponRateFactor();
 136                         }
 137                         remove (self);
 138                 }
 139         }
 140 }
 141
 142 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 143 {
 144         if(thisdir * goaldir > maxturn_cos)
 145                 return goaldir;
 146         float f, m2;
 147         vector v;
 148         // solve:
 149         //   g = normalize(thisdir + goaldir * X)
 150         //   thisdir * g = maxturn
 151         //
 152         //   gg = thisdir + goaldir * X
 153         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 154         //
 155         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 156         f = thisdir * goaldir;
 157         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 158         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 159         m2 = maxturn_cos * maxturn_cos;
 160         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 161         return normalize(thisdir + goaldir * v_y); // the larger solution!
 162 }
 163
 164 void W_Rocket_Think (void)
 165 {
 166         entity e;
 167         vector desireddir, olddir, newdir, desiredorigin, goal;
 168 #if 0
 169         float cosminang, cosmaxang, cosang;
 170 #endif
 171         float turnrate, velspeed, f;
 172         self.nextthink = time;
 173         if (time > self.cnt)
 174         {
 175                 other = world;
 176                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 177                 W_Rocket_Explode ();
 178                 return;
 179         }
 180
 181         if(g_laserguided_missile)
 182         {
 183                 // accelerate
 184                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 185                 velspeed = cvar("g_balance_rocketlauncher_laserguided_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 186                 if (velspeed > 0)
 187                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_laserguided_speedaccel") * frametime, velspeed);
 188         }
 189         else
 190         {
 191                 // accelerate
 192                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 193                 velspeed = cvar("g_balance_rocketlauncher_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 194                 if (velspeed > 0)
 195                         self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * g_weaponspeedfactor * frametime, velspeed);
 196         }
 197
 198         // laser guided, or remote detonation
 199         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 200         {
 201                 if(g_laserguided_missile)
 202                 {
 203                         if(self.rl_detonate_later)
 204                                 W_Rocket_RemoteExplode();
 205
 206                         if(cvar("g_balance_rocketlauncher_laserguided_allow_steal"))
 207                         {
 208                                 if(self.owner.laser_on)
 209                                 {
 210                                         if(self.attack_finished_single < time)
 211                                         {
 212                                                 self.attack_finished_single = time + 0.2 + random()*0.3;
 213                                                 self.enemy = FindLaserTarget(self, 0.7, 0.7);
 214                                         }
 215
 216                                         if(!self.enemy)
 217                                                 self.enemy = self.owner.weaponentity.lasertarget;
 218                                 }
 219                                 else self.enemy = world;
 220                         }
 221                         else // don't allow stealing: always target my owner's laser (if it exists)
 222                                 self.enemy = self.owner.weaponentity.lasertarget;
 223
 224                         if(self.enemy != world)
 225                         {
 226                                 //bprint("Targeting ", self.enemy.owner.netname, "'s laser\n");
 227                                 velspeed = vlen(self.velocity);
 228                                 e = self.enemy;//self.owner.weaponentity.lasertarget;
 229                                 turnrate = cvar("g_balance_rocketlauncher_laserguided_turnrate");//0.65;                                                // how fast to turn
 230                                 desireddir = normalize(e.origin - self.origin);         // get direction from my position to the laser target
 231                                 olddir = normalize(self.velocity);                                      // get my current direction
 232                                 newdir = normalize(olddir + desireddir * turnrate);     // take the average of the 2 directions; not the best method but simple & easy
 233                                 self.velocity = newdir * velspeed;                                      // make me fly in the new direction at my flight speed
 234                                 self.angles = vectoangles(self.velocity);                       // turn model in the new flight direction
 235
 236                                 ATTACK_FINISHED(self.owner) = time + 0.2 * W_WeaponRateFactor();
 237                         }
 238                 }
 239                 else
 240                 {
 241                         if(self == self.owner.lastrocket)
 242                         if not(self.owner.rl_release)
 243                         if not(self.BUTTON_ATCK2)
 244                         if(cvar("g_balance_rocketlauncher_guiderate"))
 245                         if(time > self.pushltime)
 246                         if(self.owner.deadflag == DEAD_NO)
 247                         {
 248                                 f = cvar("g_balance_rocketlauncher_guideratedelay");
 249                                 if(f)
 250                                         f = bound(0, (time - self.pushltime) / f, 1);
 251                                 else
 252                                         f = 1;
 253
 254                                 velspeed = vlen(self.velocity);
 255
 256                                 makevectors(self.owner.v_angle);
 257                                 desireddir = WarpZone_RefSys_TransformVelocity(self.owner, self, v_forward);
 258                                 desiredorigin = WarpZone_RefSys_TransformOrigin(self.owner, self, self.owner.origin + self.owner.view_ofs);
 259                                 olddir = normalize(self.velocity);
 260
 261 #if 0
 262                                 // disabled this code because it doesn't do what I want it to do :P
 263                                 cosminang = cos(cvar("g_balance_rocketlauncher_guidefadeangle") * DEG2RAD);
 264                                 cosmaxang = cos(cvar("g_balance_rocketlauncher_guidemaxangle") * DEG2RAD);
 265                                 cosang = desireddir * normalize(self.origin - desiredorigin);
 266                                 if(cosminang == cosmaxang)
 267                                         f *= (cosang >= cosminang);
 268                                 else
 269                                         f *= bound(0, (cosang - cosmaxang) / (cosminang - cosmaxang), 1);
 270 #endif
 271
 272                                 // now it gets tricky... we want to move like some curve to approximate the target direction
 273                                 // but we are limiting the rate at which we can turn!
 274                                 goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 275                                 newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * f * frametime * DEG2RAD));
 276
 277                                 self.velocity = newdir * velspeed;
 278                                 self.angles = vectoangles(self.velocity);
 279
 280                                 if(!self.count)
 281                                 {
 282                                         pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 283                                         // TODO add a better sound here
 284                                         sound (self.owner, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 285                                         self.count = 1;
 286                                 }
 287                         }
 288
 289                         if(self.rl_detonate_later)
 290                                 W_Rocket_RemoteExplode();
 291                 }
 292         }
 293
 294         if(self.csqcprojectile_clientanimate == 0)
 295                 UpdateCSQCProjectile(self);
 296 }
 297
 298 void W_Rocket_Touch (void)
 299 {
 300         W_Rocket_Unregister();
 301
 302         PROJECTILE_TOUCH;
 303         W_Rocket_Explode ();
 304 }
 305
 306 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 307 {
 308         if (self.health <= 0)
 309                 return;
 310         self.health = self.health - damage;
 311         self.angles = vectoangles(self.velocity);
 312         if (self.health <= 0)
 313                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 314 }
 315
 316 void W_Rocket_Attack (void)
 317 {
 318         local entity missile;
 319         local entity flash;
 320
 321         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 322                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 323
 324         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", cvar("g_balance_rocketlauncher_damage"));
 325         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 326
 327         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 328         missile.owner = self;
 329         self.lastrocket = missile;
 330         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 331                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 332         else
 333                 missile.spawnshieldtime = -1;
 334         missile.pushltime = time + cvar("g_balance_rocketlauncher_guidedelay");
 335         missile.classname = "rocket";
 336         missile.bot_dodge = TRUE;
 337         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 338
 339         missile.takedamage = DAMAGE_YES;
 340         missile.damageforcescale = cvar("g_balance_rocketlauncher_damageforcescale");
 341         missile.health = cvar("g_balance_rocketlauncher_health");
 342         missile.event_damage = W_Rocket_Damage;
 343
 344         missile.movetype = MOVETYPE_FLY;
 345         PROJECTILE_MAKETRIGGER(missile);
 346         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 347         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 348
 349         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 350         if(g_laserguided_missile && self.laser_on)
 351                 W_SetupProjectileVelocity(missile, cvar("g_balance_rocketlauncher_laserguided_speedstart"), 0);
 352         else
 353                 W_SetupProjectileVelocity(missile, cvar("g_balance_rocketlauncher_speedstart"), 0);
 354         missile.angles = vectoangles (missile.velocity);
 355
 356         missile.touch = W_Rocket_Touch;
 357         missile.think = W_Rocket_Think;
 358         missile.nextthink = time;
 359         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 360         missile.flags = FL_PROJECTILE;
 361
 362         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0 && !g_laserguided_missile, PROJECTILE_ROCKET, FALSE); // because of fly sound
 363
 364         // muzzle flash for 1st person view
 365         flash = spawn ();
 366         setmodel (flash, "models/flash.md3"); // precision set below
 367         SUB_SetFade (flash, time, 0.1);
 368         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 369         W_AttachToShotorg(flash, '5 0 0');
 370
 371         // common properties
 372 }
 373
 374 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 375
 376 float w_rlauncher(float req)
 377 {
 378         entity rock;
 379         float rockfound;
 380         if (req == WR_AIM)
 381         {
 382                 // aim and decide to fire if appropriate
 383                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 384                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 385                 {
 386                         // decide whether to detonate rockets
 387                         local entity missile, targetlist, targ;
 388                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 389                         local float selfdamage, teamdamage, enemydamage;
 390                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 391                         coredamage = cvar("g_balance_rocketlauncher_damage");
 392                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 393                         recipricoledgeradius = 1 / edgeradius;
 394                         selfdamage = 0;
 395                         teamdamage = 0;
 396                         enemydamage = 0;
 397                         targetlist = findchainfloat(bot_attack, TRUE);
 398                         missile = find(world, classname, "rocket");
 399                         while (missile)
 400                         {
 401                                 if (missile.owner != self)
 402                                 {
 403                                         missile = find(missile, classname, "rocket");
 404                                         continue;
 405                                 }
 406                                 targ = targetlist;
 407                                 while (targ)
 408                                 {
 409                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 410                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 411                                         // count potential damage according to type of target
 412                                         if (targ == self)
 413                                                 selfdamage = selfdamage + d;
 414                                         else if (targ.team == self.team && teams_matter)
 415                                                 teamdamage = teamdamage + d;
 416                                         else if (bot_shouldattack(targ))
 417                                                 enemydamage = enemydamage + d;
 418                                         targ = targ.chain;
 419                                 }
 420                                 missile = find(missile, classname, "rocket");
 421                         }
 422                         local float desirabledamage;
 423                         desirabledamage = enemydamage;
 424                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 425                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 426                         if (self.team && teamplay != 1)
 427                                 desirabledamage = desirabledamage - teamdamage;
 428
 429                         missile = find(world, classname, "rocket");
 430                         while (missile)
 431                         {
 432                                 if (missile.owner != self)
 433                                 {
 434                                         missile = find(missile, classname, "rocket");
 435                                         continue;
 436                                 }
 437                                 makevectors(missile.v_angle);
 438                                 targ = targetlist;
 439                                 if (skill > 9) // normal players only do this for the target they are tracking
 440                                 {
 441                                         targ = targetlist;
 442                                         while (targ)
 443                                         {
 444                                                 if (
 445                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 446                                                         && desirabledamage > 0.1*coredamage
 447                                                 )self.BUTTON_ATCK2 = TRUE;
 448                                                 targ = targ.chain;
 449                                         }
 450                                 }else{
 451                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 452                                         //As the distance gets larger, a correct detonation gets near imposible
 453                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 454                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 455                                                 if(self.enemy.classname == "player")
 456                                                         if(desirabledamage >= 0.1*coredamage)
 457                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 458                                                                         self.BUTTON_ATCK2 = TRUE;
 459                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 460                                 }
 461
 462                                 missile = find(missile, classname, "rocket");
 463                         }
 464                         // if we would be doing at X percent of the core damage, detonate it
 465                         // but don't fire a new shot at the same time!
 466                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 467                                 self.BUTTON_ATCK2 = TRUE;
 468                         if ((skill > 6.5) && (selfdamage > self.health))
 469                                 self.BUTTON_ATCK2 = FALSE;
 470                         //if(self.BUTTON_ATCK2 == TRUE)
 471                         //      dprint(ftos(desirabledamage),"\n");
 472                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 473                 }
 474         }
 475         else if (req == WR_THINK)
 476         {
 477                 if(g_laserguided_missile)
 478                 {
 479                         if (self.BUTTON_ATCK && self.rl_release)
 480                         {
 481                                 rockfound = 0;
 482                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 483                                 {
 484                                         if(!rock.rl_detonate_later)
 485                                         {
 486                                                 rock.rl_detonate_later = TRUE;
 487                                                 rockfound = 1;
 488                                         }
 489                                 }
 490                                 if(rockfound)
 491                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 492                                 else
 493                                 {
 494                                         if (weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 495                                         {
 496                                                 W_Rocket_Attack();
 497                                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 498                                         }
 499                                 }
 500                                 self.rl_release = 0;
 501                         }
 502                         if (!self.BUTTON_ATCK)
 503                                 self.rl_release = 1;
 504                         if (self.BUTTON_ATCK2)
 505                         if(self.exteriorweaponentity.attack_finished_single < time)
 506                         {
 507                                 self.exteriorweaponentity.attack_finished_single = time + 0.4;
 508                                 self.laser_on = !self.laser_on;
 509                                 // UGLY WORKAROUND: play this on CHAN_WEAPON2 so it can't cut off fire sounds
 510                                 sound (self, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 511                         }
 512                 }
 513                 else
 514                 {
 515                         if (self.BUTTON_ATCK)
 516                         {
 517                                 if(self.rl_release || cvar("g_balance_rocketlauncher_guidestop"))
 518                                 if(weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 519                                 {
 520                                         W_Rocket_Attack();
 521                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 522                                         self.rl_release = 0;
 523                                 }
 524                         }
 525                         else
 526                                 self.rl_release = 1;
 527
 528                         if (self.BUTTON_ATCK2)
 529                         {
 530                                 rockfound = 0;
 531                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 532                                 {
 533                                         if(!rock.rl_detonate_later)
 534                                         {
 535                                                 rock.rl_detonate_later = TRUE;
 536                                                 rockfound = 1;
 537                                         }
 538                                 }
 539                                 if(rockfound)
 540                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 541                         }
 542                 }
 543         }
 544         else if (req == WR_PRECACHE)
 545         {
 546                 precache_model ("models/flash.md3");
 547                 precache_model ("models/weapons/g_rl.md3");
 548                 precache_model ("models/weapons/v_rl.md3");
 549                 precache_model ("models/weapons/h_rl.iqm");
 550                 precache_sound ("weapons/rocket_det.wav");
 551                 precache_sound ("weapons/rocket_fire.wav");
 552                 precache_sound ("weapons/rocket_mode.wav");
 553                 if (g_laserguided_missile)
 554                 {
 555                         precache_model ("models/laser_dot.mdl"); // rocket launcher
 556                 }
 557         }
 558         else if (req == WR_SETUP)
 559         {
 560                 weapon_setup(WEP_ROCKET_LAUNCHER);
 561                 self.rl_release = 1;
 562         }
 563         else if (req == WR_CHECKAMMO1)
 564         {
 565                 // don't switch while guiding a missile
 566                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 567                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 568                         return FALSE;
 569         }
 570         else if (req == WR_CHECKAMMO2)
 571                 return FALSE;
 572         else if (req == WR_RESETPLAYER)
 573         {
 574                 self.rl_release = 0;
 575         }
 576         return TRUE;
 577 };
 578 #endif
 579 #ifdef CSQC
 580 float w_rlauncher(float req)
 581 {
 582         if(req == WR_IMPACTEFFECT)
 583         {
 584                 vector org2;
 585                 org2 = w_org + w_backoff * 12;
 586                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 587                 if(!w_issilent)
 588                         sound(self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 589         }
 590         else if(req == WR_PRECACHE)
 591         {
 592                 precache_sound("weapons/rocket_impact.wav");
 593         }
 594         else if (req == WR_SUICIDEMESSAGE)
 595                 w_deathtypestring = "exploded";
 596         else if (req == WR_KILLMESSAGE)
 597         {
 598                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 599                         w_deathtypestring = "got too close to #'s rocket";
 600                 else if(w_deathtype & HITTYPE_SPLASH)
 601                         w_deathtypestring = "almost dodged #'s rocket";
 602                 else
 603                         w_deathtypestring = "ate #'s rocket";
 604         }
 605         return TRUE;
 606 }
 607 #endif
 608 #endif