qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_Shotgun_SetAmmoCounter()
   7 {
   8         // set clip_load to the weapon we have switched to, if the gun uses reloading
   9         if(!autocvar_g_balance_shotgun_reload_ammo)
  10                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  11         else
  12         {
  13                 self.clip_load = self.shotgun_load;
  14                 self.clip_size = autocvar_g_balance_shotgun_reload_ammo; // for the crosshair ammo display
  15         }
  16 }
  17
  18 void W_Shotgun_ReloadedAndReady()
  19 {
  20         float t;
  21
  22         // now do the ammo transfer
  23         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  24         while(self.clip_load < autocvar_g_balance_shotgun_reload_ammo && self.ammo_shells) // make sure we don't add more ammo than we have
  25         {
  26                 self.clip_load += 1;
  27                 self.ammo_shells -= 1;
  28         }
  29         self.shotgun_load = self.clip_load;
  30
  31         t = ATTACK_FINISHED(self) - autocvar_g_balance_shotgun_reload_time - 1;
  32         ATTACK_FINISHED(self) = t;
  33         w_ready();
  34 }
  35
  36 void W_Shotgun_Reload()
  37 {
  38         // return if reloading is disabled for this weapon
  39         if(!autocvar_g_balance_shotgun_reload_ammo)
  40                 return;
  41
  42         if(!W_ReloadCheck(self.ammo_shells, autocvar_g_balance_shotgun_primary_ammo))
  43                 return;
  44
  45         float t;
  46
  47         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  48
  49         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_shotgun_reload_time + 1;
  50         ATTACK_FINISHED(self) = t;
  51
  52         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_shotgun_reload_time, W_Shotgun_ReloadedAndReady);
  53
  54         self.old_clip_load = self.clip_load;
  55         self.clip_load = -1;
  56 }
  57
  58 void W_Shotgun_Attack (void)
  59 {
  60         float   sc;
  61         float   ammoamount;
  62         float   bullets;
  63         float   d;
  64         float   f;
  65         float   spread;
  66         float   bulletspeed;
  67         float   bulletconstant;
  68         local entity flash;
  69
  70         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  71         bullets = autocvar_g_balance_shotgun_primary_bullets;
  72         d = autocvar_g_balance_shotgun_primary_damage;
  73         f = autocvar_g_balance_shotgun_primary_force;
  74         spread = autocvar_g_balance_shotgun_primary_spread;
  75         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  76         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  77
  78         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
  79         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  80         {
  81                 if(autocvar_g_balance_shotgun_reload_ammo)
  82                 {
  83                         self.clip_load -= ammoamount;
  84                         self.shotgun_load = self.clip_load;
  85                 }
  86                 else
  87                         self.ammo_shells -= ammoamount;
  88         }
  89
  90         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  91         for (sc = 0;sc < bullets;sc = sc + 1)
  92                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  93         endFireBallisticBullet();
  94
  95         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  96
  97         // casing code
  98         if (autocvar_g_casings >= 1)
  99                 for (sc = 0;sc < ammoamount;sc = sc + 1)
 100                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
 101
 102         // muzzle flash for 1st person view
 103         flash = spawn();
 104         setmodel(flash, "models/uziflash.md3"); // precision set below
 105         flash.think = SUB_Remove;
 106         flash.nextthink = time + 0.06;
 107         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 108         W_AttachToShotorg(flash, '5 0 0');
 109 }
 110
 111 void shotgun_meleethink (void)
 112 {
 113         // store time when we started swinging down inside self.cnt
 114         if(!self.cnt)
 115                 self.cnt = time;
 116
 117         makevectors(self.owner.v_angle);
 118         vector angle;
 119         angle = v_forward;
 120
 121         float meleetime;
 122         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
 123
 124         // perform trace
 125         float f;
 126         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
 127         vector targpos;
 128         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
 129
 130         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 131
 132         // apply the damage, also remove self
 133         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
 134         {
 135                 vector force;
 136                 force = angle * autocvar_g_balance_shotgun_secondary_force;
 137                 if(accuracy_isgooddamage(self.owner, trace_ent))
 138                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
 139                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
 140                 remove(self);
 141         }
 142         else if(time >= self.cnt + meleetime) // missed, remove ent
 143                 remove(self);
 144         else // continue swinging the weapon in hope of hitting someone :)
 145                 self.nextthink = time;
 146 }
 147
 148 void W_Shotgun_Attack2 (void)
 149 {
 150         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 151         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 152
 153         entity meleetemp;
 154         meleetemp = spawn();
 155         meleetemp.owner = self;
 156         meleetemp.think = shotgun_meleethink;
 157         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 158         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 159 }
 160
 161 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 162
 163 .float shotgun_primarytime;
 164
 165 float w_shotgun(float req)
 166 {
 167         if (req == WR_AIM)
 168                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 169                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 170                 else
 171                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 172         else if (req == WR_THINK)
 173         {
 174                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 175                         W_Shotgun_Reload();
 176                 else
 177                 {
 178                         if (self.BUTTON_ATCK)
 179                         {
 180                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 181                                 {
 182                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 183                                         {
 184                                                 W_Shotgun_Attack();
 185                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 186                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 187                                         }
 188                                 }
 189                         }
 190                         if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 191                         if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 192                         {
 193                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 194                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 195                         }
 196                 }
 197         if(self.wish_reload)
 198         {
 199             if(self.switchweapon == self.weapon)
 200             {
 201                 if(self.weaponentity.state == WS_READY)
 202                 {
 203                     self.wish_reload = 0;
 204                     W_Shotgun_Reload();
 205                 }
 206             }
 207         }
 208         }
 209         else if (req == WR_PRECACHE)
 210         {
 211                 precache_model ("models/uziflash.md3");
 212                 precache_model ("models/weapons/g_shotgun.md3");
 213                 precache_model ("models/weapons/v_shotgun.md3");
 214                 precache_model ("models/weapons/h_shotgun.iqm");
 215                 precache_sound ("misc/itempickup.wav");
 216                 precache_sound ("weapons/shotgun_fire.wav");
 217                 precache_sound ("weapons/shotgun_melee.wav");
 218                 precache_sound ("weapons/reload.wav");
 219         }
 220         else if (req == WR_SETUP)
 221         {
 222                 weapon_setup(WEP_SHOTGUN);
 223                 W_Shotgun_SetAmmoCounter();
 224         }
 225         else if (req == WR_CHECKAMMO1)
 226         {
 227                 if(autocvar_g_balance_shotgun_reload_ammo)
 228                         return self.shotgun_load >= autocvar_g_balance_shotgun_primary_ammo;
 229                 else
 230                         return self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 231         }
 232         else if (req == WR_CHECKAMMO2)
 233         {
 234                 return TRUE;
 235         }
 236         else if (req == WR_RELOAD)
 237         {
 238                 W_Shotgun_Reload();
 239         }
 240         else if (req == WR_SWITCHABLE)
 241         {
 242                 // checks if this weapon can be switched to, when reloading is enabled
 243                 // returns true if there's either enough load in the weapon to use it,
 244                 // or we have enough ammo to reload the weapon to a usable point
 245                 float ammo_amount;
 246                 ammo_amount = autocvar_g_balance_shotgun_primary_ammo;
 247                 return self.shotgun_load >= ammo_amount || self.ammo_shells >= ammo_amount;
 248         }
 249         return TRUE;
 250 };
 251 #endif
 252 #ifdef CSQC
 253 .float prevric;
 254 float w_shotgun(float req)
 255 {
 256         if(req == WR_IMPACTEFFECT)
 257         {
 258                 vector org2;
 259                 org2 = w_org + w_backoff * 2;
 260                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 261                 if(!w_issilent && time - self.prevric > 0.25)
 262                 {
 263                         if(w_random < 0.0165)
 264                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 265                         else if(w_random < 0.033)
 266                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 267                         else if(w_random < 0.05)
 268                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 269                         self.prevric = time;
 270                 }
 271         }
 272         else if(req == WR_PRECACHE)
 273         {
 274                 precache_sound("weapons/ric1.wav");
 275                 precache_sound("weapons/ric2.wav");
 276                 precache_sound("weapons/ric3.wav");
 277         }
 278         else if (req == WR_SUICIDEMESSAGE)
 279                 w_deathtypestring = "%s did the impossible";
 280         else if (req == WR_KILLMESSAGE)
 281         {
 282                 if(w_deathtype & HITTYPE_SECONDARY)
 283                         w_deathtypestring = "%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun";
 284                 else
 285                         w_deathtypestring = "%s was gunned by %s";
 286         }
 287         return TRUE;
 288 }
 289 #endif
 290 #endif