qcsrc/server/weapons/selection.qc

   1 #include "selection.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/items/item.qh>
   5 #include <common/mapobjects/triggers.qh>
   6 #include <common/mutators/mutator/waypoints/waypointsprites.qh>
   7 #include <common/net_linked.qh>
   8 #include <common/replicate.qh>
   9 #include <common/state.qh>
  10 #include <common/util.qh>
  11 #include <common/weapons/_all.qh>
  12 #include <common/wepent.qh>
  13 #include <server/items/items.qh>
  14 #include <server/items/spawning.qh>
  15 #include <server/weapons/weaponsystem.qh>
  16
  17 // switch between weapons
  18 void Send_WeaponComplain(entity e, float wpn, float type)
  19 {
  20         msg_entity = e;
  21         WriteHeader(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
  22         WriteByte(MSG_ONE, wpn);
  23         WriteByte(MSG_ONE, type);
  24 }
  25
  26 void Weapon_whereis(Weapon this, entity cl)
  27 {
  28         if (!autocvar_g_showweaponspawns) return;
  29         IL_EACH(g_items, it.weapon == this.m_id && (!it.team || (it.ItemStatus & ITS_AVAILABLE)),
  30         {
  31                 if (Item_IsLoot(it) && (autocvar_g_showweaponspawns < 2))
  32                 {
  33                         continue;
  34                 }
  35                 entity wp = WaypointSprite_Spawn(
  36                         WP_Weapon,
  37                         -2, 0,
  38                         NULL, it.origin + ('0 0 1' * it.maxs.z) * 1.2,
  39                         cl, 0,
  40                         NULL, enemy,
  41                         0,
  42                         RADARICON_NONE
  43                 );
  44                 wp.wp_extra = this.m_id;
  45         });
  46 }
  47
  48 bool client_hasweapon(entity this, Weapon wpn, .entity weaponentity, float andammo, bool complain)
  49 {
  50         float f = 0;
  51
  52         if (time < CS(this).hasweapon_complain_spam)
  53                 complain = 0;
  54
  55         // ignore hook button when using other offhand equipment
  56         if (this.offhand != OFFHAND_HOOK)
  57         if (wpn == WEP_HOOK && !((STAT(WEAPONS, this) | weaponsInMap) & WepSet_FromWeapon(wpn)))
  58             complain = 0;
  59
  60         if (complain)
  61                 CS(this).hasweapon_complain_spam = time + 0.2;
  62
  63         if (wpn == WEP_Null)
  64         {
  65                 if (complain)
  66                         sprint(this, "Invalid weapon\n");
  67                 return false;
  68         }
  69         if (autocvar_g_weaponswitch_debug == 2 && weaponslot(weaponentity) > 0 && !(wpn.spawnflags & WEP_FLAG_DUALWIELD) && !(PS(this).dual_weapons & wpn.m_wepset))
  70                 return false; // no complaints needed
  71         if (STAT(WEAPONS, this) & WepSet_FromWeapon(wpn))
  72         {
  73                 if (andammo)
  74                 {
  75                         if(this.items & IT_UNLIMITED_AMMO)
  76                         {
  77                                 f = 1;
  78                         }
  79                         else
  80                         {
  81                                 f = wpn.wr_checkammo1(wpn, this, weaponentity) + wpn.wr_checkammo2(wpn, this, weaponentity);
  82
  83                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
  84                                 if(wpn == WEP_MINE_LAYER)
  85                                         IL_EACH(g_mines, it.owner == this && it.weaponentity_fld == weaponentity,
  86                                         {
  87                                                 f = 1;
  88                                                 break; // no need to continue
  89                                         });
  90                         }
  91                         if (!f)
  92                         {
  93                                 if (complain)
  94                                 if(IS_REAL_CLIENT(this))
  95                                 {
  96                                         play2(this, SND(UNAVAILABLE));
  97                                         Send_WeaponComplain (this, wpn.m_id, 0);
  98                                 }
  99                                 return false;
 100                         }
 101                 }
 102                 return true;
 103         }
 104         if (complain)
 105         {
 106                 // DRESK - 3/16/07
 107                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 108                 if (weaponsInMap & WepSet_FromWeapon(wpn))
 109                 {
 110                         Send_WeaponComplain(this, wpn.m_id, 1);
 111                         if(autocvar_g_showweaponspawns < 3)
 112                                 Weapon_whereis(wpn, this);
 113                         else
 114                         {
 115                                 FOREACH(Weapons, it.impulse == wpn.impulse,
 116                                 {
 117                                         Weapon_whereis(it, this);
 118                                 });
 119                         }
 120                 }
 121                 else
 122                 {
 123                         Send_WeaponComplain (this, wpn.m_id, 2);
 124                 }
 125
 126                 play2(this, SND(UNAVAILABLE));
 127         }
 128         return false;
 129 }
 130
 131 float W_GetCycleWeapon(entity this, string weaponorder, float dir, float imp, float complain, float skipmissing, .entity weaponentity)
 132 {
 133         // We cannot tokenize in this function, as GiveItems calls this
 134         // function. Thus we must use car/cdr.
 135         float weaponwant, first_valid, prev_valid, switchtonext, switchtolast;
 136         WepSet wepset = '0 0 0';
 137         switchtonext = switchtolast = 0;
 138         first_valid = prev_valid = 0;
 139         float weaponcur;
 140         entity wep;
 141
 142         if(skipmissing || this.(weaponentity).selectweapon == 0)
 143                 weaponcur = this.(weaponentity).m_switchweapon.m_id;
 144         else
 145                 weaponcur = this.(weaponentity).selectweapon;
 146
 147         if(dir == 0)
 148                 switchtonext = 1;
 149
 150         int c = 0;
 151
 152         string rest = weaponorder;
 153         while(rest != "")
 154         {
 155                 weaponwant = stof(car(rest)); rest = cdr(rest);
 156                 wep = REGISTRY_GET(Weapons, weaponwant);
 157                 wepset = wep.m_wepset;
 158                 if(imp >= 0)
 159                 if(wep.impulse != imp)
 160                         continue;
 161
 162                 bool have_other = false;
 163                 FOREACH(Weapons, it != WEP_Null, {
 164                         if(i != weaponwant)
 165                         if(it.impulse == imp || imp < 0)
 166                         if((STAT(WEAPONS, this) & (it.m_wepset)) || (weaponsInMap & (it.m_wepset)))
 167                                 have_other = true;
 168                 });
 169
 170                 // skip weapons we don't own that aren't normal and aren't in the map
 171                 if(!(STAT(WEAPONS, this) & wepset))
 172                 if(!(weaponsInMap & wepset))
 173                 if((wep.spawnflags & WEP_FLAG_MUTATORBLOCKED) || have_other)
 174                         continue;
 175
 176                 ++c;
 177
 178                 if(!skipmissing || client_hasweapon(this, wep, weaponentity, true, false))
 179                 {
 180                         if(switchtonext)
 181                                 return weaponwant;
 182                         if(!first_valid)
 183                                 first_valid = weaponwant;
 184                         if(weaponwant == weaponcur)
 185                         {
 186                                 if(dir >= 0)
 187                                         switchtonext = 1;
 188                                 else if(prev_valid)
 189                                         return prev_valid;
 190                                 else
 191                                         switchtolast = 1;
 192                         }
 193                         prev_valid = weaponwant;
 194                 }
 195         }
 196         if(first_valid)
 197         {
 198                 if(switchtolast)
 199                         return prev_valid;
 200                 else
 201                         return first_valid;
 202         }
 203         // complain (but only for one weapon on the button that has been pressed)
 204         if(complain)
 205         {
 206                 this.weaponcomplainindex += 1;
 207                 c = (this.weaponcomplainindex % c) + 1;
 208                 rest = weaponorder;
 209                 while(rest != "")
 210                 {
 211                         weaponwant = stof(car(rest)); rest = cdr(rest);
 212                         wep = REGISTRY_GET(Weapons, weaponwant);
 213                         wepset = wep.m_wepset;
 214                         if(imp >= 0)
 215                                 if(wep.impulse != imp)
 216                                         continue;
 217
 218                         bool have_other = false;
 219                         FOREACH(Weapons, it != WEP_Null, {
 220                                 if(i != weaponwant)
 221                                 if(it.impulse == imp || imp < 0)
 222                                 if((STAT(WEAPONS, this) & (it.m_wepset)) || (weaponsInMap & (it.m_wepset)))
 223                                         have_other = true;
 224                         });
 225
 226                         // skip weapons we don't own that aren't normal and aren't in the map
 227                         if(!(STAT(WEAPONS, this) & wepset))
 228                         if(!(weaponsInMap & wepset))
 229                         if((wep.spawnflags & WEP_FLAG_MUTATORBLOCKED) || have_other)
 230                                 continue;
 231
 232                         --c;
 233                         if(c == 0)
 234                         {
 235                                 client_hasweapon(this, wep, weaponentity, true, true);
 236                                 break;
 237                         }
 238                 }
 239         }
 240         return 0;
 241 }
 242
 243 void W_SwitchWeapon_Force(Player this, Weapon wep, .entity weaponentity)
 244 {
 245         TC(Weapon, wep);
 246         this.(weaponentity).cnt = this.(weaponentity).m_switchweapon.m_id;
 247         this.(weaponentity).m_switchweapon = wep;
 248         this.(weaponentity).selectweapon = wep.m_id;
 249 }
 250
 251 // perform weapon to attack (weaponstate and attack_finished check is here)
 252 void W_SwitchToOtherWeapon(entity this, .entity weaponentity)
 253 {
 254         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
 255         Weapon ww;
 256         WepSet set = WepSet_FromWeapon(this.(weaponentity).m_weapon);
 257         if (STAT(WEAPONS, this) & set)
 258         {
 259                 STAT(WEAPONS, this) &= ~set;
 260                 ww = w_getbestweapon(this, weaponentity);
 261                 STAT(WEAPONS, this) |= set;
 262         }
 263         else
 264         {
 265                 ww = w_getbestweapon(this, weaponentity);
 266         }
 267         if (ww == WEP_Null) return;
 268         W_SwitchWeapon_Force(this, ww, weaponentity);
 269 }
 270
 271 bool W_SwitchWeapon(entity this, Weapon w, .entity weaponentity)
 272 {
 273         if(this.(weaponentity).m_switchweapon != w)
 274         {
 275                 if(client_hasweapon(this, w, weaponentity, true, true))
 276                 {
 277                         W_SwitchWeapon_Force(this, w, weaponentity);
 278                         return true;
 279                 }
 280                 else
 281                 {
 282                         this.(weaponentity).selectweapon = w.m_id; // update selectweapon anyway
 283                         return false;
 284                 }
 285         }
 286         else if(!weaponLocked(this) && CS(this).cvar_cl_weapon_switch_reload)
 287         {
 288                 entity actor = this;
 289                 w.wr_reload(w, actor, weaponentity);
 290         }
 291
 292         return true; // player already has the weapon out or needs to reload
 293 }
 294
 295 void W_SwitchWeapon_TryOthers(entity this, Weapon w, .entity weaponentity)
 296 {
 297         if(!W_SwitchWeapon(this, w, weaponentity) && CS(this).cvar_cl_weapon_switch_fallback_to_impulse)
 298                 W_NextWeaponOnImpulse(this, w.impulse, weaponentity);
 299 }
 300
 301 void W_CycleWeapon(entity this, string weaponorder, float dir, .entity weaponentity)
 302 {
 303         float w;
 304         w = W_GetCycleWeapon(this, weaponorder, dir, -1, 1, true, weaponentity);
 305         if(w > 0)
 306                 W_SwitchWeapon(this, REGISTRY_GET(Weapons, w), weaponentity);
 307 }
 308
 309 void W_NextWeaponOnImpulse(entity this, float imp, .entity weaponentity)
 310 {
 311         float w;
 312         w = W_GetCycleWeapon(this, CS(this).cvar_cl_weaponpriority, +1, imp, 1, (CS(this).cvar_cl_weaponimpulsemode == 0), weaponentity);
 313         if(w > 0)
 314                 W_SwitchWeapon(this, REGISTRY_GET(Weapons, w), weaponentity);
 315 }
 316
 317 // next weapon
 318 void W_NextWeapon(entity this, int list, .entity weaponentity)
 319 {
 320         if(list == 0)
 321                 W_CycleWeapon(this, weaponorder_byid, -1, weaponentity);
 322         else if(list == 1)
 323                 W_CycleWeapon(this, CS(this).weaponorder_byimpulse, -1, weaponentity);
 324         else if(list == 2)
 325                 W_CycleWeapon(this, CS(this).cvar_cl_weaponpriority, -1, weaponentity);
 326 }
 327
 328 // prev weapon
 329 void W_PreviousWeapon(entity this, float list, .entity weaponentity)
 330 {
 331         if(list == 0)
 332                 W_CycleWeapon(this, weaponorder_byid, +1, weaponentity);
 333         else if(list == 1)
 334                 W_CycleWeapon(this, CS(this).weaponorder_byimpulse, +1, weaponentity);
 335         else if(list == 2)
 336                 W_CycleWeapon(this, CS(this).cvar_cl_weaponpriority, +1, weaponentity);
 337 }
 338
 339 // previously used if exists and has ammo, (second) best otherwise
 340 void W_LastWeapon(entity this, .entity weaponentity)
 341 {
 342         Weapon wep = REGISTRY_GET(Weapons, this.(weaponentity).cnt);
 343         if (client_hasweapon(this, wep, weaponentity, true, false))
 344                 W_SwitchWeapon(this, wep, weaponentity);
 345         else
 346                 W_SwitchToOtherWeapon(this, weaponentity);
 347 }