qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", "Shotgun");
   3 #else
   4 #ifdef SVQC
   5 void W_Shotgun_Attack (void)
   6 {
   7         float   sc;
   8         float   ammoamount;
   9         float   bullets;
  10         float   d;
  11         float   f;
  12         float   spread;
  13         float   bulletspeed;
  14         float   bulletconstant;
  15         local entity flash;
  16
  17         ammoamount = cvar("g_balance_shotgun_primary_ammo");
  18         bullets = cvar("g_balance_shotgun_primary_bullets");
  19         d = cvar("g_balance_shotgun_primary_damage");
  20         f = cvar("g_balance_shotgun_primary_force");
  21         spread = cvar("g_balance_shotgun_primary_spread");
  22         bulletspeed = cvar("g_balance_shotgun_primary_speed");
  23         bulletconstant = cvar("g_balance_shotgun_primary_bulletconstant");
  24
  25         W_SetupShot (self, cvar("g_antilag_bullets") && bulletspeed >= cvar("g_antilag_bullets"), 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  26         for (sc = 0;sc < bullets;sc = sc + 1)
  27                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  28         endFireBallisticBullet();
  29         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  30                 self.ammo_shells = self.ammo_shells - ammoamount;
  31
  32         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, cvar("g_balance_shotgun_primary_ammo"));
  33
  34         // casing code
  35         if (cvar("g_casings") >= 1)
  36                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  37                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  38
  39         // muzzle flash for 1st person view
  40         flash = spawn();
  41         setmodel(flash, "models/uziflash.md3"); // precision set below
  42         flash.think = SUB_Remove;
  43         flash.nextthink = time + 0.06;
  44         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  45         W_AttachToShotorg(flash, '5 0 0');
  46
  47 }
  48
  49 void shotgun_meleethink (void)
  50 {
  51         // store time when we started swinging down inside self.cnt
  52         if(!self.cnt)
  53                 self.cnt = time;
  54
  55         makevectors(self.owner.v_angle);
  56         vector angle;
  57         angle = v_forward;
  58
  59         // perform trace
  60         float f;
  61         f = (self.cnt + cvar("g_balance_shotgun_secondary_melee_time") - time) / cvar("g_balance_shotgun_secondary_melee_time") * 2 - 1;
  62         vector targpos;
  63         targpos = self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_shotgun_secondary_melee_range") + v_right * f * cvar("g_balance_shotgun_secondary_melee_swing") + v_up * f * cvar("g_balance_shotgun_secondary_melee_swing");
  64
  65         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
  66
  67         // apply the damage, also remove self
  68         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
  69         {
  70                 vector force;
  71                 force = angle * cvar("g_balance_shotgun_secondary_force");
  72                 if(accuracy_isgooddamage(self.owner, trace_ent))
  73                         accuracy_add(self.owner, WEP_SHOTGUN, 0, cvar("g_balance_shotgun_secondary_damage") * min(1, f + 1));
  74                 Damage (trace_ent, self.owner, self.owner, cvar("g_balance_shotgun_secondary_damage") * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
  75                 remove(self);
  76         }
  77         else if(time >= self.cnt + cvar("g_balance_shotgun_secondary_melee_time")) // missed, remove ent
  78                 remove(self);
  79         else // continue swinging the weapon in hope of hitting someone :)
  80                 self.nextthink = time;
  81 }
  82
  83 void W_Shotgun_Attack2 (void)
  84 {
  85         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
  86         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), w_ready);
  87
  88         entity meleetemp;
  89         meleetemp = spawn();
  90         meleetemp.owner = self;
  91         meleetemp.think = shotgun_meleethink;
  92         meleetemp.nextthink = time + cvar("g_balance_shotgun_secondary_melee_delay");
  93         W_SetupShot_Range(self, TRUE, 0, "", 0, cvar("g_balance_shotgun_secondary_damage"), cvar("g_balance_shotgun_secondary_melee_range"));
  94 }
  95
  96 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
  97
  98 .float shotgun_primarytime;
  99
 100 float w_shotgun(float req)
 101 {
 102         if (req == WR_AIM)
 103                 if(vlen(self.origin-self.enemy.origin)>200)
 104                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 105                 else
 106                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 107         else if (req == WR_THINK)
 108         {
 109                 if (self.BUTTON_ATCK)
 110                 {
 111                         if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 112                         {
 113                                 if(weapon_prepareattack(0, cvar("g_balance_shotgun_primary_animtime")))
 114                                 {
 115                                         W_Shotgun_Attack();
 116                                         self.shotgun_primarytime = time + cvar("g_balance_shotgun_primary_refire");
 117                                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_shotgun_primary_animtime"), w_ready);
 118                                 }
 119                         }
 120                 }
 121                 if (self.BUTTON_ATCK2 && cvar("g_balance_shotgun_secondary"))
 122                 if (weapon_prepareattack(1, cvar("g_balance_shotgun_secondary_refire")))
 123                 {
 124                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 125                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 126                 }
 127         }
 128         else if (req == WR_PRECACHE)
 129         {
 130                 precache_model ("models/uziflash.md3");
 131                 precache_model ("models/weapons/g_shotgun.md3");
 132                 precache_model ("models/weapons/v_shotgun.md3");
 133                 precache_model ("models/weapons/h_shotgun.iqm");
 134                 precache_sound ("misc/itempickup.wav");
 135                 precache_sound ("weapons/shotgun_fire.wav");
 136                 precache_sound ("weapons/shotgun_melee.wav");
 137         }
 138         else if (req == WR_SETUP)
 139                 weapon_setup(WEP_SHOTGUN);
 140         else if (req == WR_CHECKAMMO1)
 141                 return self.ammo_shells >= cvar("g_balance_shotgun_primary_ammo");
 142         else if (req == WR_CHECKAMMO2)
 143         {
 144                 return TRUE;
 145         }
 146         return TRUE;
 147 };
 148 #endif
 149 #ifdef CSQC
 150 .float prevric;
 151 float w_shotgun(float req)
 152 {
 153         if(req == WR_IMPACTEFFECT)
 154         {
 155                 vector org2;
 156                 org2 = w_org + w_backoff * 2;
 157                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 158                 if(!w_issilent && time - self.prevric > 0.25)
 159                 {
 160                         if(w_random < 0.0165)
 161                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 162                         else if(w_random < 0.033)
 163                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 164                         else if(w_random < 0.05)
 165                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 166                         self.prevric = time;
 167                 }
 168         }
 169         else if(req == WR_PRECACHE)
 170         {
 171                 precache_sound("weapons/ric1.wav");
 172                 precache_sound("weapons/ric2.wav");
 173                 precache_sound("weapons/ric3.wav");
 174         }
 175         else if (req == WR_SUICIDEMESSAGE)
 176                 w_deathtypestring = "%s did the impossible";
 177         else if (req == WR_KILLMESSAGE)
 178         {
 179                 if(w_deathtype & HITTYPE_SECONDARY)
 180                         w_deathtypestring = "%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun";
 181                 else
 182                         w_deathtypestring = "%s was gunned by %s";
 183         }
 184         return TRUE;
 185 }
 186 #endif
 187 #endif