qcsrc/server/w_tuba.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(TUBA, w_tuba, 0, 1, WEP_FLAG_HIDDEN | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "tuba", "tuba", _("@!#%'n Tuba"))
   3 #else
   4 #ifdef SVQC
   5 //#define TUBA_NOTE(n) strcat("weapons/tuba_note", ftos(n), ".wav")
   6 .entity tuba_note;
   7 .float tuba_smoketime;
   8 .float tuba_instrument;
   9
  10 #define MAX_TUBANOTES 32
  11 .float tuba_lastnotes_last;
  12 .float tuba_lastnotes_cnt; // over
  13 .vector tuba_lastnotes[MAX_TUBANOTES];
  14
  15 float W_Tuba_HasPlayed(entity pl, string melody, float instrument, float ignorepitch, float mintempo, float maxtempo)
  16 {
  17         float i, j, mmin, mmax, nolength;
  18         float n = tokenize_console(melody);
  19         if(n > pl.tuba_lastnotes_cnt)
  20                 return FALSE;
  21         float pitchshift = 0;
  22
  23         if(instrument >= 0)
  24                 if(pl.tuba_instrument != instrument)
  25                         return FALSE;
  26
  27         // verify notes...
  28         nolength = FALSE;
  29         for(i = 0; i < n; ++i)
  30         {
  31                 vector v = pl.(tuba_lastnotes[mod(pl.tuba_lastnotes_last - i + MAX_TUBANOTES, MAX_TUBANOTES)]);
  32                 float ai = stof(argv(n - i - 1));
  33                 float np = floor(ai);
  34                 if(ai == np)
  35                         nolength = TRUE;
  36                 // n counts the last played notes BACKWARDS
  37                 // _x is start
  38                 // _y is end
  39                 // _z is note pitch
  40                 if(ignorepitch && i == 0)
  41                 {
  42                         pitchshift = np - v_z;
  43                 }
  44                 else
  45                 {
  46                         if(v_z + pitchshift != np)
  47                                 return FALSE;
  48                 }
  49         }
  50
  51         // now we know the right NOTES were played
  52         if(!nolength)
  53         {
  54                 // verify rhythm...
  55                 float ti = 0;
  56                 if(maxtempo > 0)
  57                         mmin = 240 / maxtempo; // 60 = "0.25 means 1 sec", at 120 0.5 means 1 sec, at 240 1 means 1 sec
  58                 else
  59                         mmin = 0;
  60                 if(mintempo > 0)
  61                         mmax = 240 / mintempo; // 60 = "0.25 means 1 sec", at 120 0.5 means 1 sec, at 240 1 means 1 sec
  62                 else
  63                         mmax = 240; // you won't try THAT hard... (tempo 1)
  64                 //print(sprintf("initial tempo rules: %f %f\n", mmin, mmax));
  65
  66                 for(i = 0; i < n; ++i)
  67                 {
  68                         vector vi = pl.(tuba_lastnotes[mod(pl.tuba_lastnotes_last - i + MAX_TUBANOTES, MAX_TUBANOTES)]);
  69                         float ai = stof(argv(n - i - 1));
  70                         ti -= 1 / (ai - floor(ai));
  71                         float tj = ti;
  72                         for(j = i+1; j < n; ++j)
  73                         {
  74                                 vector vj = pl.(tuba_lastnotes[mod(pl.tuba_lastnotes_last - j + MAX_TUBANOTES, MAX_TUBANOTES)]);
  75                                 float aj = stof(argv(n - j - 1));
  76                                 tj -= (aj - floor(aj));
  77
  78                                 // note i should be at m*ti+b
  79                                 // note j should be at m*tj+b
  80                                 // so:
  81                                 // we have a LINE l, so that
  82                                 // vi_x <= l(ti) <= vi_y
  83                                 // vj_x <= l(tj) <= vj_y
  84                                 // what is m?
  85
  86                                 // vi_x <= vi_y <= vj_x <= vj_y
  87                                 // ti <= tj
  88                                 //print(sprintf("first note: %f to %f, should be %f\n", vi_x, vi_y, ti));
  89                                 //print(sprintf("second note: %f to %f, should be %f\n", vj_x, vj_y, tj));
  90                                 //print(sprintf("m1 = %f\n", (vi_x - vj_y) / (ti - tj)));
  91                                 //print(sprintf("m2 = %f\n", (vi_y - vj_x) / (ti - tj)));
  92                                 mmin = max(mmin, (vi_x - vj_y) / (ti - tj)); // lower bound
  93                                 mmax = min(mmax, (vi_y - vj_x) / (ti - tj)); // upper bound
  94                         }
  95                 }
  96
  97                 if(mmin > mmax) // rhythm fail
  98                         return FALSE;
  99         }
 100
 101         pl.tuba_lastnotes_cnt = 0;
 102
 103         return TRUE;
 104 }
 105
 106 void W_Tuba_NoteOff()
 107 {
 108         // we have a note:
 109         //   on: self.spawnshieldtime
 110         //   off: time
 111         //   note: self.cnt
 112         if(self.owner.tuba_note == self)
 113         {
 114                 self.owner.tuba_lastnotes_last = mod(self.owner.tuba_lastnotes_last + 1, MAX_TUBANOTES);
 115                 self.owner.(tuba_lastnotes[self.owner.tuba_lastnotes_last]) = eX * self.spawnshieldtime + eY * time + eZ * self.cnt;
 116                 self.owner.tuba_note = world;
 117                 self.owner.tuba_lastnotes_cnt = bound(0, self.owner.tuba_lastnotes_cnt + 1, MAX_TUBANOTES);
 118
 119                 string s;
 120                 s = trigger_magicear_processmessage_forallears(self.owner, 0, world, string_null);
 121                 if(s != "")
 122                 {
 123                         // simulate a server message
 124                         switch(self.tuba_instrument)
 125                         {
 126                                 default:
 127                                 case 0: // Tuba
 128                                         bprint(strcat("\{1}\{13}* ^3", self.owner.netname, "^3 played on the @!#%'n Tuba: ^7", s, "\n"));
 129                                         break;
 130                                 case 1:
 131                                         bprint(strcat("\{1}\{13}* ^3", self.owner.netname, "^3 played on the @!#%'n Accordeon: ^7", s, "\n"));
 132                                         break;
 133                                 case 2:
 134                                         bprint(strcat("\{1}\{13}* ^3", self.owner.netname, "^3 played on the @!#%'n Klein Bottle: ^7", s, "\n"));
 135                                         break;
 136                         }
 137                 }
 138         }
 139         remove(self);
 140 }
 141
 142 float Tuba_GetNote(entity pl, float hittype)
 143 {
 144         float note;
 145         float movestate;
 146         movestate = 5;
 147         if(pl.movement_x < 0) movestate -= 3;
 148         if(pl.movement_x > 0) movestate += 3;
 149         if(pl.movement_y < 0) movestate -= 1;
 150         if(pl.movement_y > 0) movestate += 1;
 151 #ifdef GMQCC
 152         note = 0;
 153 #endif
 154         switch(movestate)
 155         {
 156         // layout: originally I wanted
 157         //   eb e  e#=f
 158         //   B  c  d
 159         //   Gb G  G#
 160         // but then you only use forward and right key. So to make things more
 161         // interesting, I swapped B with e#. Har har har...
 162         //   eb e  B
 163         // f=e# c  d
 164         //   Gb G  G#
 165                 case 1: note = -6; break; // Gb
 166                 case 2: note = -5; break; // G
 167                 case 3: note = -4; break; // G#
 168                 case 4: note = +5; break; // e#
 169                 default:
 170                 case 5: note =  0; break; // c
 171                 case 6: note = +2; break; // d
 172                 case 7: note = +3; break; // eb
 173                 case 8: note = +4; break; // e
 174                 case 9: note = -1; break; // B
 175         }
 176         if(pl.BUTTON_CROUCH)
 177                 note -= 12;
 178         if(pl.BUTTON_JUMP)
 179                 note += 12;
 180         if(hittype & HITTYPE_SECONDARY)
 181                 note += 7;
 182
 183         // we support two kinds of tubas, those tuned in Eb and those tuned in C
 184         // kind of tuba currently is player slot number, or team number if in
 185         // teamplay
 186         // that way, holes in the range of notes are "plugged"
 187         if(teamplay)
 188         {
 189                 if(pl.team == NUM_TEAM_2 || pl.team == NUM_TEAM_4)
 190                         note += 3;
 191         }
 192         else
 193         {
 194                 if(pl.clientcolors & 1)
 195                         note += 3;
 196         }
 197
 198         // total range of notes:
 199         //                       0
 200         //                 ***  ** ****
 201         //                        ***  ** ****
 202         //     ***  ** ****
 203         //            ***  ** ****
 204         //     ***  ********************* ****
 205         //     -18.........................+12
 206         //        ***  ********************* ****
 207         //     -18............................+15
 208         //     with jump: ... +24
 209         //     ... +27
 210         return note;
 211 }
 212
 213 float W_Tuba_NoteSendEntity(entity to, float sf)
 214 {
 215         float f;
 216
 217         msg_entity = to;
 218         if(!sound_allowed(MSG_ONE, self.realowner))
 219                 return FALSE;
 220
 221         WriteByte(MSG_ENTITY, ENT_CLIENT_TUBANOTE);
 222         WriteByte(MSG_ENTITY, sf);
 223         if(sf & 1)
 224         {
 225                 WriteChar(MSG_ENTITY, self.cnt);
 226                 f = 0;
 227                 if(self.realowner != to)
 228                         f |= 1;
 229                 f |= 2 * self.tuba_instrument;
 230                 WriteByte(MSG_ENTITY, f);
 231         }
 232         if(sf & 2)
 233         {
 234                 WriteCoord(MSG_ENTITY, self.origin_x);
 235                 WriteCoord(MSG_ENTITY, self.origin_y);
 236                 WriteCoord(MSG_ENTITY, self.origin_z);
 237         }
 238         return TRUE;
 239 }
 240
 241 void W_Tuba_NoteThink()
 242 {
 243         float dist_mult;
 244         float vol0, vol1;
 245         vector dir0, dir1;
 246         vector v;
 247         entity e;
 248         if(time > self.teleport_time)
 249         {
 250                 W_Tuba_NoteOff();
 251                 return;
 252         }
 253         self.nextthink = time;
 254         dist_mult = autocvar_g_balance_tuba_attenuation / autocvar_snd_soundradius;
 255         FOR_EACH_REALCLIENT(e)
 256         if(e != self.realowner)
 257         {
 258                 v = self.origin - (e.origin + e.view_ofs);
 259                 vol0 = max(0, 1 - vlen(v) * dist_mult);
 260                 dir0 = normalize(v);
 261                 v = self.realowner.origin - (e.origin + e.view_ofs);
 262                 vol1 = max(0, 1 - vlen(v) * dist_mult);
 263                 dir1 = normalize(v);
 264                 if(fabs(vol0 - vol1) > 0.005) // 0.5 percent change in volume
 265                 {
 266                         setorigin(self, self.realowner.origin);
 267                         self.SendFlags |= 2;
 268                         break;
 269                 }
 270                 if(dir0 * dir1 < 0.9994) // 2 degrees change in angle
 271                 {
 272                         setorigin(self, self.realowner.origin);
 273                         self.SendFlags |= 2;
 274                         break;
 275                 }
 276         }
 277 }
 278
 279 void W_Tuba_NoteOn(float hittype)
 280 {
 281         vector o;
 282         float n;
 283
 284         W_SetupShot(self, FALSE, 2, "", 0, autocvar_g_balance_tuba_damage);
 285
 286         n = Tuba_GetNote(self, hittype);
 287
 288         hittype = 0;
 289         if(self.tuba_instrument & 1)
 290                 hittype |= HITTYPE_SECONDARY;
 291         if(self.tuba_instrument & 2)
 292                 hittype |= HITTYPE_BOUNCE;
 293
 294         if(self.tuba_note)
 295         {
 296                 if(self.tuba_note.cnt != n || self.tuba_note.tuba_instrument != self.tuba_instrument)
 297                 {
 298                         entity oldself = self;
 299                         self = self.tuba_note;
 300                         W_Tuba_NoteOff();
 301                         self = oldself;
 302                 }
 303         }
 304
 305         if not(self.tuba_note)
 306         {
 307                 self.tuba_note = spawn();
 308                 self.tuba_note.owner = self.tuba_note.realowner = self;
 309                 self.tuba_note.cnt = n;
 310                 self.tuba_note.tuba_instrument = self.tuba_instrument;
 311                 self.tuba_note.think = W_Tuba_NoteThink;
 312                 self.tuba_note.nextthink = time;
 313                 self.tuba_note.spawnshieldtime = time;
 314                 Net_LinkEntity(self.tuba_note, FALSE, 0, W_Tuba_NoteSendEntity);
 315         }
 316
 317         self.tuba_note.teleport_time = time + autocvar_g_balance_tuba_refire * 2 * W_WeaponRateFactor(); // so it can get prolonged safely
 318
 319         //sound(self, c, TUBA_NOTE(n), bound(0, VOL_BASE * cvar("g_balance_tuba_volume"), 1), autocvar_g_balance_tuba_attenuation);
 320         RadiusDamage(self, self, autocvar_g_balance_tuba_damage, autocvar_g_balance_tuba_edgedamage, autocvar_g_balance_tuba_radius, world, autocvar_g_balance_tuba_force, hittype | WEP_TUBA, world);
 321
 322         o = gettaginfo(self.exteriorweaponentity, 0);
 323         if(time > self.tuba_smoketime)
 324         {
 325                 pointparticles(particleeffectnum("smoke_ring"), o + v_up * 45 + v_right * -6 + v_forward * 8, v_up * 100, 1);
 326                 self.tuba_smoketime = time + 0.25;
 327         }
 328 }
 329
 330 void spawnfunc_weapon_tuba (void)
 331 {
 332         weapon_defaultspawnfunc(WEP_TUBA);
 333 }
 334
 335 float w_tuba(float req)
 336 {
 337         if (req == WR_AIM)
 338         {
 339                 // bots cannot play the Tuba well yet
 340                 // I think they should start with the recorder first
 341                 if(vlen(self.origin - self.enemy.origin) < autocvar_g_balance_tuba_radius)
 342                 {
 343                         if(random() > 0.5)
 344                                 self.BUTTON_ATCK = 1;
 345                         else
 346                                 self.BUTTON_ATCK2 = 1;
 347                 }
 348         }
 349         else if (req == WR_THINK)
 350         {
 351                 if (self.BUTTON_ATCK)
 352                 if (weapon_prepareattack(0, autocvar_g_balance_tuba_refire))
 353                 {
 354                         W_Tuba_NoteOn(0);
 355                         //weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_tuba_animtime, w_ready);
 356                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_tuba_animtime, w_ready);
 357                 }
 358                 if (self.BUTTON_ATCK2)
 359                 if (weapon_prepareattack(1, autocvar_g_balance_tuba_refire))
 360                 {
 361                         W_Tuba_NoteOn(HITTYPE_SECONDARY);
 362                         //weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_tuba_animtime, w_ready);
 363                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_tuba_animtime, w_ready);
 364                 }
 365                 if(self.tuba_note)
 366                 {
 367                         if(!self.BUTTON_ATCK && !self.BUTTON_ATCK2)
 368                         {
 369                                 entity oldself = self;
 370                                 self = self.tuba_note;
 371                                 W_Tuba_NoteOff();
 372                                 self = oldself;
 373                         }
 374                 }
 375         }
 376         else if (req == WR_PRECACHE)
 377         {
 378                 precache_model ("models/weapons/g_tuba.md3");
 379                 precache_model ("models/weapons/v_tuba.md3");
 380                 precache_model ("models/weapons/h_tuba.iqm");
 381                 precache_model ("models/weapons/v_akordeon.md3");
 382                 precache_model ("models/weapons/h_akordeon.iqm");
 383                 precache_model ("models/weapons/v_kleinbottle.md3");
 384                 precache_model ("models/weapons/h_kleinbottle.iqm");
 385
 386                 //float i;
 387                 //for(i = -18; i <= +27; ++i)
 388                 //      precache_sound(TUBA_NOTE(i));
 389         }
 390         else if (req == WR_SETUP)
 391         {
 392                 weapon_setup(WEP_TUBA);
 393                 self.current_ammo = ammo_none;
 394                 self.tuba_instrument = 0;
 395         }
 396         else if (req == WR_RELOAD)
 397         {
 398                 // switch to alternate instruments :)
 399                 if(self.weaponentity.state == WS_READY)
 400                 {
 401                         switch(self.tuba_instrument)
 402                         {
 403                                 case 0:
 404                                         self.tuba_instrument = 1;
 405                                         self.weaponname = "akordeon";
 406                                         break;
 407                                 case 1:
 408                                         self.tuba_instrument = 2;
 409                                         self.weaponname = "kleinbottle";
 410                                         break;
 411                                 case 2:
 412                                         self.tuba_instrument = 0;
 413                                         self.weaponname = "tuba";
 414                                         break;
 415                         }
 416                         W_SetupShot(self, FALSE, 0, "", 0, 0);
 417                         pointparticles(particleeffectnum("teleport"), w_shotorg, '0 0 0', 1);
 418                         self.weaponentity.state = WS_INUSE;
 419                         weapon_thinkf(WFRAME_RELOAD, 0.5, w_ready);
 420                 }
 421         }
 422         else if (req == WR_CHECKAMMO1)
 423                 return TRUE; // TODO use fuel?
 424         else if (req == WR_CHECKAMMO2)
 425                 return TRUE; // TODO use fuel?
 426         else if (req == WR_SUICIDEMESSAGE)
 427         {
 428                 if(w_deathtype & HITTYPE_BOUNCE)
 429                         return WEAPON_KLEINBOTTLE_SUICIDE;
 430                 else if(w_deathtype & HITTYPE_SECONDARY)
 431                         return WEAPON_ACCORDEON_SUICIDE;
 432                 else
 433                         return WEAPON_TUBA_SUICIDE;
 434         }
 435         else if (req == WR_KILLMESSAGE)
 436         {
 437                 if(w_deathtype & HITTYPE_BOUNCE)
 438                         return WEAPON_KLEINBOTTLE_MURDER;
 439                 else if(w_deathtype & HITTYPE_SECONDARY)
 440                         return WEAPON_ACCORDEON_MURDER;
 441                 else
 442                         return WEAPON_TUBA_MURDER;
 443         }
 444         return TRUE;
 445 }
 446 #endif
 447 #ifdef CSQC
 448 float w_tuba(float req)
 449 {
 450         // nothing to do here; particles of tuba are handled differently
 451
 452         return TRUE;
 453 }
 454 #endif
 455 #endif