qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_Shotgun_SetAmmoCounter()
   7 {
   8         // set clip_load to the weapon we have switched to, if the gun uses reloading
   9         if(!autocvar_g_balance_shotgun_reload_ammo)
  10                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  11         else
  12         {
  13                 self.clip_load = self.weapon_load[WEP_SHOTGUN];
  14                 self.clip_size = autocvar_g_balance_shotgun_reload_ammo; // for the crosshair ammo display
  15         }
  16 }
  17
  18 void W_Shotgun_Reload()
  19 {
  20         self.reload_ammo_player = ammo_fuel;
  21         self.reload_ammo_min = autocvar_g_balance_shotgun_primary_ammo;
  22         self.reload_ammo_amount = autocvar_g_balance_shotgun_reload_ammo;
  23         self.reload_time = autocvar_g_balance_shotgun_reload_time;
  24         self.reload_sound = "weapons/reload.wav";
  25
  26         W_Reload();
  27 }
  28
  29 void W_Shotgun_Attack (void)
  30 {
  31         float   sc;
  32         float   ammoamount;
  33         float   bullets;
  34         float   d;
  35         float   f;
  36         float   spread;
  37         float   bulletspeed;
  38         float   bulletconstant;
  39         local entity flash;
  40
  41         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  42         bullets = autocvar_g_balance_shotgun_primary_bullets;
  43         d = autocvar_g_balance_shotgun_primary_damage;
  44         f = autocvar_g_balance_shotgun_primary_force;
  45         spread = autocvar_g_balance_shotgun_primary_spread;
  46         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  47         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  48
  49         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
  50         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  51         {
  52                 if(autocvar_g_balance_shotgun_reload_ammo)
  53                 {
  54                         self.clip_load -= ammoamount;
  55                         self.weapon_load[WEP_SHOTGUN] = self.clip_load;
  56                 }
  57                 else
  58                         self.ammo_shells -= ammoamount;
  59         }
  60
  61         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  62         for (sc = 0;sc < bullets;sc = sc + 1)
  63                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  64         endFireBallisticBullet();
  65
  66         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  67
  68         // casing code
  69         if (autocvar_g_casings >= 1)
  70                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  71                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  72
  73         // muzzle flash for 1st person view
  74         flash = spawn();
  75         setmodel(flash, "models/uziflash.md3"); // precision set below
  76         flash.think = SUB_Remove;
  77         flash.nextthink = time + 0.06;
  78         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  79         W_AttachToShotorg(flash, '5 0 0');
  80 }
  81
  82 void shotgun_meleethink (void)
  83 {
  84         // store time when we started swinging down inside self.cnt
  85         if(!self.cnt)
  86                 self.cnt = time;
  87
  88         makevectors(self.owner.v_angle);
  89         vector angle;
  90         angle = v_forward;
  91
  92         float meleetime;
  93         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  94
  95         // perform trace
  96         float f;
  97         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
  98         vector targpos;
  99         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
 100
 101         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 102
 103         // apply the damage, also remove self
 104         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
 105         {
 106                 vector force;
 107                 force = angle * autocvar_g_balance_shotgun_secondary_force;
 108                 if(accuracy_isgooddamage(self.owner, trace_ent))
 109                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
 110                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
 111                 remove(self);
 112         }
 113         else if(time >= self.cnt + meleetime) // missed, remove ent
 114                 remove(self);
 115         else // continue swinging the weapon in hope of hitting someone :)
 116                 self.nextthink = time;
 117 }
 118
 119 void W_Shotgun_Attack2 (void)
 120 {
 121         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 122         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 123
 124         entity meleetemp;
 125         meleetemp = spawn();
 126         meleetemp.owner = self;
 127         meleetemp.think = shotgun_meleethink;
 128         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 129         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 130 }
 131
 132 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 133
 134 .float shotgun_primarytime;
 135
 136 float w_shotgun(float req)
 137 {
 138         float ammo_amount;
 139         if (req == WR_AIM)
 140                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 141                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 142                 else
 143                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 144         else if (req == WR_THINK)
 145         {
 146                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 147                 {
 148                         // don't force reload an empty shotgun if its melee attack is active
 149                         if not(autocvar_g_balance_shotgun_secondary && self.ammo_shells < autocvar_g_balance_shotgun_primary_ammo)
 150                                 W_Shotgun_Reload();
 151                 }
 152                 else
 153                 {
 154                         if (self.BUTTON_ATCK)
 155                         {
 156                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 157                                 {
 158                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 159                                         {
 160                                                 W_Shotgun_Attack();
 161                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 162                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 163                                         }
 164                                 }
 165                         }
 166                 }
 167                 if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 168                 if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 169                 {
 170                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 171                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 172                 }
 173         }
 174         else if (req == WR_PRECACHE)
 175         {
 176                 precache_model ("models/uziflash.md3");
 177                 precache_model ("models/weapons/g_shotgun.md3");
 178                 precache_model ("models/weapons/v_shotgun.md3");
 179                 precache_model ("models/weapons/h_shotgun.iqm");
 180                 precache_sound ("misc/itempickup.wav");
 181                 precache_sound ("weapons/shotgun_fire.wav");
 182                 precache_sound ("weapons/shotgun_melee.wav");
 183                 precache_sound ("weapons/reload.wav");
 184         }
 185         else if (req == WR_SETUP)
 186         {
 187                 weapon_setup(WEP_SHOTGUN);
 188                 W_Shotgun_SetAmmoCounter();
 189         }
 190         else if (req == WR_CHECKAMMO1)
 191         {
 192                 ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 193                 ammo_amount += self.weapon_load[WEP_SHOTGUN] >= autocvar_g_balance_shotgun_primary_ammo;
 194                 return ammo_amount;
 195         }
 196         else if (req == WR_CHECKAMMO2)
 197         {
 198                 // melee attack is always available
 199                 return TRUE;
 200         }
 201         else if (req == WR_RESETPLAYER)
 202         {
 203                 // all weapons must be fully loaded when we spawn
 204                 self.weapon_load[WEP_SHOTGUN] = autocvar_g_balance_shotgun_reload_ammo;
 205         }
 206         else if (req == WR_RELOAD)
 207         {
 208                 W_Shotgun_Reload();
 209         }
 210         return TRUE;
 211 };
 212 #endif
 213 #ifdef CSQC
 214 .float prevric;
 215 float w_shotgun(float req)
 216 {
 217         if(req == WR_IMPACTEFFECT)
 218         {
 219                 vector org2;
 220                 org2 = w_org + w_backoff * 2;
 221                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 222                 if(!w_issilent && time - self.prevric > 0.25)
 223                 {
 224                         if(w_random < 0.0165)
 225                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 226                         else if(w_random < 0.033)
 227                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 228                         else if(w_random < 0.05)
 229                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 230                         self.prevric = time;
 231                 }
 232         }
 233         else if(req == WR_PRECACHE)
 234         {
 235                 precache_sound("weapons/ric1.wav");
 236                 precache_sound("weapons/ric2.wav");
 237                 precache_sound("weapons/ric3.wav");
 238         }
 239         else if (req == WR_SUICIDEMESSAGE)
 240                 w_deathtypestring = _("%s did the impossible");
 241         else if (req == WR_KILLMESSAGE)
 242         {
 243                 if(w_deathtype & HITTYPE_SECONDARY)
 244                         w_deathtypestring = _("%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun");
 245                 else
 246                         w_deathtypestring = _("%s was gunned by %s");
 247         }
 248         return TRUE;
 249 }
 250 #endif
 251 #endif