qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include <common/effects/all.qh>
   4
   5 #include "accuracy.qh"
   6 #include "common.qh"
   7 #include "hitplot.qh"
   8 #include "weaponsystem.qh"
   9
  10 #include "../g_damage.qh"
  11 #include "../antilag.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/net_linked.qh>
  15 #include <common/util.qh>
  16
  17 #include <common/weapons/_all.qh>
  18 #include <common/wepent.qh>
  19 #include <common/state.qh>
  20
  21 #include <lib/warpzone/common.qh>
  22
  23 // this function calculates w_shotorg and w_shotdir based on the weapon model
  24 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  25 // make sure you call makevectors first (FIXME?)
  26 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, .entity weaponentity, vector s_forward, vector mi, vector ma, float antilag, float recoil, Sound snd, float chan, float maxdamage, float range, int deathtype)
  27 {
  28         TC(Sound, snd);
  29         float oldsolid = ent.dphitcontentsmask;
  30         Weapon wep = DEATH_WEAPONOF(deathtype);
  31         if(!IS_CLIENT(ent))
  32                 antilag = false; // no antilag for non-clients!
  33         if (IS_PLAYER(ent) && (wep.spawnflags & WEP_FLAG_PENETRATEWALLS))
  34         {
  35                 // This is the reason rifle, MG, OKMG and other fireBullet weapons don't hit the crosshair when shooting at walls.
  36                 // This is intentional, otherwise if you stand too close to a (glass) wall and attempt to shoot an enemy through it,
  37                 // trueaim will cause the shot to hit the wall exactly but then miss the enemy (unless shooting from eye/center).
  38                 // TODO for fireBullet, find how far the shot will penetrate and aim at that
  39                 //      for fireRailgunbullet, find the farthest target and aim at that
  40                 //      this will avoid issues when another player is passing in front of you when you shoot
  41                 //      (currently such a shot will hit him but then miss the original target)
  42                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  43         }
  44         else
  45                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  46         if(antilag)
  47                 WarpZone_traceline_antilag(NULL, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  48                 // passing NULL, because we do NOT want it to touch dphitcontentsmask
  49         else
  50                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  51         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  52
  53         vector vf, vr, vu;
  54         vf = v_forward;
  55         vr = v_right;
  56         vu = v_up;
  57         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  58         v_forward = vf;
  59         v_right = vr;
  60         v_up = vu;
  61
  62         // un-adjust trueaim if shotend is too close
  63         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
  64                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  65
  66         // track max damage
  67         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
  68                 accuracy_add(ent, wep, maxdamage, 0);
  69
  70         if(IS_PLAYER(ent))
  71                 W_HitPlotAnalysis(ent, wep, v_forward, v_right, v_up);
  72
  73         vector md = ent.(weaponentity).movedir;
  74         vector vecs = ((md.x > 0) ? md : '0 0 0');
  75
  76         vector dv = v_forward * vecs.x + v_right * -vecs.y + v_up * vecs.z;
  77         w_shotorg = ent.origin + ent.view_ofs;
  78
  79         // now move the shotorg forward as much as requested if possible
  80         if(antilag)
  81         {
  82                 if(CS(ent).antilag_debug)
  83                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + dv, MOVE_NORMAL, ent, CS(ent).antilag_debug);
  84                 else
  85                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + dv, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  86         }
  87         else
  88                 tracebox(w_shotorg, mi, ma, w_shotorg + dv, MOVE_NORMAL, ent);
  89         w_shotorg = trace_endpos;
  90         // calculate the shotdir from the chosen shotorg
  91         if(W_DualWielding(ent))
  92                 w_shotdir = s_forward;
  93         else
  94                 w_shotdir = normalize(w_shotend - w_shotorg);
  95
  96         //vector prevdir = w_shotdir;
  97         //vector prevorg = w_shotorg;
  98         //vector prevend = w_shotend;
  99
 100         if (antilag)
 101         if (!CS(ent).cvar_cl_noantilag)
 102         {
 103                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 104                 {
 105                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 106                         if (!trace_ent.takedamage)
 107                         {
 108                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 109                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
 110                                 {
 111                                         entity e;
 112                                         e = trace_ent;
 113                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 114                                         if(trace_ent == e)
 115                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 116                                 }
 117                         }
 118                 }
 119                 else if(autocvar_g_antilag == 3) // client side hitscan
 120                 {
 121                         // this part MUST use prydon cursor
 122                         if (CS(ent).cursor_trace_ent)                 // client was aiming at someone
 123                         if (CS(ent).cursor_trace_ent != ent)         // just to make sure
 124                         if (CS(ent).cursor_trace_ent.takedamage)      // and that person is killable
 125                         if (IS_PLAYER(CS(ent).cursor_trace_ent)) // and actually a player
 126                         {
 127                                 // verify that the shot would miss without antilag
 128                                 // (avoids an issue where guns would always shoot at their origin)
 129                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 130                                 if (!trace_ent.takedamage)
 131                                 {
 132                                         // verify that the shot would hit if altered
 133                                         traceline(w_shotorg, CS(ent).cursor_trace_ent.origin, MOVE_NORMAL, ent);
 134                                         if (trace_ent == CS(ent).cursor_trace_ent)
 135                                                 w_shotdir = normalize(CS(ent).cursor_trace_ent.origin - w_shotorg);
 136                                         else
 137                                                 LOG_INFO("antilag fail");
 138                                 }
 139                         }
 140                 }
 141         }
 142
 143         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 144
 145         if (!autocvar_g_norecoil)
 146                 ent.punchangle_x = recoil * -1;
 147
 148         if (snd != SND_Null) {
 149                 sound(ent, chan, snd, (W_DualWielding(ent) ? VOL_BASE * 0.7 : VOL_BASE), ATTN_NORM);
 150                 W_PlayStrengthSound(ent);
 151         }
 152
 153         // nudge w_shotend so a trace to w_shotend hits
 154         w_shotend = w_shotend + normalize(w_shotend - w_shotorg);
 155         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 156         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 157         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 158 }
 159
 160 vector W_CalculateProjectileVelocity(entity actor, vector pvelocity, vector mvelocity, float forceAbsolute)
 161 {
 162         vector mdirection;
 163         float mspeed;
 164         vector outvelocity;
 165
 166         mvelocity = mvelocity * W_WeaponSpeedFactor(actor);
 167
 168         mdirection = normalize(mvelocity);
 169         mspeed = vlen(mvelocity);
 170
 171         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 172
 173         return outvelocity;
 174 }
 175
 176 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 177 {
 178         if(proj.owner == NULL)
 179                 error("Unowned missile");
 180
 181         dir = dir + upDir * (pUpSpeed / pSpeed);
 182         dir.z += pZSpeed / pSpeed;
 183         pSpeed *= vlen(dir);
 184         dir = normalize(dir);
 185
 186         #if 0
 187         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 188         {
 189                 mspercallsum = mspercallcount = 0;
 190                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 191         }
 192         mspercallsum -= gettime(GETTIME_HIRES);
 193         #endif
 194
 195         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 196
 197         #if 0
 198         mspercallsum += gettime(GETTIME_HIRES);
 199         mspercallcount += 1;
 200         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec");
 201         #endif
 202
 203         proj.velocity = W_CalculateProjectileVelocity(proj.owner, proj.owner.velocity, pSpeed * dir, forceAbsolute);
 204 }
 205
 206
 207 // ====================
 208 //  Ballistics Tracing
 209 // ====================
 210
 211 void FireRailgunBullet (entity this, .entity weaponentity, vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 212 {
 213         entity pseudoprojectile = NULL;
 214
 215         vector dir = normalize(end - start);
 216         float length = vlen(end - start);
 217         vector force = dir * bforce;
 218
 219         // go a little bit into the wall because we need to hit this wall later
 220         end = end + dir;
 221
 222         float totaldmg = 0;
 223
 224         // trace multiple times until we hit a wall, each obstacle will be made
 225         // non-solid so we can hit the next, while doing this we spawn effects and
 226         // note down which entities were hit so we can damage them later
 227         entity o = this;
 228         while (1)
 229         {
 230                 if(CS(this).antilag_debug)
 231                         WarpZone_traceline_antilag (this, start, end, false, o, CS(this).antilag_debug);
 232                 else
 233                         WarpZone_traceline_antilag (this, start, end, false, o, ANTILAG_LATENCY(this));
 234                 if(o && WarpZone_trace_firstzone)
 235                 {
 236                         o = NULL;
 237                         continue;
 238                 }
 239
 240                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 241                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, this);
 242
 243                 // if it is NULL we can't hurt it so stop now
 244                 if (trace_ent == NULL || trace_fraction == 1)
 245                         break;
 246
 247                 // make the entity non-solid so we can hit the next one
 248                 IL_PUSH(g_railgunhit, trace_ent);
 249                 trace_ent.railgunhit = true;
 250                 trace_ent.railgunhitloc = end;
 251                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 252                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 253                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 254
 255                 // stop if this is a wall
 256                 if (trace_ent.solid == SOLID_BSP)
 257                         break;
 258
 259                 // make the entity non-solid
 260                 trace_ent.solid = SOLID_NOT;
 261         }
 262
 263         vector endpoint = trace_endpos;
 264         entity endent = trace_ent;
 265         float endq3surfaceflags = trace_dphitq3surfaceflags;
 266
 267         // find all the entities the railgun hit and restore their solid state
 268         IL_EACH(g_railgunhit, it.railgunhit,
 269         {
 270                 it.solid = it.railgunhitsolidbackup;
 271         });
 272
 273         // spawn a temporary explosion entity for RadiusDamage calls
 274         //explosion = spawn();
 275
 276         // Find all non-hit players the beam passed close by
 277         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id) // WEAPONTODO
 278         {
 279                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != this, {
 280                         if(!it.railgunhit)
 281                         if(!(IS_SPEC(it) && it.enemy == this))
 282                         {
 283                                 msg_entity = it;
 284                                 // nearest point on the beam
 285                                 vector beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 286
 287                                 float f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 288                                 if(f <= 0)
 289                                         continue;
 290
 291                                 if(!pseudoprojectile)
 292                                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 293                                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, SND(NEXWHOOSH_RANDOM()), VOL_BASE * f, ATTEN_NONE);
 294                         }
 295                 });
 296
 297                 if(pseudoprojectile)
 298                         delete(pseudoprojectile);
 299         }
 300
 301         // find all the entities the railgun hit and hurt them
 302         IL_EACH(g_railgunhit, it.railgunhit,
 303         {
 304                 // removal from the list is handled below
 305
 306                 // get the details we need to call the damage function
 307                 vector hitloc = it.railgunhitloc;
 308
 309                 float foff = ExponentialFalloff(mindist, maxdist, halflifedist, it.railgundistance);
 310                 float ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, it.railgundistance);
 311
 312                 if(accuracy_isgooddamage(this, it))
 313                         totaldmg += bdamage * foff;
 314
 315                 // apply the damage
 316                 if (it.takedamage)
 317                         Damage (it, this, this, bdamage * foff, deathtype, weaponentity, hitloc, it.railgunforce * ffs);
 318
 319                 // create a small explosion to throw gibs around (if applicable)
 320                 //setorigin(explosion, hitloc);
 321                 //RadiusDamage (explosion, this, 10, 0, 50, NULL, NULL, 300, deathtype);
 322
 323                 it.railgunhitloc = '0 0 0';
 324                 it.railgunhitsolidbackup = SOLID_NOT;
 325                 it.railgunhit = false;
 326                 it.railgundistance = 0;
 327         });
 328
 329         IL_CLEAR(g_railgunhit);
 330
 331         // calculate hits and fired shots for hitscan
 332         if(this.(weaponentity))
 333                 accuracy_add(this, this.(weaponentity).m_weapon, 0, min(bdamage, totaldmg));
 334
 335         trace_endpos = endpoint;
 336         trace_ent = endent;
 337         trace_dphitq3surfaceflags = endq3surfaceflags;
 338 }
 339
 340 void fireBullet_trace_callback(vector start, vector hit, vector end)
 341 {
 342         if(vdist(hit - start, >, 16))
 343                 trailparticles(NULL, fireBullet_trace_callback_eff, start, hit);
 344         WarpZone_trace_forent = NULL;
 345         fireBullet_last_hit = NULL;
 346 }
 347
 348 void fireBullet(entity this, .entity weaponentity, vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, entity tracer_effect)
 349 {
 350         vector  end;
 351
 352         dir = normalize(dir + randomvec() * spread);
 353         end = start + dir * max_shot_distance;
 354
 355         fireBullet_last_hit = NULL;
 356         fireBullet_trace_callback_eff = tracer_effect;
 357
 358         float solid_penetration_left = 1;
 359         float total_damage = 0;
 360
 361         float lag = ((IS_REAL_CLIENT(this)) ? ANTILAG_LATENCY(this) : 0);
 362         if(lag < 0.001)
 363                 lag = 0;
 364         bool noantilag = ((IS_CLIENT(this)) ? CS(this).cvar_cl_noantilag : false);
 365         if(autocvar_g_antilag == 0 || noantilag)
 366                 lag = 0; // only do hitscan, but no antilag
 367         if(lag)
 368                 antilag_takeback_all(this, lag);
 369
 370         // change shooter to SOLID_BBOX so the shot can hit corpses
 371         int oldsolid = this.dphitcontentsmask;
 372         if(this)
 373                 this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 374
 375         WarpZone_trace_forent = this;
 376
 377         for (;;)
 378         {
 379                 // TODO also show effect while tracing
 380                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, NULL, fireBullet_trace_callback);
 381                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 382                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 383                 start = trace_endpos;
 384                 entity hit = trace_ent;
 385
 386                 // traced up to max_shot_distance and didn't hit anything at all
 387                 if (trace_fraction == 1.0)
 388                         break;
 389
 390                 // When hitting sky, stop.
 391                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
 392                         break;
 393
 394                 // can't use noimpact, as we need to pass through walls
 395                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 396                         //break;
 397
 398                 // if we hit "weapclip", bail out
 399                 //
 400                 // rationale of this check:
 401                 //
 402                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 403                 // shots and players, but has no other effect!
 404                 //
 405                 // if it is not trans, it is caulk and should not have this side effect
 406                 //
 407                 // matching shaders:
 408                 //   common/weapclip (intended)
 409                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 410                 bool is_weapclip = false;
 411                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 412                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 413                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 414                         is_weapclip = true;
 415
 416                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 417                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, this);
 418
 419                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 420                 {
 421                         fireBullet_last_hit = hit;
 422                         yoda = 0;
 423                         MUTATOR_CALLHOOK(FireBullet_Hit, this, hit, start, end, damage, this.(weaponentity));
 424                         damage = M_ARGV(4, float);
 425                         bool gooddamage = accuracy_isgooddamage(this, hit);
 426                         Damage(hit, this, this, damage * solid_penetration_left, dtype, weaponentity, start, force * dir * solid_penetration_left);
 427                         // calculate hits for ballistic weapons
 428                         if(gooddamage)
 429                         {
 430                                 // do not exceed 100%
 431                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 432                                 total_damage += damage * solid_penetration_left;
 433                                 accuracy_add(this, this.(weaponentity).m_weapon, 0, added_damage);
 434                         }
 435                 }
 436
 437                 if (is_weapclip && !autocvar_g_ballistics_penetrate_clips)
 438                         break;
 439
 440                 // go through solid!
 441                 // outside the world? forget it
 442                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 443                         break;
 444
 445                 float maxdist;
 446                 entity hitstore = IS_PLAYER(hit) ? PS(hit) : hit;
 447                 if(max_solid_penetration < 0)
 448                         break;
 449                 else if(hitstore.ballistics_density < -1)
 450                         break; // -2: no solid penetration, ever
 451                 else if(hitstore.ballistics_density < 0)
 452                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 453                 else if(hitstore.ballistics_density == 0)
 454                         maxdist = max_solid_penetration * solid_penetration_left;
 455                 else
 456                         maxdist = max_solid_penetration * solid_penetration_left * hitstore.ballistics_density;
 457
 458                 if(maxdist <= autocvar_g_ballistics_mindistance)
 459                         break;
 460
 461                 // move the entity along its velocity until it's out of solid, then let it resume
 462                 // The previously hit entity is ignored here!
 463                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 464                 if(trace_fraction == 1) // 1: we never got out of solid
 465                         break;
 466
 467                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 468                 // fraction_used_of_what_is_left = dist_taken / maxdist
 469                 // solid_penetration_left = solid_penetration_left - solid_penetration_left * fraction_used_of_what_is_left
 470                 solid_penetration_left *= 1 - dist_taken / maxdist;
 471                 solid_penetration_left = max(solid_penetration_left, 0);
 472
 473                 // Only show effect when going through a player (invisible otherwise)
 474                 if (hit && (hit.solid != SOLID_BSP))
 475                         if(vdist(trace_endpos - start, >, 4))
 476                                 trailparticles(this, fireBullet_trace_callback_eff, start, trace_endpos);
 477
 478                 start = trace_endpos;
 479
 480                 if(hit.solid == SOLID_BSP)
 481                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, this);
 482         }
 483
 484         if(lag)
 485                 antilag_restore_all(this);
 486
 487         // restore shooter solid type
 488         if(this)
 489                 this.dphitcontentsmask = oldsolid;
 490 }