qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_Shotgun_Reload()
   7 {
   8         W_Reload(ammo_shells, autocvar_g_balance_shotgun_primary_ammo, autocvar_g_balance_shotgun_reload_ammo, autocvar_g_balance_shotgun_reload_time, "weapons/reload.wav");
   9 }
  10
  11 void W_Shotgun_Attack (void)
  12 {
  13         float   sc;
  14         float   ammoamount;
  15         float   bullets;
  16         float   d;
  17         float   f;
  18         float   spread;
  19         float   bulletspeed;
  20         float   bulletconstant;
  21         local entity flash;
  22
  23         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  24         bullets = autocvar_g_balance_shotgun_primary_bullets;
  25         d = autocvar_g_balance_shotgun_primary_damage;
  26         f = autocvar_g_balance_shotgun_primary_force;
  27         spread = autocvar_g_balance_shotgun_primary_spread;
  28         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  29         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  30
  31         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
  32         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  33         {
  34                 if(autocvar_g_balance_shotgun_reload_ammo)
  35                 {
  36                         self.clip_load -= ammoamount;
  37                         self.weapon_load[WEP_SHOTGUN] = self.clip_load;
  38                 }
  39                 else
  40                         self.ammo_shells -= ammoamount;
  41         }
  42
  43         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  44         for (sc = 0;sc < bullets;sc = sc + 1)
  45                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  46         endFireBallisticBullet();
  47
  48         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  49
  50         // casing code
  51         if (autocvar_g_casings >= 1)
  52                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  53                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  54
  55         // muzzle flash for 1st person view
  56         flash = spawn();
  57         setmodel(flash, "models/uziflash.md3"); // precision set below
  58         flash.think = SUB_Remove;
  59         flash.nextthink = time + 0.06;
  60         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  61         W_AttachToShotorg(flash, '5 0 0');
  62 }
  63
  64 void shotgun_meleethink (void)
  65 {
  66         // store time when we started swinging down inside self.cnt
  67         if(!self.cnt)
  68                 self.cnt = time;
  69
  70         makevectors(self.owner.v_angle);
  71         vector angle;
  72         angle = v_forward;
  73
  74         float meleetime;
  75         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  76
  77         // perform trace
  78         float f;
  79         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
  80         vector targpos;
  81         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
  82
  83         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
  84
  85         // apply the damage, also remove self
  86         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
  87         {
  88                 vector force;
  89                 force = angle * autocvar_g_balance_shotgun_secondary_force;
  90                 if(accuracy_isgooddamage(self.owner, trace_ent))
  91                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
  92                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
  93                 remove(self);
  94         }
  95         else if(time >= self.cnt + meleetime) // missed, remove ent
  96                 remove(self);
  97         else // continue swinging the weapon in hope of hitting someone :)
  98                 self.nextthink = time;
  99 }
 100
 101 void W_Shotgun_Attack2 (void)
 102 {
 103         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 104         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 105
 106         entity meleetemp;
 107         meleetemp = spawn();
 108         meleetemp.owner = self;
 109         meleetemp.think = shotgun_meleethink;
 110         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 111         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 112 }
 113
 114 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 115
 116 .float shotgun_primarytime;
 117
 118 float w_shotgun(float req)
 119 {
 120         float ammo_amount;
 121         if (req == WR_AIM)
 122                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 123                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 124                 else
 125                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 126         else if (req == WR_THINK)
 127         {
 128                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 129                 {
 130                         // don't force reload an empty shotgun if its melee attack is active
 131                         if not(autocvar_g_balance_shotgun_secondary && self.ammo_shells < autocvar_g_balance_shotgun_primary_ammo)
 132                                 W_Shotgun_Reload();
 133                 }
 134                 else
 135                 {
 136                         if (self.BUTTON_ATCK)
 137                         {
 138                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 139                                 {
 140                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 141                                         {
 142                                                 W_Shotgun_Attack();
 143                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 144                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 145                                         }
 146                                 }
 147                         }
 148                 }
 149                 if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 150                 if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 151                 {
 152                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 153                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 154                 }
 155         }
 156         else if (req == WR_PRECACHE)
 157         {
 158                 precache_model ("models/uziflash.md3");
 159                 precache_model ("models/weapons/g_shotgun.md3");
 160                 precache_model ("models/weapons/v_shotgun.md3");
 161                 precache_model ("models/weapons/h_shotgun.iqm");
 162                 precache_sound ("misc/itempickup.wav");
 163                 precache_sound ("weapons/shotgun_fire.wav");
 164                 precache_sound ("weapons/shotgun_melee.wav");
 165                 precache_sound ("weapons/reload.wav");
 166         }
 167         else if (req == WR_SETUP)
 168         {
 169                 weapon_setup(WEP_SHOTGUN);
 170         }
 171         else if (req == WR_CHECKAMMO1)
 172         {
 173                 ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 174                 ammo_amount += self.weapon_load[WEP_SHOTGUN] >= autocvar_g_balance_shotgun_primary_ammo;
 175                 return ammo_amount;
 176         }
 177         else if (req == WR_CHECKAMMO2)
 178         {
 179                 // melee attack is always available
 180                 return TRUE;
 181         }
 182         else if (req == WR_RELOAD)
 183         {
 184                 W_Shotgun_Reload();
 185         }
 186         return TRUE;
 187 };
 188 #endif
 189 #ifdef CSQC
 190 .float prevric;
 191 float w_shotgun(float req)
 192 {
 193         if(req == WR_IMPACTEFFECT)
 194         {
 195                 vector org2;
 196                 org2 = w_org + w_backoff * 2;
 197                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 198                 if(!w_issilent && time - self.prevric > 0.25)
 199                 {
 200                         if(w_random < 0.0165)
 201                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 202                         else if(w_random < 0.033)
 203                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 204                         else if(w_random < 0.05)
 205                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 206                         self.prevric = time;
 207                 }
 208         }
 209         else if(req == WR_PRECACHE)
 210         {
 211                 precache_sound("weapons/ric1.wav");
 212                 precache_sound("weapons/ric2.wav");
 213                 precache_sound("weapons/ric3.wav");
 214         }
 215         else if (req == WR_SUICIDEMESSAGE)
 216                 w_deathtypestring = _("%s did the impossible");
 217         else if (req == WR_KILLMESSAGE)
 218         {
 219                 if(w_deathtype & HITTYPE_SECONDARY)
 220                         w_deathtypestring = _("%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun");
 221                 else
 222                         w_deathtypestring = _("%s was gunned by %s");
 223         }
 224         return TRUE;
 225 }
 226 #endif
 227 #endif