29c4018bd23870f30c76f1639bfc21936803178b
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / weapons / weaponsystem.qc
1 #include "weaponsystem.qh"
2
3 #include "selection.qh"
4
5 #include "../command/common.qh"
6 #include <server/mutators/_mod.qh>
7 #include "../round_handler.qh"
8 #include <server/cheats.qh>
9 #include <server/resources.qh>
10 #include <common/t_items.qh>
11 #include <common/animdecide.qh>
12 #include <common/constants.qh>
13 #include <common/net_linked.qh>
14 #include <common/monsters/_mod.qh>
15 #include <common/notifications/all.qh>
16 #include <common/util.qh>
17 #include <common/weapons/_all.qh>
18 #include <common/state.qh>
19 #include <lib/csqcmodel/sv_model.qh>
20 #include <common/wepent.qh>
21
22 .int state;
23
24 .float weapon_frametime;
25
26 float W_WeaponRateFactor(entity this)
27 {
28         float t = 1;
29         if(g_weaponratefactor > 0)
30                 t = 1.0 / g_weaponratefactor;
31
32         MUTATOR_CALLHOOK(WeaponRateFactor, t, this);
33         t = M_ARGV(0, float);
34
35         return t;
36 }
37
38 float W_WeaponSpeedFactor(entity this)
39 {
40         float t = 1.0 * g_weaponspeedfactor;
41
42         MUTATOR_CALLHOOK(WeaponSpeedFactor, t, this);
43         t = M_ARGV(0, float);
44
45         return t;
46 }
47
48
49 bool CL_Weaponentity_CustomizeEntityForClient(entity this, entity client)
50 {
51         this.viewmodelforclient = this.owner;
52         if (IS_SPEC(client) && client.enemy == this.owner) this.viewmodelforclient = client;
53         return true;
54 }
55
56 vector CL_Weapon_GetShotOrg(int wpn)
57 {
58         entity wi = Weapons_from(wpn);
59         entity e = spawn();
60         CL_WeaponEntity_SetModel(e, wi.mdl, false);
61         vector ret = e.movedir;
62         CL_WeaponEntity_SetModel(e, "", false);
63         delete(e);
64         return ret;
65 }
66
67 .float m_alpha;
68 .string w_weaponname;
69 .int w_dmg;
70 .int w_deadflag;
71
72 void CL_Weaponentity_Think(entity this)
73 {
74         this.nextthink = time;
75         if (game_stopped) this.frame = this.anim_idle.x;
76         .entity weaponentity = this.weaponentity_fld;
77         if (this.owner.(weaponentity) != this)
78         {
79                 // owner has new gun; remove old one
80                 if (this.weaponchild) delete(this.weaponchild);
81                 if (this.hook) delete(this.hook);
82                 delete(this);
83                 return;
84         }
85         if (IS_DEAD(this.owner))
86         {
87                 // owner died; disappear
88                 this.model = "";
89                 if (this.weaponchild) this.weaponchild.model = "";
90                 return;
91         }
92         if (this.w_weaponname != this.weaponname
93             || this.w_dmg != this.modelindex
94             || this.w_deadflag != this.deadflag)
95         {
96                 // owner changed weapons; update appearance
97                 this.w_weaponname = this.weaponname;
98                 this.w_dmg = this.modelindex;
99                 this.w_deadflag = this.deadflag;
100
101                 CL_WeaponEntity_SetModel(this, this.weaponname, true);
102         }
103
104         this.alpha = -1;  // TODO: don't render this entity at all
105
106         if (this.owner.alpha == default_player_alpha) this.m_alpha = default_weapon_alpha;
107         else if (this.owner.alpha != 0) this.m_alpha = this.owner.alpha;
108         else this.m_alpha  = 1;
109
110         if (this.weaponchild)
111         {
112                 this.weaponchild.alpha = this.alpha;
113                 this.weaponchild.effects = this.effects;
114         }
115 }
116
117 void CL_ExteriorWeaponentity_Think(entity this)
118 {
119         this.nextthink = time;
120         .entity weaponentity = this.weaponentity_fld;
121         entity w_ent = this.owner.(weaponentity);
122         if (this.owner.exteriorweaponentity != this)
123         {
124                 delete(this);
125                 return;
126         }
127         if (IS_DEAD(this.owner))
128         {
129                 this.model = "";
130                 return;
131         }
132         if (this.weaponname != w_ent.weaponname || this.dmg != w_ent.modelindex
133             || this.deadflag != w_ent.deadflag)
134         {
135                 this.weaponname = w_ent.weaponname;
136                 this.dmg = w_ent.modelindex;
137                 this.deadflag = w_ent.deadflag;
138                 if (w_ent.weaponname != "")
139                 {
140                         _setmodel(this, W_Model(strcat("v_", w_ent.weaponname, ".md3")));
141                         setsize(this, '0 0 0', '0 0 0');
142                 }
143                 else this.model = "";
144
145                 int tag_found;
146                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
147                 {
148                         this.tag_index = tag_found;
149                         this.tag_entity = this.owner;
150                 }
151                 else
152                 {
153                         setattachment(this, this.owner, "bip01 r hand");
154                 }
155         }
156         this.effects = this.owner.effects;
157         this.effects |= EF_LOWPRECISION;
158         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
159         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
160         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
161         else this.alpha = 1;
162
163     Weapon wep = this.owner.(weaponentity).m_weapon;
164         if (wep) this.glowmod = weaponentity_glowmod(wep, this.owner, this.owner.clientcolors, this.owner.(weaponentity));
165         this.colormap = this.owner.colormap;
166
167         CSQCMODEL_AUTOUPDATE(this);
168 }
169
170 // spawning weaponentity for client
171 void CL_SpawnWeaponentity(entity actor, .entity weaponentity)
172 {
173         entity view = actor.(weaponentity) = new(weaponentity);
174         view.solid = SOLID_NOT;
175         view.owner = actor;
176         setmodel(view, MDL_Null);  // precision set when changed
177         setorigin(view, '0 0 0');
178         view.weaponentity_fld = weaponentity;
179         setthink(view, CL_Weaponentity_Think);
180         view.nextthink = time;
181         view.viewmodelforclient = actor;
182         view.draggable = drag_undraggable;
183         setcefc(view, CL_Weaponentity_CustomizeEntityForClient);
184
185         wepent_link(view);
186
187         if (weaponentity == weaponentities[0]) // only one exterior model, thank you very much
188         {
189                 entity exterior = actor.exteriorweaponentity = new(exteriorweaponentity);
190                 exterior.solid = SOLID_NOT;
191                 exterior.owner = actor;
192                 exterior.draggable = drag_undraggable;
193                 exterior.weaponentity_fld = weaponentity;
194                 setorigin(exterior, '0 0 0');
195                 setthink(exterior, CL_ExteriorWeaponentity_Think);
196                 exterior.nextthink = time;
197
198                 CSQCMODEL_AUTOINIT(exterior);
199         }
200 }
201
202 // Weapon subs
203 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
204 {
205         actor.(weaponentity).m_weapon = WEP_Null;
206         actor.(weaponentity).m_switchingweapon = WEP_Null;
207         entity this = actor.(weaponentity);
208         if (this)
209         {
210                 this.state = WS_CLEAR;
211                 this.effects = 0;
212         }
213 }
214
215 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
216 {
217         entity this = actor.(weaponentity);
218         if (this) this.state = WS_READY;
219         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
220 }
221
222 .float prevdryfire;
223 .float prevwarntime;
224 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary, .entity weaponentity)
225 {
226         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
227         bool ammo = false;
228         if (secondary) ammo = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
229         else ammo = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
230         if (ammo) return true;
231         // always keep the Mine Layer if we placed mines, so that we can detonate them
232         if (thiswep == WEP_MINE_LAYER)
233         {
234                 IL_EACH(g_mines, it.owner == actor && it.weaponentity_fld == weaponentity,
235                 {
236                         return false;
237                 });
238         }
239
240         if (thiswep == WEP_SHOTGUN)
241                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;           // no clicking, just allow
242
243         if (thiswep == actor.(weaponentity).m_switchweapon && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
244         {
245                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
246                 actor.prevdryfire = time;
247         }
248
249         // check if the other firing mode has enough ammo
250         bool ammo_other = false;
251         if (secondary) ammo_other = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
252         else ammo_other = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
253         if (ammo_other)
254         {
255                 if (time - actor.prevwarntime > 1)
256                 {
257                         Send_Notification(
258                                 NOTIF_ONE,
259                                 actor,
260                                 MSG_MULTI,
261                                 ITEM_WEAPON_PRIMORSEC,
262                                 thiswep.m_id,
263                                 secondary,
264                                 (1 - secondary)
265                                          );
266                 }
267                 actor.prevwarntime = time;
268         }
269         else  // this weapon is totally unable to fire, switch to another one
270         {
271                 W_SwitchToOtherWeapon(actor, weaponentity);
272         }
273
274         return false;
275 }
276
277 .float race_penalty;
278 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
279 {
280         if (actor.weaponentity == NULL) return true;
281         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary, weaponentity)) return false;
282
283         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
284         // if all players readied up and the countdown is running
285         if (time < game_starttime || time < actor.race_penalty) return false;
286
287         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
288                 return false;
289
290         // do not even think about shooting if switching
291         if (actor.(weaponentity).m_switchweapon != actor.(weaponentity).m_weapon) return false;
292
293         if (attacktime >= 0)
294         {
295                 int slot = weaponslot(weaponentity);
296                 // don't fire if previous attack is not finished
297                 if (ATTACK_FINISHED(actor, slot) > time + actor.(weaponentity).weapon_frametime * 0.5) return false;
298                 entity this = actor.(weaponentity);
299                 // don't fire while changing weapon
300                 if (this.state != WS_READY) return false;
301         }
302         return true;
303 }
304
305 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
306 {
307         entity this = actor.(weaponentity);
308         if (this == NULL) return;
309         this.state = WS_INUSE;
310
311         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
312
313         // if the weapon hasn't been firing continuously, reset the timer
314         if (attacktime >= 0)
315         {
316                 int slot = weaponslot(weaponentity);
317                 if (ATTACK_FINISHED(actor, slot) < time - this.weapon_frametime * 1.5)
318                 {
319                         ATTACK_FINISHED(actor, slot) = time;
320                         // dprint("resetting attack finished to ", ftos(time), "\n");
321                 }
322                 ATTACK_FINISHED(actor, slot) = ATTACK_FINISHED(actor, slot) + attacktime * W_WeaponRateFactor(actor);
323
324                 if(autocvar_g_weaponswitch_debug_alternate && W_DualWielding(actor))
325                 {
326                         for(int wepslot = 0; wepslot < MAX_WEAPONSLOTS; ++wepslot)
327                         {
328                                 if(slot == wepslot)
329                                         continue;
330                                 .entity wepent = weaponentities[wepslot];
331                                 if(actor.(wepent) && actor.(wepent).m_weapon != WEP_Null)
332                                 {
333                                         if (ATTACK_FINISHED(actor, wepslot) < time - actor.(wepent).weapon_frametime * 1.5)
334                                                 ATTACK_FINISHED(actor, wepslot) = time;
335                                         ATTACK_FINISHED(actor, wepslot) = ATTACK_FINISHED(actor, wepslot) + (attacktime * W_WeaponRateFactor(actor)) * 0.5;
336                                 }
337                         }
338                 }
339         }
340         this.bulletcounter += 1;
341         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, slot)), "\n");
342 }
343
344 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
345 {
346         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
347         {
348                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
349                 return true;
350         }
351         return false;
352 }
353
354 /**
355  * @param t defer thinking until time + t
356  * @param func next think function
357  */
358 void weapon_thinkf(entity actor, .entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,
359         .entity weaponentity, int fire) func)
360 {
361         entity this = actor.(weaponentity);
362         if (this == NULL) return;
363         bool restartanim;
364         if (fr == WFRAME_DONTCHANGE)
365         {
366                 fr = this.wframe;
367                 restartanim = false;
368         }
369         else
370         {
371                 restartanim = fr != WFRAME_IDLE;
372         }
373
374         vector of = v_forward;
375         vector or = v_right;
376         vector ou = v_up;
377
378         vector a = '0 0 0';
379     this.wframe = fr;
380     if (fr == WFRAME_IDLE) a = this.anim_idle;
381     else if (fr == WFRAME_FIRE1) a = this.anim_fire1;
382     else if (fr == WFRAME_FIRE2) a = this.anim_fire2;
383     else  // if (fr == WFRAME_RELOAD)
384         a = this.anim_reload;
385     a.z *= g_weaponratefactor;
386
387         v_forward = of;
388         v_right = or;
389         v_up = ou;
390
391         if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE) backtrace(
392                         "Tried to override initial weapon think function - should this really happen?");
393
394         t *= W_WeaponRateFactor(actor);
395
396         // VorteX: haste can be added here
397         if (this.weapon_think == w_ready)
398         {
399                 this.weapon_nextthink = time;
400                 // dprint("started firing at ", ftos(time), "\n");
401         }
402         if (this.weapon_nextthink < time - this.weapon_frametime * 1.5
403             || this.weapon_nextthink > time + this.weapon_frametime * 1.5)
404         {
405                 this.weapon_nextthink = time;
406                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
407         }
408         this.weapon_nextthink += t;
409         this.weapon_think = func;
410         // dprint("next ", ftos(this.weapon_nextthink), "\n");
411
412         if (this)
413         {
414                 FOREACH_CLIENT(true, {
415                         if(it == actor || (IS_SPEC(it) && it.enemy == actor))
416                                 wframe_send(it, this, a, restartanim);
417                 });
418         }
419
420         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
421         {
422                 bool primary_melee = boolean(fr == WFRAME_FIRE1 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_PRI));
423                 bool secondary_melee = boolean(fr == WFRAME_FIRE2 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_SEC));
424                 int act = (primary_melee || secondary_melee)
425                         ? ANIMACTION_MELEE
426                         : ANIMACTION_SHOOT
427                         ;
428                 animdecide_setaction(actor, act, restartanim);
429         }
430         else if (actor.anim_upper_action == ANIMACTION_SHOOT || actor.anim_upper_action == ANIMACTION_MELEE)
431         {
432                 actor.anim_upper_action = 0;
433         }
434 }
435
436 bool forbidWeaponUse(entity player)
437 {
438         if (time < game_starttime && !sv_ready_restart_after_countdown) return true;
439         if (player.player_blocked) return true;
440         if (game_stopped) return true;
441         if (STAT(FROZEN, player)) return true;
442         if (MUTATOR_CALLHOOK(ForbidWeaponUse, player)) return true;
443         return false;
444 }
445
446 .bool hook_switchweapon;
447
448 void W_WeaponFrame(Player actor, .entity weaponentity)
449 {
450         TC(Player, actor);
451         TC(PlayerState, PS(actor));
452         entity this = actor.(weaponentity);
453         if (frametime) this.weapon_frametime = frametime;
454
455         if (!this || GetResourceAmount(actor, RESOURCE_HEALTH) < 1) return;  // Dead player can't use weapons and injure impulse commands
456
457         int button_atck = PHYS_INPUT_BUTTON_ATCK(actor);
458         int button_atck2 = PHYS_INPUT_BUTTON_ATCK2(actor);
459
460         if (round_handler_IsActive() && !round_handler_IsRoundStarted())
461                 button_atck = button_atck2 = 0; // forbid primary and secondary fire, switching is allowed
462
463         if (forbidWeaponUse(actor))
464         {
465                 if (this.state != WS_CLEAR)
466                 {
467                         Weapon wpn = this.m_weapon;
468                         w_ready(wpn, actor, weaponentity, button_atck | (button_atck2 << 1));
469                         return;
470                 }
471         }
472
473         if(autocvar_g_weaponswitch_debug == 2 && weaponslot(weaponentity) > 0)
474         {
475                 .entity wepe1 = weaponentities[0];
476                 entity wep1 = actor.(wepe1);
477                 this.m_switchweapon = wep1.m_switchweapon;
478                 entity store = IS_PLAYER(actor) ? PS(actor) : actor;
479                 if(!(this.m_switchweapon.spawnflags & WEP_FLAG_DUALWIELD) && !(store.dual_weapons & wep1.m_switchweapon.m_wepset))
480                 {
481                         this.m_weapon = WEP_Null;
482                         this.m_switchingweapon = WEP_Null;
483                         this.m_switchweapon = WEP_Null;
484                         this.state = WS_CLEAR;
485                         this.weaponname = "";
486                         return;
487                 }
488         }
489
490         if (this.m_switchweapon == WEP_Null)
491         {
492                 if (this.state != WS_CLEAR)
493                         w_ready(this.m_weapon, actor, weaponentity, button_atck | (button_atck2 << 1));
494                 this.m_weapon = WEP_Null;
495                 this.m_switchingweapon = WEP_Null;
496                 this.state = WS_CLEAR;
497                 this.weaponname = "";
498                 return;
499         }
500
501         makevectors(actor.v_angle);
502         vector fo = v_forward;  // save them in case the weapon think functions change it
503         vector ri = v_right;
504         vector up = v_up;
505
506         // Change weapon
507         if (this.m_weapon != this.m_switchweapon)
508         {
509                 switch (this.state)
510                 {
511                         default:
512                                 LOG_WARNF("unhandled weaponentity (%i) state for player (%i): %d", this, actor, this.state);
513                                 break;
514                         case WS_INUSE:
515                         case WS_RAISE:
516                                 break;
517                         case WS_CLEAR:
518                         {
519                                 // end switching!
520                                 Weapon newwep = this.m_switchweapon;
521                                 this.m_switchingweapon = newwep;
522
523                                 // the two weapon entities will notice this has changed and update their models
524                                 this.m_weapon = newwep;
525                                 this.weaponname = newwep.mdl;
526                                 this.bulletcounter = 0;
527                                 newwep.wr_setup(newwep, actor, weaponentity);
528                                 this.state = WS_RAISE;
529
530                                 // set our clip load to the load of the weapon we switched to, if it's reloadable
531                                 if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
532                                 {
533                                         this.clip_load = this.(weapon_load[this.m_switchweapon.m_id]);
534                                         this.clip_size = newwep.reloading_ammo;
535                                 }
536                                 else
537                                 {
538                                         this.clip_load = this.clip_size = 0;
539                                 }
540
541                                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, newwep.switchdelay_raise, w_ready);
542                                 break;
543                         }
544                         case WS_DROP:
545                         {
546                                 // in dropping phase we can switch at any time
547                                 this.m_switchingweapon = this.m_switchweapon;
548                                 break;
549                         }
550                         case WS_READY:
551                         {
552                                 // start switching!
553                                 this.m_switchingweapon = this.m_switchweapon;
554                                 entity oldwep = this.m_weapon;
555
556                                 // set up weapon switch think in the future, and start drop anim
557                                 if (INDEPENDENT_ATTACK_FINISHED || ATTACK_FINISHED(actor, weaponslot(weaponentity)) <= time + this.weapon_frametime * 0.5)
558                                 {
559                                         sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
560                                         this.state = WS_DROP;
561                                         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
562                                 }
563                                 break;
564                         }
565                 }
566         }
567
568         // LordHavoc: network timing test code
569         // if (actor.button0)
570         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, slot)), " >= ", ftos(this.weapon_nextthink), "\n");
571
572         Weapon w = this.m_weapon;
573
574         // call the think code which may fire the weapon
575         // and do so multiple times to resolve framerate dependency issues if the
576         // server framerate is very low and the weapon fire rate very high
577         for (int c = 0; c < W_TICSPERFRAME; ++c)
578         {
579                 if (w != WEP_Null && !(STAT(WEAPONS, actor) & WepSet_FromWeapon(w)))
580                 {
581                         if (this.m_weapon == this.m_switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
582                         w = WEP_Null;
583                 }
584
585                 v_forward = fo;
586                 v_right = ri;
587                 v_up = up;
588
589                 bool block_weapon = false;
590                 {
591                         bool key_pressed = PHYS_INPUT_BUTTON_HOOK(actor) && !actor.vehicle;
592                         if (round_handler_IsActive() && !round_handler_IsRoundStarted())
593                                 key_pressed = false;
594
595                         Weapon off = actor.offhand;
596                         if (off && (!(STAT(WEAPONS, actor) & WEPSET(HOOK)) || off != OFFHAND_HOOK))
597                         {
598                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
599                         }
600                         else
601                         {
602                                 if (key_pressed && this.m_switchweapon != WEP_HOOK && !actor.hook_switchweapon)
603                                         W_SwitchWeapon(actor, WEP_HOOK, weaponentity);
604                                 actor.hook_switchweapon = key_pressed;
605                                 Weapon h = WEP_HOOK;
606                                 block_weapon = (this.m_weapon == h && (button_atck || key_pressed));
607                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
608                         }
609                 }
610
611                 v_forward = fo;
612                 v_right = ri;
613                 v_up = up;
614
615                 if (!block_weapon)
616                 {
617                         Weapon e = this.m_weapon;
618                         TC(Weapon, e);
619                         if (w != WEP_Null)
620                         {
621                                 e.wr_think(e, actor, weaponentity, button_atck | (button_atck2 << 1));
622                         }
623                         else if (e)
624                         {
625                                 e.wr_gonethink(e, actor, weaponentity);
626                         }
627                 }
628
629                 if (time + this.weapon_frametime * 0.5 >= this.weapon_nextthink)
630                 {
631                         if (this.weapon_think)
632                         {
633                                 v_forward = fo;
634                                 v_right = ri;
635                                 v_up = up;
636                                 Weapon wpn = this.m_weapon;
637                                 this.weapon_think(wpn, actor, weaponentity,
638                                         button_atck | (button_atck2 << 1));
639                         }
640                         else
641                         {
642                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
643                         }
644                 }
645         }
646 }
647
648 void W_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
649 {
650         flash.owner = actor;
651         flash.angles_z = random() * 360;
652
653         entity view = actor.(weaponentity);
654         entity exterior = actor.exteriorweaponentity;
655
656         if (gettagindex(view, "shot")) setattachment(flash, view, "shot");
657         else setattachment(flash, view, "tag_shot");
658         setorigin(flash, offset);
659
660         entity xflash = spawn();
661         copyentity(flash, xflash);
662
663         flash.viewmodelforclient = actor;
664
665         if (view.oldorigin.x > 0)
666         {
667                 setattachment(xflash, exterior, "");
668                 setorigin(xflash, view.oldorigin + offset);
669         }
670         else
671         {
672                 if (gettagindex(exterior, "shot")) setattachment(xflash, exterior, "shot");
673                 else setattachment(xflash, exterior, "tag_shot");
674                 setorigin(xflash, offset);
675         }
676 }
677
678 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use, .entity weaponentity)
679 {
680         if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor, actor.(weaponentity), ammo_use)) return;
681         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
682
683         ammo_use = M_ARGV(2, float);
684
685         entity w_ent = actor.(weaponentity);
686
687         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
688         if (wep.reloading_ammo)
689         {
690                 w_ent.clip_load -= ammo_use;
691                 w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
692         }
693         else if (wep.ammo_type != RESOURCE_NONE)
694         {
695                 float ammo = GetResourceAmount(actor, wep.ammo_type);
696                 if (ammo < ammo_use)
697                 {
698                         backtrace(sprintf(
699                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
700                                 "Please notify the developers immediately with a copy of this backtrace!\n",
701                                 ammo_use,
702                                 wep.netname,
703                                 GetAmmoPicture(wep.ammo_type),
704                                 actor.netname,
705                                 ammo
706                                              ));
707                 }
708                 SetResourceAmount(actor, wep.ammo_type, ammo - ammo_use);
709         }
710 }
711
712 // weapon reloading code
713
714 .float reload_ammo_amount, reload_ammo_min, reload_time;
715 .float reload_complain;
716 .string reload_sound;
717
718 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
719 {
720         // finish the reloading process, and do the ammo transfer
721
722         entity w_ent = actor.(weaponentity);
723         Weapon wpn = w_ent.m_weapon;
724
725         w_ent.clip_load = w_ent.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
726
727         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
728         if (!w_ent.reload_ammo_min || (actor.items & IT_UNLIMITED_WEAPON_AMMO) || wpn.ammo_type == RESOURCE_NONE)
729         {
730                 w_ent.clip_load = w_ent.reload_ammo_amount;
731         }
732         else
733         {
734                 // make sure we don't add more ammo than we have
735                 float ammo = GetResourceAmount(actor, wpn.ammo_type);
736                 float load = min(w_ent.reload_ammo_amount - w_ent.clip_load, ammo);
737                 w_ent.clip_load += load;
738                 SetResourceAmount(actor, wpn.ammo_type, ammo - load);
739         }
740         w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
741
742         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
743         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
744         // so your weapon is disabled for a few seconds without reason
745
746         // ATTACK_FINISHED(actor, slot) -= w_ent.reload_time - 1;
747
748         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
749 }
750
751 void W_Reload(entity actor, .entity weaponentity, float sent_ammo_min, Sound sent_sound)
752 {
753         TC(Sound, sent_sound);
754         // set global values to work with
755         entity this = actor.(weaponentity);
756         Weapon e = this.m_weapon;
757
758         if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
759
760         this.reload_ammo_min = sent_ammo_min;
761         this.reload_ammo_amount = e.reloading_ammo;
762         this.reload_time = e.reloading_time;
763         strcpy(actor.reload_sound, Sound_fixpath(sent_sound));
764
765         // don't reload weapons that don't have the RELOADABLE flag
766         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
767         {
768                 LOG_TRACE(
769                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
770                 return;
771         }
772
773         // return if reloading is disabled for this weapon
774         if (!this.reload_ammo_amount) return;
775
776         // our weapon is fully loaded, no need to reload
777         if (this.clip_load >= this.reload_ammo_amount) return;
778
779         // no ammo, so nothing to load
780         if (e.ammo_type != RESOURCE_NONE)
781         {
782                 if (!GetResourceAmount(actor, e.ammo_type) && this.reload_ammo_min)
783                 {
784                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
785                         {
786                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
787                                 {
788                                         play2(actor, SND(UNAVAILABLE));
789                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", this.m_weapon.m_name, "\n"));
790                                         actor.reload_complain = time + 1;
791                                 }
792                                 // switch away if the amount of ammo is not enough to keep using this weapon
793                                 if (!(e.wr_checkammo1(e, actor, weaponentity) + e.wr_checkammo2(e, actor, weaponentity)))
794                                 {
795                                         this.clip_load = -1;  // reload later
796                                         W_SwitchToOtherWeapon(actor, weaponentity);
797                                 }
798                                 return;
799                         }
800                 }
801         }
802
803         if (this)
804         {
805                 if (this.wframe == WFRAME_RELOAD) return;
806
807                 // allow switching away while reloading, but this will cause a new reload!
808                 this.state = WS_READY;
809         }
810
811         // now begin the reloading process
812
813         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
814
815         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
816         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
817         // so your weapon is disabled for a few seconds without reason
818
819         // ATTACK_FINISHED(actor, slot) = max(time, ATTACK_FINISHED(actor, slot)) + this.reload_time + 1;
820
821         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, this.reload_time, W_ReloadedAndReady);
822
823         if (this.clip_load < 0) this.clip_load = 0;
824         this.old_clip_load = this.clip_load;
825         this.clip_load = this.(weapon_load[this.m_weapon.m_id]) = -1;
826 }
827
828 void W_DropEvent(.void(Weapon, entity actor, .entity) event, entity player, float weapon_type, entity weapon_item, .entity weaponentity)
829 {
830         Weapon w = Weapons_from(weapon_type);
831         weapon_dropevent_item = weapon_item;
832         w.event(w, player, weaponentity);
833 }