qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include "accuracy.qh"
   4 #include "common.qh"
   5 #include "hitplot.qh"
   6 #include "weaponsystem.qh"
   7
   8 #include "../g_damage.qh"
   9 #include "../g_subs.qh"
  10 #include "../antilag.qh"
  11
  12 #include "../../common/constants.qh"
  13 #include "../../common/util.qh"
  14
  15 #include "../../common/weapons/all.qh"
  16
  17 #include "../../lib/warpzone/common.qh"
  18
  19 // this function calculates w_shotorg and w_shotdir based on the weapon model
  20 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  21 // make sure you call makevectors first (FIXME?)
  22 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
  23 {
  24         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  25         float oldsolid;
  26         vector vecs, dv;
  27         oldsolid = ent.dphitcontentsmask;
  28         if(ent.weapon == WEP_RIFLE.m_id)
  29                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  30         else
  31                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  32         if(antilag)
  33                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  34                 // passing world, because we do NOT want it to touch dphitcontentsmask
  35         else
  36                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  37         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  38
  39         vector vf, vr, vu;
  40         vf = v_forward;
  41         vr = v_right;
  42         vu = v_up;
  43         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  44         v_forward = vf;
  45         v_right = vr;
  46         v_up = vu;
  47
  48         // un-adjust trueaim if shotend is too close
  49         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
  50                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  51
  52         // track max damage
  53         if(accuracy_canbegooddamage(ent))
  54                 accuracy_add(ent, ent.weapon, maxdamage, 0);
  55
  56         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
  57
  58         int slot = 0; // TODO: unhardcode
  59         if(ent.weaponentity[slot].movedir.x > 0)
  60                 vecs = ent.weaponentity[slot].movedir;
  61         else
  62                 vecs = '0 0 0';
  63
  64         dv = v_right * -vecs.y + v_up * vecs.z;
  65         w_shotorg = ent.origin + ent.view_ofs + dv;
  66
  67         // now move the shotorg forward as much as requested if possible
  68         if(antilag)
  69         {
  70                 if(ent.antilag_debug)
  71                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
  72                 else
  73                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  74         }
  75         else
  76                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
  77         w_shotorg = trace_endpos - v_forward * nudge;
  78         // calculate the shotdir from the chosen shotorg
  79         w_shotdir = normalize(w_shotend - w_shotorg);
  80
  81         //vector prevdir = w_shotdir;
  82         //vector prevorg = w_shotorg;
  83         //vector prevend = w_shotend;
  84
  85         if (antilag)
  86         if (!ent.cvar_cl_noantilag)
  87         {
  88                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  89                 {
  90                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  91                         if (!trace_ent.takedamage)
  92                         {
  93                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  94                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
  95                                 {
  96                                         entity e;
  97                                         e = trace_ent;
  98                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
  99                                         if(trace_ent == e)
 100                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 101                                 }
 102                         }
 103                 }
 104                 else if(autocvar_g_antilag == 3) // client side hitscan
 105                 {
 106                         // this part MUST use prydon cursor
 107                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 108                         if (ent.cursor_trace_ent != ent)         // just to make sure
 109                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 110                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
 111                         {
 112                                 // verify that the shot would miss without antilag
 113                                 // (avoids an issue where guns would always shoot at their origin)
 114                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 115                                 if (!trace_ent.takedamage)
 116                                 {
 117                                         // verify that the shot would hit if altered
 118                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 119                                         if (trace_ent == ent.cursor_trace_ent)
 120                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 121                                         else
 122                                                 LOG_INFO("antilag fail\n");
 123                                 }
 124                         }
 125                 }
 126         }
 127
 128         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 129
 130         if (!autocvar_g_norecoil)
 131                 ent.punchangle_x = recoil * -1;
 132
 133         if (snd != "")
 134         {
 135                 _sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 136                 W_PlayStrengthSound(ent);
 137         }
 138
 139         // nudge w_shotend so a trace to w_shotend hits
 140         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 141         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 142         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 143         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 144 }
 145
 146 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
 147 {
 148         vector mdirection;
 149         float mspeed;
 150         vector outvelocity;
 151
 152         mvelocity = mvelocity * W_WeaponSpeedFactor();
 153
 154         mdirection = normalize(mvelocity);
 155         mspeed = vlen(mvelocity);
 156
 157         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 158
 159         return outvelocity;
 160 }
 161
 162 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 163 {
 164         if(proj.owner == world)
 165                 error("Unowned missile");
 166
 167         dir = dir + upDir * (pUpSpeed / pSpeed);
 168         dir.z += pZSpeed / pSpeed;
 169         pSpeed *= vlen(dir);
 170         dir = normalize(dir);
 171
 172         #if 0
 173         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 174         {
 175                 mspercallsum = mspercallcount = 0;
 176                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 177         }
 178         mspercallsum -= gettime(GETTIME_HIRES);
 179         #endif
 180
 181         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 182
 183         #if 0
 184         mspercallsum += gettime(GETTIME_HIRES);
 185         mspercallcount += 1;
 186         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
 187         #endif
 188
 189         proj.velocity = W_CalculateProjectileVelocity(proj.owner.velocity, pSpeed * dir, forceAbsolute);
 190 }
 191
 192
 193 // ====================
 194 //  Ballistics Tracing
 195 // ====================
 196
 197 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 198 {SELFPARAM();
 199         vector hitloc, force, endpoint, dir;
 200         entity ent, endent;
 201         float endq3surfaceflags;
 202         float totaldmg;
 203         entity o;
 204
 205         float length;
 206         vector beampos;
 207         string snd;
 208         entity pseudoprojectile;
 209         float f, ffs;
 210
 211         pseudoprojectile = world;
 212
 213         dir = normalize(end - start);
 214         length = vlen(end - start);
 215         force = dir * bforce;
 216
 217         // go a little bit into the wall because we need to hit this wall later
 218         end = end + dir;
 219
 220         totaldmg = 0;
 221
 222         // trace multiple times until we hit a wall, each obstacle will be made
 223         // non-solid so we can hit the next, while doing this we spawn effects and
 224         // note down which entities were hit so we can damage them later
 225         o = self;
 226         while (1)
 227         {
 228                 if(self.antilag_debug)
 229                         WarpZone_traceline_antilag (self, start, end, false, o, self.antilag_debug);
 230                 else
 231                         WarpZone_traceline_antilag (self, start, end, false, o, ANTILAG_LATENCY(self));
 232                 if(o && WarpZone_trace_firstzone)
 233                 {
 234                         o = world;
 235                         continue;
 236                 }
 237
 238                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 239                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, self);
 240
 241                 // if it is world we can't hurt it so stop now
 242                 if (trace_ent == world || trace_fraction == 1)
 243                         break;
 244
 245                 // make the entity non-solid so we can hit the next one
 246                 trace_ent.railgunhit = true;
 247                 trace_ent.railgunhitloc = end;
 248                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 249                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 250                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 251
 252                 // stop if this is a wall
 253                 if (trace_ent.solid == SOLID_BSP)
 254                         break;
 255
 256                 // make the entity non-solid
 257                 trace_ent.solid = SOLID_NOT;
 258         }
 259
 260         endpoint = trace_endpos;
 261         endent = trace_ent;
 262         endq3surfaceflags = trace_dphitq3surfaceflags;
 263
 264         // find all the entities the railgun hit and restore their solid state
 265         ent = findfloat(world, railgunhit, true);
 266         while (ent)
 267         {
 268                 // restore their solid type
 269                 ent.solid = ent.railgunhitsolidbackup;
 270                 ent = findfloat(ent, railgunhit, true);
 271         }
 272
 273         // spawn a temporary explosion entity for RadiusDamage calls
 274         //explosion = spawn();
 275
 276         // Find all non-hit players the beam passed close by
 277         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id)
 278         {
 279                 FOR_EACH_REALCLIENT(msg_entity)
 280                 if(msg_entity != self)
 281                 if(!msg_entity.railgunhit)
 282                 if(!(IS_SPEC(msg_entity) && msg_entity.enemy == self)) // we use realclient, so spectators can hear the whoosh too
 283                 {
 284                         // nearest point on the beam
 285                         beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 286
 287                         f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 288                         if(f <= 0)
 289                                 continue;
 290
 291                         snd = SND(NEXWHOOSH_RANDOM());
 292
 293                         if(!pseudoprojectile)
 294                                 pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 295                         soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, snd, VOL_BASE * f, ATTEN_NONE);
 296                 }
 297
 298                 if(pseudoprojectile)
 299                         remove(pseudoprojectile);
 300         }
 301
 302         // find all the entities the railgun hit and hurt them
 303         ent = findfloat(world, railgunhit, true);
 304         while (ent)
 305         {
 306                 // get the details we need to call the damage function
 307                 hitloc = ent.railgunhitloc;
 308
 309                 f = ExponentialFalloff(mindist, maxdist, halflifedist, ent.railgundistance);
 310                 ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, ent.railgundistance);
 311
 312                 if(accuracy_isgooddamage(self, ent))
 313                         totaldmg += bdamage * f;
 314
 315                 // apply the damage
 316                 if (ent.takedamage)
 317                         Damage (ent, self, self, bdamage * f, deathtype, hitloc, ent.railgunforce * ffs);
 318
 319                 // create a small explosion to throw gibs around (if applicable)
 320                 //setorigin (explosion, hitloc);
 321                 //RadiusDamage (explosion, self, 10, 0, 50, world, world, 300, deathtype);
 322
 323                 ent.railgunhitloc = '0 0 0';
 324                 ent.railgunhitsolidbackup = SOLID_NOT;
 325                 ent.railgunhit = false;
 326                 ent.railgundistance = 0;
 327
 328                 // advance to the next entity
 329                 ent = findfloat(ent, railgunhit, true);
 330         }
 331
 332         // calculate hits and fired shots for hitscan
 333         accuracy_add(self, self.weapon, 0, min(bdamage, totaldmg));
 334
 335         trace_endpos = endpoint;
 336         trace_ent = endent;
 337         trace_dphitq3surfaceflags = endq3surfaceflags;
 338 }
 339
 340 void fireBullet_trace_callback(vector start, vector hit, vector end)
 341 {
 342         if(vlen(hit - start) > 16)
 343                 trailparticles(world, fireBullet_trace_callback_eff, start, hit);
 344         WarpZone_trace_forent = world;
 345         fireBullet_last_hit = world;
 346 }
 347
 348 void fireBullet(vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, int tracereffects)
 349 {SELFPARAM();
 350         vector  end;
 351
 352         dir = normalize(dir + randomvec() * spread);
 353         end = start + dir * MAX_SHOT_DISTANCE;
 354
 355         entity pl;
 356         fireBullet_last_hit = world;
 357         float solid_penetration_left = 1;
 358         float total_damage = 0;
 359
 360         if(tracereffects & EF_RED)
 361                 fireBullet_trace_callback_eff = particleeffectnum(EFFECT_RIFLE);
 362         else if(tracereffects & EF_BLUE)
 363                 fireBullet_trace_callback_eff = particleeffectnum(EFFECT_RIFLE_WEAK);
 364         else
 365                 fireBullet_trace_callback_eff = particleeffectnum(EFFECT_BULLET);
 366
 367         float lag = ANTILAG_LATENCY(self);
 368         if(lag < 0.001)
 369                 lag = 0;
 370         if (!IS_REAL_CLIENT(self))
 371                 lag = 0;
 372         if(autocvar_g_antilag == 0 || self.cvar_cl_noantilag)
 373                 lag = 0; // only do hitscan, but no antilag
 374         if(lag)
 375         {
 376                 FOR_EACH_PLAYER(pl)
 377                         if(pl != self)
 378                                 antilag_takeback(pl, time - lag);
 379                 FOR_EACH_MONSTER(pl)
 380                         antilag_takeback(pl, time - lag);
 381         }
 382
 383         WarpZone_trace_forent = self;
 384
 385         for (;;)
 386         {
 387                 // TODO also show effect while tracing
 388                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, world, fireBullet_trace_callback);
 389                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 390                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 391                 start = trace_endpos;
 392                 entity hit = trace_ent;
 393
 394                 // When hitting sky, stop.
 395                 if (pointcontents(start) == CONTENT_SKY)
 396                         break;
 397
 398                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 399                         break;
 400
 401                 // if we hit "weapclip", bail out
 402                 //
 403                 // rationale of this check:
 404                 //
 405                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 406                 // shots and players, but has no other effect!
 407                 //
 408                 // if it is not trans, it is caulk and should not have this side effect
 409                 //
 410                 // matching shaders:
 411                 //   common/weapclip (intended)
 412                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 413                 float is_weapclip = 0;
 414                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 415                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 416                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 417                         is_weapclip = 1;
 418
 419                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 420                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, self);
 421
 422                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 423                 {
 424                         fireBullet_last_hit = hit;
 425                         yoda = 0;
 426                         MUTATOR_CALLHOOK(FireBullet_Hit, self, hit, start, end, damage);
 427                         damage = frag_damage;
 428                         float g = accuracy_isgooddamage(self, hit);
 429                         Damage(hit, self, self, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
 430                         // calculate hits for ballistic weapons
 431                         if(g)
 432                         {
 433                                 // do not exceed 100%
 434                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 435                                 total_damage += damage * solid_penetration_left;
 436                                 accuracy_add(self, self.weapon, 0, added_damage);
 437                         }
 438                 }
 439
 440                 if (is_weapclip)
 441                         break;
 442
 443                 // go through solid!
 444                 // outside the world? forget it
 445                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 446                         break;
 447
 448                 float maxdist;
 449                 if(max_solid_penetration < 0)
 450                         break;
 451                 else if(hit.ballistics_density < -1)
 452                         break; // -2: no solid penetration, ever
 453                 else if(hit.ballistics_density < 0)
 454                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 455                 else if(hit.ballistics_density == 0)
 456                         maxdist = max_solid_penetration * solid_penetration_left;
 457                 else
 458                         maxdist = max_solid_penetration * solid_penetration_left * hit.ballistics_density;
 459
 460                 if(maxdist <= autocvar_g_ballistics_mindistance)
 461                         break;
 462
 463                 // move the entity along its velocity until it's out of solid, then let it resume
 464                 // The previously hit entity is ignored here!
 465                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 466                 if(trace_fraction == 1) // 1: we never got out of solid
 467                         break;
 468
 469                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 470                 solid_penetration_left *= (dist_taken / maxdist);
 471
 472                 // Only show effect when going through a player (invisible otherwise)
 473                 if (hit && (hit.solid != SOLID_BSP))
 474                         if(vlen(trace_endpos - start) > 4)
 475                                 trailparticles(self, fireBullet_trace_callback_eff, start, trace_endpos);
 476
 477                 start = trace_endpos;
 478
 479                 if(hit.solid == SOLID_BSP)
 480                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, self);
 481         }
 482
 483         if(lag)
 484         {
 485                 FOR_EACH_PLAYER(pl)
 486                         if(pl != self)
 487                                 antilag_restore(pl);
 488                 FOR_EACH_MONSTER(pl)
 489                         antilag_restore(pl);
 490         }
 491 }