qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include <common/effects/all.qh>
   4
   5 #include "accuracy.qh"
   6 #include "common.qh"
   7 #include "hitplot.qh"
   8 #include "weaponsystem.qh"
   9
  10 #include "../g_damage.qh"
  11 #include "../antilag.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/net_linked.qh>
  15 #include <common/util.qh>
  16
  17 #include <common/weapons/_all.qh>
  18 #include <common/wepent.qh>
  19 #include <common/state.qh>
  20
  21 #include <lib/warpzone/common.qh>
  22
  23 // this function calculates w_shotorg and w_shotdir based on the weapon model
  24 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  25 // make sure you call makevectors first (FIXME?)
  26 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, .entity weaponentity, vector s_forward, vector mi, vector ma, float antilag, float recoil, Sound snd, float chan, float maxdamage, float range, int deathtype)
  27 {
  28         TC(Sound, snd);
  29         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  30         float oldsolid = ent.dphitcontentsmask;
  31         Weapon wep = DEATH_WEAPONOF(deathtype);
  32         if(!IS_CLIENT(ent))
  33                 antilag = false; // no antilag for non-clients!
  34         if (IS_PLAYER(ent) && (wep.spawnflags & WEP_FLAG_PENETRATEWALLS))
  35                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  36         else
  37                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  38         if(antilag)
  39                 WarpZone_traceline_antilag(NULL, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  40                 // passing NULL, because we do NOT want it to touch dphitcontentsmask
  41         else
  42                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  43         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  44
  45         vector vf, vr, vu;
  46         vf = v_forward;
  47         vr = v_right;
  48         vu = v_up;
  49         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  50         v_forward = vf;
  51         v_right = vr;
  52         v_up = vu;
  53
  54         // un-adjust trueaim if shotend is too close
  55         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
  56                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  57
  58         // track max damage
  59         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
  60                 accuracy_add(ent, wep.m_id, maxdamage, 0);
  61
  62         if(IS_PLAYER(ent))
  63                 W_HitPlotAnalysis(ent, wep, v_forward, v_right, v_up);
  64
  65         vector md = ent.(weaponentity).movedir;
  66         vector vecs = ((md.x > 0) ? md : '0 0 0');
  67
  68         vector dv = v_right * -vecs.y + v_up * vecs.z;
  69         w_shotorg = ent.origin + ent.view_ofs + dv;
  70
  71         // now move the shotorg forward as much as requested if possible
  72         if(antilag)
  73         {
  74                 if(CS(ent).antilag_debug)
  75                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, CS(ent).antilag_debug);
  76                 else
  77                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  78         }
  79         else
  80                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
  81         w_shotorg = trace_endpos - v_forward * nudge;
  82         // calculate the shotdir from the chosen shotorg
  83         if(W_DualWielding(ent))
  84                 w_shotdir = s_forward;
  85         else
  86                 w_shotdir = normalize(w_shotend - w_shotorg);
  87
  88         //vector prevdir = w_shotdir;
  89         //vector prevorg = w_shotorg;
  90         //vector prevend = w_shotend;
  91
  92         if (antilag)
  93         if (!CS(ent).cvar_cl_noantilag)
  94         {
  95                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  96                 {
  97                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  98                         if (!trace_ent.takedamage)
  99                         {
 100                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 101                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
 102                                 {
 103                                         entity e;
 104                                         e = trace_ent;
 105                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 106                                         if(trace_ent == e)
 107                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 108                                 }
 109                         }
 110                 }
 111                 else if(autocvar_g_antilag == 3) // client side hitscan
 112                 {
 113                         // this part MUST use prydon cursor
 114                         if (CS(ent).cursor_trace_ent)                 // client was aiming at someone
 115                         if (CS(ent).cursor_trace_ent != ent)         // just to make sure
 116                         if (CS(ent).cursor_trace_ent.takedamage)      // and that person is killable
 117                         if (IS_PLAYER(CS(ent).cursor_trace_ent)) // and actually a player
 118                         {
 119                                 // verify that the shot would miss without antilag
 120                                 // (avoids an issue where guns would always shoot at their origin)
 121                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 122                                 if (!trace_ent.takedamage)
 123                                 {
 124                                         // verify that the shot would hit if altered
 125                                         traceline(w_shotorg, CS(ent).cursor_trace_ent.origin, MOVE_NORMAL, ent);
 126                                         if (trace_ent == CS(ent).cursor_trace_ent)
 127                                                 w_shotdir = normalize(CS(ent).cursor_trace_ent.origin - w_shotorg);
 128                                         else
 129                                                 LOG_INFO("antilag fail");
 130                                 }
 131                         }
 132                 }
 133         }
 134
 135         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 136
 137         if (!autocvar_g_norecoil)
 138                 ent.punchangle_x = recoil * -1;
 139
 140         if (snd != SND_Null) {
 141                 sound(ent, chan, snd, (W_DualWielding(ent) ? VOL_BASE * 0.7 : VOL_BASE), ATTN_NORM);
 142                 W_PlayStrengthSound(ent);
 143         }
 144
 145         // nudge w_shotend so a trace to w_shotend hits
 146         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 147         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 148         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 149         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 150 }
 151
 152 vector W_CalculateProjectileVelocity(entity actor, vector pvelocity, vector mvelocity, float forceAbsolute)
 153 {
 154         vector mdirection;
 155         float mspeed;
 156         vector outvelocity;
 157
 158         mvelocity = mvelocity * W_WeaponSpeedFactor(actor);
 159
 160         mdirection = normalize(mvelocity);
 161         mspeed = vlen(mvelocity);
 162
 163         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 164
 165         return outvelocity;
 166 }
 167
 168 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 169 {
 170         if(proj.owner == NULL)
 171                 error("Unowned missile");
 172
 173         dir = dir + upDir * (pUpSpeed / pSpeed);
 174         dir.z += pZSpeed / pSpeed;
 175         pSpeed *= vlen(dir);
 176         dir = normalize(dir);
 177
 178         #if 0
 179         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 180         {
 181                 mspercallsum = mspercallcount = 0;
 182                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 183         }
 184         mspercallsum -= gettime(GETTIME_HIRES);
 185         #endif
 186
 187         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 188
 189         #if 0
 190         mspercallsum += gettime(GETTIME_HIRES);
 191         mspercallcount += 1;
 192         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec");
 193         #endif
 194
 195         proj.velocity = W_CalculateProjectileVelocity(proj.owner, proj.owner.velocity, pSpeed * dir, forceAbsolute);
 196 }
 197
 198
 199 // ====================
 200 //  Ballistics Tracing
 201 // ====================
 202
 203 void FireRailgunBullet (entity this, .entity weaponentity, vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 204 {
 205         entity pseudoprojectile = NULL;
 206
 207         vector dir = normalize(end - start);
 208         float length = vlen(end - start);
 209         vector force = dir * bforce;
 210
 211         // go a little bit into the wall because we need to hit this wall later
 212         end = end + dir;
 213
 214         float totaldmg = 0;
 215
 216         // trace multiple times until we hit a wall, each obstacle will be made
 217         // non-solid so we can hit the next, while doing this we spawn effects and
 218         // note down which entities were hit so we can damage them later
 219         entity o = this;
 220         while (1)
 221         {
 222                 if(CS(this).antilag_debug)
 223                         WarpZone_traceline_antilag (this, start, end, false, o, CS(this).antilag_debug);
 224                 else
 225                         WarpZone_traceline_antilag (this, start, end, false, o, ANTILAG_LATENCY(this));
 226                 if(o && WarpZone_trace_firstzone)
 227                 {
 228                         o = NULL;
 229                         continue;
 230                 }
 231
 232                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 233                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, this);
 234
 235                 // if it is NULL we can't hurt it so stop now
 236                 if (trace_ent == NULL || trace_fraction == 1)
 237                         break;
 238
 239                 // make the entity non-solid so we can hit the next one
 240                 IL_PUSH(g_railgunhit, trace_ent);
 241                 trace_ent.railgunhit = true;
 242                 trace_ent.railgunhitloc = end;
 243                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 244                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 245                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 246
 247                 // stop if this is a wall
 248                 if (trace_ent.solid == SOLID_BSP)
 249                         break;
 250
 251                 // make the entity non-solid
 252                 trace_ent.solid = SOLID_NOT;
 253         }
 254
 255         vector endpoint = trace_endpos;
 256         entity endent = trace_ent;
 257         float endq3surfaceflags = trace_dphitq3surfaceflags;
 258
 259         // find all the entities the railgun hit and restore their solid state
 260         IL_EACH(g_railgunhit, it.railgunhit,
 261         {
 262                 it.solid = it.railgunhitsolidbackup;
 263         });
 264
 265         // spawn a temporary explosion entity for RadiusDamage calls
 266         //explosion = spawn();
 267
 268         // Find all non-hit players the beam passed close by
 269         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id)
 270         {
 271                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != this, {
 272                         if(!it.railgunhit)
 273                         if(!(IS_SPEC(it) && it.enemy == this))
 274                         {
 275                                 msg_entity = it;
 276                                 // nearest point on the beam
 277                                 vector beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 278
 279                                 float f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 280                                 if(f <= 0)
 281                                         continue;
 282
 283                                 if(!pseudoprojectile)
 284                                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 285                                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, SND(NEXWHOOSH_RANDOM()), VOL_BASE * f, ATTEN_NONE);
 286                         }
 287                 });
 288
 289                 if(pseudoprojectile)
 290                         delete(pseudoprojectile);
 291         }
 292
 293         // find all the entities the railgun hit and hurt them
 294         IL_EACH(g_railgunhit, it.railgunhit,
 295         {
 296                 // removal from the list is handled below
 297
 298                 // get the details we need to call the damage function
 299                 vector hitloc = it.railgunhitloc;
 300
 301                 float foff = ExponentialFalloff(mindist, maxdist, halflifedist, it.railgundistance);
 302                 float ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, it.railgundistance);
 303
 304                 if(accuracy_isgooddamage(this, it))
 305                         totaldmg += bdamage * foff;
 306
 307                 // apply the damage
 308                 if (it.takedamage)
 309                         Damage (it, this, this, bdamage * foff, deathtype, weaponentity, hitloc, it.railgunforce * ffs);
 310
 311                 // create a small explosion to throw gibs around (if applicable)
 312                 //setorigin(explosion, hitloc);
 313                 //RadiusDamage (explosion, this, 10, 0, 50, NULL, NULL, 300, deathtype);
 314
 315                 it.railgunhitloc = '0 0 0';
 316                 it.railgunhitsolidbackup = SOLID_NOT;
 317                 it.railgunhit = false;
 318                 it.railgundistance = 0;
 319         });
 320
 321         IL_CLEAR(g_railgunhit);
 322
 323         // calculate hits and fired shots for hitscan
 324         accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, min(bdamage, totaldmg));
 325
 326         trace_endpos = endpoint;
 327         trace_ent = endent;
 328         trace_dphitq3surfaceflags = endq3surfaceflags;
 329 }
 330
 331 void fireBullet_trace_callback(vector start, vector hit, vector end)
 332 {
 333         if(vdist(hit - start, >, 16))
 334                 trailparticles(NULL, fireBullet_trace_callback_eff, start, hit);
 335         WarpZone_trace_forent = NULL;
 336         fireBullet_last_hit = NULL;
 337 }
 338
 339 void fireBullet(entity this, .entity weaponentity, vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, int tracereffects)
 340 {
 341         vector  end;
 342
 343         dir = normalize(dir + randomvec() * spread);
 344         end = start + dir * max_shot_distance;
 345
 346         fireBullet_last_hit = NULL;
 347         float solid_penetration_left = 1;
 348         float total_damage = 0;
 349
 350         if(tracereffects & EF_RED)
 351                 fireBullet_trace_callback_eff = EFFECT_RIFLE;
 352         else if(tracereffects & EF_BLUE)
 353                 fireBullet_trace_callback_eff = EFFECT_RIFLE_WEAK;
 354         else
 355                 fireBullet_trace_callback_eff = EFFECT_BULLET;
 356
 357         float lag = ((IS_REAL_CLIENT(this)) ? ANTILAG_LATENCY(this) : 0);
 358         if(lag < 0.001)
 359                 lag = 0;
 360         bool noantilag = ((IS_CLIENT(this)) ? CS(this).cvar_cl_noantilag : false);
 361         if(autocvar_g_antilag == 0 || noantilag)
 362                 lag = 0; // only do hitscan, but no antilag
 363         if(lag)
 364                 antilag_takeback_all(this, lag);
 365
 366         // change shooter to SOLID_BBOX so the shot can hit corpses
 367         int oldsolid = this.dphitcontentsmask;
 368         if(this)
 369                 this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 370
 371         WarpZone_trace_forent = this;
 372
 373         for (;;)
 374         {
 375                 // TODO also show effect while tracing
 376                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, NULL, fireBullet_trace_callback);
 377                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 378                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 379                 start = trace_endpos;
 380                 entity hit = trace_ent;
 381
 382                 // traced up to max_shot_distance and didn't hit anything at all
 383                 if (trace_fraction == 1.0)
 384                         break;
 385
 386                 // When hitting sky, stop.
 387                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
 388                         break;
 389
 390                 // can't use noimpact, as we need to pass through walls
 391                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 392                         //break;
 393
 394                 // if we hit "weapclip", bail out
 395                 //
 396                 // rationale of this check:
 397                 //
 398                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 399                 // shots and players, but has no other effect!
 400                 //
 401                 // if it is not trans, it is caulk and should not have this side effect
 402                 //
 403                 // matching shaders:
 404                 //   common/weapclip (intended)
 405                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 406                 bool is_weapclip = false;
 407                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 408                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 409                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 410                         is_weapclip = true;
 411
 412                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 413                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, this);
 414
 415                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 416                 {
 417                         fireBullet_last_hit = hit;
 418                         yoda = 0;
 419                         MUTATOR_CALLHOOK(FireBullet_Hit, this, hit, start, end, damage, this.(weaponentity));
 420                         damage = M_ARGV(4, float);
 421                         bool gooddamage = accuracy_isgooddamage(this, hit);
 422                         Damage(hit, this, this, damage * solid_penetration_left, dtype, weaponentity, start, force * dir * solid_penetration_left);
 423                         // calculate hits for ballistic weapons
 424                         if(gooddamage)
 425                         {
 426                                 // do not exceed 100%
 427                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 428                                 total_damage += damage * solid_penetration_left;
 429                                 accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, added_damage);
 430                         }
 431                 }
 432
 433                 if (is_weapclip && !autocvar_g_ballistics_penetrate_clips)
 434                         break;
 435
 436                 // go through solid!
 437                 // outside the world? forget it
 438                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 439                         break;
 440
 441                 float maxdist;
 442                 entity hitstore = IS_PLAYER(hit) ? PS(hit) : hit;
 443                 if(max_solid_penetration < 0)
 444                         break;
 445                 else if(hitstore.ballistics_density < -1)
 446                         break; // -2: no solid penetration, ever
 447                 else if(hitstore.ballistics_density < 0)
 448                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 449                 else if(hitstore.ballistics_density == 0)
 450                         maxdist = max_solid_penetration * solid_penetration_left;
 451                 else
 452                         maxdist = max_solid_penetration * solid_penetration_left * hitstore.ballistics_density;
 453
 454                 if(maxdist <= autocvar_g_ballistics_mindistance)
 455                         break;
 456
 457                 // move the entity along its velocity until it's out of solid, then let it resume
 458                 // The previously hit entity is ignored here!
 459                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 460                 if(trace_fraction == 1) // 1: we never got out of solid
 461                         break;
 462
 463                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 464                 // fraction_used_of_what_is_left = dist_taken / maxdist
 465                 // solid_penetration_left = solid_penetration_left - solid_penetration_left * fraction_used_of_what_is_left
 466                 solid_penetration_left *= 1 - dist_taken / maxdist;
 467                 solid_penetration_left = max(solid_penetration_left, 0);
 468
 469                 // Only show effect when going through a player (invisible otherwise)
 470                 if (hit && (hit.solid != SOLID_BSP))
 471                         if(vdist(trace_endpos - start, >, 4))
 472                                 trailparticles(this, fireBullet_trace_callback_eff, start, trace_endpos);
 473
 474                 start = trace_endpos;
 475
 476                 if(hit.solid == SOLID_BSP)
 477                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, this);
 478         }
 479
 480         if(lag)
 481                 antilag_restore_all(this);
 482
 483         // restore shooter solid type
 484         if(this)
 485                 this.dphitcontentsmask = oldsolid;
 486 }