Merge branch 'Mario/headshots' into 'master'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / weapons / tracing.qc
1 #include "tracing.qh"
2
3 #include <common/effects/all.qh>
4
5 #include "accuracy.qh"
6 #include "common.qh"
7 #include "hitplot.qh"
8 #include "weaponsystem.qh"
9
10 #include "../g_damage.qh"
11 #include "../antilag.qh"
12
13 #include <common/constants.qh>
14 #include <common/net_linked.qh>
15 #include <common/util.qh>
16
17 #include <common/weapons/_all.qh>
18 #include <common/wepent.qh>
19 #include <common/state.qh>
20
21 #include <lib/warpzone/common.qh>
22
23 // this function calculates w_shotorg and w_shotdir based on the weapon model
24 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
25 // make sure you call makevectors first (FIXME?)
26 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, .entity weaponentity, vector s_forward, vector mi, vector ma, float antilag, float recoil, Sound snd, float chan, float maxdamage, float range, int deathtype)
27 {
28         TC(Sound, snd);
29         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
30         float oldsolid = ent.dphitcontentsmask;
31         Weapon wep = DEATH_WEAPONOF(deathtype);
32         if(!IS_CLIENT(ent))
33                 antilag = false; // no antilag for non-clients!
34         if (IS_PLAYER(ent) && (wep.spawnflags & WEP_FLAG_PENETRATEWALLS))
35         {
36                 // This is the reason rifle, MG, OKMG and other fireBullet weapons don't hit the crosshair when shooting at walls.
37                 // This is intentional, otherwise if you stand too close to a (glass) wall and attempt to shoot an enemy through it,
38                 // trueaim will cause the shot to hit the wall exactly but then miss the enemy (unless shooting from eye/center).
39                 // TODO for fireBullet, find how far the shot will penetrate and aim at that
40                 //      for fireRailgunbullet, find the farthest target and aim at that
41                 //      this will avoid issues when another player is passing in front of you when you shoot
42                 //      (currently such a shot will hit him but then miss the original target)
43                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
44         }
45         else
46                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
47         if(antilag)
48                 WarpZone_traceline_antilag(NULL, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
49                 // passing NULL, because we do NOT want it to touch dphitcontentsmask
50         else
51                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
52         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
53
54         vector forward, right, up;
55         forward = v_forward;
56         right = v_right;
57         up = v_up;
58         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
59         v_forward = forward;
60         v_right = right;
61         v_up = up;
62
63         // un-adjust trueaim if shotend is too close
64         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
65                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
66
67         // track max damage
68         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
69                 accuracy_add(ent, wep, maxdamage, 0);
70
71         if(IS_PLAYER(ent))
72                 W_HitPlotAnalysis(ent, wep, forward, right, up);
73
74         vector md = ent.(weaponentity).movedir;
75         vector vecs = ((md.x > 0) ? md : '0 0 0');
76
77         // TODO this is broken - see 637056bea7bf7f5c9c0fc6113e94731a2767476 for an attempted fix
78         // which fixes issue #1957 but causes #2129
79         vector dv = right * -vecs.y + up * vecs.z;
80         w_shotorg = ent.origin + ent.view_ofs + dv;
81
82         // now move the shotorg forward as much as requested if possible
83         if(antilag)
84         {
85                 if(CS(ent).antilag_debug)
86                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + forward * (vecs.x + nudge), MOVE_NORMAL, ent, CS(ent).antilag_debug);
87                 else
88                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
89         }
90         else
91                 tracebox(w_shotorg, mi, ma, w_shotorg + forward * (vecs.x + nudge), MOVE_NORMAL, ent);
92         w_shotorg = trace_endpos - forward * nudge;
93         // calculate the shotdir from the chosen shotorg
94         if(W_DualWielding(ent))
95                 w_shotdir = s_forward;
96         else
97                 w_shotdir = normalize(w_shotend - w_shotorg);
98
99         //vector prevdir = w_shotdir;
100         //vector prevorg = w_shotorg;
101         //vector prevend = w_shotend;
102
103         if (antilag)
104         if (!CS(ent).cvar_cl_noantilag)
105         {
106                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
107                 {
108                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
109                         if (!trace_ent.takedamage)
110                         {
111                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
112                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
113                                 {
114                                         entity e;
115                                         e = trace_ent;
116                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
117                                         if(trace_ent == e)
118                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
119                                 }
120                         }
121                 }
122                 else if(autocvar_g_antilag == 3) // client side hitscan
123                 {
124                         // this part MUST use prydon cursor
125                         if (CS(ent).cursor_trace_ent)                 // client was aiming at someone
126                         if (CS(ent).cursor_trace_ent != ent)         // just to make sure
127                         if (CS(ent).cursor_trace_ent.takedamage)      // and that person is killable
128                         if (IS_PLAYER(CS(ent).cursor_trace_ent)) // and actually a player
129                         {
130                                 // verify that the shot would miss without antilag
131                                 // (avoids an issue where guns would always shoot at their origin)
132                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
133                                 if (!trace_ent.takedamage)
134                                 {
135                                         // verify that the shot would hit if altered
136                                         traceline(w_shotorg, CS(ent).cursor_trace_ent.origin, MOVE_NORMAL, ent);
137                                         if (trace_ent == CS(ent).cursor_trace_ent)
138                                                 w_shotdir = normalize(CS(ent).cursor_trace_ent.origin - w_shotorg);
139                                         else
140                                                 LOG_INFO("antilag fail");
141                                 }
142                         }
143                 }
144         }
145
146         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
147
148         if (!autocvar_g_norecoil)
149                 ent.punchangle_x = recoil * -1;
150
151         if (snd != SND_Null) {
152                 sound(ent, chan, snd, (W_DualWielding(ent) ? VOL_BASE * 0.7 : VOL_BASE), ATTN_NORM);
153                 W_PlayStrengthSound(ent);
154         }
155
156         // nudge w_shotend so a trace to w_shotend hits
157         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
158         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
159         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
160         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
161 }
162
163 vector W_CalculateProjectileVelocity(entity actor, vector pvelocity, vector mvelocity, float forceAbsolute)
164 {
165         vector mdirection;
166         float mspeed;
167         vector outvelocity;
168
169         mvelocity = mvelocity * W_WeaponSpeedFactor(actor);
170
171         mdirection = normalize(mvelocity);
172         mspeed = vlen(mvelocity);
173
174         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
175
176         return outvelocity;
177 }
178
179 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
180 {
181         if(proj.owner == NULL)
182                 error("Unowned missile");
183
184         dir = dir + upDir * (pUpSpeed / pSpeed);
185         dir.z += pZSpeed / pSpeed;
186         pSpeed *= vlen(dir);
187         dir = normalize(dir);
188
189         #if 0
190         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
191         {
192                 mspercallsum = mspercallcount = 0;
193                 mspercallsstyle = autocvar_g_projectiles_spread_style;
194         }
195         mspercallsum -= gettime(GETTIME_HIRES);
196         #endif
197
198         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
199
200         #if 0
201         mspercallsum += gettime(GETTIME_HIRES);
202         mspercallcount += 1;
203         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec");
204         #endif
205
206         proj.velocity = W_CalculateProjectileVelocity(proj.owner, proj.owner.velocity, pSpeed * dir, forceAbsolute);
207 }
208
209
210 // ====================
211 //  Ballistics Tracing
212 // ====================
213
214 bool Headshot(entity targ, entity ent, vector start, vector end)
215 {
216         if(!IS_PLAYER(targ) || IS_DEAD(targ) || STAT(FROZEN, targ) || !targ.takedamage)
217                 return false;
218         vector org = targ.origin; // antilag is already taken into consideration //antilag_takebackorigin(targ, CS(targ), time - ANTILAG_LATENCY(ent));
219         vector headmins = org + '0.6 0 0' * targ.mins_x + '0 0.6 0' * targ.mins_y + '0 0 1' * (1.3 * targ.view_ofs_z - 0.3 * targ.maxs_z);
220         vector headmaxs = org + '0.6 0 0' * targ.maxs_x + '0 0.6 0' * targ.maxs_y + '0 0 1' * targ.maxs_z;
221
222         return trace_hits_box(start, end, headmins, headmaxs);
223 }
224
225 void FireRailgunBullet (entity this, .entity weaponentity, vector start, vector end, float bdamage, bool headshot_notify, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
226 {
227         vector dir = normalize(end - start);
228         vector force = dir * bforce;
229
230         // go a little bit into the wall because we need to hit this wall later
231         end = end + dir;
232
233         float totaldmg = 0;
234         bool headshot = false; // indicates that one of the targets hit was a headshot
235
236         // trace multiple times until we hit a wall, each obstacle will be made
237         // non-solid so we can hit the next, while doing this we spawn effects and
238         // note down which entities were hit so we can damage them later
239         entity o = this;
240         while (1)
241         {
242                 if(CS(this).antilag_debug)
243                         WarpZone_traceline_antilag (this, start, end, false, o, CS(this).antilag_debug);
244                 else
245                         WarpZone_traceline_antilag (this, start, end, false, o, ANTILAG_LATENCY(this));
246                 if(o && WarpZone_trace_firstzone)
247                 {
248                         o = NULL;
249                         continue;
250                 }
251
252                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
253                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, this);
254
255                 // if it is NULL we can't hurt it so stop now
256                 if (trace_ent == NULL || trace_fraction == 1)
257                         break;
258
259                 if(headshot_notify && !headshot && Headshot(trace_ent, this, start, end))
260                         headshot = true;
261
262                 // make the entity non-solid so we can hit the next one
263                 IL_PUSH(g_railgunhit, trace_ent);
264                 trace_ent.railgunhit = true;
265                 trace_ent.railgunhitloc = end;
266                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
267                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
268                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
269
270                 // stop if this is a wall
271                 if (trace_ent.solid == SOLID_BSP)
272                         break;
273
274                 // make the entity non-solid
275                 trace_ent.solid = SOLID_NOT;
276         }
277
278         vector endpoint = trace_endpos;
279         entity endent = trace_ent;
280         float endq3surfaceflags = trace_dphitq3surfaceflags;
281
282         // find all the entities the railgun hit and restore their solid state
283         IL_EACH(g_railgunhit, it.railgunhit,
284         {
285                 it.solid = it.railgunhitsolidbackup;
286         });
287
288         // Find all players the beam passed close by (even those hit)
289         float length = vlen(endpoint - start);
290         entity pseudoprojectile = NULL;
291         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != this, {
292                 // not when spectating the shooter
293                 if (IS_SPEC(it) && it.enemy == this) continue;
294
295                 // nearest point on the beam
296                 vector beampos = start + dir * bound(0, (it.origin - start) * dir, length);
297
298                 if(!pseudoprojectile)
299                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
300
301                 msg_entity = it;
302                 // we want this to be very loud when close but fall off quickly -> using max base volume and high attenuation
303                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, SND(NEXWHOOSH_RANDOM()), VOL_BASEVOICE, ATTEN_IDLE, 0);
304         });
305         if(pseudoprojectile)
306                 delete(pseudoprojectile);
307
308         // find all the entities the railgun hit and hurt them
309         IL_EACH(g_railgunhit, it.railgunhit,
310         {
311                 // removal from the list is handled below
312
313                 float foff = ExponentialFalloff(mindist, maxdist, halflifedist, it.railgundistance);
314                 float ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, it.railgundistance);
315
316                 if(accuracy_isgooddamage(this, it))
317                         totaldmg += bdamage * foff;
318
319                 // apply the damage
320                 if (it.takedamage)
321                         Damage(it, this, this, bdamage * foff, deathtype, weaponentity, it.railgunhitloc, it.railgunforce * ffs);
322
323                 it.railgunhitloc = '0 0 0';
324                 it.railgunhitsolidbackup = SOLID_NOT;
325                 it.railgunhit = false;
326                 it.railgundistance = 0;
327         });
328
329         IL_CLEAR(g_railgunhit);
330
331         if(headshot)
332                 Send_Notification(NOTIF_ONE, this, MSG_ANNCE, ANNCE_HEADSHOT);
333
334         // calculate hits and fired shots for hitscan
335         if(this.(weaponentity))
336                 accuracy_add(this, this.(weaponentity).m_weapon, 0, min(bdamage, totaldmg));
337
338         trace_endpos = endpoint;
339         trace_ent = endent;
340         trace_dphitq3surfaceflags = endq3surfaceflags;
341 }
342
343 void fireBullet_trace_callback(vector start, vector hit, vector end)
344 {
345         if(vdist(hit - start, >, 16))
346                 trailparticles(NULL, fireBullet_trace_callback_eff, start, hit);
347         WarpZone_trace_forent = NULL;
348         fireBullet_last_hit = NULL;
349 }
350
351 void fireBullet_antilag(entity this, .entity weaponentity, vector start, vector dir, float spread, float max_solid_penetration, float damage, float headshot_multiplier, float force, float dtype, entity tracer_effect, bool do_antilag)
352 {
353         dir = normalize(dir + randomvec() * spread);
354         vector end = start + dir * max_shot_distance;
355
356         fireBullet_last_hit = NULL;
357         fireBullet_trace_callback_eff = tracer_effect;
358
359         float solid_penetration_fraction = 1;
360         float damage_fraction = 1;
361         float total_damage = 0;
362
363         float lag = ((do_antilag) ? antilag_getlag(this) : 0);
364         if(lag)
365                 antilag_takeback_all(this, lag);
366
367         // change shooter to SOLID_BBOX so the shot can hit corpses
368         int oldsolid = this.dphitcontentsmask;
369         if(this)
370                 this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
371
372         WarpZone_trace_forent = this;
373
374         bool headshot = false; // indicates that one of the hit targets was a headshot
375         for (;;)
376         {
377                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, NULL, fireBullet_trace_callback);
378                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
379                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
380                 start = trace_endpos;
381                 entity hit = trace_ent;
382
383                 // traced up to max_shot_distance and didn't hit anything at all
384                 if (trace_fraction == 1.0)
385                         break;
386
387                 // When hitting sky, stop.
388                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
389                         break;
390
391                 // can't use noimpact, as we need to pass through walls
392                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
393                         //break;
394
395                 // if we hit "weapclip", bail out
396                 //
397                 // rationale of this check:
398                 //
399                 // any shader that is solid, nodraw AND trans is meant to clip weapon
400                 // shots and players, but has no other effect!
401                 //
402                 // if it is not trans, it is caulk and should not have this side effect
403                 //
404                 // matching shaders:
405                 //   common/weapclip (intended)
406                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
407                 bool is_weapclip = false;
408                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
409                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
410                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
411                         is_weapclip = true;
412
413                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
414                         Damage_DamageInfo(start, damage * damage_fraction, 0, 0, max(1, force) * dir * damage_fraction, dtype, hit.species, this);
415
416                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
417                 {
418                         fireBullet_last_hit = hit;
419                         yoda = 0;
420                         MUTATOR_CALLHOOK(FireBullet_Hit, this, hit, start, end, damage, this.(weaponentity));
421                         damage = M_ARGV(4, float);
422                         if(headshot_multiplier && Headshot(hit, this, start, end))
423                         {
424                                 damage *= headshot_multiplier;
425                                 headshot = true;
426                         }
427                         bool gooddamage = accuracy_isgooddamage(this, hit);
428                         Damage(hit, this, this, damage * damage_fraction, dtype, weaponentity, start, force * dir * damage_fraction);
429                         // calculate hits for ballistic weapons
430                         if(gooddamage)
431                         {
432                                 // do not exceed 100%
433                                 float added_damage = min(damage - total_damage, damage * damage_fraction);
434                                 total_damage += damage * damage_fraction;
435                                 accuracy_add(this, this.(weaponentity).m_weapon, 0, added_damage);
436                         }
437                 }
438
439                 if (is_weapclip && !autocvar_g_ballistics_penetrate_clips)
440                         break;
441
442                 // go through solid!
443                 // outside the world? forget it
444                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
445                         break;
446
447                 float maxdist;
448                 entity hitstore = IS_PLAYER(hit) ? PS(hit) : hit;
449                 if(max_solid_penetration < 0)
450                         break;
451                 else if(hitstore.ballistics_density < -1)
452                         break; // -2: no solid penetration, ever
453                 else if(hitstore.ballistics_density < 0)
454                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
455                 else if(hitstore.ballistics_density == 0)
456                         maxdist = max_solid_penetration * solid_penetration_fraction;
457                 else
458                         maxdist = max_solid_penetration * solid_penetration_fraction / hitstore.ballistics_density;
459
460                 if(maxdist <= autocvar_g_ballistics_mindistance)
461                         break;
462
463                 // move the entity along its velocity until it's out of solid, then let it resume
464                 // The previously hit entity is ignored here!
465                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
466                 if(trace_fraction == 1) // 1: we never got out of solid
467                         break;
468
469                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
470                 float fraction_used_of_what_is_left = dist_taken / maxdist;
471                 solid_penetration_fraction -= solid_penetration_fraction * fraction_used_of_what_is_left;
472                 solid_penetration_fraction = max(solid_penetration_fraction, 0);
473                 damage_fraction = pow(solid_penetration_fraction, autocvar_g_ballistics_solidpenetration_exponent);
474
475                 // Only show effect when going through a player (invisible otherwise)
476                 if (hit && (hit.solid != SOLID_BSP))
477                         if(vdist(trace_endpos - start, >, 4))
478                                 trailparticles(this, fireBullet_trace_callback_eff, start, trace_endpos);
479
480                 start = trace_endpos;
481
482                 if(hit.solid == SOLID_BSP)
483                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -damage_fraction, dtype, 0, this);
484         }
485
486         if(headshot)
487                 Send_Notification(NOTIF_ONE, this, MSG_ANNCE, ANNCE_HEADSHOT);
488
489         if(lag)
490                 antilag_restore_all(this);
491
492         // restore shooter solid type
493         if(this)
494                 this.dphitcontentsmask = oldsolid;
495 }
496
497 void fireBullet(entity this, .entity weaponentity, vector start, vector dir, float spread, float max_solid_penetration, float damage, float headshot_multiplier, float force, float dtype, entity tracer_effect)
498 {
499         fireBullet_antilag(this, weaponentity, start, dir, spread, max_solid_penetration, damage, headshot_multiplier, force, dtype, tracer_effect, true);
500 }