5ecfcfac324faca416eb17924b5a416b72d3b420
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / w_shotgun.qc
1 #ifdef REGISTER_WEAPON
2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", "Shotgun");
3 #else
4 #ifdef SVQC
5 void W_Shotgun_Attack (void)
6 {
7         float   sc;
8         float   ammoamount;
9         float   bullets;
10         float   d;
11         float   f;
12         float   spread;
13         float   bulletspeed;
14         float   bulletconstant;
15         local entity flash;
16
17         ammoamount = cvar("g_balance_shotgun_primary_ammo");
18         bullets = cvar("g_balance_shotgun_primary_bullets");
19         d = cvar("g_balance_shotgun_primary_damage");
20         f = cvar("g_balance_shotgun_primary_force");
21         spread = cvar("g_balance_shotgun_primary_spread");
22         bulletspeed = cvar("g_balance_shotgun_primary_speed");
23         bulletconstant = cvar("g_balance_shotgun_primary_bulletconstant");
24
25         W_SetupShot (self, cvar("g_antilag_bullets") && bulletspeed >= cvar("g_antilag_bullets"), 5, "weapons/shotgun_fire.wav", cvar("g_balance_shotgun_primary_damage"));
26         for (sc = 0;sc < bullets;sc = sc + 1)
27                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
28         endFireBallisticBullet();
29         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
30                 self.ammo_shells = self.ammo_shells - ammoamount;
31
32         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, cvar("g_balance_shotgun_primary_ammo"));
33
34         // casing code
35         if (cvar("g_casings") >= 1)
36                 for (sc = 0;sc < ammoamount;sc = sc + 1)
37                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
38
39         // muzzle flash for 1st person view
40         flash = spawn();
41         setmodel(flash, "models/uziflash.md3"); // precision set below
42         flash.think = SUB_Remove;
43         flash.nextthink = time + 0.06;
44         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
45         W_AttachToShotorg(flash, '5 0 0');
46
47 }
48
49 void shotgun_meleethink (void)
50 {
51         // store time when we started swinging down inside self.cnt
52         if(!self.cnt)
53                 self.cnt = time;
54
55         makevectors(self.owner.v_angle);
56         vector angle;
57         angle = v_forward;
58
59         // perform trace
60         float f;
61         f = (self.cnt + cvar("g_balance_shotgun_secondary_melee_time") - time) / cvar("g_balance_shotgun_secondary_melee_time") * 2 - 1;
62         vector targpos;
63         targpos = self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_shotgun_secondary_melee_range") + v_right * f * cvar("g_balance_shotgun_secondary_melee_swing") + v_up * f * cvar("g_balance_shotgun_secondary_melee_swing");
64
65         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
66
67         // apply the damage, also remove self
68         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
69         {
70                 vector force;
71                 force = angle * cvar("g_balance_shotgun_secondary_force");
72                 Damage (trace_ent, self.owner, self.owner, cvar("g_balance_shotgun_secondary_damage") * ((f + 1) / 2), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
73                 Damage_RecordDamage(self.owner, WEP_SHOTGUN | HITTYPE_SECONDARY, cvar("g_balance_shotgun_secondary_damage") * ((f + 1) / 2));
74                 remove(self);
75         }
76         else if(time >= self.cnt + cvar("g_balance_shotgun_secondary_melee_time")) // missed, remove ent
77                 remove(self);
78         else // continue swinging the weapon in hope of hitting someone :)
79                 self.nextthink = time;
80 }
81
82 void W_Shotgun_Attack2 (void)
83 {
84         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
85         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), w_ready);
86
87         entity meleetemp;
88         meleetemp = spawn();
89         meleetemp.owner = self;
90         meleetemp.think = shotgun_meleethink;
91         meleetemp.nextthink = time + cvar("g_balance_shotgun_secondary_melee_delay");
92         W_SetupShot_Range(self, TRUE, 0, "", cvar("g_balance_shotgun_secondary_damage"), cvar("g_balance_shotgun_secondary_melee_range"));
93 }
94
95 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
96
97 float w_shotgun(float req)
98 {
99         if (req == WR_AIM)
100                 if(vlen(self.origin-self.enemy.origin)>200)
101                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
102                 else
103                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
104         else if (req == WR_THINK)
105         {
106                 if (self.BUTTON_ATCK)
107                 if (weapon_prepareattack(0, cvar("g_balance_shotgun_primary_refire")))
108                 {
109                         W_Shotgun_Attack();
110                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_shotgun_primary_animtime"), w_ready);
111                 }
112                 if (self.BUTTON_ATCK2 && cvar("g_balance_shotgun_secondary"))
113                 if (weapon_prepareattack(1, cvar("g_balance_shotgun_secondary_refire")))
114                 {
115                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
116                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
117                 }
118         }
119         else if (req == WR_PRECACHE)
120         {
121                 precache_model ("models/uziflash.md3");
122                 precache_model ("models/weapons/g_shotgun.md3");
123                 precache_model ("models/weapons/v_shotgun.md3");
124                 precache_model ("models/weapons/h_shotgun.iqm");
125                 precache_sound ("misc/itempickup.wav");
126                 precache_sound ("weapons/shotgun_fire.wav");
127                 precache_sound ("weapons/shotgun_melee.wav");
128         }
129         else if (req == WR_SETUP)
130                 weapon_setup(WEP_SHOTGUN);
131         else if (req == WR_CHECKAMMO1)
132                 return self.ammo_shells >= cvar("g_balance_shotgun_primary_ammo");
133         else if (req == WR_CHECKAMMO2)
134         {
135                 return TRUE;
136         }
137         return TRUE;
138 };
139 #endif
140 #ifdef CSQC
141 float w_shotgun(float req)
142 {
143         if(req == WR_IMPACTEFFECT)
144         {
145                 vector org2;
146                 org2 = w_org + w_backoff * 2;
147                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
148                 if(!w_issilent)
149                 {
150                         if(w_random < 0.05)
151                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
152                         else if(w_random < 0.1)
153                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
154                         else if(w_random < 0.2)
155                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
156                 }
157         }
158         else if(req == WR_PRECACHE)
159         {
160                 precache_sound("weapons/ric1.wav");
161                 precache_sound("weapons/ric2.wav");
162                 precache_sound("weapons/ric3.wav");
163         }
164         else if (req == WR_SUICIDEMESSAGE)
165                 w_deathtypestring = "%s did the impossible";
166         else if (req == WR_KILLMESSAGE)
167         {
168                 if(w_deathtype & HITTYPE_SECONDARY)
169                         w_deathtypestring = "%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun";
170                 else
171                         w_deathtypestring = "%s was gunned by %s";
172         }
173         return TRUE;
174 }
175 #endif
176 #endif