qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 // weapon load persistence, for weapons that support reloading
   7 .float shotgun_load;
   8
   9 void W_Shotgun_SetAmmoCounter()
  10 {
  11         // set clip_load to the weapon we have switched to, if the gun uses reloading
  12         if(!autocvar_g_balance_shotgun_reload_ammo)
  13                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  14         else
  15         {
  16                 self.clip_load = self.shotgun_load;
  17                 self.clip_size = autocvar_g_balance_shotgun_reload_ammo; // for the crosshair ammo display
  18         }
  19 }
  20
  21 void W_Shotgun_Reload()
  22 {
  23         self.reload_ammo_player = ammo_fuel;
  24         self.reload_ammo_min = autocvar_g_balance_shotgun_primary_ammo;
  25         self.reload_ammo_amount = autocvar_g_balance_shotgun_reload_ammo;
  26         self.reload_time = autocvar_g_balance_shotgun_reload_time;
  27         self.reload_sound = "weapons/reload.wav";
  28
  29         W_Reload();
  30 }
  31
  32 void W_Shotgun_Attack (void)
  33 {
  34         float   sc;
  35         float   ammoamount;
  36         float   bullets;
  37         float   d;
  38         float   f;
  39         float   spread;
  40         float   bulletspeed;
  41         float   bulletconstant;
  42         local entity flash;
  43
  44         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  45         bullets = autocvar_g_balance_shotgun_primary_bullets;
  46         d = autocvar_g_balance_shotgun_primary_damage;
  47         f = autocvar_g_balance_shotgun_primary_force;
  48         spread = autocvar_g_balance_shotgun_primary_spread;
  49         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  50         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  51
  52         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
  53         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  54         {
  55                 if(autocvar_g_balance_shotgun_reload_ammo)
  56                 {
  57                         self.clip_load -= ammoamount;
  58                         self.shotgun_load = self.clip_load;
  59                 }
  60                 else
  61                         self.ammo_shells -= ammoamount;
  62         }
  63
  64         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  65         for (sc = 0;sc < bullets;sc = sc + 1)
  66                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  67         endFireBallisticBullet();
  68
  69         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  70
  71         // casing code
  72         if (autocvar_g_casings >= 1)
  73                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  74                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  75
  76         // muzzle flash for 1st person view
  77         flash = spawn();
  78         setmodel(flash, "models/uziflash.md3"); // precision set below
  79         flash.think = SUB_Remove;
  80         flash.nextthink = time + 0.06;
  81         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  82         W_AttachToShotorg(flash, '5 0 0');
  83 }
  84
  85 void shotgun_meleethink (void)
  86 {
  87         // store time when we started swinging down inside self.cnt
  88         if(!self.cnt)
  89                 self.cnt = time;
  90
  91         makevectors(self.owner.v_angle);
  92         vector angle;
  93         angle = v_forward;
  94
  95         float meleetime;
  96         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  97
  98         // perform trace
  99         float f;
 100         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
 101         vector targpos;
 102         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
 103
 104         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 105
 106         // apply the damage, also remove self
 107         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
 108         {
 109                 vector force;
 110                 force = angle * autocvar_g_balance_shotgun_secondary_force;
 111                 if(accuracy_isgooddamage(self.owner, trace_ent))
 112                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
 113                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
 114                 remove(self);
 115         }
 116         else if(time >= self.cnt + meleetime) // missed, remove ent
 117                 remove(self);
 118         else // continue swinging the weapon in hope of hitting someone :)
 119                 self.nextthink = time;
 120 }
 121
 122 void W_Shotgun_Attack2 (void)
 123 {
 124         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 125         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 126
 127         entity meleetemp;
 128         meleetemp = spawn();
 129         meleetemp.owner = self;
 130         meleetemp.think = shotgun_meleethink;
 131         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 132         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 133 }
 134
 135 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 136
 137 .float shotgun_primarytime;
 138
 139 float w_shotgun(float req)
 140 {
 141         float ammo_amount;
 142         if (req == WR_AIM)
 143                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 144                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 145                 else
 146                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 147         else if (req == WR_THINK)
 148         {
 149                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 150                 {
 151                         // don't force reload an empty shotgun if its melee attack is active
 152                         if not(autocvar_g_balance_shotgun_secondary && self.ammo_shells < autocvar_g_balance_shotgun_primary_ammo)
 153                                 W_Shotgun_Reload();
 154                 }
 155                 else
 156                 {
 157                         if (self.BUTTON_ATCK)
 158                         {
 159                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 160                                 {
 161                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 162                                         {
 163                                                 W_Shotgun_Attack();
 164                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 165                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 166                                         }
 167                                 }
 168                         }
 169                 }
 170                 if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 171                 if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 172                 {
 173                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 174                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 175                 }
 176         }
 177         else if (req == WR_PRECACHE)
 178         {
 179                 precache_model ("models/uziflash.md3");
 180                 precache_model ("models/weapons/g_shotgun.md3");
 181                 precache_model ("models/weapons/v_shotgun.md3");
 182                 precache_model ("models/weapons/h_shotgun.iqm");
 183                 precache_sound ("misc/itempickup.wav");
 184                 precache_sound ("weapons/shotgun_fire.wav");
 185                 precache_sound ("weapons/shotgun_melee.wav");
 186                 precache_sound ("weapons/reload.wav");
 187         }
 188         else if (req == WR_SETUP)
 189         {
 190                 weapon_setup(WEP_SHOTGUN);
 191                 W_Shotgun_SetAmmoCounter();
 192         }
 193         else if (req == WR_CHECKAMMO1)
 194         {
 195                 ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 196                 ammo_amount += self.shotgun_load >= autocvar_g_balance_shotgun_primary_ammo;
 197                 return ammo_amount;
 198         }
 199         else if (req == WR_CHECKAMMO2)
 200         {
 201                 // melee attack is always available
 202                 return TRUE;
 203         }
 204         else if (req == WR_RESETPLAYER)
 205         {
 206                 // all weapons must be fully loaded when we spawn
 207                 self.shotgun_load = autocvar_g_balance_shotgun_reload_ammo;
 208         }
 209         else if (req == WR_RELOAD)
 210         {
 211                 W_Shotgun_Reload();
 212         }
 213         return TRUE;
 214 };
 215 #endif
 216 #ifdef CSQC
 217 .float prevric;
 218 float w_shotgun(float req)
 219 {
 220         if(req == WR_IMPACTEFFECT)
 221         {
 222                 vector org2;
 223                 org2 = w_org + w_backoff * 2;
 224                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 225                 if(!w_issilent && time - self.prevric > 0.25)
 226                 {
 227                         if(w_random < 0.0165)
 228                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 229                         else if(w_random < 0.033)
 230                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 231                         else if(w_random < 0.05)
 232                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 233                         self.prevric = time;
 234                 }
 235         }
 236         else if(req == WR_PRECACHE)
 237         {
 238                 precache_sound("weapons/ric1.wav");
 239                 precache_sound("weapons/ric2.wav");
 240                 precache_sound("weapons/ric3.wav");
 241         }
 242         else if (req == WR_SUICIDEMESSAGE)
 243                 w_deathtypestring = _("%s did the impossible");
 244         else if (req == WR_KILLMESSAGE)
 245         {
 246                 if(w_deathtype & HITTYPE_SECONDARY)
 247                         w_deathtypestring = _("%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun");
 248                 else
 249                         w_deathtypestring = _("%s was gunned by %s");
 250         }
 251         return TRUE;
 252 }
 253 #endif
 254 #endif