qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include <common/effects/all.qh>
   4
   5 #include "accuracy.qh"
   6 #include "common.qh"
   7 #include "hitplot.qh"
   8 #include "weaponsystem.qh"
   9
  10 #include "../g_damage.qh"
  11 #include "../antilag.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/net_linked.qh>
  15 #include <common/util.qh>
  16
  17 #include <common/weapons/_all.qh>
  18 #include <common/wepent.qh>
  19 #include <common/state.qh>
  20
  21 #include <lib/warpzone/common.qh>
  22
  23 // this function calculates w_shotorg and w_shotdir based on the weapon model
  24 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  25 // make sure you call makevectors first (FIXME?)
  26 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, .entity weaponentity, vector s_forward, vector mi, vector ma, float antilag, float recoil, Sound snd, float chan, float maxdamage, float range, int deathtype)
  27 {
  28         TC(Sound, snd);
  29         float oldsolid = ent.dphitcontentsmask;
  30         Weapon wep = DEATH_WEAPONOF(deathtype);
  31         if(!IS_CLIENT(ent))
  32                 antilag = false; // no antilag for non-clients!
  33         if (IS_PLAYER(ent) && (wep.spawnflags & WEP_FLAG_PENETRATEWALLS))
  34                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  35         else
  36                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  37         if(antilag)
  38                 WarpZone_traceline_antilag(NULL, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  39                 // passing NULL, because we do NOT want it to touch dphitcontentsmask
  40         else
  41                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  42         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  43
  44         vector vf, vr, vu;
  45         vf = v_forward;
  46         vr = v_right;
  47         vu = v_up;
  48         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  49         v_forward = vf;
  50         v_right = vr;
  51         v_up = vu;
  52
  53         // un-adjust trueaim if shotend is too close
  54         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
  55                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  56
  57         // track max damage
  58         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
  59                 accuracy_add(ent, wep, maxdamage, 0);
  60
  61         if(IS_PLAYER(ent))
  62                 W_HitPlotAnalysis(ent, wep, v_forward, v_right, v_up);
  63
  64         vector md = ent.(weaponentity).movedir;
  65         vector vecs = ((md.x > 0) ? md : '0 0 0');
  66
  67         vector dv = v_forward * vecs.x + v_right * -vecs.y + v_up * vecs.z;
  68         w_shotorg = ent.origin + ent.view_ofs;
  69
  70         // now move the shotorg forward as much as requested if possible
  71         if(antilag)
  72         {
  73                 if(CS(ent).antilag_debug)
  74                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + dv, MOVE_NORMAL, ent, CS(ent).antilag_debug);
  75                 else
  76                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + dv, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  77         }
  78         else
  79                 tracebox(w_shotorg, mi, ma, w_shotorg + dv, MOVE_NORMAL, ent);
  80         w_shotorg = trace_endpos;
  81         // calculate the shotdir from the chosen shotorg
  82         if(W_DualWielding(ent))
  83                 w_shotdir = s_forward;
  84         else
  85                 w_shotdir = normalize(w_shotend - w_shotorg);
  86
  87         //vector prevdir = w_shotdir;
  88         //vector prevorg = w_shotorg;
  89         //vector prevend = w_shotend;
  90
  91         if (antilag)
  92         if (!CS(ent).cvar_cl_noantilag)
  93         {
  94                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  95                 {
  96                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  97                         if (!trace_ent.takedamage)
  98                         {
  99                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 100                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
 101                                 {
 102                                         entity e;
 103                                         e = trace_ent;
 104                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 105                                         if(trace_ent == e)
 106                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 107                                 }
 108                         }
 109                 }
 110                 else if(autocvar_g_antilag == 3) // client side hitscan
 111                 {
 112                         // this part MUST use prydon cursor
 113                         if (CS(ent).cursor_trace_ent)                 // client was aiming at someone
 114                         if (CS(ent).cursor_trace_ent != ent)         // just to make sure
 115                         if (CS(ent).cursor_trace_ent.takedamage)      // and that person is killable
 116                         if (IS_PLAYER(CS(ent).cursor_trace_ent)) // and actually a player
 117                         {
 118                                 // verify that the shot would miss without antilag
 119                                 // (avoids an issue where guns would always shoot at their origin)
 120                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 121                                 if (!trace_ent.takedamage)
 122                                 {
 123                                         // verify that the shot would hit if altered
 124                                         traceline(w_shotorg, CS(ent).cursor_trace_ent.origin, MOVE_NORMAL, ent);
 125                                         if (trace_ent == CS(ent).cursor_trace_ent)
 126                                                 w_shotdir = normalize(CS(ent).cursor_trace_ent.origin - w_shotorg);
 127                                         else
 128                                                 LOG_INFO("antilag fail");
 129                                 }
 130                         }
 131                 }
 132         }
 133
 134         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 135
 136         if (!autocvar_g_norecoil)
 137                 ent.punchangle_x = recoil * -1;
 138
 139         if (snd != SND_Null) {
 140                 sound(ent, chan, snd, (W_DualWielding(ent) ? VOL_BASE * 0.7 : VOL_BASE), ATTN_NORM);
 141                 W_PlayStrengthSound(ent);
 142         }
 143
 144         // nudge w_shotend so a trace to w_shotend hits
 145         w_shotend = w_shotend + normalize(w_shotend - w_shotorg);
 146         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 147         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 148         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 149 }
 150
 151 vector W_CalculateProjectileVelocity(entity actor, vector pvelocity, vector mvelocity, float forceAbsolute)
 152 {
 153         vector mdirection;
 154         float mspeed;
 155         vector outvelocity;
 156
 157         mvelocity = mvelocity * W_WeaponSpeedFactor(actor);
 158
 159         mdirection = normalize(mvelocity);
 160         mspeed = vlen(mvelocity);
 161
 162         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 163
 164         return outvelocity;
 165 }
 166
 167 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 168 {
 169         if(proj.owner == NULL)
 170                 error("Unowned missile");
 171
 172         dir = dir + upDir * (pUpSpeed / pSpeed);
 173         dir.z += pZSpeed / pSpeed;
 174         pSpeed *= vlen(dir);
 175         dir = normalize(dir);
 176
 177         #if 0
 178         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 179         {
 180                 mspercallsum = mspercallcount = 0;
 181                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 182         }
 183         mspercallsum -= gettime(GETTIME_HIRES);
 184         #endif
 185
 186         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 187
 188         #if 0
 189         mspercallsum += gettime(GETTIME_HIRES);
 190         mspercallcount += 1;
 191         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec");
 192         #endif
 193
 194         proj.velocity = W_CalculateProjectileVelocity(proj.owner, proj.owner.velocity, pSpeed * dir, forceAbsolute);
 195 }
 196
 197
 198 // ====================
 199 //  Ballistics Tracing
 200 // ====================
 201
 202 void FireRailgunBullet (entity this, .entity weaponentity, vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 203 {
 204         entity pseudoprojectile = NULL;
 205
 206         vector dir = normalize(end - start);
 207         float length = vlen(end - start);
 208         vector force = dir * bforce;
 209
 210         // go a little bit into the wall because we need to hit this wall later
 211         end = end + dir;
 212
 213         float totaldmg = 0;
 214
 215         // trace multiple times until we hit a wall, each obstacle will be made
 216         // non-solid so we can hit the next, while doing this we spawn effects and
 217         // note down which entities were hit so we can damage them later
 218         entity o = this;
 219         while (1)
 220         {
 221                 if(CS(this).antilag_debug)
 222                         WarpZone_traceline_antilag (this, start, end, false, o, CS(this).antilag_debug);
 223                 else
 224                         WarpZone_traceline_antilag (this, start, end, false, o, ANTILAG_LATENCY(this));
 225                 if(o && WarpZone_trace_firstzone)
 226                 {
 227                         o = NULL;
 228                         continue;
 229                 }
 230
 231                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 232                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, this);
 233
 234                 // if it is NULL we can't hurt it so stop now
 235                 if (trace_ent == NULL || trace_fraction == 1)
 236                         break;
 237
 238                 // make the entity non-solid so we can hit the next one
 239                 IL_PUSH(g_railgunhit, trace_ent);
 240                 trace_ent.railgunhit = true;
 241                 trace_ent.railgunhitloc = end;
 242                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 243                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 244                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 245
 246                 // stop if this is a wall
 247                 if (trace_ent.solid == SOLID_BSP)
 248                         break;
 249
 250                 // make the entity non-solid
 251                 trace_ent.solid = SOLID_NOT;
 252         }
 253
 254         vector endpoint = trace_endpos;
 255         entity endent = trace_ent;
 256         float endq3surfaceflags = trace_dphitq3surfaceflags;
 257
 258         // find all the entities the railgun hit and restore their solid state
 259         IL_EACH(g_railgunhit, it.railgunhit,
 260         {
 261                 it.solid = it.railgunhitsolidbackup;
 262         });
 263
 264         // spawn a temporary explosion entity for RadiusDamage calls
 265         //explosion = spawn();
 266
 267         // Find all non-hit players the beam passed close by
 268         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id) // WEAPONTODO
 269         {
 270                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != this, {
 271                         if(!it.railgunhit)
 272                         if(!(IS_SPEC(it) && it.enemy == this))
 273                         {
 274                                 msg_entity = it;
 275                                 // nearest point on the beam
 276                                 vector beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 277
 278                                 float f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 279                                 if(f <= 0)
 280                                         continue;
 281
 282                                 if(!pseudoprojectile)
 283                                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 284                                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, SND(NEXWHOOSH_RANDOM()), VOL_BASE * f, ATTEN_NONE);
 285                         }
 286                 });
 287
 288                 if(pseudoprojectile)
 289                         delete(pseudoprojectile);
 290         }
 291
 292         // find all the entities the railgun hit and hurt them
 293         IL_EACH(g_railgunhit, it.railgunhit,
 294         {
 295                 // removal from the list is handled below
 296
 297                 // get the details we need to call the damage function
 298                 vector hitloc = it.railgunhitloc;
 299
 300                 float foff = ExponentialFalloff(mindist, maxdist, halflifedist, it.railgundistance);
 301                 float ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, it.railgundistance);
 302
 303                 if(accuracy_isgooddamage(this, it))
 304                         totaldmg += bdamage * foff;
 305
 306                 // apply the damage
 307                 if (it.takedamage)
 308                         Damage (it, this, this, bdamage * foff, deathtype, weaponentity, hitloc, it.railgunforce * ffs);
 309
 310                 // create a small explosion to throw gibs around (if applicable)
 311                 //setorigin(explosion, hitloc);
 312                 //RadiusDamage (explosion, this, 10, 0, 50, NULL, NULL, 300, deathtype);
 313
 314                 it.railgunhitloc = '0 0 0';
 315                 it.railgunhitsolidbackup = SOLID_NOT;
 316                 it.railgunhit = false;
 317                 it.railgundistance = 0;
 318         });
 319
 320         IL_CLEAR(g_railgunhit);
 321
 322         // calculate hits and fired shots for hitscan
 323         if(this.(weaponentity))
 324                 accuracy_add(this, this.(weaponentity).m_weapon, 0, min(bdamage, totaldmg));
 325
 326         trace_endpos = endpoint;
 327         trace_ent = endent;
 328         trace_dphitq3surfaceflags = endq3surfaceflags;
 329 }
 330
 331 void fireBullet_trace_callback(vector start, vector hit, vector end)
 332 {
 333         if(vdist(hit - start, >, 16))
 334                 trailparticles(NULL, fireBullet_trace_callback_eff, start, hit);
 335         WarpZone_trace_forent = NULL;
 336         fireBullet_last_hit = NULL;
 337 }
 338
 339 void fireBullet(entity this, .entity weaponentity, vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, entity tracer_effect)
 340 {
 341         vector  end;
 342
 343         dir = normalize(dir + randomvec() * spread);
 344         end = start + dir * max_shot_distance;
 345
 346         fireBullet_last_hit = NULL;
 347         fireBullet_trace_callback_eff = tracer_effect;
 348
 349         float solid_penetration_left = 1;
 350         float total_damage = 0;
 351
 352         float lag = ((IS_REAL_CLIENT(this)) ? ANTILAG_LATENCY(this) : 0);
 353         if(lag < 0.001)
 354                 lag = 0;
 355         bool noantilag = ((IS_CLIENT(this)) ? CS(this).cvar_cl_noantilag : false);
 356         if(autocvar_g_antilag == 0 || noantilag)
 357                 lag = 0; // only do hitscan, but no antilag
 358         if(lag)
 359                 antilag_takeback_all(this, lag);
 360
 361         // change shooter to SOLID_BBOX so the shot can hit corpses
 362         int oldsolid = this.dphitcontentsmask;
 363         if(this)
 364                 this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 365
 366         WarpZone_trace_forent = this;
 367
 368         for (;;)
 369         {
 370                 // TODO also show effect while tracing
 371                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, NULL, fireBullet_trace_callback);
 372                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 373                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 374                 start = trace_endpos;
 375                 entity hit = trace_ent;
 376
 377                 // traced up to max_shot_distance and didn't hit anything at all
 378                 if (trace_fraction == 1.0)
 379                         break;
 380
 381                 // When hitting sky, stop.
 382                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
 383                         break;
 384
 385                 // can't use noimpact, as we need to pass through walls
 386                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 387                         //break;
 388
 389                 // if we hit "weapclip", bail out
 390                 //
 391                 // rationale of this check:
 392                 //
 393                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 394                 // shots and players, but has no other effect!
 395                 //
 396                 // if it is not trans, it is caulk and should not have this side effect
 397                 //
 398                 // matching shaders:
 399                 //   common/weapclip (intended)
 400                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 401                 bool is_weapclip = false;
 402                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 403                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 404                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 405                         is_weapclip = true;
 406
 407                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 408                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, this);
 409
 410                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 411                 {
 412                         fireBullet_last_hit = hit;
 413                         yoda = 0;
 414                         MUTATOR_CALLHOOK(FireBullet_Hit, this, hit, start, end, damage, this.(weaponentity));
 415                         damage = M_ARGV(4, float);
 416                         bool gooddamage = accuracy_isgooddamage(this, hit);
 417                         Damage(hit, this, this, damage * solid_penetration_left, dtype, weaponentity, start, force * dir * solid_penetration_left);
 418                         // calculate hits for ballistic weapons
 419                         if(gooddamage)
 420                         {
 421                                 // do not exceed 100%
 422                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 423                                 total_damage += damage * solid_penetration_left;
 424                                 accuracy_add(this, this.(weaponentity).m_weapon, 0, added_damage);
 425                         }
 426                 }
 427
 428                 if (is_weapclip && !autocvar_g_ballistics_penetrate_clips)
 429                         break;
 430
 431                 // go through solid!
 432                 // outside the world? forget it
 433                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 434                         break;
 435
 436                 float maxdist;
 437                 entity hitstore = IS_PLAYER(hit) ? PS(hit) : hit;
 438                 if(max_solid_penetration < 0)
 439                         break;
 440                 else if(hitstore.ballistics_density < -1)
 441                         break; // -2: no solid penetration, ever
 442                 else if(hitstore.ballistics_density < 0)
 443                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 444                 else if(hitstore.ballistics_density == 0)
 445                         maxdist = max_solid_penetration * solid_penetration_left;
 446                 else
 447                         maxdist = max_solid_penetration * solid_penetration_left * hitstore.ballistics_density;
 448
 449                 if(maxdist <= autocvar_g_ballistics_mindistance)
 450                         break;
 451
 452                 // move the entity along its velocity until it's out of solid, then let it resume
 453                 // The previously hit entity is ignored here!
 454                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 455                 if(trace_fraction == 1) // 1: we never got out of solid
 456                         break;
 457
 458                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 459                 // fraction_used_of_what_is_left = dist_taken / maxdist
 460                 // solid_penetration_left = solid_penetration_left - solid_penetration_left * fraction_used_of_what_is_left
 461                 solid_penetration_left *= 1 - dist_taken / maxdist;
 462                 solid_penetration_left = max(solid_penetration_left, 0);
 463
 464                 // Only show effect when going through a player (invisible otherwise)
 465                 if (hit && (hit.solid != SOLID_BSP))
 466                         if(vdist(trace_endpos - start, >, 4))
 467                                 trailparticles(this, fireBullet_trace_callback_eff, start, trace_endpos);
 468
 469                 start = trace_endpos;
 470
 471                 if(hit.solid == SOLID_BSP)
 472                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, this);
 473         }
 474
 475         if(lag)
 476                 antilag_restore_all(this);
 477
 478         // restore shooter solid type
 479         if(this)
 480                 this.dphitcontentsmask = oldsolid;
 481 }