qcsrc/server/w_tuba.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(TUBA, w_tuba, 0, 1, WEP_FLAG_HIDDEN | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "tuba", "tuba", _("@!#%'n Tuba"))
   3 #else
   4 #ifdef SVQC
   5 //#define TUBA_NOTE(n) strcat("weapons/tuba_note", ftos(n), ".wav")
   6 .entity tuba_note;
   7 .float tuba_smoketime;
   8 .float tuba_instrument;
   9
  10 #define MAX_TUBANOTES 32
  11 .float tuba_lastnotes_last;
  12 .float tuba_lastnotes_cnt; // over
  13 .vector tuba_lastnotes[MAX_TUBANOTES];
  14
  15 float W_Tuba_HasPlayed(entity pl, string melody, float instrument, float ignorepitch, float mintempo, float maxtempo)
  16 {
  17         float i, j, mmin, mmax, nolength;
  18         float n = tokenize_console(melody);
  19         if(n > pl.tuba_lastnotes_cnt)
  20                 return FALSE;
  21         float pitchshift = 0;
  22
  23         if(instrument >= 0)
  24                 if(pl.tuba_instrument != instrument)
  25                         return FALSE;
  26
  27         // verify notes...
  28         nolength = FALSE;
  29         for(i = 0; i < n; ++i)
  30         {
  31                 vector v = pl.(tuba_lastnotes[mod(pl.tuba_lastnotes_last - i + MAX_TUBANOTES, MAX_TUBANOTES)]);
  32                 float ai = stof(argv(n - i - 1));
  33                 float np = floor(ai);
  34                 if(ai == np)
  35                         nolength = TRUE;
  36                 // n counts the last played notes BACKWARDS
  37                 // _x is start
  38                 // _y is end
  39                 // _z is note pitch
  40                 if(ignorepitch && i == 0)
  41                 {
  42                         pitchshift = np - v_z;
  43                 }
  44                 else
  45                 {
  46                         if(v_z + pitchshift != np)
  47                                 return FALSE;
  48                 }
  49         }
  50
  51         // now we know the right NOTES were played
  52         if(!nolength)
  53         {
  54                 // verify rhythm...
  55                 float ti = 0;
  56                 if(maxtempo > 0)
  57                         mmin = 240 / maxtempo; // 60 = "0.25 means 1 sec", at 120 0.5 means 1 sec, at 240 1 means 1 sec
  58                 else
  59                         mmin = 0;
  60                 if(mintempo > 0)
  61                         mmax = 240 / mintempo; // 60 = "0.25 means 1 sec", at 120 0.5 means 1 sec, at 240 1 means 1 sec
  62                 else
  63                         mmax = 240; // you won't try THAT hard... (tempo 1)
  64                 //print(sprintf("initial tempo rules: %f %f\n", mmin, mmax));
  65
  66                 for(i = 0; i < n; ++i)
  67                 {
  68                         vector vi = pl.(tuba_lastnotes[mod(pl.tuba_lastnotes_last - i + MAX_TUBANOTES, MAX_TUBANOTES)]);
  69                         float ai = stof(argv(n - i - 1));
  70                         ti -= 1 / (ai - floor(ai));
  71                         float tj = ti;
  72                         for(j = i+1; j < n; ++j)
  73                         {
  74                                 vector vj = pl.(tuba_lastnotes[mod(pl.tuba_lastnotes_last - j + MAX_TUBANOTES, MAX_TUBANOTES)]);
  75                                 float aj = stof(argv(n - j - 1));
  76                                 tj -= (aj - floor(aj));
  77
  78                                 // note i should be at m*ti+b
  79                                 // note j should be at m*tj+b
  80                                 // so:
  81                                 // we have a LINE l, so that
  82                                 // vi_x <= l(ti) <= vi_y
  83                                 // vj_x <= l(tj) <= vj_y
  84                                 // what is m?
  85
  86                                 // vi_x <= vi_y <= vj_x <= vj_y
  87                                 // ti <= tj
  88                                 //print(sprintf("first note: %f to %f, should be %f\n", vi_x, vi_y, ti));
  89                                 //print(sprintf("second note: %f to %f, should be %f\n", vj_x, vj_y, tj));
  90                                 //print(sprintf("m1 = %f\n", (vi_x - vj_y) / (ti - tj)));
  91                                 //print(sprintf("m2 = %f\n", (vi_y - vj_x) / (ti - tj)));
  92                                 mmin = max(mmin, (vi_x - vj_y) / (ti - tj)); // lower bound
  93                                 mmax = min(mmax, (vi_y - vj_x) / (ti - tj)); // upper bound
  94                         }
  95                 }
  96
  97                 if(mmin > mmax) // rhythm fail
  98                         return FALSE;
  99         }
 100
 101         pl.tuba_lastnotes_cnt = 0;
 102
 103         return TRUE;
 104 }
 105
 106 void W_Tuba_NoteOff()
 107 {
 108         // we have a note:
 109         //   on: self.spawnshieldtime
 110         //   off: time
 111         //   note: self.cnt
 112         if(self.owner.tuba_note == self)
 113         {
 114                 self.owner.tuba_lastnotes_last = mod(self.owner.tuba_lastnotes_last + 1, MAX_TUBANOTES);
 115                 self.owner.(tuba_lastnotes[self.owner.tuba_lastnotes_last]) = eX * self.spawnshieldtime + eY * time + eZ * self.cnt;
 116                 self.owner.tuba_note = world;
 117                 self.owner.tuba_lastnotes_cnt = bound(0, self.owner.tuba_lastnotes_cnt + 1, MAX_TUBANOTES);
 118
 119                 string s;
 120                 s = trigger_magicear_processmessage_forallears(self.owner, 0, world, string_null);
 121                 if(s != "")
 122                 {
 123                         // simulate a server message
 124                         switch(self.tuba_instrument)
 125                         {
 126                                 default:
 127                                 case 0: // Tuba
 128                                         bprint(strcat("\{1}\{13}* ^3", self.owner.netname, "^3 played on the @!#%'n Tuba: ^7", s, "\n"));
 129                                         break;
 130                                 case 1:
 131                                         bprint(strcat("\{1}\{13}* ^3", self.owner.netname, "^3 played on the @!#%'n Accordeon: ^7", s, "\n"));
 132                                         break;
 133                         }
 134                 }
 135         }
 136         remove(self);
 137 }
 138
 139 float Tuba_GetNote(entity pl, float hittype)
 140 {
 141         float note;
 142         float movestate;
 143         movestate = 5;
 144         if(pl.movement_x < 0) movestate -= 3;
 145         if(pl.movement_x > 0) movestate += 3;
 146         if(pl.movement_y < 0) movestate -= 1;
 147         if(pl.movement_y > 0) movestate += 1;
 148         switch(movestate)
 149         {
 150         // layout: originally I wanted
 151         //   eb e  e#=f
 152         //   B  c  d
 153         //   Gb G  G#
 154         // but then you only use forward and right key. So to make things more
 155         // interesting, I swapped B with e#. Har har har...
 156         //   eb e  B
 157         // f=e# c  d
 158         //   Gb G  G#
 159                 case 1: note = -6; break; // Gb
 160                 case 2: note = -5; break; // G
 161                 case 3: note = -4; break; // G#
 162                 case 4: note = +5; break; // e#
 163                 case 5: note =  0; break; // c
 164                 case 6: note = +2; break; // d
 165                 case 7: note = +3; break; // eb
 166                 case 8: note = +4; break; // e
 167                 case 9: note = -1; break; // B
 168         }
 169         if(pl.BUTTON_CROUCH)
 170                 note -= 12;
 171         if(pl.BUTTON_JUMP)
 172                 note += 12;
 173         if(hittype & HITTYPE_SECONDARY)
 174                 note += 7;
 175
 176         // we support two kinds of tubas, those tuned in Eb and those tuned in C
 177         // kind of tuba currently is player slot number, or team number if in
 178         // teamplay
 179         // that way, holes in the range of notes are "plugged"
 180         if(teamplay)
 181         {
 182                 if(pl.team == COLOR_TEAM2 || pl.team == COLOR_TEAM4)
 183                         note += 3;
 184         }
 185         else
 186         {
 187                 if(pl.clientcolors & 1)
 188                         note += 3;
 189         }
 190
 191         // total range of notes:
 192         //                       0
 193         //                 ***  ** ****
 194         //                        ***  ** ****
 195         //     ***  ** ****
 196         //            ***  ** ****
 197         //     ***  ********************* ****
 198         //     -18.........................+12
 199         //        ***  ********************* ****
 200         //     -18............................+15
 201         //     with jump: ... +24
 202         //     ... +27
 203         return note;
 204 }
 205
 206 float W_Tuba_NoteSendEntity(entity to, float sf)
 207 {
 208         float f;
 209
 210         msg_entity = to;
 211         if(!sound_allowed(MSG_ONE, self.realowner))
 212                 return FALSE;
 213
 214         WriteByte(MSG_ENTITY, ENT_CLIENT_TUBANOTE);
 215         WriteByte(MSG_ENTITY, sf);
 216         if(sf & 1)
 217         {
 218                 WriteChar(MSG_ENTITY, self.cnt);
 219                 f = 0;
 220                 if(self.realowner != to)
 221                         f |= 1;
 222                 f |= 2 * self.tuba_instrument;
 223                 WriteByte(MSG_ENTITY, f);
 224         }
 225         if(sf & 2)
 226         {
 227                 WriteCoord(MSG_ENTITY, self.origin_x);
 228                 WriteCoord(MSG_ENTITY, self.origin_y);
 229                 WriteCoord(MSG_ENTITY, self.origin_z);
 230         }
 231         return TRUE;
 232 }
 233
 234 void W_Tuba_NoteThink()
 235 {
 236         float dist_mult;
 237         float vol0, vol1;
 238         vector dir0, dir1;
 239         vector v;
 240         entity e;
 241         if(time > self.teleport_time)
 242         {
 243                 W_Tuba_NoteOff();
 244                 return;
 245         }
 246         self.nextthink = time;
 247         dist_mult = autocvar_g_balance_tuba_attenuation / autocvar_snd_soundradius;
 248         FOR_EACH_REALCLIENT(e)
 249         if(e != self.realowner)
 250         {
 251                 v = self.origin - (e.origin + e.view_ofs);
 252                 vol0 = max(0, 1 - vlen(v) * dist_mult);
 253                 dir0 = normalize(v);
 254                 v = self.realowner.origin - (e.origin + e.view_ofs);
 255                 vol1 = max(0, 1 - vlen(v) * dist_mult);
 256                 dir1 = normalize(v);
 257                 if(fabs(vol0 - vol1) > 0.005) // 0.5 percent change in volume
 258                 {
 259                         setorigin(self, self.realowner.origin);
 260                         self.SendFlags |= 2;
 261                         break;
 262                 }
 263                 if(dir0 * dir1 < 0.9994) // 2 degrees change in angle
 264                 {
 265                         setorigin(self, self.realowner.origin);
 266                         self.SendFlags |= 2;
 267                         break;
 268                 }
 269         }
 270 }
 271
 272 void W_Tuba_NoteOn(float hittype)
 273 {
 274         vector o;
 275         float n;
 276
 277         W_SetupShot(self, FALSE, 2, "", 0, autocvar_g_balance_tuba_damage);
 278
 279         n = Tuba_GetNote(self, hittype);
 280
 281         hittype = 0;
 282         if(self.tuba_instrument & 1)
 283                 hittype |= HITTYPE_SECONDARY;
 284         if(self.tuba_instrument & 2)
 285                 hittype |= HITTYPE_BOUNCE;
 286         if(self.tuba_instrument & 4)
 287                 hittype |= HITTYPE_HEADSHOT;
 288
 289         if(self.tuba_note)
 290         {
 291                 if(self.tuba_note.cnt != n || self.tuba_note.tuba_instrument != self.tuba_instrument)
 292                 {
 293                         entity oldself = self;
 294                         self = self.tuba_note;
 295                         W_Tuba_NoteOff();
 296                         self = oldself;
 297                 }
 298         }
 299
 300         if not(self.tuba_note)
 301         {
 302                 self.tuba_note = spawn();
 303                 self.tuba_note.owner = self.tuba_note.realowner = self;
 304                 self.tuba_note.cnt = n;
 305                 self.tuba_note.tuba_instrument = self.tuba_instrument;
 306                 self.tuba_note.think = W_Tuba_NoteThink;
 307                 self.tuba_note.nextthink = time;
 308                 self.tuba_note.spawnshieldtime = time;
 309                 Net_LinkEntity(self.tuba_note, FALSE, 0, W_Tuba_NoteSendEntity);
 310         }
 311
 312         self.tuba_note.teleport_time = time + autocvar_g_balance_tuba_refire * 2 * W_WeaponRateFactor(); // so it can get prolonged safely
 313
 314         //sound(self, c, TUBA_NOTE(n), bound(0, VOL_BASE * cvar("g_balance_tuba_volume"), 1), autocvar_g_balance_tuba_attenuation);
 315         RadiusDamage(self, self, autocvar_g_balance_tuba_damage, autocvar_g_balance_tuba_edgedamage, autocvar_g_balance_tuba_radius, world, autocvar_g_balance_tuba_force, hittype | WEP_TUBA, world);
 316
 317         o = gettaginfo(self.exteriorweaponentity, 0);
 318         if(time > self.tuba_smoketime)
 319         {
 320                 pointparticles(particleeffectnum("smoke_ring"), o + v_up * 45 + v_right * -6 + v_forward * 8, v_up * 100, 1);
 321                 self.tuba_smoketime = time + 0.25;
 322         }
 323 }
 324
 325 void spawnfunc_weapon_tuba (void)
 326 {
 327         weapon_defaultspawnfunc(WEP_TUBA);
 328 }
 329
 330 float w_tuba(float req)
 331 {
 332         if (req == WR_AIM)
 333         {
 334                 // bots cannot play the Tuba well yet
 335                 // I think they should start with the recorder first
 336                 if(vlen(self.origin - self.enemy.origin) < autocvar_g_balance_tuba_radius)
 337                 {
 338                         if(random() > 0.5)
 339                                 self.BUTTON_ATCK = 1;
 340                         else
 341                                 self.BUTTON_ATCK2 = 1;
 342                 }
 343         }
 344         else if (req == WR_THINK)
 345         {
 346                 if (self.BUTTON_ATCK)
 347                 if (weapon_prepareattack(0, autocvar_g_balance_tuba_refire))
 348                 {
 349                         W_Tuba_NoteOn(0);
 350                         //weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_tuba_animtime, w_ready);
 351                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_tuba_animtime, w_ready);
 352                 }
 353                 if (self.BUTTON_ATCK2)
 354                 if (weapon_prepareattack(1, autocvar_g_balance_tuba_refire))
 355                 {
 356                         W_Tuba_NoteOn(HITTYPE_SECONDARY);
 357                         //weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_tuba_animtime, w_ready);
 358                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_tuba_animtime, w_ready);
 359                 }
 360                 if(self.tuba_note)
 361                 {
 362                         if(!self.BUTTON_ATCK && !self.BUTTON_ATCK2)
 363                         {
 364                                 entity oldself = self;
 365                                 self = self.tuba_note;
 366                                 W_Tuba_NoteOff();
 367                                 self = oldself;
 368                         }
 369                 }
 370         }
 371         else if (req == WR_PRECACHE)
 372         {
 373                 precache_model ("models/weapons/g_tuba.md3");
 374                 precache_model ("models/weapons/v_tuba.md3");
 375                 precache_model ("models/weapons/h_tuba.iqm");
 376                 precache_model ("models/weapons/g_akordeon.md3");
 377                 precache_model ("models/weapons/v_akordeon.md3");
 378                 precache_model ("models/weapons/h_akordeon.iqm");
 379
 380                 //float i;
 381                 //for(i = -18; i <= +27; ++i)
 382                 //      precache_sound(TUBA_NOTE(i));
 383         }
 384         else if (req == WR_SETUP)
 385         {
 386                 weapon_setup(WEP_TUBA);
 387                 self.current_ammo = ammo_none;
 388                 self.tuba_instrument = 0;
 389         }
 390         else if (req == WR_RELOAD)
 391         {
 392                 // switch to alternate instruments :)
 393                 if(self.weaponentity.state == WS_READY)
 394                 {
 395                         switch(self.tuba_instrument)
 396                         {
 397                                 case 0:
 398                                         self.tuba_instrument = 1;
 399                                         self.weaponname = "akordeon";
 400                                         break;
 401                                 case 1:
 402                                         self.tuba_instrument = 0;
 403                                         self.weaponname = "tuba";
 404                                         break;
 405                         }
 406                         W_SetupShot(self, FALSE, 0, "", 0, 0);
 407                         pointparticles(particleeffectnum("teleport"), w_shotorg, '0 0 0', 1);
 408                         self.weaponentity.state = WS_INUSE;
 409                         weapon_thinkf(WFRAME_RELOAD, 0.5, w_ready);
 410                 }
 411         }
 412         else if (req == WR_CHECKAMMO1)
 413                 return TRUE; // TODO use fuel?
 414         else if (req == WR_CHECKAMMO2)
 415                 return TRUE; // TODO use fuel?
 416         return TRUE;
 417 }
 418 #endif
 419 #ifdef CSQC
 420 float w_tuba(float req)
 421 {
 422         if(req == WR_IMPACTEFFECT)
 423         {
 424                 // nothing to do here; particles of tuba are handled differently
 425         }
 426         else if(req == WR_PRECACHE)
 427         {
 428                 // nothing to do
 429         }
 430         else if (req == WR_SUICIDEMESSAGE)
 431         {
 432                 float instr;
 433                 instr = 0;
 434                 if(w_deathtype & HITTYPE_SECONDARY)
 435                         instr |= 1;
 436                 if(w_deathtype & HITTYPE_BOUNCE)
 437                         instr |= 2;
 438                 if(w_deathtype & HITTYPE_HEADSHOT)
 439                         instr |= 4;
 440                 switch(instr)
 441                 {
 442                         default:
 443                         case 0: // Tuba
 444                                 w_deathtypestring = _("%s hurt his own ears with the @!#%%'n Tuba");
 445                                 break;
 446                         case 1: // Accordeon
 447                                 w_deathtypestring = _("%s hurt his own ears with the @!#%%'n Accordeon");
 448                                 break;
 449                 }
 450         }
 451         else if (req == WR_KILLMESSAGE)
 452         {
 453                 float instr;
 454                 instr = 0;
 455                 if(w_deathtype & HITTYPE_SECONDARY)
 456                         instr |= 1;
 457                 if(w_deathtype & HITTYPE_BOUNCE)
 458                         instr |= 2;
 459                 if(w_deathtype & HITTYPE_HEADSHOT)
 460                         instr |= 4;
 461                 switch(instr)
 462                 {
 463                         default:
 464                         case 0: // Tuba
 465                                 w_deathtypestring = _("%s died of %s's great playing on the @!#%%'n Tuba");
 466                                 break;
 467                         case 1: // Accordeon
 468                                 w_deathtypestring = _("%s died of %s's great playing on the @!#%%'n Accordeon");
 469                                 break;
 470                 }
 471         }
 472         return TRUE;
 473 }
 474 #endif
 475 #endif