qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_Shotgun_Reload()
   7 {
   8         self.reload_ammo_player = ammo_shells;
   9         self.reload_ammo_min = autocvar_g_balance_shotgun_primary_ammo;
  10         self.reload_ammo_amount = autocvar_g_balance_shotgun_reload_ammo;
  11         self.reload_time = autocvar_g_balance_shotgun_reload_time;
  12         self.reload_sound = "weapons/reload.wav";
  13
  14         W_Reload();
  15 }
  16
  17 void W_Shotgun_Attack (void)
  18 {
  19         float   sc;
  20         float   ammoamount;
  21         float   bullets;
  22         float   d;
  23         float   f;
  24         float   spread;
  25         float   bulletspeed;
  26         float   bulletconstant;
  27         local entity flash;
  28
  29         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  30         bullets = autocvar_g_balance_shotgun_primary_bullets;
  31         d = autocvar_g_balance_shotgun_primary_damage;
  32         f = autocvar_g_balance_shotgun_primary_force;
  33         spread = autocvar_g_balance_shotgun_primary_spread;
  34         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  35         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  36
  37         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
  38         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  39         {
  40                 if(autocvar_g_balance_shotgun_reload_ammo)
  41                 {
  42                         self.clip_load -= ammoamount;
  43                         self.weapon_load[WEP_SHOTGUN] = self.clip_load;
  44                 }
  45                 else
  46                         self.ammo_shells -= ammoamount;
  47         }
  48
  49         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  50         for (sc = 0;sc < bullets;sc = sc + 1)
  51                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  52         endFireBallisticBullet();
  53
  54         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  55
  56         // casing code
  57         if (autocvar_g_casings >= 1)
  58                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  59                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  60
  61         // muzzle flash for 1st person view
  62         flash = spawn();
  63         setmodel(flash, "models/uziflash.md3"); // precision set below
  64         flash.think = SUB_Remove;
  65         flash.nextthink = time + 0.06;
  66         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  67         W_AttachToShotorg(flash, '5 0 0');
  68 }
  69
  70 void shotgun_meleethink (void)
  71 {
  72         // store time when we started swinging down inside self.cnt
  73         if(!self.cnt)
  74                 self.cnt = time;
  75
  76         makevectors(self.owner.v_angle);
  77         vector angle;
  78         angle = v_forward;
  79
  80         float meleetime;
  81         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  82
  83         // perform trace
  84         float f;
  85         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
  86         vector targpos;
  87         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
  88
  89         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
  90
  91         // apply the damage, also remove self
  92         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
  93         {
  94                 vector force;
  95                 force = angle * autocvar_g_balance_shotgun_secondary_force;
  96                 if(accuracy_isgooddamage(self.owner, trace_ent))
  97                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
  98                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
  99                 remove(self);
 100         }
 101         else if(time >= self.cnt + meleetime) // missed, remove ent
 102                 remove(self);
 103         else // continue swinging the weapon in hope of hitting someone :)
 104                 self.nextthink = time;
 105 }
 106
 107 void W_Shotgun_Attack2 (void)
 108 {
 109         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 110         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 111
 112         entity meleetemp;
 113         meleetemp = spawn();
 114         meleetemp.owner = self;
 115         meleetemp.think = shotgun_meleethink;
 116         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 117         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 118 }
 119
 120 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 121
 122 .float shotgun_primarytime;
 123
 124 float w_shotgun(float req)
 125 {
 126         float ammo_amount;
 127         if (req == WR_AIM)
 128                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 129                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 130                 else
 131                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 132         else if (req == WR_THINK)
 133         {
 134                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 135                 {
 136                         // don't force reload an empty shotgun if its melee attack is active
 137                         if not(autocvar_g_balance_shotgun_secondary && self.ammo_shells < autocvar_g_balance_shotgun_primary_ammo)
 138                                 W_Shotgun_Reload();
 139                 }
 140                 else
 141                 {
 142                         if (self.BUTTON_ATCK)
 143                         {
 144                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 145                                 {
 146                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 147                                         {
 148                                                 W_Shotgun_Attack();
 149                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 150                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 151                                         }
 152                                 }
 153                         }
 154                 }
 155                 if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 156                 if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 157                 {
 158                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 159                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 160                 }
 161         }
 162         else if (req == WR_PRECACHE)
 163         {
 164                 precache_model ("models/uziflash.md3");
 165                 precache_model ("models/weapons/g_shotgun.md3");
 166                 precache_model ("models/weapons/v_shotgun.md3");
 167                 precache_model ("models/weapons/h_shotgun.iqm");
 168                 precache_sound ("misc/itempickup.wav");
 169                 precache_sound ("weapons/shotgun_fire.wav");
 170                 precache_sound ("weapons/shotgun_melee.wav");
 171                 precache_sound ("weapons/reload.wav");
 172         }
 173         else if (req == WR_SETUP)
 174         {
 175                 weapon_setup(WEP_SHOTGUN);
 176         }
 177         else if (req == WR_CHECKAMMO1)
 178         {
 179                 ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 180                 ammo_amount += self.weapon_load[WEP_SHOTGUN] >= autocvar_g_balance_shotgun_primary_ammo;
 181                 return ammo_amount;
 182         }
 183         else if (req == WR_CHECKAMMO2)
 184         {
 185                 // melee attack is always available
 186                 return TRUE;
 187         }
 188         else if (req == WR_RELOAD)
 189         {
 190                 W_Shotgun_Reload();
 191         }
 192         return TRUE;
 193 };
 194 #endif
 195 #ifdef CSQC
 196 .float prevric;
 197 float w_shotgun(float req)
 198 {
 199         if(req == WR_IMPACTEFFECT)
 200         {
 201                 vector org2;
 202                 org2 = w_org + w_backoff * 2;
 203                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 204                 if(!w_issilent && time - self.prevric > 0.25)
 205                 {
 206                         if(w_random < 0.0165)
 207                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 208                         else if(w_random < 0.033)
 209                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 210                         else if(w_random < 0.05)
 211                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 212                         self.prevric = time;
 213                 }
 214         }
 215         else if(req == WR_PRECACHE)
 216         {
 217                 precache_sound("weapons/ric1.wav");
 218                 precache_sound("weapons/ric2.wav");
 219                 precache_sound("weapons/ric3.wav");
 220         }
 221         else if (req == WR_SUICIDEMESSAGE)
 222                 w_deathtypestring = _("%s did the impossible");
 223         else if (req == WR_KILLMESSAGE)
 224         {
 225                 if(w_deathtype & HITTYPE_SECONDARY)
 226                         w_deathtypestring = _("%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun");
 227                 else
 228                         w_deathtypestring = _("%s was gunned by %s");
 229         }
 230         return TRUE;
 231 }
 232 #endif
 233 #endif