qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include "accuracy.qh"
   4 #include "common.qh"
   5 #include "hitplot.qh"
   6 #include "weaponsystem.qh"
   7
   8 #include "../g_damage.qh"
   9 #include "../g_subs.qh"
  10 #include "../antilag.qh"
  11
  12 #include "../../common/constants.qh"
  13 #include "../../common/util.qh"
  14
  15 #include "../../common/weapons/all.qh"
  16
  17 #include "../../lib/warpzone/common.qh"
  18
  19 // this function calculates w_shotorg and w_shotdir based on the weapon model
  20 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  21 // make sure you call makevectors first (FIXME?)
  22 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
  23 {
  24         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  25         float oldsolid;
  26         vector vecs, dv;
  27         oldsolid = ent.dphitcontentsmask;
  28         if(ent.weapon == WEP_RIFLE.m_id)
  29                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  30         else
  31                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  32         if(antilag)
  33                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  34                 // passing world, because we do NOT want it to touch dphitcontentsmask
  35         else
  36                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  37         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  38
  39         vector vf, vr, vu;
  40         vf = v_forward;
  41         vr = v_right;
  42         vu = v_up;
  43         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  44         v_forward = vf;
  45         v_right = vr;
  46         v_up = vu;
  47
  48         // un-adjust trueaim if shotend is too close
  49         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
  50                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  51
  52         // track max damage
  53         if(accuracy_canbegooddamage(ent))
  54                 accuracy_add(ent, ent.weapon, maxdamage, 0);
  55
  56         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
  57
  58         if(ent.weaponentity.movedir.x > 0)
  59                 vecs = ent.weaponentity.movedir;
  60         else
  61                 vecs = '0 0 0';
  62
  63         dv = v_right * -vecs.y + v_up * vecs.z;
  64         w_shotorg = ent.origin + ent.view_ofs + dv;
  65
  66         // now move the shotorg forward as much as requested if possible
  67         if(antilag)
  68         {
  69                 if(ent.antilag_debug)
  70                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
  71                 else
  72                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  73         }
  74         else
  75                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
  76         w_shotorg = trace_endpos - v_forward * nudge;
  77         // calculate the shotdir from the chosen shotorg
  78         w_shotdir = normalize(w_shotend - w_shotorg);
  79
  80         //vector prevdir = w_shotdir;
  81         //vector prevorg = w_shotorg;
  82         //vector prevend = w_shotend;
  83
  84         if (antilag)
  85         if (!ent.cvar_cl_noantilag)
  86         {
  87                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  88                 {
  89                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  90                         if (!trace_ent.takedamage)
  91                         {
  92                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  93                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
  94                                 {
  95                                         entity e;
  96                                         e = trace_ent;
  97                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
  98                                         if(trace_ent == e)
  99                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 100                                 }
 101                         }
 102                 }
 103                 else if(autocvar_g_antilag == 3) // client side hitscan
 104                 {
 105                         // this part MUST use prydon cursor
 106                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 107                         if (ent.cursor_trace_ent != ent)         // just to make sure
 108                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 109                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
 110                         {
 111                                 // verify that the shot would miss without antilag
 112                                 // (avoids an issue where guns would always shoot at their origin)
 113                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 114                                 if (!trace_ent.takedamage)
 115                                 {
 116                                         // verify that the shot would hit if altered
 117                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 118                                         if (trace_ent == ent.cursor_trace_ent)
 119                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 120                                         else
 121                                                 LOG_INFO("antilag fail\n");
 122                                 }
 123                         }
 124                 }
 125         }
 126
 127         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 128
 129         if (!autocvar_g_norecoil)
 130                 ent.punchangle_x = recoil * -1;
 131
 132         if (snd != "")
 133         {
 134                 _sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 135                 W_PlayStrengthSound(ent);
 136         }
 137
 138         // nudge w_shotend so a trace to w_shotend hits
 139         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 140         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 141         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 142         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 143 }
 144
 145 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
 146 {
 147         vector mdirection;
 148         float mspeed;
 149         vector outvelocity;
 150
 151         mvelocity = mvelocity * W_WeaponSpeedFactor();
 152
 153         mdirection = normalize(mvelocity);
 154         mspeed = vlen(mvelocity);
 155
 156         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 157
 158         return outvelocity;
 159 }
 160
 161 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 162 {
 163         if(proj.owner == world)
 164                 error("Unowned missile");
 165
 166         dir = dir + upDir * (pUpSpeed / pSpeed);
 167         dir.z += pZSpeed / pSpeed;
 168         pSpeed *= vlen(dir);
 169         dir = normalize(dir);
 170
 171         #if 0
 172         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 173         {
 174                 mspercallsum = mspercallcount = 0;
 175                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 176         }
 177         mspercallsum -= gettime(GETTIME_HIRES);
 178         #endif
 179
 180         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 181
 182         #if 0
 183         mspercallsum += gettime(GETTIME_HIRES);
 184         mspercallcount += 1;
 185         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
 186         #endif
 187
 188         proj.velocity = W_CalculateProjectileVelocity(proj.owner.velocity, pSpeed * dir, forceAbsolute);
 189 }
 190
 191
 192 // ====================
 193 //  Ballistics Tracing
 194 // ====================
 195
 196 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 197 {SELFPARAM();
 198         vector hitloc, force, endpoint, dir;
 199         entity ent, endent;
 200         float endq3surfaceflags;
 201         float totaldmg;
 202         entity o;
 203
 204         float length;
 205         vector beampos;
 206         string snd;
 207         entity pseudoprojectile;
 208         float f, ffs;
 209
 210         pseudoprojectile = world;
 211
 212         dir = normalize(end - start);
 213         length = vlen(end - start);
 214         force = dir * bforce;
 215
 216         // go a little bit into the wall because we need to hit this wall later
 217         end = end + dir;
 218
 219         totaldmg = 0;
 220
 221         // trace multiple times until we hit a wall, each obstacle will be made
 222         // non-solid so we can hit the next, while doing this we spawn effects and
 223         // note down which entities were hit so we can damage them later
 224         o = self;
 225         while (1)
 226         {
 227                 if(self.antilag_debug)
 228                         WarpZone_traceline_antilag (self, start, end, false, o, self.antilag_debug);
 229                 else
 230                         WarpZone_traceline_antilag (self, start, end, false, o, ANTILAG_LATENCY(self));
 231                 if(o && WarpZone_trace_firstzone)
 232                 {
 233                         o = world;
 234                         continue;
 235                 }
 236
 237                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 238                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, self);
 239
 240                 // if it is world we can't hurt it so stop now
 241                 if (trace_ent == world || trace_fraction == 1)
 242                         break;
 243
 244                 // make the entity non-solid so we can hit the next one
 245                 trace_ent.railgunhit = true;
 246                 trace_ent.railgunhitloc = end;
 247                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 248                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 249                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 250
 251                 // stop if this is a wall
 252                 if (trace_ent.solid == SOLID_BSP)
 253                         break;
 254
 255                 // make the entity non-solid
 256                 trace_ent.solid = SOLID_NOT;
 257         }
 258
 259         endpoint = trace_endpos;
 260         endent = trace_ent;
 261         endq3surfaceflags = trace_dphitq3surfaceflags;
 262
 263         // find all the entities the railgun hit and restore their solid state
 264         ent = findfloat(world, railgunhit, true);
 265         while (ent)
 266         {
 267                 // restore their solid type
 268                 ent.solid = ent.railgunhitsolidbackup;
 269                 ent = findfloat(ent, railgunhit, true);
 270         }
 271
 272         // spawn a temporary explosion entity for RadiusDamage calls
 273         //explosion = spawn();
 274
 275         // Find all non-hit players the beam passed close by
 276         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id)
 277         {
 278                 FOR_EACH_REALCLIENT(msg_entity)
 279                 if(msg_entity != self)
 280                 if(!msg_entity.railgunhit)
 281                 if(!(IS_SPEC(msg_entity) && msg_entity.enemy == self)) // we use realclient, so spectators can hear the whoosh too
 282                 {
 283                         // nearest point on the beam
 284                         beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 285
 286                         f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 287                         if(f <= 0)
 288                                 continue;
 289
 290                         snd = SND(NEXWHOOSH_RANDOM());
 291
 292                         if(!pseudoprojectile)
 293                                 pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 294                         soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, snd, VOL_BASE * f, ATTEN_NONE);
 295                 }
 296
 297                 if(pseudoprojectile)
 298                         remove(pseudoprojectile);
 299         }
 300
 301         // find all the entities the railgun hit and hurt them
 302         ent = findfloat(world, railgunhit, true);
 303         while (ent)
 304         {
 305                 // get the details we need to call the damage function
 306                 hitloc = ent.railgunhitloc;
 307
 308                 f = ExponentialFalloff(mindist, maxdist, halflifedist, ent.railgundistance);
 309                 ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, ent.railgundistance);
 310
 311                 if(accuracy_isgooddamage(self, ent))
 312                         totaldmg += bdamage * f;
 313
 314                 // apply the damage
 315                 if (ent.takedamage)
 316                         Damage (ent, self, self, bdamage * f, deathtype, hitloc, ent.railgunforce * ffs);
 317
 318                 // create a small explosion to throw gibs around (if applicable)
 319                 //setorigin (explosion, hitloc);
 320                 //RadiusDamage (explosion, self, 10, 0, 50, world, world, 300, deathtype);
 321
 322                 ent.railgunhitloc = '0 0 0';
 323                 ent.railgunhitsolidbackup = SOLID_NOT;
 324                 ent.railgunhit = false;
 325                 ent.railgundistance = 0;
 326
 327                 // advance to the next entity
 328                 ent = findfloat(ent, railgunhit, true);
 329         }
 330
 331         // calculate hits and fired shots for hitscan
 332         accuracy_add(self, self.weapon, 0, min(bdamage, totaldmg));
 333
 334         trace_endpos = endpoint;
 335         trace_ent = endent;
 336         trace_dphitq3surfaceflags = endq3surfaceflags;
 337 }
 338
 339 void fireBullet_trace_callback(vector start, vector hit, vector end)
 340 {
 341         if(vlen(hit - start) > 16)
 342                 trailparticles(world, fireBullet_trace_callback_eff, start, hit);
 343         WarpZone_trace_forent = world;
 344         fireBullet_last_hit = world;
 345 }
 346
 347 void fireBullet(vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, int tracereffects)
 348 {SELFPARAM();
 349         vector  end;
 350
 351         dir = normalize(dir + randomvec() * spread);
 352         end = start + dir * MAX_SHOT_DISTANCE;
 353
 354         entity pl;
 355         fireBullet_last_hit = world;
 356         float solid_penetration_left = 1;
 357         float total_damage = 0;
 358
 359         if(tracereffects & EF_RED)
 360                 fireBullet_trace_callback_eff = particleeffectnum(EFFECT_RIFLE);
 361         else if(tracereffects & EF_BLUE)
 362                 fireBullet_trace_callback_eff = particleeffectnum(EFFECT_RIFLE_WEAK);
 363         else
 364                 fireBullet_trace_callback_eff = particleeffectnum(EFFECT_BULLET);
 365
 366         float lag = ANTILAG_LATENCY(self);
 367         if(lag < 0.001)
 368                 lag = 0;
 369         if (!IS_REAL_CLIENT(self))
 370                 lag = 0;
 371         if(autocvar_g_antilag == 0 || self.cvar_cl_noantilag)
 372                 lag = 0; // only do hitscan, but no antilag
 373         if(lag)
 374         {
 375                 FOR_EACH_PLAYER(pl)
 376                         if(pl != self)
 377                                 antilag_takeback(pl, time - lag);
 378                 FOR_EACH_MONSTER(pl)
 379                         antilag_takeback(pl, time - lag);
 380         }
 381
 382         WarpZone_trace_forent = self;
 383
 384         for (;;)
 385         {
 386                 // TODO also show effect while tracing
 387                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, world, fireBullet_trace_callback);
 388                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 389                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 390                 start = trace_endpos;
 391                 entity hit = trace_ent;
 392
 393                 // When hitting sky, stop.
 394                 if (pointcontents(start) == CONTENT_SKY)
 395                         break;
 396
 397                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 398                         break;
 399
 400                 // if we hit "weapclip", bail out
 401                 //
 402                 // rationale of this check:
 403                 //
 404                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 405                 // shots and players, but has no other effect!
 406                 //
 407                 // if it is not trans, it is caulk and should not have this side effect
 408                 //
 409                 // matching shaders:
 410                 //   common/weapclip (intended)
 411                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 412                 float is_weapclip = 0;
 413                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 414                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 415                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 416                         is_weapclip = 1;
 417
 418                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 419                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, self);
 420
 421                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 422                 {
 423                         fireBullet_last_hit = hit;
 424                         yoda = 0;
 425                         MUTATOR_CALLHOOK(FireBullet_Hit, self, hit, start, end, damage);
 426                         damage = frag_damage;
 427                         float g = accuracy_isgooddamage(self, hit);
 428                         Damage(hit, self, self, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
 429                         // calculate hits for ballistic weapons
 430                         if(g)
 431                         {
 432                                 // do not exceed 100%
 433                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 434                                 total_damage += damage * solid_penetration_left;
 435                                 accuracy_add(self, self.weapon, 0, added_damage);
 436                         }
 437                 }
 438
 439                 if (is_weapclip)
 440                         break;
 441
 442                 // go through solid!
 443                 // outside the world? forget it
 444                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 445                         break;
 446
 447                 float maxdist;
 448                 if(max_solid_penetration < 0)
 449                         break;
 450                 else if(hit.ballistics_density < -1)
 451                         break; // -2: no solid penetration, ever
 452                 else if(hit.ballistics_density < 0)
 453                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 454                 else if(hit.ballistics_density == 0)
 455                         maxdist = max_solid_penetration * solid_penetration_left;
 456                 else
 457                         maxdist = max_solid_penetration * solid_penetration_left * hit.ballistics_density;
 458
 459                 if(maxdist <= autocvar_g_ballistics_mindistance)
 460                         break;
 461
 462                 // move the entity along its velocity until it's out of solid, then let it resume
 463                 // The previously hit entity is ignored here!
 464                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 465                 if(trace_fraction == 1) // 1: we never got out of solid
 466                         break;
 467
 468                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 469                 solid_penetration_left *= (dist_taken / maxdist);
 470
 471                 // Only show effect when going through a player (invisible otherwise)
 472                 if (hit && (hit.solid != SOLID_BSP))
 473                         if(vlen(trace_endpos - start) > 4)
 474                                 trailparticles(self, fireBullet_trace_callback_eff, start, trace_endpos);
 475
 476                 start = trace_endpos;
 477
 478                 if(hit.solid == SOLID_BSP)
 479                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, self);
 480         }
 481
 482         if(lag)
 483         {
 484                 FOR_EACH_PLAYER(pl)
 485                         if(pl != self)
 486                                 antilag_restore(pl);
 487                 FOR_EACH_MONSTER(pl)
 488                         antilag_restore(pl);
 489         }
 490 }