qcsrc/server/w_seeker.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SEEKER, w_seeker, IT_ROCKETS, 8, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "seeker", "seeker", _("T.A.G. Seeker"))
   3 #else
   4 #ifdef SVQC
   5 //.float proxytime; = autoswitch
   6 //.float tl; = wait
   7 .entity tag_target, wps_tag_tracker;
   8 .float tag_time;
   9
  10 // ============================
  11 // Begin: Missile functions, these are general functions to be manipulated by other code
  12 // ============================
  13 void Seeker_Missile_Explode ()
  14 {
  15         self.event_damage = SUB_Null;
  16         RadiusDamage (self, self.realowner, autocvar_g_balance_seeker_missile_damage, autocvar_g_balance_seeker_missile_edgedamage, autocvar_g_balance_seeker_missile_radius, world, world, autocvar_g_balance_seeker_missile_force, self.projectiledeathtype, other);
  17
  18         remove (self);
  19 }
  20
  21 void Seeker_Missile_Touch()
  22 {
  23         PROJECTILE_TOUCH;
  24
  25         Seeker_Missile_Explode();
  26 }
  27
  28 void Seeker_Missile_Think()
  29 {
  30         entity e;
  31         vector desireddir, olddir, newdir, eorg;
  32         float turnrate;
  33         float dist;
  34         float spd;
  35
  36         if (time > self.cnt)
  37         {
  38                 self.projectiledeathtype |= HITTYPE_SPLASH;
  39                 Seeker_Missile_Explode();
  40         }
  41
  42         spd = vlen(self.velocity);
  43         spd = bound(
  44                 spd - autocvar_g_balance_seeker_missile_decel * frametime,
  45                 autocvar_g_balance_seeker_missile_speed_max,
  46                 spd + autocvar_g_balance_seeker_missile_accel * frametime
  47         );
  48
  49         if (self.enemy != world)
  50                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
  51                         self.enemy = world;
  52
  53         if (self.enemy != world)
  54         {
  55                 e               = self.enemy;
  56                 eorg            = 0.5 * (e.absmin + e.absmax);
  57                 turnrate        = autocvar_g_balance_seeker_missile_turnrate; // how fast to turn
  58                 desireddir      = normalize(eorg - self.origin);
  59                 olddir          = normalize(self.velocity); // get my current direction
  60                 dist            = vlen(eorg - self.origin);
  61
  62                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
  63                 if (autocvar_g_balance_seeker_missile_smart && (dist > autocvar_g_balance_seeker_missile_smart_mindist))
  64                 {
  65                         // Is it a better idea (shorter distance) to trace to the target itself?
  66                         if ( vlen(self.origin + olddir * self.wait) < dist)
  67                                 traceline(self.origin, self.origin + olddir * self.wait, FALSE, self);
  68                         else
  69                                 traceline(self.origin, eorg, FALSE, self);
  70
  71                         // Setup adaptive tracelength
  72                         self.wait = bound(autocvar_g_balance_seeker_missile_smart_trace_min, vlen(self.origin - trace_endpos), self.wait = autocvar_g_balance_seeker_missile_smart_trace_max);
  73
  74                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
  75                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
  76                 }
  77
  78                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
  79                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
  80         }
  81         else
  82                 dist = 0;
  83
  84         // Proxy
  85         if (autocvar_g_balance_seeker_missile_proxy)
  86         {
  87                 if ( dist <= autocvar_g_balance_seeker_missile_proxy_maxrange)
  88                 {
  89                         if (self.autoswitch == 0)
  90                         {
  91                                 self.autoswitch = time + autocvar_g_balance_seeker_missile_proxy_delay;
  92                         }
  93                         else
  94                         {
  95                                 if (self.autoswitch <= time)
  96                                 {
  97                                         Seeker_Missile_Explode();
  98                                         self.autoswitch = 0;
  99                                 }
 100                         }
 101                 }
 102                 else
 103                 {
 104                         if (self.autoswitch != 0)
 105                                 self.autoswitch = 0;
 106                 }
 107         }
 108         ///////////////
 109
 110         if (self.enemy.deadflag != DEAD_NO)
 111         {
 112                 self.enemy = world;
 113                 self.cnt = time + 1 + (random() * 4);
 114                 self.nextthink = self.cnt;
 115                 return;
 116         }
 117
 118         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 119         self.nextthink = time;// + 0.05; // csqc projectiles
 120         UpdateCSQCProjectile(self);
 121 }
 122
 123
 124
 125 void Seeker_Missile_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 126 {
 127         if (self.health <= 0)
 128                 return;
 129
 130         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 131                 return; // g_projectiles_damage says to halt
 132
 133         if (self.realowner == attacker)
 134                 self.health = self.health - (damage * 0.25);
 135         else
 136                 self.health = self.health - damage;
 137
 138         if (self.health <= 0)
 139                 W_PrepareExplosionByDamage(attacker, Seeker_Missile_Explode);
 140 }
 141
 142 /*
 143 void Seeker_Missile_Animate()
 144 {
 145         self.frame = self.frame +1;
 146         self.nextthink = time + 0.05;
 147
 148         if (self.enemy != world)
 149                 if (self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 150                         self.enemy = world;
 151
 152         if(self.frame == 5)
 153         {
 154                 self.think           = Seeker_Missile_Think;
 155                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 156
 157                 if (autocvar_g_balance_seeker_missile_proxy)
 158                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 159                 else
 160                         self.movetype    = MOVETYPE_FLYMISSILE;
 161         }
 162
 163         UpdateCSQCProjectile(self);
 164 }
 165 */
 166
 167 void Seeker_Fire_Missile(vector f_diff, entity m_target)
 168 {
 169         entity missile;
 170
 171         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_seeker_missile_ammo, autocvar_g_balance_seeker_reload_ammo);
 172
 173         makevectors(self.v_angle);
 174         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/seeker_fire.wav", CH_WEAPON_A, 0);
 175         w_shotorg += f_diff;
 176         pointparticles(particleeffectnum("seeker_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 177
 178         //self.detornator         = FALSE;
 179
 180         missile                 = spawn();
 181         missile.owner           = missile.realowner = self;
 182         missile.classname       = "seeker_missile";
 183         missile.bot_dodge       = TRUE;
 184         missile.bot_dodgerating = autocvar_g_balance_seeker_missile_damage;
 185
 186         missile.think           = Seeker_Missile_Think;
 187         missile.touch           = Seeker_Missile_Touch;
 188         missile.event_damage    = Seeker_Missile_Damage;
 189         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 190         missile.cnt             = time + autocvar_g_balance_seeker_missile_lifetime;
 191         missile.enemy           = m_target;
 192         missile.solid           = SOLID_BBOX;
 193         missile.scale           = 2;
 194         missile.takedamage      = DAMAGE_YES;
 195         missile.health          = autocvar_g_balance_seeker_missile_health;
 196         missile.damageforcescale = autocvar_g_balance_seeker_missile_damageforcescale;
 197         missile.damagedbycontents = TRUE;
 198         //missile.think           = Seeker_Missile_Animate; // csqc projectiles.
 199
 200         if (missile.enemy != world)
 201                 missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 202         else
 203                 missile.projectiledeathtype = WEP_SEEKER;
 204
 205
 206         setorigin (missile, w_shotorg);
 207         setsize (missile, '-4 -4 -4', '4 4 4');
 208         missile.movetype    = MOVETYPE_FLYMISSILE;
 209         missile.flags       = FL_PROJECTILE;
 210         W_SETUPPROJECTILEVELOCITY_UP(missile, g_balance_seeker_missile);
 211
 212         missile.angles = vectoangles (missile.velocity);
 213
 214         CSQCProjectile(missile, FALSE, PROJECTILE_SEEKER, TRUE);
 215
 216         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 217 }
 218
 219 // ============================
 220 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 221 // ============================
 222 void Seeker_Flac_Explode ()
 223 {
 224         self.event_damage = SUB_Null;
 225
 226         RadiusDamage (self, self.realowner, autocvar_g_balance_seeker_flac_damage, autocvar_g_balance_seeker_flac_edgedamage, autocvar_g_balance_seeker_flac_radius, world, world, autocvar_g_balance_seeker_flac_force, self.projectiledeathtype, other);
 227
 228         remove (self);
 229 }
 230
 231 void Seeker_Flac_Touch()
 232 {
 233         PROJECTILE_TOUCH;
 234
 235         Seeker_Flac_Explode();
 236 }
 237
 238 void Seeker_Fire_Flac()
 239 {
 240         entity missile;
 241         vector f_diff;
 242         float c;
 243
 244         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_seeker_flac_ammo, autocvar_g_balance_seeker_reload_ammo);
 245
 246         c = mod(self.bulletcounter, 4);
 247         switch(c)
 248         {
 249                 case 0:
 250                         f_diff = '-1.25 -3.75 0';
 251                         break;
 252                 case 1:
 253                         f_diff = '+1.25 -3.75 0';
 254                         break;
 255                 case 2:
 256                         f_diff = '-1.25 +3.75 0';
 257                         break;
 258                 case 3:
 259                 default:
 260                         f_diff = '+1.25 +3.75 0';
 261                         break;
 262         }
 263         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/flac_fire.wav", CH_WEAPON_A, autocvar_g_balance_seeker_flac_damage);
 264         w_shotorg += f_diff;
 265
 266         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 267
 268         missile                                 = spawn ();
 269         missile.owner                   = missile.realowner = self;
 270         missile.classname               = "missile";
 271         missile.bot_dodge               = TRUE;
 272         missile.bot_dodgerating = autocvar_g_balance_seeker_flac_damage;
 273         missile.touch                   = Seeker_Flac_Explode;
 274         missile.use                     = Seeker_Flac_Explode;
 275         missile.think                   = adaptor_think2use_hittype_splash;
 276         missile.nextthink               = time + autocvar_g_balance_seeker_flac_lifetime + autocvar_g_balance_seeker_flac_lifetime_rand;
 277         missile.solid                   = SOLID_BBOX;
 278         missile.movetype                = MOVETYPE_FLY;
 279         missile.projectiledeathtype = WEP_SEEKER;
 280         missile.projectiledeathtype = WEP_SEEKER | HITTYPE_SECONDARY;
 281         missile.flags                           = FL_PROJECTILE;
 282
 283         // csqc projectiles
 284         //missile.angles                                = vectoangles (missile.velocity);
 285         //missile.scale = 0.4; // BUG: the model is too big
 286
 287         setorigin (missile, w_shotorg);
 288         setsize (missile, '-2 -2 -2', '2 2 2');
 289
 290         W_SETUPPROJECTILEVELOCITY_UP(missile, g_balance_seeker_flac);
 291         CSQCProjectile(missile, TRUE, PROJECTILE_FLAC, TRUE);
 292
 293         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 294 }
 295
 296 // ============================
 297 // Begin: Tag and rocket controllers
 298 // ============================
 299 entity Seeker_Tagged_Info(entity isowner, entity istarget)
 300 {
 301         entity tag;
 302         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 303                 if ((tag.realowner == isowner) && (tag.tag_target == istarget))
 304                         return tag;
 305
 306         return world;
 307 }
 308
 309 void Seeker_Attack()
 310 {
 311         entity tracker, closest_target;
 312
 313         closest_target = world;
 314         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 315         {
 316                 if (closest_target)
 317                 {
 318                         if (vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 319                                 closest_target = tracker.tag_target;
 320                 }
 321                 else
 322                         closest_target = tracker.tag_target;
 323         }
 324
 325         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 326         if ((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 327                 closest_target = world;
 328
 329         Seeker_Fire_Missile('0 0 0', closest_target);
 330 }
 331
 332 void Seeker_Vollycontroller_Think() // TODO: Merge this with Seeker_Attack
 333 {
 334         float c;
 335         entity oldself,oldenemy;
 336         self.cnt = self.cnt - 1;
 337
 338         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.ammo_rockets < autocvar_g_balance_seeker_missile_ammo) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER))
 339         {
 340                 remove(self);
 341                 return;
 342         }
 343
 344         self.nextthink = time + autocvar_g_balance_seeker_missile_delay * W_WeaponRateFactor();
 345
 346         oldself = self;
 347         self = self.realowner;
 348
 349         oldenemy = self.enemy;
 350         self.enemy = oldself.enemy;
 351
 352         c = mod(self.cnt, 4);
 353         switch(c)
 354         {
 355                 case 0:
 356                         Seeker_Fire_Missile('-1.25 -3.75 0', self.enemy);
 357                         break;
 358                 case 1:
 359                         Seeker_Fire_Missile('+1.25 -3.75 0', self.enemy);
 360                         break;
 361                 case 2:
 362                         Seeker_Fire_Missile('-1.25 +3.75 0', self.enemy);
 363                         break;
 364                 case 3:
 365                 default:
 366                         Seeker_Fire_Missile('+1.25 +3.75 0', self.enemy);
 367                         break;
 368         }
 369
 370         self.enemy = oldenemy;
 371         self = oldself;
 372 }
 373
 374 void Seeker_Tracker_Think()
 375 {
 376         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 377         if ((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER)
 378         || (time > self.tag_time + autocvar_g_balance_seeker_tag_tracker_lifetime))
 379         {
 380                 if (self)
 381                 {
 382                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 383                         remove(self);
 384                 }
 385                 return;
 386         }
 387
 388         // Update the think method information
 389         self.nextthink = time;
 390 }
 391
 392 // ============================
 393 // Begin: Tag projectile
 394 // ============================
 395 void Seeker_Tag_Explode ()
 396 {
 397         //if(other==self.realowner)
 398         //    return;
 399         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_BOUNCE, other.species, self);
 400
 401         remove (self);
 402 }
 403
 404 void Seeker_Tag_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 405 {
 406         if (self.health <= 0)
 407                 return;
 408         self.health = self.health - damage;
 409         if (self.health <= 0)
 410                 Seeker_Tag_Explode();
 411 }
 412
 413 void Seeker_Tag_Touch()
 414 {
 415         vector dir;
 416         vector org2;
 417         entity e;
 418
 419         PROJECTILE_TOUCH;
 420
 421         dir     = normalize (self.realowner.origin - self.origin);
 422         org2    = findbetterlocation (self.origin, 8);
 423
 424         te_knightspike(org2);
 425
 426         self.event_damage = SUB_Null;
 427         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER | HITTYPE_HEADSHOT, other.species, self);
 428
 429         if (other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 430         {
 431                 // check to see if this person is already tagged by me
 432                 entity tag = Seeker_Tagged_Info(self.realowner, other);
 433
 434                 if (tag != world)
 435                 {
 436                         if (other.wps_tag_tracker && (autocvar_g_balance_seeker_type == 1)) // don't attach another waypointsprite without killing the old one first
 437                                 WaypointSprite_Kill(other.wps_tag_tracker);
 438
 439                         tag.tag_time = time;
 440                 }
 441                 else
 442                 {
 443                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 444                         e             = spawn();
 445                         e.cnt         = autocvar_g_balance_seeker_missile_count;
 446                         e.classname   = "tag_tracker";
 447                         e.owner       = self.owner;
 448                         e.realowner   = self.realowner;
 449
 450                         if      (autocvar_g_balance_seeker_type == 1)
 451                         {
 452                                 e.tag_target  = other;
 453                                 e.tag_time    = time;
 454                                 e.think       = Seeker_Tracker_Think;
 455                         }
 456                         else
 457                         {
 458                                 e.enemy     = other;
 459                                 e.think     = Seeker_Vollycontroller_Think;
 460                         }
 461
 462                         e.nextthink   = time;
 463                 }
 464
 465                 if      (autocvar_g_balance_seeker_type == 1)
 466                 {
 467                         WaypointSprite_Spawn("tagged-target", autocvar_g_balance_seeker_tag_tracker_lifetime, 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, TRUE, RADARICON_TAGGED, '0.5 1 0');
 468                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 469                 }
 470         }
 471
 472         remove(self);
 473         return;
 474 }
 475
 476 void Seeker_Fire_Tag()
 477 {
 478         entity missile;
 479         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_seeker_tag_ammo, autocvar_g_balance_seeker_reload_ammo);
 480
 481         W_SetupShot_ProjectileSize (self, '-2 -2 -2', '2 2 2', FALSE, 2, "weapons/tag_fire.wav", CH_WEAPON_A, autocvar_g_balance_seeker_missile_damage * autocvar_g_balance_seeker_missile_count);
 482
 483         missile                 = spawn();
 484         missile.owner           = missile.realowner = self;
 485         missile.classname       = "seeker_tag";
 486         missile.bot_dodge       = TRUE;
 487         missile.bot_dodgerating = 50;
 488         missile.touch           = Seeker_Tag_Touch;
 489         missile.think           = SUB_Remove;
 490         missile.nextthink       = time + autocvar_g_balance_seeker_tag_lifetime;
 491         missile.movetype        = MOVETYPE_FLY;
 492         missile.solid           = SOLID_BBOX;
 493
 494         missile.takedamage       = DAMAGE_YES;
 495         missile.event_damage    = Seeker_Tag_Explode;
 496         missile.health          = autocvar_g_balance_seeker_tag_health;
 497         missile.damageforcescale = autocvar_g_balance_seeker_tag_damageforcescale;
 498
 499         setorigin (missile, w_shotorg);
 500         setsize (missile, '-2 -2 -2', '2 2 2');
 501
 502         missile.flags       = FL_PROJECTILE;
 503
 504         missile.movetype    = MOVETYPE_FLY;
 505         W_SETUPPROJECTILEVELOCITY(missile, g_balance_seeker_tag);
 506         missile.angles = vectoangles (missile.velocity);
 507
 508         CSQCProjectile(missile, TRUE, PROJECTILE_TAG, FALSE); // has sound
 509
 510         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 511 }
 512
 513 // ============================
 514 // Begin: Genereal weapon functions
 515 // ============================
 516 void spawnfunc_weapon_seeker (void)
 517 {
 518         weapon_defaultspawnfunc(WEP_SEEKER);
 519 }
 520
 521 float w_seeker(float req)
 522 {
 523         float ammo_amount;
 524
 525         if (req == WR_AIM)
 526         {
 527                 if (autocvar_g_balance_seeker_type == 1)
 528                         if (Seeker_Tagged_Info(self, self.enemy) != world)
 529                                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_seeker_missile_speed_max, 0, autocvar_g_balance_seeker_missile_lifetime, FALSE);
 530                         else
 531                                 self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_seeker_tag_speed, 0, autocvar_g_balance_seeker_tag_lifetime, FALSE);
 532                 else
 533                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_seeker_tag_speed, 0, autocvar_g_balance_seeker_tag_lifetime, FALSE);
 534         }
 535         else if (req == WR_THINK)
 536         {
 537                 if(autocvar_g_balance_seeker_reload_ammo && self.clip_load < min(autocvar_g_balance_seeker_missile_ammo, autocvar_g_balance_seeker_tag_ammo)) // forced reload
 538                         weapon_action(self.weapon, WR_RELOAD);
 539
 540                 else if (self.BUTTON_ATCK)
 541                 {
 542                         if (autocvar_g_balance_seeker_type == 1)
 543                         {
 544                                 if (weapon_prepareattack(0, autocvar_g_balance_seeker_missile_refire))
 545                                 {
 546                                         Seeker_Attack();
 547                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_seeker_missile_animtime, w_ready);
 548                                 }
 549                         }
 550                         else
 551                         {
 552                                 if (weapon_prepareattack(0, autocvar_g_balance_seeker_tag_refire))
 553                                 {
 554                                         Seeker_Fire_Tag();
 555                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_seeker_tag_animtime, w_ready);
 556                                 }
 557                         }
 558                 }
 559
 560                 else if (self.BUTTON_ATCK2)
 561                 {
 562                         if (autocvar_g_balance_seeker_type == 1)
 563                         {
 564                                 if (weapon_prepareattack(0, autocvar_g_balance_seeker_tag_refire))
 565                                 {
 566                                         Seeker_Fire_Tag();
 567                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_seeker_tag_animtime, w_ready);
 568                                 }
 569                         }
 570                         else
 571                         {
 572                                 if (weapon_prepareattack(0, autocvar_g_balance_seeker_flac_refire))
 573                                 {
 574                                         Seeker_Fire_Flac();
 575                                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_seeker_flac_animtime, w_ready);
 576                                 }
 577                         }
 578                 }
 579         }
 580         else if (req == WR_PRECACHE)
 581         {
 582                 precache_model ("models/weapons/g_seeker.md3");
 583                 precache_model ("models/weapons/v_seeker.md3");
 584                 precache_model ("models/weapons/h_seeker.iqm");
 585                 precache_sound ("weapons/tag_fire.wav");
 586                 precache_sound ("weapons/flac_fire.wav");
 587                 precache_sound ("weapons/seeker_fire.wav");
 588                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 589         }
 590         else if (req == WR_SETUP)
 591         {
 592                 weapon_setup(WEP_SEEKER);
 593                 self.current_ammo = ammo_rockets;
 594         }
 595         else if (req == WR_CHECKAMMO1)
 596         {
 597                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_seeker_missile_ammo;
 598                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= autocvar_g_balance_seeker_missile_ammo;
 599                 return ammo_amount;
 600         }
 601         else if (req == WR_CHECKAMMO2)
 602         {
 603                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_seeker_tag_ammo;
 604                 ammo_amount += self.(weapon_load[WEP_SEEKER]) >= autocvar_g_balance_seeker_tag_ammo;
 605                 return ammo_amount;
 606         }
 607         else if (req == WR_RELOAD)
 608         {
 609                 W_Reload(min(autocvar_g_balance_seeker_missile_ammo, autocvar_g_balance_seeker_tag_ammo), autocvar_g_balance_seeker_reload_ammo, autocvar_g_balance_seeker_reload_time, "weapons/reload.wav");
 610         }
 611         return TRUE;
 612 }
 613 #endif
 614 #ifdef CSQC
 615 float w_seeker(float req)
 616 {
 617         if(req == WR_IMPACTEFFECT)
 618         {
 619                 vector org2;
 620                 org2 = w_org + w_backoff * 6;
 621                 if(w_deathtype & HITTYPE_BOUNCE)
 622                 {
 623                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 624                         if(!w_issilent)
 625                         {
 626                                 if (w_random<0.15)
 627                                         sound(self, CH_SHOTS, "weapons/tagexp1.wav", 1, ATTN_NORM);
 628                                 else if (w_random<0.7)
 629                                         sound(self, CH_SHOTS, "weapons/tagexp2.wav", 1, ATTN_NORM);
 630                                 else
 631                                         sound(self, CH_SHOTS, "weapons/tagexp3.wav", 1, ATTN_NORM);
 632                         }
 633                 }
 634                 else if(w_deathtype & HITTYPE_HEADSHOT)
 635                 {
 636                         if(!w_issilent)
 637                                 sound(self, CH_SHOTS, "weapons/tag_impact.wav", 1, ATTN_NORM);
 638                 }
 639                 else
 640                 {
 641                         pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 642                         if(!w_issilent)
 643                         {
 644                                 if (w_random<0.15)
 645                                         sound(self, CH_SHOTS, "weapons/seekerexp1.wav", 1, ATTN_NORM);
 646                                 else if (w_random<0.7)
 647                                         sound(self, CH_SHOTS, "weapons/seekerexp2.wav", 1, ATTN_NORM);
 648                                 else
 649                                         sound(self, CH_SHOTS, "weapons/seekerexp3.wav", 1, ATTN_NORM);
 650                         }
 651                 }
 652         }
 653         else if(req == WR_PRECACHE)
 654         {
 655                 precache_sound("weapons/seekerexp1.wav");
 656                 precache_sound("weapons/seekerexp2.wav");
 657                 precache_sound("weapons/seekerexp3.wav");
 658                 precache_sound("weapons/tagexp1.wav");
 659                 precache_sound("weapons/tagexp2.wav");
 660                 precache_sound("weapons/tagexp3.wav");
 661                 precache_sound("weapons/tag_impact.wav");
 662         }
 663         else if (req == WR_SUICIDEMESSAGE)
 664                 w_deathtypestring = _("%s played with tiny seeker rockets");
 665         else if (req == WR_KILLMESSAGE)
 666         {
 667                 if(w_deathtype & HITTYPE_SECONDARY)
 668                         w_deathtypestring = _("%s was tagged with a seeker by %s");
 669                 else
 670                         w_deathtypestring = _("%s was pummeled with seeker rockets by %s");
 671         }
 672         return TRUE;
 673 }
 674 #endif
 675 #endif