qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include <common/effects/all.qh>
   4
   5 #include "accuracy.qh"
   6 #include "common.qh"
   7 #include "hitplot.qh"
   8 #include "weaponsystem.qh"
   9
  10 #include "../g_damage.qh"
  11 #include "../g_subs.qh"
  12 #include "../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/util.qh>
  17
  18 #include <common/weapons/_all.qh>
  19 #include <common/wepent.qh>
  20 #include <common/state.qh>
  21
  22 #include <lib/warpzone/common.qh>
  23
  24 // this function calculates w_shotorg and w_shotdir based on the weapon model
  25 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  26 // make sure you call makevectors first (FIXME?)
  27 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, .entity weaponentity, vector s_forward, vector mi, vector ma, float antilag, float recoil, Sound snd, float chan, float maxdamage, float range)
  28 {
  29         TC(Sound, snd);
  30         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  31         float oldsolid = ent.dphitcontentsmask;
  32         if(!IS_CLIENT(ent))
  33                 antilag = false; // no antilag for non-clients!
  34         if (IS_PLAYER(ent) && (ent.(weaponentity).m_weapon.spawnflags & WEP_FLAG_PENETRATEWALLS))
  35                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  36         else
  37                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  38         if(antilag)
  39                 WarpZone_traceline_antilag(NULL, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  40                 // passing NULL, because we do NOT want it to touch dphitcontentsmask
  41         else
  42                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  43         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  44
  45         vector vf, vr, vu;
  46         vf = v_forward;
  47         vr = v_right;
  48         vu = v_up;
  49         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  50         v_forward = vf;
  51         v_right = vr;
  52         v_up = vu;
  53
  54         // un-adjust trueaim if shotend is too close
  55         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
  56                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  57
  58         // track max damage
  59         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
  60                 accuracy_add(ent, ent.(weaponentity).m_weapon.m_id, maxdamage, 0);
  61
  62         if(IS_PLAYER(ent))
  63                 W_HitPlotAnalysis(ent, weaponentity, v_forward, v_right, v_up);
  64
  65         vector md = ent.(weaponentity).movedir;
  66         vector vecs = ((md.x > 0) ? md : '0 0 0');
  67
  68         vector dv = v_right * -vecs.y + v_up * vecs.z;
  69         w_shotorg = ent.origin + ent.view_ofs + dv;
  70
  71         // now move the shotorg forward as much as requested if possible
  72         if(antilag)
  73         {
  74                 if(CS(ent).antilag_debug)
  75                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, CS(ent).antilag_debug);
  76                 else
  77                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  78         }
  79         else
  80                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
  81         w_shotorg = trace_endpos - v_forward * nudge;
  82         // calculate the shotdir from the chosen shotorg
  83         w_shotdir = normalize(w_shotend - w_shotorg);
  84
  85         //vector prevdir = w_shotdir;
  86         //vector prevorg = w_shotorg;
  87         //vector prevend = w_shotend;
  88
  89         if (antilag)
  90         if (!CS(ent).cvar_cl_noantilag)
  91         {
  92                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  93                 {
  94                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  95                         if (!trace_ent.takedamage)
  96                         {
  97                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  98                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
  99                                 {
 100                                         entity e;
 101                                         e = trace_ent;
 102                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 103                                         if(trace_ent == e)
 104                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 105                                 }
 106                         }
 107                 }
 108                 else if(autocvar_g_antilag == 3) // client side hitscan
 109                 {
 110                         // this part MUST use prydon cursor
 111                         if (CS(ent).cursor_trace_ent)                 // client was aiming at someone
 112                         if (CS(ent).cursor_trace_ent != ent)         // just to make sure
 113                         if (CS(ent).cursor_trace_ent.takedamage)      // and that person is killable
 114                         if (IS_PLAYER(CS(ent).cursor_trace_ent)) // and actually a player
 115                         {
 116                                 // verify that the shot would miss without antilag
 117                                 // (avoids an issue where guns would always shoot at their origin)
 118                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 119                                 if (!trace_ent.takedamage)
 120                                 {
 121                                         // verify that the shot would hit if altered
 122                                         traceline(w_shotorg, CS(ent).cursor_trace_ent.origin, MOVE_NORMAL, ent);
 123                                         if (trace_ent == CS(ent).cursor_trace_ent)
 124                                                 w_shotdir = normalize(CS(ent).cursor_trace_ent.origin - w_shotorg);
 125                                         else
 126                                                 LOG_INFO("antilag fail");
 127                                 }
 128                         }
 129                 }
 130         }
 131
 132         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 133
 134         if (!autocvar_g_norecoil)
 135                 ent.punchangle_x = recoil * -1;
 136
 137         if (snd != SND_Null) {
 138                 int held_weapons = 0; // HACK: muffle weapon sounds slightly while dual wielding!
 139                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 140                 {
 141                         .entity wep_ent = weaponentities[slot];
 142                         if(ent.(wep_ent) && ent.(wep_ent).m_switchweapon != WEP_Null)
 143                                 ++held_weapons;
 144                 }
 145                 sound (ent, chan, snd, ((held_weapons > 1) ? VOL_BASE * 0.7 : VOL_BASE), ATTN_NORM);
 146                 W_PlayStrengthSound(ent);
 147         }
 148
 149         // nudge w_shotend so a trace to w_shotend hits
 150         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 151         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 152         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 153         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 154 }
 155
 156 vector W_CalculateProjectileVelocity(entity actor, vector pvelocity, vector mvelocity, float forceAbsolute)
 157 {
 158         vector mdirection;
 159         float mspeed;
 160         vector outvelocity;
 161
 162         mvelocity = mvelocity * W_WeaponSpeedFactor(actor);
 163
 164         mdirection = normalize(mvelocity);
 165         mspeed = vlen(mvelocity);
 166
 167         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 168
 169         return outvelocity;
 170 }
 171
 172 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 173 {
 174         if(proj.owner == NULL)
 175                 error("Unowned missile");
 176
 177         dir = dir + upDir * (pUpSpeed / pSpeed);
 178         dir.z += pZSpeed / pSpeed;
 179         pSpeed *= vlen(dir);
 180         dir = normalize(dir);
 181
 182         #if 0
 183         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 184         {
 185                 mspercallsum = mspercallcount = 0;
 186                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 187         }
 188         mspercallsum -= gettime(GETTIME_HIRES);
 189         #endif
 190
 191         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 192
 193         #if 0
 194         mspercallsum += gettime(GETTIME_HIRES);
 195         mspercallcount += 1;
 196         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec");
 197         #endif
 198
 199         proj.velocity = W_CalculateProjectileVelocity(proj.owner, proj.owner.velocity, pSpeed * dir, forceAbsolute);
 200 }
 201
 202
 203 // ====================
 204 //  Ballistics Tracing
 205 // ====================
 206
 207 void FireRailgunBullet (entity this, .entity weaponentity, vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 208 {
 209         entity pseudoprojectile = NULL;
 210
 211         vector dir = normalize(end - start);
 212         float length = vlen(end - start);
 213         vector force = dir * bforce;
 214
 215         // go a little bit into the wall because we need to hit this wall later
 216         end = end + dir;
 217
 218         float totaldmg = 0;
 219
 220         // trace multiple times until we hit a wall, each obstacle will be made
 221         // non-solid so we can hit the next, while doing this we spawn effects and
 222         // note down which entities were hit so we can damage them later
 223         entity o = this;
 224         while (1)
 225         {
 226                 if(CS(this).antilag_debug)
 227                         WarpZone_traceline_antilag (this, start, end, false, o, CS(this).antilag_debug);
 228                 else
 229                         WarpZone_traceline_antilag (this, start, end, false, o, ANTILAG_LATENCY(this));
 230                 if(o && WarpZone_trace_firstzone)
 231                 {
 232                         o = NULL;
 233                         continue;
 234                 }
 235
 236                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 237                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, this);
 238
 239                 // if it is NULL we can't hurt it so stop now
 240                 if (trace_ent == NULL || trace_fraction == 1)
 241                         break;
 242
 243                 // make the entity non-solid so we can hit the next one
 244                 IL_PUSH(g_railgunhit, trace_ent);
 245                 trace_ent.railgunhit = true;
 246                 trace_ent.railgunhitloc = end;
 247                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 248                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 249                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 250
 251                 // stop if this is a wall
 252                 if (trace_ent.solid == SOLID_BSP)
 253                         break;
 254
 255                 // make the entity non-solid
 256                 trace_ent.solid = SOLID_NOT;
 257         }
 258
 259         vector endpoint = trace_endpos;
 260         entity endent = trace_ent;
 261         float endq3surfaceflags = trace_dphitq3surfaceflags;
 262
 263         // find all the entities the railgun hit and restore their solid state
 264         IL_EACH(g_railgunhit, it.railgunhit,
 265         {
 266                 it.solid = it.railgunhitsolidbackup;
 267         });
 268
 269         // spawn a temporary explosion entity for RadiusDamage calls
 270         //explosion = spawn();
 271
 272         // Find all non-hit players the beam passed close by
 273         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id)
 274         {
 275                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != this, {
 276                         if(!it.railgunhit)
 277                         if(!(IS_SPEC(it) && it.enemy == this))
 278                         {
 279                                 msg_entity = it;
 280                                 // nearest point on the beam
 281                                 vector beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 282
 283                                 float f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 284                                 if(f <= 0)
 285                                         continue;
 286
 287                                 if(!pseudoprojectile)
 288                                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 289                                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, SND(NEXWHOOSH_RANDOM()), VOL_BASE * f, ATTEN_NONE);
 290                         }
 291                 });
 292
 293                 if(pseudoprojectile)
 294                         delete(pseudoprojectile);
 295         }
 296
 297         // find all the entities the railgun hit and hurt them
 298         IL_EACH(g_railgunhit, it.railgunhit,
 299         {
 300                 // removal from the list is handled below
 301
 302                 // get the details we need to call the damage function
 303                 vector hitloc = it.railgunhitloc;
 304
 305                 float foff = ExponentialFalloff(mindist, maxdist, halflifedist, it.railgundistance);
 306                 float ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, it.railgundistance);
 307
 308                 if(accuracy_isgooddamage(this, it))
 309                         totaldmg += bdamage * foff;
 310
 311                 // apply the damage
 312                 if (it.takedamage)
 313                         Damage (it, this, this, bdamage * foff, deathtype, hitloc, it.railgunforce * ffs);
 314
 315                 // create a small explosion to throw gibs around (if applicable)
 316                 //setorigin(explosion, hitloc);
 317                 //RadiusDamage (explosion, this, 10, 0, 50, NULL, NULL, 300, deathtype);
 318
 319                 it.railgunhitloc = '0 0 0';
 320                 it.railgunhitsolidbackup = SOLID_NOT;
 321                 it.railgunhit = false;
 322                 it.railgundistance = 0;
 323         });
 324
 325         IL_CLEAR(g_railgunhit);
 326
 327         // calculate hits and fired shots for hitscan
 328         accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, min(bdamage, totaldmg));
 329
 330         trace_endpos = endpoint;
 331         trace_ent = endent;
 332         trace_dphitq3surfaceflags = endq3surfaceflags;
 333 }
 334
 335 void fireBullet_trace_callback(vector start, vector hit, vector end)
 336 {
 337         if(vdist(hit - start, >, 16))
 338                 trailparticles(NULL, fireBullet_trace_callback_eff, start, hit);
 339         WarpZone_trace_forent = NULL;
 340         fireBullet_last_hit = NULL;
 341 }
 342
 343 void fireBullet(entity this, .entity weaponentity, vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, int tracereffects)
 344 {
 345         vector  end;
 346
 347         dir = normalize(dir + randomvec() * spread);
 348         end = start + dir * max_shot_distance;
 349
 350         fireBullet_last_hit = NULL;
 351         float solid_penetration_left = 1;
 352         float total_damage = 0;
 353
 354         if(tracereffects & EF_RED)
 355                 fireBullet_trace_callback_eff = EFFECT_RIFLE;
 356         else if(tracereffects & EF_BLUE)
 357                 fireBullet_trace_callback_eff = EFFECT_RIFLE_WEAK;
 358         else
 359                 fireBullet_trace_callback_eff = EFFECT_BULLET;
 360
 361         float lag = ((IS_REAL_CLIENT(this)) ? ANTILAG_LATENCY(this) : 0);
 362         if(lag < 0.001)
 363                 lag = 0;
 364         bool noantilag = ((IS_CLIENT(this)) ? CS(this).cvar_cl_noantilag : false);
 365         if(autocvar_g_antilag == 0 || noantilag)
 366                 lag = 0; // only do hitscan, but no antilag
 367         if(lag)
 368                 antilag_takeback_all(this, lag);
 369
 370         // change shooter to SOLID_BBOX so the shot can hit corpses
 371         int oldsolid = this.dphitcontentsmask;
 372         if(this)
 373                 this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 374
 375         WarpZone_trace_forent = this;
 376
 377         for (;;)
 378         {
 379                 // TODO also show effect while tracing
 380                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, NULL, fireBullet_trace_callback);
 381                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 382                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 383                 start = trace_endpos;
 384                 entity hit = trace_ent;
 385
 386                 // traced up to max_shot_distance and didn't hit anything at all
 387                 if (trace_fraction == 1.0)
 388                         break;
 389
 390                 // When hitting sky, stop.
 391                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
 392                         break;
 393
 394                 // can't use noimpact, as we need to pass through walls
 395                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 396                         //break;
 397
 398                 // if we hit "weapclip", bail out
 399                 //
 400                 // rationale of this check:
 401                 //
 402                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 403                 // shots and players, but has no other effect!
 404                 //
 405                 // if it is not trans, it is caulk and should not have this side effect
 406                 //
 407                 // matching shaders:
 408                 //   common/weapclip (intended)
 409                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 410                 bool is_weapclip = false;
 411                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 412                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 413                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 414                         is_weapclip = true;
 415
 416                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 417                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, this);
 418
 419                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 420                 {
 421                         fireBullet_last_hit = hit;
 422                         yoda = 0;
 423                         MUTATOR_CALLHOOK(FireBullet_Hit, this, hit, start, end, damage, this.(weaponentity));
 424                         damage = M_ARGV(4, float);
 425                         float g = accuracy_isgooddamage(this, hit);
 426                         Damage(hit, this, this, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
 427                         // calculate hits for ballistic weapons
 428                         if(g)
 429                         {
 430                                 // do not exceed 100%
 431                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 432                                 total_damage += damage * solid_penetration_left;
 433                                 accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, added_damage);
 434                         }
 435                 }
 436
 437                 if (is_weapclip && !autocvar_g_ballistics_penetrate_clips)
 438                         break;
 439
 440                 // go through solid!
 441                 // outside the world? forget it
 442                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 443                         break;
 444
 445                 float maxdist;
 446                 entity hitstore = IS_PLAYER(hit) ? PS(hit) : hit;
 447                 if(max_solid_penetration < 0)
 448                         break;
 449                 else if(hitstore.ballistics_density < -1)
 450                         break; // -2: no solid penetration, ever
 451                 else if(hitstore.ballistics_density < 0)
 452                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 453                 else if(hitstore.ballistics_density == 0)
 454                         maxdist = max_solid_penetration * solid_penetration_left;
 455                 else
 456                         maxdist = max_solid_penetration * solid_penetration_left * hitstore.ballistics_density;
 457
 458                 if(maxdist <= autocvar_g_ballistics_mindistance)
 459                         break;
 460
 461                 // move the entity along its velocity until it's out of solid, then let it resume
 462                 // The previously hit entity is ignored here!
 463                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 464                 if(trace_fraction == 1) // 1: we never got out of solid
 465                         break;
 466
 467                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 468                 // fraction_used_of_what_is_left = dist_taken / maxdist
 469                 // solid_penetration_left = solid_penetration_left - solid_penetration_left * fraction_used_of_what_is_left
 470                 solid_penetration_left *= 1 - dist_taken / maxdist;
 471                 solid_penetration_left = max(solid_penetration_left, 0);
 472
 473                 // Only show effect when going through a player (invisible otherwise)
 474                 if (hit && (hit.solid != SOLID_BSP))
 475                         if(vdist(trace_endpos - start, >, 4))
 476                                 trailparticles(this, fireBullet_trace_callback_eff, start, trace_endpos);
 477
 478                 start = trace_endpos;
 479
 480                 if(hit.solid == SOLID_BSP)
 481                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, this);
 482         }
 483
 484         if(lag)
 485                 antilag_restore_all(this);
 486
 487         // restore shooter solid type
 488         if(this)
 489                 this.dphitcontentsmask = oldsolid;
 490 }