Transifex autosync
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / weapons / accuracy.qc
1 #include "accuracy.qh"
2
3 #include <common/constants.qh>
4 #include <common/net_linked.qh>
5 #include <common/teams.qh>
6 #include <common/util.qh>
7 #include <common/weapons/_all.qh>
8 #include <server/client.qh>
9 #include <server/damage.qh>
10 #include <server/mutators/_mod.qh>
11 #include <server/player.qh>
12 #include <server/world.qh>
13
14 int accuracy_byte(float n, float d)
15 {
16         if (n <= 0) return 0;
17         if (n > d) return 255;
18         return 1 + rint(n * 100.0 / d);
19 }
20
21 bool accuracy_send(entity this, entity to, int sf)
22 {
23         WriteHeader(MSG_ENTITY, ENT_CLIENT_ACCURACY);
24
25         entity a = this.owner;
26         if (IS_SPEC(a)) a = a.enemy;
27         a = CS(a).accuracy;
28
29         if (to != a.owner)
30                 if (!autocvar_sv_accuracy_data_share && !CS_CVAR(a.owner).cvar_cl_accuracy_data_share)
31                         sf = 0;
32         // note: zero sendflags can never be sent... so we can use that to say that we send no accuracy!
33         WriteInt24_t(MSG_ENTITY, sf);
34         if (sf == 0) return true;
35         // note: we know that client and server agree about SendFlags...
36         int f = 1;
37         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
38                 if (sf & f) WriteByte(MSG_ENTITY, accuracy_byte(a.accuracy_hit[w], a.accuracy_fired[w]));
39                 f = (f == 0x800000) ? 1 : f * 2;
40         }
41         return true;
42 }
43
44 // init/free
45 void accuracy_init(entity e)
46 {
47         entity a = CS(e).accuracy = new_pure(accuracy);
48         a.owner = e;
49         a.drawonlytoclient = e;
50         Net_LinkEntity(a, false, 0, accuracy_send);
51 }
52
53 void accuracy_free(entity e)
54 {
55         delete(CS(e).accuracy);
56 }
57
58 // force a resend of a player's accuracy stats
59 void accuracy_resend(entity e)
60 {
61         CS(e).accuracy.SendFlags = 0xFFFFFF;
62 }
63
64 // update accuracy stats
65 //.float hit_time;
66 .float fired_time;
67
68 void accuracy_add(entity this, Weapon w, float fired, float hit)
69 {
70         if (IS_INDEPENDENT_PLAYER(this)) return;
71         entity a = CS(this).accuracy;
72         if (!a) return;
73         if (!hit && !fired) return;
74         if (w == WEP_Null) return;
75         int wepid = w.m_id;
76         wepid -= WEP_FIRST;
77         int b = accuracy_byte(a.accuracy_hit[wepid], a.accuracy_fired[wepid]);
78         if (hit)    a.accuracy_hit  [wepid] += hit;
79         if (fired)  a.accuracy_fired[wepid] += fired;
80
81     if (hit && STAT(HIT_TIME, a) != time) { // only run this once per frame
82         a.accuracy_cnt_hit[wepid] += 1;
83         STAT(HIT_TIME, a) = time;
84     }
85
86     if (fired && a.fired_time != time) { // only run this once per frame
87         a.accuracy_cnt_fired[wepid] += 1;
88         a.fired_time = time;
89     }
90
91         if (b == accuracy_byte(a.accuracy_hit[wepid], a.accuracy_fired[wepid])) return; // no change
92         int sf = 1 << (wepid % 24);
93         a.SendFlags |= sf;
94         FOREACH_CLIENT(IS_SPEC(it) && it.enemy == this, { CS(it).accuracy.SendFlags |= sf; });
95 }
96
97 bool accuracy_isgooddamage(entity attacker, entity targ)
98 {
99         int mutator_check = MUTATOR_CALLHOOK(AccuracyTargetValid, attacker, targ);
100
101         if (warmup_stage || game_stopped) return false;
102
103         // damage to dead/frozen players is good only if it happens in the frame they get killed / frozen
104         // so that stats for weapons that shoot multiple projectiles per shot are properly counted
105         if (IS_DEAD(targ) && time > targ.death_time) return false;
106         if (STAT(FROZEN, targ) && time > targ.freeze_time) return false;
107         if (SAME_TEAM(attacker, targ)) return false;
108
109         if (mutator_check == MUT_ACCADD_INVALID) return true;
110
111         if (mutator_check != MUT_ACCADD_VALID) return false;
112         if (!IS_CLIENT(targ) || !IS_CLIENT(attacker)) return false;
113
114         return true;
115 }
116
117 bool accuracy_canbegooddamage(entity attacker)
118 {
119         return !warmup_stage && IS_CLIENT(attacker);
120 }