qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include "accuracy.qh"
   4 #include "common.qh"
   5 #include "hitplot.qh"
   6 #include "weaponsystem.qh"
   7
   8 #include "../g_damage.qh"
   9 #include "../g_subs.qh"
  10 #include "../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/util.qh>
  14
  15 #include <common/weapons/all.qh>
  16
  17 #include <lib/warpzone/common.qh>
  18
  19 // this function calculates w_shotorg and w_shotdir based on the weapon model
  20 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  21 // make sure you call makevectors first (FIXME?)
  22 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
  23 {
  24         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  25         float oldsolid;
  26         vector vecs, dv;
  27         oldsolid = ent.dphitcontentsmask;
  28         if (IS_PLAYER(ent) && PS(ent).m_weapon == WEP_RIFLE)
  29                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  30         else
  31                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  32         if(antilag)
  33                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  34                 // passing world, because we do NOT want it to touch dphitcontentsmask
  35         else
  36                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  37         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  38
  39         vector vf, vr, vu;
  40         vf = v_forward;
  41         vr = v_right;
  42         vu = v_up;
  43         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  44         v_forward = vf;
  45         v_right = vr;
  46         v_up = vu;
  47
  48         // un-adjust trueaim if shotend is too close
  49         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
  50                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  51
  52         // track max damage
  53         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
  54                 accuracy_add(ent, PS(ent).m_weapon.m_id, maxdamage, 0);
  55
  56         if(IS_PLAYER(ent))
  57                 W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
  58
  59         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
  60         vector md = ent.(weaponentity).movedir;
  61         if(md.x > 0)
  62                 vecs = md;
  63         else
  64                 vecs = '0 0 0';
  65
  66         dv = v_right * -vecs.y + v_up * vecs.z;
  67         w_shotorg = ent.origin + ent.view_ofs + dv;
  68
  69         // now move the shotorg forward as much as requested if possible
  70         if(antilag)
  71         {
  72                 if(CS(ent).antilag_debug)
  73                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, CS(ent).antilag_debug);
  74                 else
  75                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  76         }
  77         else
  78                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
  79         w_shotorg = trace_endpos - v_forward * nudge;
  80         // calculate the shotdir from the chosen shotorg
  81         w_shotdir = normalize(w_shotend - w_shotorg);
  82
  83         //vector prevdir = w_shotdir;
  84         //vector prevorg = w_shotorg;
  85         //vector prevend = w_shotend;
  86
  87         if (antilag)
  88         if (!ent.cvar_cl_noantilag)
  89         {
  90                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  91                 {
  92                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  93                         if (!trace_ent.takedamage)
  94                         {
  95                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  96                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
  97                                 {
  98                                         entity e;
  99                                         e = trace_ent;
 100                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 101                                         if(trace_ent == e)
 102                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 103                                 }
 104                         }
 105                 }
 106                 else if(autocvar_g_antilag == 3) // client side hitscan
 107                 {
 108                         // this part MUST use prydon cursor
 109                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 110                         if (ent.cursor_trace_ent != ent)         // just to make sure
 111                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 112                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
 113                         {
 114                                 // verify that the shot would miss without antilag
 115                                 // (avoids an issue where guns would always shoot at their origin)
 116                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 117                                 if (!trace_ent.takedamage)
 118                                 {
 119                                         // verify that the shot would hit if altered
 120                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 121                                         if (trace_ent == ent.cursor_trace_ent)
 122                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 123                                         else
 124                                                 LOG_INFO("antilag fail\n");
 125                                 }
 126                         }
 127                 }
 128         }
 129
 130         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 131
 132         if (!autocvar_g_norecoil)
 133                 ent.punchangle_x = recoil * -1;
 134
 135         if (snd != "")
 136         {
 137                 _sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 138                 W_PlayStrengthSound(ent);
 139         }
 140
 141         // nudge w_shotend so a trace to w_shotend hits
 142         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 143         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 144         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 145         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 146 }
 147
 148 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
 149 {
 150         vector mdirection;
 151         float mspeed;
 152         vector outvelocity;
 153
 154         mvelocity = mvelocity * W_WeaponSpeedFactor();
 155
 156         mdirection = normalize(mvelocity);
 157         mspeed = vlen(mvelocity);
 158
 159         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 160
 161         return outvelocity;
 162 }
 163
 164 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 165 {
 166         if(proj.owner == world)
 167                 error("Unowned missile");
 168
 169         dir = dir + upDir * (pUpSpeed / pSpeed);
 170         dir.z += pZSpeed / pSpeed;
 171         pSpeed *= vlen(dir);
 172         dir = normalize(dir);
 173
 174         #if 0
 175         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 176         {
 177                 mspercallsum = mspercallcount = 0;
 178                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 179         }
 180         mspercallsum -= gettime(GETTIME_HIRES);
 181         #endif
 182
 183         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 184
 185         #if 0
 186         mspercallsum += gettime(GETTIME_HIRES);
 187         mspercallcount += 1;
 188         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
 189         #endif
 190
 191         proj.velocity = W_CalculateProjectileVelocity(proj.owner.velocity, pSpeed * dir, forceAbsolute);
 192 }
 193
 194
 195 // ====================
 196 //  Ballistics Tracing
 197 // ====================
 198
 199 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 200 {SELFPARAM();
 201         vector hitloc, force, endpoint, dir;
 202         entity ent, endent;
 203         float endq3surfaceflags;
 204         float totaldmg;
 205         entity o;
 206
 207         float length;
 208         vector beampos;
 209         string snd;
 210         entity pseudoprojectile;
 211         float f, ffs;
 212
 213         pseudoprojectile = world;
 214
 215         dir = normalize(end - start);
 216         length = vlen(end - start);
 217         force = dir * bforce;
 218
 219         // go a little bit into the wall because we need to hit this wall later
 220         end = end + dir;
 221
 222         totaldmg = 0;
 223
 224         // trace multiple times until we hit a wall, each obstacle will be made
 225         // non-solid so we can hit the next, while doing this we spawn effects and
 226         // note down which entities were hit so we can damage them later
 227         o = self;
 228         while (1)
 229         {
 230                 if(CS(self).antilag_debug)
 231                         WarpZone_traceline_antilag (self, start, end, false, o, CS(self).antilag_debug);
 232                 else
 233                         WarpZone_traceline_antilag (self, start, end, false, o, ANTILAG_LATENCY(self));
 234                 if(o && WarpZone_trace_firstzone)
 235                 {
 236                         o = world;
 237                         continue;
 238                 }
 239
 240                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 241                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, self);
 242
 243                 // if it is world we can't hurt it so stop now
 244                 if (trace_ent == world || trace_fraction == 1)
 245                         break;
 246
 247                 // make the entity non-solid so we can hit the next one
 248                 trace_ent.railgunhit = true;
 249                 trace_ent.railgunhitloc = end;
 250                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 251                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 252                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 253
 254                 // stop if this is a wall
 255                 if (trace_ent.solid == SOLID_BSP)
 256                         break;
 257
 258                 // make the entity non-solid
 259                 trace_ent.solid = SOLID_NOT;
 260         }
 261
 262         endpoint = trace_endpos;
 263         endent = trace_ent;
 264         endq3surfaceflags = trace_dphitq3surfaceflags;
 265
 266         // find all the entities the railgun hit and restore their solid state
 267         ent = findfloat(world, railgunhit, true);
 268         while (ent)
 269         {
 270                 // restore their solid type
 271                 ent.solid = ent.railgunhitsolidbackup;
 272                 ent = findfloat(ent, railgunhit, true);
 273         }
 274
 275         // spawn a temporary explosion entity for RadiusDamage calls
 276         //explosion = spawn();
 277
 278         // Find all non-hit players the beam passed close by
 279         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id)
 280         {
 281                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != self, LAMBDA(
 282                         if(!it.railgunhit)
 283                         if(!(IS_SPEC(it) && it.enemy == self))
 284                         {
 285                                 msg_entity = it;
 286                                 // nearest point on the beam
 287                                 beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 288
 289                                 f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 290                                 if(f <= 0)
 291                                         continue;
 292
 293                                 snd = SND(NEXWHOOSH_RANDOM());
 294
 295                                 if(!pseudoprojectile)
 296                                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 297                                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, snd, VOL_BASE * f, ATTEN_NONE);
 298                         }
 299                 ));
 300
 301                 if(pseudoprojectile)
 302                         remove(pseudoprojectile);
 303         }
 304
 305         // find all the entities the railgun hit and hurt them
 306         ent = findfloat(world, railgunhit, true);
 307         while (ent)
 308         {
 309                 // get the details we need to call the damage function
 310                 hitloc = ent.railgunhitloc;
 311
 312                 f = ExponentialFalloff(mindist, maxdist, halflifedist, ent.railgundistance);
 313                 ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, ent.railgundistance);
 314
 315                 if(accuracy_isgooddamage(self, ent))
 316                         totaldmg += bdamage * f;
 317
 318                 // apply the damage
 319                 if (ent.takedamage)
 320                         Damage (ent, self, self, bdamage * f, deathtype, hitloc, ent.railgunforce * ffs);
 321
 322                 // create a small explosion to throw gibs around (if applicable)
 323                 //setorigin (explosion, hitloc);
 324                 //RadiusDamage (explosion, self, 10, 0, 50, world, world, 300, deathtype);
 325
 326                 ent.railgunhitloc = '0 0 0';
 327                 ent.railgunhitsolidbackup = SOLID_NOT;
 328                 ent.railgunhit = false;
 329                 ent.railgundistance = 0;
 330
 331                 // advance to the next entity
 332                 ent = findfloat(ent, railgunhit, true);
 333         }
 334
 335         // calculate hits and fired shots for hitscan
 336         accuracy_add(self, PS(self).m_weapon.m_id, 0, min(bdamage, totaldmg));
 337
 338         trace_endpos = endpoint;
 339         trace_ent = endent;
 340         trace_dphitq3surfaceflags = endq3surfaceflags;
 341 }
 342
 343 void fireBullet_trace_callback(vector start, vector hit, vector end)
 344 {
 345         if(vdist(hit - start, >, 16))
 346                 trailparticles(world, fireBullet_trace_callback_eff, start, hit);
 347         WarpZone_trace_forent = world;
 348         fireBullet_last_hit = world;
 349 }
 350
 351 void fireBullet(vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, int tracereffects)
 352 {SELFPARAM();
 353         vector  end;
 354
 355         dir = normalize(dir + randomvec() * spread);
 356         end = start + dir * MAX_SHOT_DISTANCE;
 357
 358         fireBullet_last_hit = world;
 359         float solid_penetration_left = 1;
 360         float total_damage = 0;
 361
 362         if(tracereffects & EF_RED)
 363                 fireBullet_trace_callback_eff = EFFECT_RIFLE;
 364         else if(tracereffects & EF_BLUE)
 365                 fireBullet_trace_callback_eff = EFFECT_RIFLE_WEAK;
 366         else
 367                 fireBullet_trace_callback_eff = EFFECT_BULLET;
 368
 369         float lag = ANTILAG_LATENCY(self);
 370         if(lag < 0.001)
 371                 lag = 0;
 372         if (!IS_REAL_CLIENT(self))
 373                 lag = 0;
 374         if(autocvar_g_antilag == 0 || self.cvar_cl_noantilag)
 375                 lag = 0; // only do hitscan, but no antilag
 376         if(lag)
 377         {
 378                 FOREACH_CLIENT(IS_PLAYER(it) && it != self, LAMBDA(antilag_takeback(it, time - lag)));
 379                 FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
 380                         if(it != self)
 381                                 antilag_takeback(it, time - lag);
 382                 ));
 383         }
 384
 385         // change shooter to SOLID_BBOX so the shot can hit corpses
 386         int oldsolid = self.dphitcontentsmask;
 387         if(self)
 388                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 389
 390         WarpZone_trace_forent = self;
 391
 392         for (;;)
 393         {
 394                 // TODO also show effect while tracing
 395                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, world, fireBullet_trace_callback);
 396                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 397                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 398                 start = trace_endpos;
 399                 entity hit = trace_ent;
 400
 401                 // When hitting sky, stop.
 402                 if (pointcontents(start) == CONTENT_SKY)
 403                         break;
 404
 405                 // can't use noimpact, as we need to pass through walls
 406                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 407                         //break;
 408
 409                 // if we hit "weapclip", bail out
 410                 //
 411                 // rationale of this check:
 412                 //
 413                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 414                 // shots and players, but has no other effect!
 415                 //
 416                 // if it is not trans, it is caulk and should not have this side effect
 417                 //
 418                 // matching shaders:
 419                 //   common/weapclip (intended)
 420                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 421                 bool is_weapclip = false;
 422                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 423                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 424                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 425                         is_weapclip = true;
 426
 427                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 428                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, self);
 429
 430                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 431                 {
 432                         fireBullet_last_hit = hit;
 433                         yoda = 0;
 434                         MUTATOR_CALLHOOK(FireBullet_Hit, self, hit, start, end, damage);
 435                         damage = frag_damage;
 436                         float g = accuracy_isgooddamage(self, hit);
 437                         Damage(hit, self, self, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
 438                         // calculate hits for ballistic weapons
 439                         if(g)
 440                         {
 441                                 // do not exceed 100%
 442                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 443                                 total_damage += damage * solid_penetration_left;
 444                                 accuracy_add(self, PS(self).m_weapon.m_id, 0, added_damage);
 445                         }
 446                 }
 447
 448                 if (is_weapclip)
 449                         break;
 450
 451                 // go through solid!
 452                 // outside the world? forget it
 453                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 454                         break;
 455
 456                 float maxdist;
 457                 if(max_solid_penetration < 0)
 458                         break;
 459                 else if(hit.ballistics_density < -1)
 460                         break; // -2: no solid penetration, ever
 461                 else if(hit.ballistics_density < 0)
 462                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 463                 else if(hit.ballistics_density == 0)
 464                         maxdist = max_solid_penetration * solid_penetration_left;
 465                 else
 466                         maxdist = max_solid_penetration * solid_penetration_left * hit.ballistics_density;
 467
 468                 if(maxdist <= autocvar_g_ballistics_mindistance)
 469                         break;
 470
 471                 // move the entity along its velocity until it's out of solid, then let it resume
 472                 // The previously hit entity is ignored here!
 473                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 474                 if(trace_fraction == 1) // 1: we never got out of solid
 475                         break;
 476
 477                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 478                 solid_penetration_left *= (dist_taken / maxdist);
 479
 480                 // Only show effect when going through a player (invisible otherwise)
 481                 if (hit && (hit.solid != SOLID_BSP))
 482                         if(vdist(trace_endpos - start, >, 4))
 483                                 trailparticles(self, fireBullet_trace_callback_eff, start, trace_endpos);
 484
 485                 start = trace_endpos;
 486
 487                 if(hit.solid == SOLID_BSP)
 488                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, self);
 489         }
 490
 491         if(lag)
 492         {
 493                 FOREACH_CLIENT(IS_PLAYER(it) && it != self, LAMBDA(antilag_restore(it)));
 494                 FOREACH_ENTITY_FLAGS(flags, FL_MONSTER, LAMBDA(
 495                         if(it != self)
 496                                 antilag_restore(it);
 497                 ));
 498         }
 499
 500         // restore shooter solid type
 501         if(self)
 502                 self.dphitcontentsmask = oldsolid;
 503 }