qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_Shotgun_Attack (void)
   7 {
   8         float   sc;
   9         float   ammoamount;
  10         float   bullets;
  11         float   d;
  12         float   f;
  13         float   spread;
  14         float   bulletspeed;
  15         float   bulletconstant;
  16         local entity flash;
  17
  18         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  19         bullets = autocvar_g_balance_shotgun_primary_bullets;
  20         d = autocvar_g_balance_shotgun_primary_damage;
  21         f = autocvar_g_balance_shotgun_primary_force;
  22         spread = autocvar_g_balance_shotgun_primary_spread;
  23         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  24         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  25
  26         W_DecreaseAmmo(ammo_shells, ammoamount, autocvar_g_balance_shotgun_reload_ammo);
  27
  28         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CH_WEAPON_A, d * bullets);
  29         for (sc = 0;sc < bullets;sc = sc + 1)
  30                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  31         endFireBallisticBullet();
  32
  33         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  34
  35         // casing code
  36         if (autocvar_g_casings >= 1)
  37                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  38                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  39
  40         // muzzle flash for 1st person view
  41         flash = spawn();
  42         setmodel(flash, "models/uziflash.md3"); // precision set below
  43         flash.think = SUB_Remove;
  44         flash.nextthink = time + 0.06;
  45         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  46         W_AttachToShotorg(flash, '5 0 0');
  47 }
  48
  49 entity lgbeam_owner_ent;
  50 void shotgun_meleethink (void)
  51 {
  52         // store time when we started swinging down inside self.cnt
  53         if(!self.cnt)
  54                 self.cnt = time;
  55
  56         makevectors(self.realowner.v_angle);
  57         vector angle;
  58         angle = v_forward;
  59
  60         float meleetime;
  61         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  62
  63         // perform trace
  64         float f;
  65         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
  66         vector targpos;
  67         targpos = self.realowner.origin + self.realowner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
  68
  69         if(!lgbeam_owner_ent)
  70         {
  71                 lgbeam_owner_ent = spawn();
  72                 lgbeam_owner_ent.classname = "lgbeam_owner_ent";
  73         }
  74         WarpZone_traceline_antilag(lgbeam_owner_ent, self.realowner.origin + self.realowner.view_ofs, targpos, FALSE, lgbeam_owner_ent, ANTILAG_LATENCY(self.realowner));
  75
  76         // apply the damage, also remove self
  77         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
  78         {
  79                 vector force;
  80                 force = angle * autocvar_g_balance_shotgun_secondary_force;
  81                 if(accuracy_isgooddamage(self.realowner, trace_ent))
  82                         accuracy_add(self.realowner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
  83                 Damage (trace_ent, self.realowner, self.realowner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.realowner.origin + self.realowner.view_ofs, force);
  84                 remove(self);
  85         }
  86         else if(time >= self.cnt + meleetime || (self.realowner.deadflag != DEAD_NO && autocvar_g_balance_shotgun_secondary_melee_no_doubleslap)) // missed or owner died, remove ent
  87                 remove(self);
  88         else // continue swinging the weapon in hope of hitting someone :)
  89                 self.nextthink = time;
  90 }
  91
  92 void W_Shotgun_Attack2 (void)
  93 {
  94         sound (self, CH_SHOTS, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
  95         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
  96
  97         entity meleetemp;
  98         meleetemp = spawn();
  99         meleetemp.owner = meleetemp.realowner = self;
 100         meleetemp.think = shotgun_meleethink;
 101         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 102         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 103 }
 104
 105 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 106
 107 .float shotgun_primarytime;
 108
 109 float w_shotgun(float req)
 110 {
 111         float ammo_amount;
 112         if (req == WR_AIM)
 113                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 114                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 115                 else
 116                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 117         else if (req == WR_THINK)
 118         {
 119                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 120                 {
 121                         // don't force reload an empty shotgun if its melee attack is active
 122                         if not(autocvar_g_balance_shotgun_secondary && self.ammo_shells < autocvar_g_balance_shotgun_primary_ammo)
 123                                 weapon_action(self.weapon, WR_RELOAD);
 124                 }
 125                 else
 126                 {
 127                         if (self.BUTTON_ATCK)
 128                         {
 129                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 130                                 {
 131                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 132                                         {
 133                                                 W_Shotgun_Attack();
 134                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 135                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 136                                         }
 137                                 }
 138                         }
 139                 }
 140                 if (self.clip_load >= 0) // we are not currently reloading
 141                 if (!self.crouch) // we are not currently crouching; this fixes an exploit where your melee anim is not visible, and besides wouldn't make much sense
 142                 if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 143                 if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 144                 {
 145                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 146                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 147                 }
 148         }
 149         else if (req == WR_PRECACHE)
 150         {
 151                 precache_model ("models/uziflash.md3");
 152                 precache_model ("models/weapons/g_shotgun.md3");
 153                 precache_model ("models/weapons/v_shotgun.md3");
 154                 precache_model ("models/weapons/h_shotgun.iqm");
 155                 precache_sound ("misc/itempickup.wav");
 156                 precache_sound ("weapons/shotgun_fire.wav");
 157                 precache_sound ("weapons/shotgun_melee.wav");
 158                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 159         }
 160         else if (req == WR_SETUP)
 161         {
 162                 weapon_setup(WEP_SHOTGUN);
 163                 self.current_ammo = ammo_shells;
 164         }
 165         else if (req == WR_CHECKAMMO1)
 166         {
 167                 ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 168                 ammo_amount += self.weapon_load[WEP_SHOTGUN] >= autocvar_g_balance_shotgun_primary_ammo;
 169                 return ammo_amount;
 170         }
 171         else if (req == WR_CHECKAMMO2)
 172         {
 173                 // melee attack is always available
 174                 return TRUE;
 175         }
 176         else if (req == WR_RELOAD)
 177         {
 178                 W_Reload(autocvar_g_balance_shotgun_primary_ammo, autocvar_g_balance_shotgun_reload_ammo, autocvar_g_balance_shotgun_reload_time, "weapons/reload.wav");
 179         }
 180         return TRUE;
 181 };
 182 #endif
 183 #ifdef CSQC
 184 .float prevric;
 185 float w_shotgun(float req)
 186 {
 187         if(req == WR_IMPACTEFFECT)
 188         {
 189                 vector org2;
 190                 org2 = w_org + w_backoff * 2;
 191                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 192                 if(!w_issilent && time - self.prevric > 0.25)
 193                 {
 194                         if(w_random < 0.0165)
 195                                 sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 196                         else if(w_random < 0.033)
 197                                 sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 198                         else if(w_random < 0.05)
 199                                 sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 200                         self.prevric = time;
 201                 }
 202         }
 203         else if(req == WR_PRECACHE)
 204         {
 205                 precache_sound("weapons/ric1.wav");
 206                 precache_sound("weapons/ric2.wav");
 207                 precache_sound("weapons/ric3.wav");
 208         }
 209         else if (req == WR_SUICIDEMESSAGE)
 210                 w_deathtypestring = _("%s is now thinking with portals");
 211         else if (req == WR_KILLMESSAGE)
 212         {
 213                 if(w_deathtype & HITTYPE_SECONDARY)
 214                         w_deathtypestring = _("%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun");
 215                 else
 216                         w_deathtypestring = _("%s was gunned by %s");
 217         }
 218         return TRUE;
 219 }
 220 #endif
 221 #endif