qcsrc/server/w_rocketlauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ROCKET_LAUNCHER, w_rlauncher, IT_ROCKETS, 9, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "rl", "rocketlauncher", "Rocket Launcher");
   3 #else
   4 #ifdef SVQC
   5 .float rl_release;
   6 .float rl_detonate_later;
   7
   8 void W_Rocket_Unregister()
   9 {
  10         if(self.owner && self.owner.lastrocket == self)
  11         {
  12                 self.owner.lastrocket = world;
  13                 // self.owner.rl_release = 1;
  14         }
  15 }
  16
  17 void W_Rocket_Explode ()
  18 {
  19         W_Rocket_Unregister();
  20
  21         if(other.takedamage == DAMAGE_AIM)
  22                 if(other.classname == "player")
  23                         if(IsDifferentTeam(self.owner, other))
  24                                 if(IsFlying(other))
  25                                         AnnounceTo(self.owner, "airshot");
  26
  27         self.event_damage = SUB_Null;
  28         self.takedamage = DAMAGE_NO;
  29
  30         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_damage"), cvar("g_balance_rocketlauncher_edgedamage"), cvar("g_balance_rocketlauncher_radius"), world, cvar("g_balance_rocketlauncher_force"), self.projectiledeathtype, other);
  31
  32         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  33         {
  34                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  35                 {
  36                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  37                         ATTACK_FINISHED(self.owner) = time;
  38                         self.owner.switchweapon = w_getbestweapon(self.owner);
  39                 }
  40         }
  41         remove (self);
  42 }
  43
  44 void W_Rocket_DoRemoteExplode ()
  45 {
  46         W_Rocket_Unregister();
  47
  48         self.event_damage = SUB_Null;
  49         self.takedamage = DAMAGE_NO;
  50
  51         RadiusDamage (self, self.owner, cvar("g_balance_rocketlauncher_remote_damage"), cvar("g_balance_rocketlauncher_remote_edgedamage"), cvar("g_balance_rocketlauncher_remote_radius"), world, cvar("g_balance_rocketlauncher_remote_force"), self.projectiledeathtype | HITTYPE_BOUNCE, world);
  52
  53         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  54         {
  55                 if(self.owner.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
  56                 {
  57                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  58                         ATTACK_FINISHED(self.owner) = time;
  59                         self.owner.switchweapon = w_getbestweapon(self.owner);
  60                 }
  61         }
  62         remove (self);
  63 }
  64
  65 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
  66 {
  67         entity head, selected;
  68         vector dir;
  69         float dist, maxdist,// bestdist,
  70                 dot,// bestdot,
  71                 points, bestpoints;
  72         //bestdist = 9999;
  73         //bestdot = -2;
  74         bestpoints = 0;
  75         maxdist = 800;
  76         selected = world;
  77
  78         makevectors(e.angles);
  79
  80         head = find(world, classname, "laser_target");
  81         while(head)
  82         {
  83                 points = 0;
  84                 dir = normalize(head.origin - self.origin);
  85                 dot = dir * v_forward;
  86                 dist = vlen(head.origin - self.origin);
  87                 if(dist > maxdist)
  88                         dist = maxdist;
  89
  90                 // gain points for being in front
  91                 points = points + ((dot+1)*0.5) * 500
  92                         * (1 + crandom()*dot_variance);
  93                 // gain points for being close away
  94                 points = points + (1 - dist/maxdist) * 1000
  95                         * (1 + crandom()*dot_variance);
  96
  97                 traceline(e.origin, head.origin, TRUE, self);
  98                 if(trace_fraction < 1)
  99                 {
 100                         points = 0;
 101                 }
 102
 103                 if(points > bestpoints)//random() > 0.5)//
 104                 {
 105                         bestpoints = points;
 106                         selected = head;
 107                 }
 108
 109                 head = find(head, classname, "laser_target");
 110         }
 111
 112         //bprint(selected.owner.netname);
 113         //bprint("\n");
 114         return selected;
 115 }
 116
 117 void W_Rocket_RemoteExplode()
 118 {
 119         if(self.owner.deadflag == DEAD_NO)
 120         if(self.owner.lastrocket)
 121         {
 122                 if((self.spawnshieldtime >= 0)
 123                         ? (time >= self.spawnshieldtime) // timer
 124                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_rocketlauncher_remote_radius")) // safety device
 125                 )
 126                 {
 127                         W_Rocket_DoRemoteExplode();
 128                 }
 129         }
 130 }
 131
 132 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 133 {
 134         if(thisdir * goaldir > maxturn_cos)
 135                 return goaldir;
 136         float f, m2;
 137         vector v;
 138         // solve:
 139         //   g = normalize(thisdir + goaldir * X)
 140         //   thisdir * g = maxturn
 141         //
 142         //   gg = thisdir + goaldir * X
 143         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 144         //
 145         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 146         f = thisdir * goaldir;
 147         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 148         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 149         m2 = maxturn_cos * maxturn_cos;
 150         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 151         return normalize(thisdir + goaldir * v_y); // the larger solution!
 152 }
 153
 154 void W_Rocket_Think (void)
 155 {
 156         vector desireddir, olddir, newdir, desiredorigin, goal;
 157 #if 0
 158         float cosminang, cosmaxang, cosang;
 159 #endif
 160         float velspeed, f;
 161         self.nextthink = time;
 162         if (time > self.cnt)
 163         {
 164                 other = world;
 165                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 166                 W_Rocket_Explode ();
 167                 return;
 168         }
 169
 170         // accelerate
 171         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 172         velspeed = cvar("g_balance_rocketlauncher_speed") * g_weaponspeedfactor - (self.velocity * v_forward);
 173         if (velspeed > 0)
 174                 self.velocity = self.velocity + v_forward * min(cvar("g_balance_rocketlauncher_speedaccel") * g_weaponspeedfactor * frametime, velspeed);
 175
 176         // laser guided, or remote detonation
 177         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 178         {
 179                 if(self == self.owner.lastrocket)
 180                 if not(self.owner.rl_release)
 181                 if not(self.BUTTON_ATCK2)
 182                 if(cvar("g_balance_rocketlauncher_guiderate"))
 183                 if(time > self.pushltime)
 184                 if(self.owner.deadflag == DEAD_NO)
 185                 {
 186                         f = cvar("g_balance_rocketlauncher_guideratedelay");
 187                         if(f)
 188                                 f = bound(0, (time - self.pushltime) / f, 1);
 189                         else
 190                                 f = 1;
 191
 192                         velspeed = vlen(self.velocity);
 193
 194                         makevectors(self.owner.v_angle);
 195                         desireddir = WarpZone_RefSys_TransformVelocity(self.owner, self, v_forward);
 196                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.owner, self, self.owner.origin + self.owner.view_ofs);
 197                         olddir = normalize(self.velocity);
 198
 199 #if 0
 200                         // disabled this code because it doesn't do what I want it to do :P
 201                         cosminang = cos(cvar("g_balance_rocketlauncher_guidefadeangle") * DEG2RAD);
 202                         cosmaxang = cos(cvar("g_balance_rocketlauncher_guidemaxangle") * DEG2RAD);
 203                         cosang = desireddir * normalize(self.origin - desiredorigin);
 204                         if(cosminang == cosmaxang)
 205                                 f *= (cosang >= cosminang);
 206                         else
 207                                 f *= bound(0, (cosang - cosmaxang) / (cosminang - cosmaxang), 1);
 208 #endif
 209
 210                         // now it gets tricky... we want to move like some curve to approximate the target direction
 211                         // but we are limiting the rate at which we can turn!
 212                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + cvar("g_balance_rocketlauncher_guidegoal")) * desireddir;
 213                         newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(cvar("g_balance_rocketlauncher_guiderate") * f * frametime * DEG2RAD));
 214
 215                         self.velocity = newdir * velspeed;
 216                         self.angles = vectoangles(self.velocity);
 217
 218                         if(!self.count)
 219                         {
 220                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 221                                 // TODO add a better sound here
 222                                 sound (self.owner, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 223                                 self.count = 1;
 224                         }
 225                 }
 226
 227                 if(self.rl_detonate_later)
 228                         W_Rocket_RemoteExplode();
 229         }
 230
 231         if(self.csqcprojectile_clientanimate == 0)
 232                 UpdateCSQCProjectile(self);
 233 }
 234
 235 void W_Rocket_Touch (void)
 236 {
 237         if(WarpZone_Projectile_Touch())
 238         {
 239                 if(wasfreed(self))
 240                         W_Rocket_Unregister();
 241                 return;
 242         }
 243         W_Rocket_Unregister();
 244         W_Rocket_Explode ();
 245 }
 246
 247 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 248 {
 249         if (self.health <= 0)
 250                 return;
 251         self.health = self.health - damage;
 252         self.angles = vectoangles(self.velocity);
 253         if (self.health <= 0)
 254                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 255 }
 256
 257 void W_Rocket_Attack (void)
 258 {
 259         local entity missile;
 260         local entity flash;
 261
 262         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 263                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_rocketlauncher_ammo");
 264
 265         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CHAN_WEAPON, cvar("g_balance_rocketlauncher_damage"));
 266         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 267
 268         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 269         missile.owner = self;
 270         self.lastrocket = missile;
 271         if(cvar("g_balance_rocketlauncher_detonatedelay") >= 0)
 272                 missile.spawnshieldtime = time + cvar("g_balance_rocketlauncher_detonatedelay");
 273         else
 274                 missile.spawnshieldtime = -1;
 275         missile.pushltime = time + cvar("g_balance_rocketlauncher_guidedelay");
 276         missile.classname = "rocket";
 277         missile.bot_dodge = TRUE;
 278         missile.bot_dodgerating = cvar("g_balance_rocketlauncher_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 279
 280         missile.takedamage = DAMAGE_YES;
 281         missile.damageforcescale = cvar("g_balance_rocketlauncher_damageforcescale");
 282         missile.health = cvar("g_balance_rocketlauncher_health");
 283         missile.event_damage = W_Rocket_Damage;
 284
 285         missile.movetype = MOVETYPE_FLY;
 286         PROJECTILE_MAKETRIGGER(missile);
 287         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 288         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 289
 290         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 291         W_SetupProjectileVelocity(missile, cvar("g_balance_rocketlauncher_speedstart"), 0);
 292         missile.angles = vectoangles (missile.velocity);
 293
 294         missile.touch = W_Rocket_Touch;
 295         missile.think = W_Rocket_Think;
 296         missile.nextthink = time;
 297         missile.cnt = time + cvar("g_balance_rocketlauncher_lifetime");
 298         missile.flags = FL_PROJECTILE;
 299
 300         CSQCProjectile(missile, cvar("g_balance_rocketlauncher_guiderate") == 0 && cvar("g_balance_rocketlauncher_speedaccel") == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 301
 302         // muzzle flash for 1st person view
 303         flash = spawn ();
 304         setmodel (flash, "models/flash.md3"); // precision set below
 305         SUB_SetFade (flash, time, 0.1);
 306         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 307         W_AttachToShotorg(flash, '5 0 0');
 308
 309         // common properties
 310         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 311 }
 312
 313 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 314
 315 float w_rlauncher(float req)
 316 {
 317         entity rock;
 318         float rockfound;
 319         if (req == WR_AIM)
 320         {
 321                 // aim and decide to fire if appropriate
 322                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_rocketlauncher_speed"), 0, cvar("g_balance_rocketlauncher_lifetime"), FALSE);
 323                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 324                 {
 325                         // decide whether to detonate rockets
 326                         local entity missile, targetlist, targ;
 327                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 328                         local float selfdamage, teamdamage, enemydamage;
 329                         edgedamage = cvar("g_balance_rocketlauncher_edgedamage");
 330                         coredamage = cvar("g_balance_rocketlauncher_damage");
 331                         edgeradius = cvar("g_balance_rocketlauncher_radius");
 332                         recipricoledgeradius = 1 / edgeradius;
 333                         selfdamage = 0;
 334                         teamdamage = 0;
 335                         enemydamage = 0;
 336                         targetlist = findchainfloat(bot_attack, TRUE);
 337                         missile = find(world, classname, "rocket");
 338                         while (missile)
 339                         {
 340                                 if (missile.owner != self)
 341                                 {
 342                                         missile = find(missile, classname, "rocket");
 343                                         continue;
 344                                 }
 345                                 targ = targetlist;
 346                                 while (targ)
 347                                 {
 348                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 349                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 350                                         // count potential damage according to type of target
 351                                         if (targ == self)
 352                                                 selfdamage = selfdamage + d;
 353                                         else if (targ.team == self.team && teams_matter)
 354                                                 teamdamage = teamdamage + d;
 355                                         else if (bot_shouldattack(targ))
 356                                                 enemydamage = enemydamage + d;
 357                                         targ = targ.chain;
 358                                 }
 359                                 missile = find(missile, classname, "rocket");
 360                         }
 361                         local float desirabledamage;
 362                         desirabledamage = enemydamage;
 363                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 364                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 365                         if (self.team && teamplay != 1)
 366                                 desirabledamage = desirabledamage - teamdamage;
 367
 368                         missile = find(world, classname, "rocket");
 369                         while (missile)
 370                         {
 371                                 if (missile.owner != self)
 372                                 {
 373                                         missile = find(missile, classname, "rocket");
 374                                         continue;
 375                                 }
 376                                 makevectors(missile.v_angle);
 377                                 targ = targetlist;
 378                                 if (skill > 9) // normal players only do this for the target they are tracking
 379                                 {
 380                                         targ = targetlist;
 381                                         while (targ)
 382                                         {
 383                                                 if (
 384                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 385                                                         && desirabledamage > 0.1*coredamage
 386                                                 )self.BUTTON_ATCK2 = TRUE;
 387                                                 targ = targ.chain;
 388                                         }
 389                                 }else{
 390                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 391                                         //As the distance gets larger, a correct detonation gets near imposible
 392                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 393                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 394                                                 if(self.enemy.classname == "player")
 395                                                         if(desirabledamage >= 0.1*coredamage)
 396                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 397                                                                         self.BUTTON_ATCK2 = TRUE;
 398                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 399                                 }
 400
 401                                 missile = find(missile, classname, "rocket");
 402                         }
 403                         // if we would be doing at X percent of the core damage, detonate it
 404                         // but don't fire a new shot at the same time!
 405                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 406                                 self.BUTTON_ATCK2 = TRUE;
 407                         if ((skill > 6.5) && (selfdamage > self.health))
 408                                 self.BUTTON_ATCK2 = FALSE;
 409                         //if(self.BUTTON_ATCK2 == TRUE)
 410                         //      dprint(ftos(desirabledamage),"\n");
 411                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 412                 }
 413         }
 414         else if (req == WR_THINK)
 415         {
 416                 if (self.BUTTON_ATCK)
 417                 {
 418                         if(self.rl_release || cvar("g_balance_rocketlauncher_guidestop"))
 419                         if(weapon_prepareattack(0, cvar("g_balance_rocketlauncher_refire")))
 420                         {
 421                                 W_Rocket_Attack();
 422                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_rocketlauncher_animtime"), w_ready);
 423                                 self.rl_release = 0;
 424                         }
 425                 }
 426                 else
 427                         self.rl_release = 1;
 428
 429                 if (self.BUTTON_ATCK2)
 430                 {
 431                         rockfound = 0;
 432                         for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 433                         {
 434                                 if(!rock.rl_detonate_later)
 435                                 {
 436                                         rock.rl_detonate_later = TRUE;
 437                                         rockfound = 1;
 438                                 }
 439                         }
 440                         if(rockfound)
 441                                 sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 442                 }
 443         }
 444         else if (req == WR_PRECACHE)
 445         {
 446                 precache_model ("models/flash.md3");
 447                 precache_model ("models/weapons/g_rl.md3");
 448                 precache_model ("models/weapons/v_rl.md3");
 449                 precache_model ("models/weapons/h_rl.iqm");
 450                 precache_sound ("weapons/rocket_det.wav");
 451                 precache_sound ("weapons/rocket_fire.wav");
 452                 precache_sound ("weapons/rocket_mode.wav");
 453         }
 454         else if (req == WR_SETUP)
 455         {
 456                 weapon_setup(WEP_ROCKET_LAUNCHER);
 457                 self.rl_release = 1;
 458         }
 459         else if (req == WR_CHECKAMMO1)
 460         {
 461                 // don't switch while guiding a missile
 462                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 463                         && self.ammo_rockets < cvar("g_balance_rocketlauncher_ammo"))
 464                         return FALSE;
 465         }
 466         else if (req == WR_CHECKAMMO2)
 467                 return FALSE;
 468         else if (req == WR_RESETPLAYER)
 469         {
 470                 self.rl_release = 0;
 471         }
 472         return TRUE;
 473 };
 474 #endif
 475 #ifdef CSQC
 476 float w_rlauncher(float req)
 477 {
 478         if(req == WR_IMPACTEFFECT)
 479         {
 480                 vector org2;
 481                 org2 = w_org + w_backoff * 12;
 482                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 483                 if(!w_issilent)
 484                         sound(self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 485         }
 486         else if(req == WR_PRECACHE)
 487         {
 488                 precache_sound("weapons/rocket_impact.wav");
 489         }
 490         else if (req == WR_SUICIDEMESSAGE)
 491                 w_deathtypestring = "%s exploded";
 492         else if (req == WR_KILLMESSAGE)
 493         {
 494                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 495                         w_deathtypestring = "%s got too close to %s's rocket";
 496                 else if(w_deathtype & HITTYPE_SPLASH)
 497                         w_deathtypestring = "%s almost dodged %s's rocket";
 498                 else
 499                         w_deathtypestring = "%s ate %s's rocket";
 500         }
 501         return TRUE;
 502 }
 503 #endif
 504 #endif