qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 .float shotgun_load;
   7
   8 void W_Shotgun_SetAmmoCounter()
   9 {
  10         // set clip_load to the weapon we have switched to, if the gun uses reloading
  11         if(!autocvar_g_balance_shotgun_reload_ammo)
  12                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  13         else
  14         {
  15                 self.clip_load = self.shotgun_load;
  16                 self.clip_size = autocvar_g_balance_shotgun_reload_ammo; // for the crosshair ammo display
  17         }
  18 }
  19
  20 void W_Shotgun_ReloadedAndReady()
  21 {
  22         float t;
  23
  24         // now do the ammo transfer
  25         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  26         while(self.clip_load < autocvar_g_balance_shotgun_reload_ammo && self.ammo_shells) // make sure we don't add more ammo than we have
  27         {
  28                 self.clip_load += 1;
  29                 self.ammo_shells -= 1;
  30         }
  31         self.shotgun_load = self.clip_load;
  32
  33         t = ATTACK_FINISHED(self) - autocvar_g_balance_shotgun_reload_time - 1;
  34         ATTACK_FINISHED(self) = t;
  35         w_ready();
  36 }
  37
  38 void W_Shotgun_Reload()
  39 {
  40         // return if reloading is disabled for this weapon
  41         if(!autocvar_g_balance_shotgun_reload_ammo)
  42                 return;
  43
  44         if(!W_ReloadCheck(self.ammo_shells, autocvar_g_balance_shotgun_primary_ammo))
  45                 return;
  46
  47         float t;
  48
  49         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  50
  51         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_shotgun_reload_time + 1;
  52         ATTACK_FINISHED(self) = t;
  53
  54         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_shotgun_reload_time, W_Shotgun_ReloadedAndReady);
  55
  56         self.old_clip_load = self.clip_load;
  57         self.clip_load = -1;
  58 }
  59
  60 void W_Shotgun_Attack (void)
  61 {
  62         float   sc;
  63         float   ammoamount;
  64         float   bullets;
  65         float   d;
  66         float   f;
  67         float   spread;
  68         float   bulletspeed;
  69         float   bulletconstant;
  70         local entity flash;
  71
  72         // if there's not enough ammo for this attack (but we still have the weapon), reload
  73         if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo)
  74         {
  75                 W_Shotgun_Reload();
  76                 return;
  77         }
  78
  79         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  80         bullets = autocvar_g_balance_shotgun_primary_bullets;
  81         d = autocvar_g_balance_shotgun_primary_damage;
  82         f = autocvar_g_balance_shotgun_primary_force;
  83         spread = autocvar_g_balance_shotgun_primary_spread;
  84         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  85         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  86
  87         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
  88         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  89         {
  90                 if(autocvar_g_balance_shotgun_reload_ammo)
  91                 {
  92                         self.clip_load -= ammoamount;
  93                         self.shotgun_load = self.clip_load;
  94                 }
  95                 else
  96                         self.ammo_shells -= ammoamount;
  97         }
  98
  99         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
 100         for (sc = 0;sc < bullets;sc = sc + 1)
 101                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
 102         endFireBallisticBullet();
 103
 104         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
 105
 106         // casing code
 107         if (autocvar_g_casings >= 1)
 108                 for (sc = 0;sc < ammoamount;sc = sc + 1)
 109                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
 110
 111         // muzzle flash for 1st person view
 112         flash = spawn();
 113         setmodel(flash, "models/uziflash.md3"); // precision set below
 114         flash.think = SUB_Remove;
 115         flash.nextthink = time + 0.06;
 116         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 117         W_AttachToShotorg(flash, '5 0 0');
 118 }
 119
 120 void shotgun_meleethink (void)
 121 {
 122         // store time when we started swinging down inside self.cnt
 123         if(!self.cnt)
 124                 self.cnt = time;
 125
 126         makevectors(self.owner.v_angle);
 127         vector angle;
 128         angle = v_forward;
 129
 130         float meleetime;
 131         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
 132
 133         // perform trace
 134         float f;
 135         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
 136         vector targpos;
 137         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
 138
 139         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 140
 141         // apply the damage, also remove self
 142         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
 143         {
 144                 vector force;
 145                 force = angle * autocvar_g_balance_shotgun_secondary_force;
 146                 if(accuracy_isgooddamage(self.owner, trace_ent))
 147                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
 148                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
 149                 remove(self);
 150         }
 151         else if(time >= self.cnt + meleetime) // missed, remove ent
 152                 remove(self);
 153         else // continue swinging the weapon in hope of hitting someone :)
 154                 self.nextthink = time;
 155 }
 156
 157 void W_Shotgun_Attack2 (void)
 158 {
 159         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 160         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 161
 162         entity meleetemp;
 163         meleetemp = spawn();
 164         meleetemp.owner = self;
 165         meleetemp.think = shotgun_meleethink;
 166         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 167         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 168 }
 169
 170 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 171
 172 .float shotgun_primarytime;
 173
 174 float w_shotgun(float req)
 175 {
 176         if (req == WR_AIM)
 177                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 178                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 179                 else
 180                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 181         else if (req == WR_THINK)
 182         {
 183                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 184                         W_Shotgun_Reload();
 185                 else
 186                 {
 187                         if (self.BUTTON_ATCK)
 188                         {
 189                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 190                                 {
 191                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 192                                         {
 193                                                 W_Shotgun_Attack();
 194                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 195                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 196                                         }
 197                                 }
 198                         }
 199                         if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 200                         if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 201                         {
 202                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 203                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 204                         }
 205                 }
 206         if(self.wish_reload)
 207         {
 208             if(self.switchweapon == self.weapon)
 209             {
 210                 if(self.weaponentity.state == WS_READY)
 211                 {
 212                     self.wish_reload = 0;
 213                     W_Shotgun_Reload();
 214                 }
 215             }
 216         }
 217         }
 218         else if (req == WR_PRECACHE)
 219         {
 220                 precache_model ("models/uziflash.md3");
 221                 precache_model ("models/weapons/g_shotgun.md3");
 222                 precache_model ("models/weapons/v_shotgun.md3");
 223                 precache_model ("models/weapons/h_shotgun.iqm");
 224                 precache_sound ("misc/itempickup.wav");
 225                 precache_sound ("weapons/shotgun_fire.wav");
 226                 precache_sound ("weapons/shotgun_melee.wav");
 227                 precache_sound ("weapons/reload.wav");
 228         }
 229         else if (req == WR_SETUP)
 230         {
 231                 weapon_setup(WEP_SHOTGUN);
 232                 W_Shotgun_SetAmmoCounter();
 233         }
 234         else if (req == WR_CHECKAMMO1)
 235         {
 236                 if(autocvar_g_balance_shotgun_reload_ammo)
 237                         return self.shotgun_load >= autocvar_g_balance_shotgun_primary_ammo;
 238                 else
 239                         return self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 240         }
 241         else if (req == WR_CHECKAMMO2)
 242         {
 243                 return TRUE;
 244         }
 245         else if (req == WR_RELOAD)
 246         {
 247                 W_Shotgun_Reload();
 248         }
 249         return TRUE;
 250 };
 251 #endif
 252 #ifdef CSQC
 253 .float prevric;
 254 float w_shotgun(float req)
 255 {
 256         if(req == WR_IMPACTEFFECT)
 257         {
 258                 vector org2;
 259                 org2 = w_org + w_backoff * 2;
 260                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 261                 if(!w_issilent && time - self.prevric > 0.25)
 262                 {
 263                         if(w_random < 0.0165)
 264                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 265                         else if(w_random < 0.033)
 266                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 267                         else if(w_random < 0.05)
 268                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 269                         self.prevric = time;
 270                 }
 271         }
 272         else if(req == WR_PRECACHE)
 273         {
 274                 precache_sound("weapons/ric1.wav");
 275                 precache_sound("weapons/ric2.wav");
 276                 precache_sound("weapons/ric3.wav");
 277         }
 278         else if (req == WR_SUICIDEMESSAGE)
 279                 w_deathtypestring = "%s did the impossible";
 280         else if (req == WR_KILLMESSAGE)
 281         {
 282                 if(w_deathtype & HITTYPE_SECONDARY)
 283                         w_deathtypestring = "%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun";
 284                 else
 285                         w_deathtypestring = "%s was gunned by %s";
 286         }
 287         return TRUE;
 288 }
 289 #endif
 290 #endif