qcsrc/server/w_uzi.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(UZI, w_uzi, IT_NAILS, 3, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_MID, "uzi", "uzi", _("Machine Gun"))
   3 #else
   4 #ifdef SVQC
   5
   6 // leilei's fancy muzzleflash stuff
   7 void UZI_Flash_Go()
   8 {
   9         self.frame = self.frame + 2;
  10         self.scale = self.scale * 0.5;
  11         self.alpha = self.alpha - 0.25;
  12         self.nextthink = time + 0.05;
  13
  14         if (self.alpha <= 0)
  15         {
  16                 self.think = SUB_Remove;
  17                 self.nextthink = time;
  18                 self.realowner.muzzle_flash = world;
  19                 return;
  20         }
  21
  22 }
  23
  24 void UziFlash()
  25 {
  26         if (self.muzzle_flash == world)
  27                 self.muzzle_flash = spawn();
  28
  29         // muzzle flash for 1st person view
  30         setmodel(self.muzzle_flash, "models/uziflash.md3"); // precision set below
  31
  32         self.muzzle_flash.scale = 0.75;
  33         self.muzzle_flash.think = UZI_Flash_Go;
  34         self.muzzle_flash.nextthink = time + 0.02;
  35         self.muzzle_flash.frame = 2;
  36         self.muzzle_flash.alpha = 0.75;
  37         self.muzzle_flash.angles_z = random() * 180;
  38         self.muzzle_flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  39         self.muzzle_flash.owner = self.muzzle_flash.realowner = self;
  40 }
  41
  42 void W_UZI_Attack (float deathtype)
  43 {
  44         W_SetupShot (self, autocvar_g_antilag_bullets && autocvar_g_balance_uzi_speed >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, ((self.misc_bulletcounter == 1) ? autocvar_g_balance_uzi_first_damage : autocvar_g_balance_uzi_sustained_damage));
  45         if (!g_norecoil)
  46         {
  47                 self.punchangle_x = random () - 0.5;
  48                 self.punchangle_y = random () - 0.5;
  49         }
  50
  51         // this attack_finished just enforces a cooldown at the end of a burst
  52         ATTACK_FINISHED(self) = time + autocvar_g_balance_uzi_first_refire * W_WeaponRateFactor();
  53
  54         if (self.misc_bulletcounter == 1)
  55                 fireBallisticBullet(w_shotorg, w_shotdir, autocvar_g_balance_uzi_first_spread, autocvar_g_balance_uzi_speed, 5, autocvar_g_balance_uzi_first_damage, 0, autocvar_g_balance_uzi_first_force, deathtype, 0, 1, autocvar_g_balance_uzi_bulletconstant);
  56         else
  57                 fireBallisticBullet(w_shotorg, w_shotdir, autocvar_g_balance_uzi_sustained_spread, autocvar_g_balance_uzi_speed, 5, autocvar_g_balance_uzi_sustained_damage, 0, autocvar_g_balance_uzi_sustained_force, deathtype, 0, 1, autocvar_g_balance_uzi_bulletconstant);
  58         endFireBallisticBullet();
  59
  60         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  61
  62         UziFlash();
  63         W_AttachToShotorg(self.muzzle_flash, '5 0 0');
  64
  65         // casing code
  66         if (autocvar_g_casings >= 2)
  67                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
  68
  69         if (self.misc_bulletcounter == 1)
  70                 W_DecreaseAmmo(ammo_nails, autocvar_g_balance_uzi_first_ammo, autocvar_g_balance_uzi_reload_ammo);
  71         else
  72                 W_DecreaseAmmo(ammo_nails, autocvar_g_balance_uzi_sustained_ammo, autocvar_g_balance_uzi_reload_ammo);
  73 }
  74
  75 // weapon frames
  76 void uzi_fire1_02()
  77 {
  78         if(self.weapon != self.switchweapon) // abort immediately if switching
  79         {
  80                 w_ready();
  81                 return;
  82         }
  83         if (self.BUTTON_ATCK)
  84         {
  85                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
  86                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  87                 {
  88                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
  89                         w_ready();
  90                         return;
  91                 }
  92                 self.misc_bulletcounter = self.misc_bulletcounter + 1;
  93                 W_UZI_Attack(WEP_UZI);
  94                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_uzi_sustained_refire, uzi_fire1_02);
  95         }
  96         else
  97                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_uzi_sustained_refire, w_ready);
  98 }
  99
 100
 101 void uzi_mode1_fire_auto()
 102 {
 103         float uzi_spread;
 104
 105         W_DecreaseAmmo(ammo_nails, autocvar_g_balance_uzi_sustained_ammo, autocvar_g_balance_uzi_reload_ammo);
 106
 107         if (self.BUTTON_ATCK)
 108                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_uzi_sustained_refire, uzi_mode1_fire_auto);
 109         else
 110         {
 111                 ATTACK_FINISHED(self) = time + autocvar_g_balance_uzi_first_refire * W_WeaponRateFactor();
 112                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_uzi_sustained_refire, w_ready);
 113                 return;
 114         }
 115
 116         if (!weapon_action(self.weapon, WR_CHECKAMMO1))
 117         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 118         {
 119                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 120                 w_ready();
 121                 return;
 122         }
 123
 124         W_SetupShot (self, autocvar_g_antilag_bullets && autocvar_g_balance_uzi_speed >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, autocvar_g_balance_uzi_sustained_damage);
 125         if (!g_norecoil)
 126         {
 127                 self.punchangle_x = random () - 0.5;
 128                 self.punchangle_y = random () - 0.5;
 129         }
 130
 131         uzi_spread = bound(autocvar_g_balance_uzi_spread_min, autocvar_g_balance_uzi_spread_min + (autocvar_g_balance_uzi_spread_add * self.misc_bulletcounter), autocvar_g_balance_uzi_spread_max);
 132         fireBallisticBullet(w_shotorg, w_shotdir, uzi_spread, autocvar_g_balance_uzi_speed, 5, autocvar_g_balance_uzi_sustained_damage, 0, autocvar_g_balance_uzi_sustained_force, WEP_UZI, 0, 1, autocvar_g_balance_uzi_bulletconstant);
 133         endFireBallisticBullet();
 134
 135         self.misc_bulletcounter = self.misc_bulletcounter + 1;
 136
 137         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 138
 139         UziFlash();
 140         W_AttachToShotorg(self.muzzle_flash, '5 0 0');
 141
 142         if (autocvar_g_casings >= 2) // casing code
 143                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
 144 }
 145
 146 void uzi_mode1_fire_burst()
 147 {
 148         W_SetupShot (self, autocvar_g_antilag_bullets && autocvar_g_balance_uzi_speed >= autocvar_g_antilag_bullets, 0, "weapons/uzi_fire.wav", CH_WEAPON_A, autocvar_g_balance_uzi_sustained_damage);
 149         if (!g_norecoil)
 150         {
 151                 self.punchangle_x = random () - 0.5;
 152                 self.punchangle_y = random () - 0.5;
 153         }
 154
 155         fireBallisticBullet(w_shotorg, w_shotdir, autocvar_g_balance_uzi_burst_spread, autocvar_g_balance_uzi_speed, 5, autocvar_g_balance_uzi_sustained_damage, 0, autocvar_g_balance_uzi_sustained_force, WEP_UZI, 0, 1, autocvar_g_balance_uzi_bulletconstant);
 156         endFireBallisticBullet();
 157
 158
 159         pointparticles(particleeffectnum("uzi_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 160
 161         UziFlash();
 162         W_AttachToShotorg(self.muzzle_flash, '5 0 0');
 163
 164         if (autocvar_g_casings >= 2) // casing code
 165                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, self);
 166
 167         self.misc_bulletcounter = self.misc_bulletcounter + 1;
 168         if (self.misc_bulletcounter == 0)
 169         {
 170                 ATTACK_FINISHED(self) = time + autocvar_g_balance_uzi_burst_refire2 * W_WeaponRateFactor();
 171                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_uzi_burst_animtime, w_ready);
 172         }
 173         else
 174         {
 175                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_uzi_burst_refire, uzi_mode1_fire_burst);
 176         }
 177
 178 }
 179
 180 void spawnfunc_weapon_machinegun(); // defined in t_items.qc
 181
 182 float w_uzi(float req)
 183 {
 184         float ammo_amount;
 185         if (req == WR_AIM)
 186                 if(vlen(self.origin-self.enemy.origin) < 3000 - bound(0, skill, 10) * 200)
 187                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 188                 else
 189                 {
 190                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 191                 }
 192         else if (req == WR_THINK)
 193         {
 194                 if(autocvar_g_balance_uzi_reload_ammo && self.clip_load < min(max(autocvar_g_balance_uzi_sustained_ammo, autocvar_g_balance_uzi_first_ammo), autocvar_g_balance_uzi_burst_ammo)) // forced reload
 195                         weapon_action(self.weapon, WR_RELOAD);
 196                 else if(autocvar_g_balance_uzi_mode == 1)
 197                 {
 198                         if (self.BUTTON_ATCK)
 199                         if (weapon_prepareattack(0, 0))
 200                         {
 201                                 self.misc_bulletcounter = 0;
 202                                 uzi_mode1_fire_auto();
 203                         }
 204
 205                         if(self.BUTTON_ATCK2)
 206                         if(weapon_prepareattack(1, 0))
 207                         {
 208                                 if (!weapon_action(self.weapon, WR_CHECKAMMO2))
 209                                 {
 210                                         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 211                                         w_ready();
 212                                         return FALSE;
 213                                 }
 214
 215                                 W_DecreaseAmmo(ammo_nails, autocvar_g_balance_uzi_burst_ammo, autocvar_g_balance_uzi_reload_ammo);
 216
 217                                 self.misc_bulletcounter = autocvar_g_balance_uzi_burst * -1;
 218                                 uzi_mode1_fire_burst();
 219                         }
 220                 }
 221                 else
 222                 {
 223
 224                         if (self.BUTTON_ATCK)
 225                         if (weapon_prepareattack(0, 0))
 226                         {
 227                                 self.misc_bulletcounter = 1;
 228                                 W_UZI_Attack(WEP_UZI); // sets attack_finished
 229                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_uzi_sustained_refire, uzi_fire1_02);
 230                         }
 231
 232                         if (self.BUTTON_ATCK2 && autocvar_g_balance_uzi_first)
 233                         if (weapon_prepareattack(1, 0))
 234                         {
 235                                 self.misc_bulletcounter = 1;
 236                                 W_UZI_Attack(WEP_UZI | HITTYPE_SECONDARY); // sets attack_finished
 237                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_uzi_first_refire, w_ready);
 238                         }
 239                 }
 240         }
 241         else if (req == WR_PRECACHE)
 242         {
 243                 precache_model ("models/uziflash.md3");
 244                 precache_model ("models/weapons/g_uzi.md3");
 245                 precache_model ("models/weapons/v_uzi.md3");
 246                 precache_model ("models/weapons/h_uzi.iqm");
 247                 precache_sound ("weapons/uzi_fire.wav");
 248                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 249         }
 250         else if (req == WR_SETUP)
 251         {
 252                 weapon_setup(WEP_UZI);
 253                 self.current_ammo = ammo_nails;
 254         }
 255         else if (req == WR_CHECKAMMO1)
 256         {
 257                 if(autocvar_g_balance_uzi_mode == 1)
 258                         ammo_amount = self.ammo_nails >= autocvar_g_balance_uzi_sustained_ammo;
 259                 else
 260                         ammo_amount = self.ammo_nails >= autocvar_g_balance_uzi_first_ammo;
 261
 262                 if(autocvar_g_balance_uzi_reload_ammo)
 263                 {
 264                         if(autocvar_g_balance_uzi_mode == 1)
 265                                 ammo_amount += self.weapon_load[WEP_UZI] >= autocvar_g_balance_uzi_sustained_ammo;
 266                         else
 267                                 ammo_amount += self.weapon_load[WEP_UZI] >= autocvar_g_balance_uzi_first_ammo;
 268                 }
 269                 return ammo_amount;
 270         }
 271         else if (req == WR_CHECKAMMO2)
 272         {
 273                 if(autocvar_g_balance_uzi_mode == 1)
 274                         ammo_amount = self.ammo_nails >= autocvar_g_balance_uzi_burst_ammo;
 275                 else
 276                         ammo_amount = self.ammo_nails >= autocvar_g_balance_uzi_first_ammo;
 277
 278                 if(autocvar_g_balance_uzi_reload_ammo)
 279                 {
 280                         if(autocvar_g_balance_uzi_mode == 1)
 281                                 ammo_amount += self.weapon_load[WEP_UZI] >= autocvar_g_balance_uzi_burst_ammo;
 282                         else
 283                                 ammo_amount += self.weapon_load[WEP_UZI] >= autocvar_g_balance_uzi_first_ammo;
 284                 }
 285                 return ammo_amount;
 286         }
 287         else if (req == WR_RELOAD)
 288         {
 289                 W_Reload(min(max(autocvar_g_balance_uzi_sustained_ammo, autocvar_g_balance_uzi_first_ammo), autocvar_g_balance_uzi_burst_ammo), autocvar_g_balance_uzi_reload_ammo, autocvar_g_balance_uzi_reload_time, "weapons/reload.wav");
 290         }
 291         return TRUE;
 292 };
 293 #endif
 294 #ifdef CSQC
 295 float w_uzi(float req)
 296 {
 297         if(req == WR_IMPACTEFFECT)
 298         {
 299                 vector org2;
 300                 org2 = w_org + w_backoff * 2;
 301                 pointparticles(particleeffectnum("machinegun_impact"), org2, w_backoff * 1000, 1);
 302                 if(!w_issilent)
 303                         if(w_random < 0.05)
 304                                 sound(self, CH_SHOTS_SINGLE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 305                         else if(w_random < 0.1)
 306                                 sound(self, CH_SHOTS_SINGLE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 307                         else if(w_random < 0.2)
 308                                 sound(self, CH_SHOTS_SINGLE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 309         }
 310         else if(req == WR_PRECACHE)
 311         {
 312                 precache_sound("weapons/ric1.wav");
 313                 precache_sound("weapons/ric2.wav");
 314                 precache_sound("weapons/ric3.wav");
 315         }
 316         else if (req == WR_SUICIDEMESSAGE)
 317                 w_deathtypestring = _("%s is now thinking with portals");
 318         else if (req == WR_KILLMESSAGE)
 319         {
 320                 if(w_deathtype & HITTYPE_SECONDARY)
 321                         w_deathtypestring = _("%s was sniped by %s");
 322                 else
 323                         w_deathtypestring = _("%s was riddled full of holes by %s");
 324         }
 325         return TRUE;
 326 }
 327 #endif
 328 #endif