qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", "Shotgun");
   3 #else
   4 #ifdef SVQC
   5 void W_Shotgun_Attack (void)
   6 {
   7         float   sc;
   8         float   ammoamount;
   9         float   bullets;
  10         float   d;
  11         float   f;
  12         float   spread;
  13         float   bulletspeed;
  14         float   bulletconstant;
  15         local entity flash;
  16
  17         ammoamount = cvar("g_balance_shotgun_primary_ammo");
  18         bullets = cvar("g_balance_shotgun_primary_bullets");
  19         d = cvar("g_balance_shotgun_primary_damage");
  20         f = cvar("g_balance_shotgun_primary_force");
  21         spread = cvar("g_balance_shotgun_primary_spread");
  22         bulletspeed = cvar("g_balance_shotgun_primary_speed");
  23         bulletconstant = cvar("g_balance_shotgun_primary_bulletconstant");
  24
  25         W_SetupShot (self, cvar("g_antilag_bullets") && bulletspeed >= cvar("g_antilag_bullets"), 5, "weapons/shotgun_fire.wav", cvar("g_balance_shotgun_primary_damage"));
  26         for (sc = 0;sc < bullets;sc = sc + 1)
  27                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  28         endFireBallisticBullet();
  29         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  30                 self.ammo_shells = self.ammo_shells - ammoamount;
  31
  32         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, cvar("g_balance_shotgun_primary_ammo"));
  33
  34         // casing code
  35         if (cvar("g_casings") >= 1)
  36                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  37                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  38
  39         // muzzle flash for 1st person view
  40         flash = spawn();
  41         setmodel(flash, "models/uziflash.md3"); // precision set below
  42         flash.think = SUB_Remove;
  43         flash.nextthink = time + 0.06;
  44         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  45         W_AttachToShotorg(flash, '5 0 0');
  46
  47 }
  48
  49 void shotgun_meleethink (void)
  50 {
  51         // store time when we started swinging down inside self.cnt
  52         if(!self.cnt)
  53                 self.cnt = time;
  54
  55         makevectors(self.owner.v_angle);
  56         vector angle;
  57         angle = v_forward;
  58
  59         // perform trace
  60         float f;
  61         f = (self.cnt + cvar("g_balance_shotgun_secondary_melee_time") - time) / cvar("g_balance_shotgun_secondary_melee_time") * 2 - 1;
  62         vector targpos;
  63         targpos = self.owner.origin + self.owner.view_ofs + angle * cvar("g_balance_shotgun_secondary_melee_range") + v_right * f * cvar("g_balance_shotgun_secondary_melee_swing") + v_up * f * cvar("g_balance_shotgun_secondary_melee_swing");
  64         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
  65
  66         // apply the damage, also remove self
  67         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && trace_ent.classname == "player")
  68         {
  69                 vector force;
  70                 force = angle * cvar("g_balance_shotgun_secondary_force");
  71                 Damage (trace_ent, self.owner, self.owner, cvar("g_balance_shotgun_secondary_damage") * ((f + 1) / 2), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
  72                 remove(self);
  73         }
  74         else if(time >= self.cnt + cvar("g_balance_shotgun_secondary_melee_time")) // missed, remove ent
  75                 remove(self);
  76         else // continue swinging the weapon in hope of hitting someone :)
  77                 self.nextthink = time;
  78 }
  79
  80 void W_Shotgun_Attack2 (void)
  81 {
  82         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
  83         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_shotgun_secondary_animtime"), w_ready);
  84
  85         entity meleetemp;
  86         meleetemp = spawn();
  87         meleetemp.owner = self;
  88         meleetemp.think = shotgun_meleethink;
  89         meleetemp.nextthink = time + cvar("g_balance_shotgun_secondary_melee_delay");
  90 }
  91
  92 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
  93
  94 float w_shotgun(float req)
  95 {
  96         if (req == WR_AIM)
  97                 if(vlen(self.origin-self.enemy.origin)>200)
  98                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
  99                 else
 100                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 101         else if (req == WR_THINK)
 102         {
 103                 if (self.BUTTON_ATCK)
 104                 if (weapon_prepareattack(0, cvar("g_balance_shotgun_primary_refire")))
 105                 {
 106                         W_Shotgun_Attack();
 107                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_shotgun_primary_animtime"), w_ready);
 108                 }
 109                 if (self.BUTTON_ATCK2 && cvar("g_balance_shotgun_secondary"))
 110                 if (weapon_prepareattack(1, cvar("g_balance_shotgun_secondary_refire")))
 111                 {
 112                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 113                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 114                 }
 115         }
 116         else if (req == WR_PRECACHE)
 117         {
 118                 precache_model ("models/uziflash.md3");
 119                 precache_model ("models/weapons/g_shotgun.md3");
 120                 precache_model ("models/weapons/v_shotgun.md3");
 121                 precache_model ("models/weapons/h_shotgun.iqm");
 122                 precache_sound ("misc/itempickup.wav");
 123                 precache_sound ("weapons/shotgun_fire.wav");
 124                 precache_sound ("weapons/shotgun_melee.wav");
 125         }
 126         else if (req == WR_SETUP)
 127                 weapon_setup(WEP_SHOTGUN);
 128         else if (req == WR_CHECKAMMO1)
 129                 return self.ammo_shells >= cvar("g_balance_shotgun_primary_ammo");
 130         else if (req == WR_CHECKAMMO2)
 131         {
 132                 return TRUE;
 133         }
 134         return TRUE;
 135 };
 136 #endif
 137 #ifdef CSQC
 138 float w_shotgun(float req)
 139 {
 140         if(req == WR_IMPACTEFFECT)
 141         {
 142                 vector org2;
 143                 org2 = w_org + w_backoff * 2;
 144                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 145                 if(!w_issilent)
 146                 {
 147                         if(w_random < 0.05)
 148                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 149                         else if(w_random < 0.1)
 150                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 151                         else if(w_random < 0.2)
 152                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 153                 }
 154         }
 155         else if(req == WR_PRECACHE)
 156         {
 157                 precache_sound("weapons/ric1.wav");
 158                 precache_sound("weapons/ric2.wav");
 159                 precache_sound("weapons/ric3.wav");
 160         }
 161         else if (req == WR_SUICIDEMESSAGE)
 162                 w_deathtypestring = "%s did the impossible";
 163         else if (req == WR_KILLMESSAGE)
 164         {
 165                 w_deathtypestring = "%s was gunned by %s"; // unchecked: SECONDARY
 166         }
 167         return TRUE;
 168 }
 169 #endif
 170 #endif