qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_Shotgun_Attack (void)
   7 {
   8         float   sc;
   9         float   ammoamount;
  10         float   bullets;
  11         float   d;
  12         float   f;
  13         float   spread;
  14         float   bulletspeed;
  15         float   bulletconstant;
  16         local entity flash;
  17
  18         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  19         bullets = autocvar_g_balance_shotgun_primary_bullets;
  20         d = autocvar_g_balance_shotgun_primary_damage;
  21         f = autocvar_g_balance_shotgun_primary_force;
  22         spread = autocvar_g_balance_shotgun_primary_spread;
  23         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  24         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  25
  26         W_DecreaseAmmo(ammo_shells, ammoamount, autocvar_g_balance_shotgun_reload_ammo);
  27
  28         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  29         for (sc = 0;sc < bullets;sc = sc + 1)
  30                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  31         endFireBallisticBullet();
  32
  33         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  34
  35         // casing code
  36         if (autocvar_g_casings >= 1)
  37                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  38                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  39
  40         // muzzle flash for 1st person view
  41         flash = spawn();
  42         setmodel(flash, "models/uziflash.md3"); // precision set below
  43         flash.think = SUB_Remove;
  44         flash.nextthink = time + 0.06;
  45         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  46         W_AttachToShotorg(flash, '5 0 0');
  47 }
  48
  49 void shotgun_meleethink (void)
  50 {
  51         // store time when we started swinging down inside self.cnt
  52         if(!self.cnt)
  53                 self.cnt = time;
  54
  55         makevectors(self.owner.v_angle);
  56         vector angle;
  57         angle = v_forward;
  58
  59         float meleetime;
  60         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  61
  62         // perform trace
  63         float f;
  64         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
  65         vector targpos;
  66         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
  67
  68         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
  69
  70         // apply the damage, also remove self
  71         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
  72         {
  73                 vector force;
  74                 force = angle * autocvar_g_balance_shotgun_secondary_force;
  75                 if(accuracy_isgooddamage(self.owner, trace_ent))
  76                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
  77                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
  78                 remove(self);
  79         }
  80         else if(time >= self.cnt + meleetime || (self.owner.deadflag != DEAD_NO && autocvar_g_balance_shotgun_secondary_melee_no_doubleslap)) // missed or owner died, remove ent
  81                 remove(self);
  82         else // continue swinging the weapon in hope of hitting someone :)
  83                 self.nextthink = time;
  84 }
  85
  86 void W_Shotgun_Attack2 (void)
  87 {
  88         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
  89         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
  90
  91         entity meleetemp;
  92         meleetemp = spawn();
  93         meleetemp.owner = self;
  94         meleetemp.think = shotgun_meleethink;
  95         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
  96         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
  97 }
  98
  99 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 100
 101 .float shotgun_primarytime;
 102
 103 float w_shotgun(float req)
 104 {
 105         float ammo_amount;
 106         if (req == WR_AIM)
 107                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 108                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 109                 else
 110                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 111         else if (req == WR_THINK)
 112         {
 113                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 114                 {
 115                         // don't force reload an empty shotgun if its melee attack is active
 116                         if not(autocvar_g_balance_shotgun_secondary && self.ammo_shells < autocvar_g_balance_shotgun_primary_ammo)
 117                                 weapon_action(self.weapon, WR_RELOAD);
 118                 }
 119                 else
 120                 {
 121                         if (self.BUTTON_ATCK)
 122                         {
 123                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 124                                 {
 125                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 126                                         {
 127                                                 W_Shotgun_Attack();
 128                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 129                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 130                                         }
 131                                 }
 132                         }
 133                 }
 134                 if (self.clip_load >= 0) // we are not currently reloading
 135                 if (!self.crouch) // we are not currently crouching; this fixes an exploit where your melee anim is not visible, and besides wouldn't make much sense
 136                 if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 137                 if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 138                 {
 139                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 140                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 141                 }
 142         }
 143         else if (req == WR_PRECACHE)
 144         {
 145                 precache_model ("models/uziflash.md3");
 146                 precache_model ("models/weapons/g_shotgun.md3");
 147                 precache_model ("models/weapons/v_shotgun.md3");
 148                 precache_model ("models/weapons/h_shotgun.iqm");
 149                 precache_sound ("misc/itempickup.wav");
 150                 precache_sound ("weapons/shotgun_fire.wav");
 151                 precache_sound ("weapons/shotgun_melee.wav");
 152                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 153         }
 154         else if (req == WR_SETUP)
 155         {
 156                 weapon_setup(WEP_SHOTGUN);
 157                 self.current_ammo = ammo_shells;
 158         }
 159         else if (req == WR_CHECKAMMO1)
 160         {
 161                 ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 162                 ammo_amount += self.weapon_load[WEP_SHOTGUN] >= autocvar_g_balance_shotgun_primary_ammo;
 163                 return ammo_amount;
 164         }
 165         else if (req == WR_CHECKAMMO2)
 166         {
 167                 // melee attack is always available
 168                 return TRUE;
 169         }
 170         else if (req == WR_RELOAD)
 171         {
 172                 W_Reload(autocvar_g_balance_shotgun_primary_ammo, autocvar_g_balance_shotgun_reload_ammo, autocvar_g_balance_shotgun_reload_time, "weapons/reload.wav");
 173         }
 174         return TRUE;
 175 };
 176 #endif
 177 #ifdef CSQC
 178 .float prevric;
 179 float w_shotgun(float req)
 180 {
 181         if(req == WR_IMPACTEFFECT)
 182         {
 183                 vector org2;
 184                 org2 = w_org + w_backoff * 2;
 185                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 186                 if(!w_issilent && time - self.prevric > 0.25)
 187                 {
 188                         if(w_random < 0.0165)
 189                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 190                         else if(w_random < 0.033)
 191                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 192                         else if(w_random < 0.05)
 193                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 194                         self.prevric = time;
 195                 }
 196         }
 197         else if(req == WR_PRECACHE)
 198         {
 199                 precache_sound("weapons/ric1.wav");
 200                 precache_sound("weapons/ric2.wav");
 201                 precache_sound("weapons/ric3.wav");
 202         }
 203         else if (req == WR_SUICIDEMESSAGE)
 204                 w_deathtypestring = _("%s did the impossible");
 205         else if (req == WR_KILLMESSAGE)
 206         {
 207                 if(w_deathtype & HITTYPE_SECONDARY)
 208                         w_deathtypestring = _("%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun");
 209                 else
 210                         w_deathtypestring = _("%s was gunned by %s");
 211         }
 212         return TRUE;
 213 }
 214 #endif
 215 #endif