qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 // weapon load persistence, for weapons that support reloading
   7 .float shotgun_load;
   8
   9 void W_Shotgun_SetAmmoCounter()
  10 {
  11         // set clip_load to the weapon we have switched to, if the gun uses reloading
  12         if(!autocvar_g_balance_shotgun_reload_ammo)
  13                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  14         else
  15         {
  16                 self.clip_load = self.shotgun_load;
  17                 self.clip_size = autocvar_g_balance_shotgun_reload_ammo; // for the crosshair ammo display
  18         }
  19 }
  20
  21 void W_Shotgun_ReloadedAndReady()
  22 {
  23         float t;
  24
  25         // now do the ammo transfer
  26         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  27         while(self.clip_load < autocvar_g_balance_shotgun_reload_ammo && self.ammo_shells) // make sure we don't add more ammo than we have
  28         {
  29                 self.clip_load += 1;
  30                 self.ammo_shells -= 1;
  31         }
  32         self.shotgun_load = self.clip_load;
  33
  34         t = ATTACK_FINISHED(self) - autocvar_g_balance_shotgun_reload_time - 1;
  35         ATTACK_FINISHED(self) = t;
  36         w_ready();
  37 }
  38
  39 void W_Shotgun_Reload()
  40 {
  41         // return if reloading is disabled for this weapon
  42         if(!autocvar_g_balance_shotgun_reload_ammo)
  43                 return;
  44
  45         if(!W_ReloadCheck(self.ammo_shells, autocvar_g_balance_shotgun_primary_ammo))
  46                 return;
  47
  48         float t;
  49
  50         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  51
  52         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_shotgun_reload_time + 1;
  53         ATTACK_FINISHED(self) = t;
  54
  55         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_shotgun_reload_time, W_Shotgun_ReloadedAndReady);
  56
  57         self.old_clip_load = self.clip_load;
  58         self.clip_load = -1;
  59 }
  60
  61 void W_Shotgun_Attack (void)
  62 {
  63         float   sc;
  64         float   ammoamount;
  65         float   bullets;
  66         float   d;
  67         float   f;
  68         float   spread;
  69         float   bulletspeed;
  70         float   bulletconstant;
  71         local entity flash;
  72
  73         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  74         bullets = autocvar_g_balance_shotgun_primary_bullets;
  75         d = autocvar_g_balance_shotgun_primary_damage;
  76         f = autocvar_g_balance_shotgun_primary_force;
  77         spread = autocvar_g_balance_shotgun_primary_spread;
  78         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  79         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  80
  81         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
  82         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  83         {
  84                 if(autocvar_g_balance_shotgun_reload_ammo)
  85                 {
  86                         self.clip_load -= ammoamount;
  87                         self.shotgun_load = self.clip_load;
  88                 }
  89                 else
  90                         self.ammo_shells -= ammoamount;
  91         }
  92
  93         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  94         for (sc = 0;sc < bullets;sc = sc + 1)
  95                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  96         endFireBallisticBullet();
  97
  98         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  99
 100         // casing code
 101         if (autocvar_g_casings >= 1)
 102                 for (sc = 0;sc < ammoamount;sc = sc + 1)
 103                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
 104
 105         // muzzle flash for 1st person view
 106         flash = spawn();
 107         setmodel(flash, "models/uziflash.md3"); // precision set below
 108         flash.think = SUB_Remove;
 109         flash.nextthink = time + 0.06;
 110         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 111         W_AttachToShotorg(flash, '5 0 0');
 112 }
 113
 114 void shotgun_meleethink (void)
 115 {
 116         // store time when we started swinging down inside self.cnt
 117         if(!self.cnt)
 118                 self.cnt = time;
 119
 120         makevectors(self.owner.v_angle);
 121         vector angle;
 122         angle = v_forward;
 123
 124         float meleetime;
 125         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
 126
 127         // perform trace
 128         float f;
 129         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
 130         vector targpos;
 131         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
 132
 133         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 134
 135         // apply the damage, also remove self
 136         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
 137         {
 138                 vector force;
 139                 force = angle * autocvar_g_balance_shotgun_secondary_force;
 140                 if(accuracy_isgooddamage(self.owner, trace_ent))
 141                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
 142                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
 143                 remove(self);
 144         }
 145         else if(time >= self.cnt + meleetime) // missed, remove ent
 146                 remove(self);
 147         else // continue swinging the weapon in hope of hitting someone :)
 148                 self.nextthink = time;
 149 }
 150
 151 void W_Shotgun_Attack2 (void)
 152 {
 153         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 154         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 155
 156         entity meleetemp;
 157         meleetemp = spawn();
 158         meleetemp.owner = self;
 159         meleetemp.think = shotgun_meleethink;
 160         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 161         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 162 }
 163
 164 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 165
 166 .float shotgun_primarytime;
 167
 168 float w_shotgun(float req)
 169 {
 170         float ammo_amount;
 171         if (req == WR_AIM)
 172                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 173                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 174                 else
 175                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 176         else if (req == WR_THINK)
 177         {
 178                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 179                         W_Shotgun_Reload();
 180                 else
 181                 {
 182                         if (self.BUTTON_ATCK)
 183                         {
 184                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 185                                 {
 186                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 187                                         {
 188                                                 W_Shotgun_Attack();
 189                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 190                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 191                                         }
 192                                 }
 193                         }
 194                         if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 195                         if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 196                         {
 197                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 198                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 199                         }
 200                 }
 201         }
 202         else if (req == WR_PRECACHE)
 203         {
 204                 precache_model ("models/uziflash.md3");
 205                 precache_model ("models/weapons/g_shotgun.md3");
 206                 precache_model ("models/weapons/v_shotgun.md3");
 207                 precache_model ("models/weapons/h_shotgun.iqm");
 208                 precache_sound ("misc/itempickup.wav");
 209                 precache_sound ("weapons/shotgun_fire.wav");
 210                 precache_sound ("weapons/shotgun_melee.wav");
 211                 precache_sound ("weapons/reload.wav");
 212         }
 213         else if (req == WR_SETUP)
 214         {
 215                 weapon_setup(WEP_SHOTGUN);
 216                 W_Shotgun_SetAmmoCounter();
 217         }
 218         else if (req == WR_CHECKAMMO1)
 219         {
 220                 ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 221                 ammo_amount += (autocvar_g_balance_shotgun_reload_ammo && self.shotgun_load >= autocvar_g_balance_shotgun_primary_ammo);
 222                 return ammo_amount;
 223         }
 224         else if (req == WR_CHECKAMMO2)
 225         {
 226                 // melee attack is always available
 227                 return TRUE;
 228         }
 229         else if (req == WR_RESETPLAYER)
 230         {
 231                 // all weapons must be fully loaded when we spawn
 232                 self.shotgun_load = autocvar_g_balance_shotgun_reload_ammo;
 233         }
 234         else if (req == WR_RELOAD)
 235         {
 236                 W_Shotgun_Reload();
 237         }
 238         return TRUE;
 239 };
 240 #endif
 241 #ifdef CSQC
 242 .float prevric;
 243 float w_shotgun(float req)
 244 {
 245         if(req == WR_IMPACTEFFECT)
 246         {
 247                 vector org2;
 248                 org2 = w_org + w_backoff * 2;
 249                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 250                 if(!w_issilent && time - self.prevric > 0.25)
 251                 {
 252                         if(w_random < 0.0165)
 253                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 254                         else if(w_random < 0.033)
 255                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 256                         else if(w_random < 0.05)
 257                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 258                         self.prevric = time;
 259                 }
 260         }
 261         else if(req == WR_PRECACHE)
 262         {
 263                 precache_sound("weapons/ric1.wav");
 264                 precache_sound("weapons/ric2.wav");
 265                 precache_sound("weapons/ric3.wav");
 266         }
 267         else if (req == WR_SUICIDEMESSAGE)
 268                 w_deathtypestring = "%s did the impossible";
 269         else if (req == WR_KILLMESSAGE)
 270         {
 271                 if(w_deathtype & HITTYPE_SECONDARY)
 272                         w_deathtypestring = "%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun";
 273                 else
 274                         w_deathtypestring = "%s was gunned by %s";
 275         }
 276         return TRUE;
 277 }
 278 #endif
 279 #endif