qcsrc/server/weapons/weaponsystem.qc

   1 #include "weaponsystem.qh"
   2
   3 #include "selection.qh"
   4
   5 #include "../command/common.qh"
   6 #include "../mutators/_mod.qh"
   7 #include "../round_handler.qh"
   8 #include <common/t_items.qh>
   9 #include <common/animdecide.qh>
  10 #include <common/constants.qh>
  11 #include <common/net_linked.qh>
  12 #include <common/monsters/_mod.qh>
  13 #include <common/notifications/all.qh>
  14 #include <common/util.qh>
  15 #include <common/weapons/_all.qh>
  16 #include <common/state.qh>
  17 #include <lib/csqcmodel/sv_model.qh>
  18 #include <common/wepent.qh>
  19
  20 .int state;
  21
  22 .float weapon_frametime;
  23
  24 float W_WeaponRateFactor(entity this)
  25 {
  26         float t = 1;
  27         if(g_weaponratefactor > 0)
  28                 t = 1.0 / g_weaponratefactor;
  29
  30         MUTATOR_CALLHOOK(WeaponRateFactor, t, this);
  31         t = M_ARGV(0, float);
  32
  33         return t;
  34 }
  35
  36 float W_WeaponSpeedFactor(entity this)
  37 {
  38         float t = 1.0 * g_weaponspeedfactor;
  39
  40         MUTATOR_CALLHOOK(WeaponSpeedFactor, t, this);
  41         t = M_ARGV(0, float);
  42
  43         return t;
  44 }
  45
  46
  47 bool CL_Weaponentity_CustomizeEntityForClient(entity this, entity client)
  48 {
  49         this.viewmodelforclient = this.owner;
  50         if (IS_SPEC(client) && client.enemy == this.owner) this.viewmodelforclient = client;
  51         return true;
  52 }
  53
  54 vector CL_Weapon_GetShotOrg(int wpn)
  55 {
  56         entity wi = Weapons_from(wpn);
  57         entity e = spawn();
  58         CL_WeaponEntity_SetModel(e, wi.mdl, false);
  59         vector ret = e.movedir;
  60         CL_WeaponEntity_SetModel(e, "", false);
  61         delete(e);
  62         return ret;
  63 }
  64
  65 .float m_alpha;
  66 .string w_weaponname;
  67 .int w_dmg;
  68 .int w_deadflag;
  69
  70 void CL_Weaponentity_Think(entity this)
  71 {
  72         this.nextthink = time;
  73         if (game_stopped) this.frame = this.anim_idle.x;
  74         .entity weaponentity = this.weaponentity_fld;
  75         if (this.owner.(weaponentity) != this)
  76         {
  77                 // owner has new gun; remove old one
  78                 if (this.weaponchild) delete(this.weaponchild);
  79                 if (this.hook) delete(this.hook);
  80                 delete(this);
  81                 return;
  82         }
  83         if (IS_DEAD(this.owner))
  84         {
  85                 // owner died; disappear
  86                 this.model = "";
  87                 if (this.weaponchild) this.weaponchild.model = "";
  88                 return;
  89         }
  90         if (this.w_weaponname != this.weaponname
  91             || this.w_dmg != this.modelindex
  92             || this.w_deadflag != this.deadflag)
  93         {
  94                 // owner changed weapons; update appearance
  95                 this.w_weaponname = this.weaponname;
  96                 this.w_dmg = this.modelindex;
  97                 this.w_deadflag = this.deadflag;
  98
  99                 CL_WeaponEntity_SetModel(this, this.weaponname, true);
 100         }
 101
 102         this.alpha = -1;  // TODO: don't render this entity at all
 103
 104         if (this.owner.alpha == default_player_alpha) this.m_alpha = default_weapon_alpha;
 105         else if (this.owner.alpha != 0) this.m_alpha = this.owner.alpha;
 106         else this.m_alpha  = 1;
 107
 108         if (this.weaponchild)
 109         {
 110                 this.weaponchild.alpha = this.alpha;
 111                 this.weaponchild.effects = this.effects;
 112         }
 113 }
 114
 115 void CL_ExteriorWeaponentity_Think(entity this)
 116 {
 117         this.nextthink = time;
 118         .entity weaponentity = this.weaponentity_fld;
 119         entity w_ent = this.owner.(weaponentity);
 120         if (this.owner.exteriorweaponentity != this)
 121         {
 122                 delete(this);
 123                 return;
 124         }
 125         if (IS_DEAD(this.owner))
 126         {
 127                 this.model = "";
 128                 return;
 129         }
 130         if (this.weaponname != w_ent.weaponname || this.dmg != w_ent.modelindex
 131             || this.deadflag != w_ent.deadflag)
 132         {
 133                 this.weaponname = w_ent.weaponname;
 134                 this.dmg = w_ent.modelindex;
 135                 this.deadflag = w_ent.deadflag;
 136                 if (w_ent.weaponname != "")
 137                 {
 138                         _setmodel(this, W_Model(strcat("v_", w_ent.weaponname, ".md3")));
 139                         setsize(this, '0 0 0', '0 0 0');
 140                 }
 141                 else this.model = "";
 142
 143                 int tag_found;
 144                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
 145                 {
 146                         this.tag_index = tag_found;
 147                         this.tag_entity = this.owner;
 148                 }
 149                 else
 150                 {
 151                         setattachment(this, this.owner, "bip01 r hand");
 152                 }
 153         }
 154         this.effects = this.owner.effects;
 155         this.effects |= EF_LOWPRECISION;
 156         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
 157         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 158         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 159         else this.alpha = 1;
 160
 161     Weapon wep = this.owner.(weaponentity).m_weapon;
 162         if (wep) this.glowmod = weaponentity_glowmod(wep, this.owner, this.owner.clientcolors, this.owner.(weaponentity));
 163         this.colormap = this.owner.colormap;
 164
 165         CSQCMODEL_AUTOUPDATE(this);
 166 }
 167
 168 // spawning weaponentity for client
 169 void CL_SpawnWeaponentity(entity actor, .entity weaponentity)
 170 {
 171         entity view = actor.(weaponentity) = new(weaponentity);
 172         view.solid = SOLID_NOT;
 173         view.owner = actor;
 174         setmodel(view, MDL_Null);  // precision set when changed
 175         setorigin(view, '0 0 0');
 176         view.weaponentity_fld = weaponentity;
 177         setthink(view, CL_Weaponentity_Think);
 178         view.nextthink = time;
 179         view.viewmodelforclient = actor;
 180         setcefc(view, CL_Weaponentity_CustomizeEntityForClient);
 181
 182         wepent_link(view);
 183
 184         if (weaponentity == weaponentities[0]) // only one exterior model, thank you very much
 185         {
 186                 entity exterior = actor.exteriorweaponentity = new(exteriorweaponentity);
 187                 exterior.solid = SOLID_NOT;
 188                 exterior.owner = actor;
 189                 exterior.weaponentity_fld = weaponentity;
 190                 setorigin(exterior, '0 0 0');
 191                 setthink(exterior, CL_ExteriorWeaponentity_Think);
 192                 exterior.nextthink = time;
 193
 194                 CSQCMODEL_AUTOINIT(exterior);
 195         }
 196 }
 197
 198 // Weapon subs
 199 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 200 {
 201         actor.(weaponentity).m_weapon = WEP_Null;
 202         actor.(weaponentity).m_switchingweapon = WEP_Null;
 203         entity this = actor.(weaponentity);
 204         if (this)
 205         {
 206                 this.state = WS_CLEAR;
 207                 this.effects = 0;
 208         }
 209 }
 210
 211 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 212 {
 213         entity this = actor.(weaponentity);
 214         if (this) this.state = WS_READY;
 215         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
 216 }
 217
 218 .float prevdryfire;
 219 .float prevwarntime;
 220 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary, .entity weaponentity)
 221 {
 222         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
 223         bool ammo = false;
 224         if (secondary) ammo = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
 225         else ammo = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
 226         if (ammo) return true;
 227         // always keep the Mine Layer if we placed mines, so that we can detonate them
 228         if (thiswep == WEP_MINE_LAYER)
 229         {
 230                 IL_EACH(g_mines, it.owner == actor && it.weaponentity_fld == weaponentity,
 231                 {
 232                         return false;
 233                 });
 234         }
 235
 236         if (thiswep == WEP_SHOTGUN)
 237                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;           // no clicking, just allow
 238
 239         if (thiswep == actor.(weaponentity).m_switchweapon && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 240         {
 241                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
 242                 actor.prevdryfire = time;
 243         }
 244
 245         // check if the other firing mode has enough ammo
 246         bool ammo_other = false;
 247         if (secondary) ammo_other = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
 248         else ammo_other = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
 249         if (ammo_other)
 250         {
 251                 if (time - actor.prevwarntime > 1)
 252                 {
 253                         Send_Notification(
 254                                 NOTIF_ONE,
 255                                 actor,
 256                                 MSG_MULTI,
 257                                 ITEM_WEAPON_PRIMORSEC,
 258                                 thiswep.m_id,
 259                                 secondary,
 260                                 (1 - secondary)
 261                                          );
 262                 }
 263                 actor.prevwarntime = time;
 264         }
 265         else  // this weapon is totally unable to fire, switch to another one
 266         {
 267                 W_SwitchToOtherWeapon(actor, weaponentity);
 268         }
 269
 270         return false;
 271 }
 272
 273 .float race_penalty;
 274 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 275 {
 276         if (actor.weaponentity == NULL) return true;
 277         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary, weaponentity)) return false;
 278
 279         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 280         // if all players readied up and the countdown is running
 281         if (time < game_starttime || time < actor.race_penalty) return false;
 282
 283         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
 284                 return false;
 285
 286         // do not even think about shooting if switching
 287         if (actor.(weaponentity).m_switchweapon != actor.(weaponentity).m_weapon) return false;
 288
 289         if (attacktime >= 0)
 290         {
 291                 int slot = weaponslot(weaponentity);
 292                 // don't fire if previous attack is not finished
 293                 if (ATTACK_FINISHED(actor, slot) > time + actor.(weaponentity).weapon_frametime * 0.5) return false;
 294                 entity this = actor.(weaponentity);
 295                 // don't fire while changing weapon
 296                 if (this.state != WS_READY) return false;
 297         }
 298         return true;
 299 }
 300
 301 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
 302 {
 303         entity this = actor.(weaponentity);
 304         if (this == NULL) return;
 305         this.state = WS_INUSE;
 306
 307         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
 308
 309         // if the weapon hasn't been firing continuously, reset the timer
 310         if (attacktime >= 0)
 311         {
 312                 int slot = weaponslot(weaponentity);
 313                 if (ATTACK_FINISHED(actor, slot) < time - this.weapon_frametime * 1.5)
 314                 {
 315                         ATTACK_FINISHED(actor, slot) = time;
 316                         // dprint("resetting attack finished to ", ftos(time), "\n");
 317                 }
 318                 ATTACK_FINISHED(actor, slot) = ATTACK_FINISHED(actor, slot) + attacktime * W_WeaponRateFactor(actor);
 319         }
 320         this.bulletcounter += 1;
 321         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, slot)), "\n");
 322 }
 323
 324 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 325 {
 326         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
 327         {
 328                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
 329                 return true;
 330         }
 331         return false;
 332 }
 333
 334 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim);
 335
 336 /**
 337  * @param t defer thinking until time + t
 338  * @param func next think function
 339  */
 340 void weapon_thinkf(entity actor, .entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,
 341         .entity weaponentity, int fire) func)
 342 {
 343         entity this = actor.(weaponentity);
 344         if (this == NULL) return;
 345         bool restartanim;
 346         if (fr == WFRAME_DONTCHANGE)
 347         {
 348                 fr = this.wframe;
 349                 restartanim = false;
 350         }
 351         else
 352         {
 353                 restartanim = fr != WFRAME_IDLE;
 354         }
 355
 356         vector of = v_forward;
 357         vector or = v_right;
 358         vector ou = v_up;
 359
 360         vector a = '0 0 0';
 361     this.wframe = fr;
 362     if (fr == WFRAME_IDLE) a = this.anim_idle;
 363     else if (fr == WFRAME_FIRE1) a = this.anim_fire1;
 364     else if (fr == WFRAME_FIRE2) a = this.anim_fire2;
 365     else  // if (fr == WFRAME_RELOAD)
 366         a = this.anim_reload;
 367     a.z *= g_weaponratefactor;
 368
 369         v_forward = of;
 370         v_right = or;
 371         v_up = ou;
 372
 373         if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE) backtrace(
 374                         "Tried to override initial weapon think function - should this really happen?");
 375
 376         t *= W_WeaponRateFactor(actor);
 377
 378         // VorteX: haste can be added here
 379         if (this.weapon_think == w_ready)
 380         {
 381                 this.weapon_nextthink = time;
 382                 // dprint("started firing at ", ftos(time), "\n");
 383         }
 384         if (this.weapon_nextthink < time - this.weapon_frametime * 1.5
 385             || this.weapon_nextthink > time + this.weapon_frametime * 1.5)
 386         {
 387                 this.weapon_nextthink = time;
 388                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
 389         }
 390         this.weapon_nextthink += t;
 391         this.weapon_think = func;
 392         // dprint("next ", ftos(this.weapon_nextthink), "\n");
 393
 394         if (this)
 395         {
 396                 FOREACH_CLIENT(true, LAMBDA(
 397                         if(it == actor || (IS_SPEC(it) && it.enemy == actor))
 398                                 wframe_send(it, this, a, restartanim);
 399                 ));
 400         }
 401
 402         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 403         {
 404                 bool primary_melee = boolean(fr == WFRAME_FIRE1 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_PRI));
 405                 bool secondary_melee = boolean(fr == WFRAME_FIRE2 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_SEC));
 406                 int act = (primary_melee || secondary_melee)
 407                         ? ANIMACTION_MELEE
 408                         : ANIMACTION_SHOOT
 409                         ;
 410                 animdecide_setaction(actor, act, restartanim);
 411         }
 412         else if (actor.anim_upper_action == ANIMACTION_SHOOT || actor.anim_upper_action == ANIMACTION_MELEE)
 413         {
 414                 actor.anim_upper_action = 0;
 415         }
 416 }
 417
 418 bool forbidWeaponUse(entity player)
 419 {
 420         if (time < game_starttime && !autocvar_sv_ready_restart_after_countdown) return true;
 421         if (player.player_blocked) return true;
 422         if (game_stopped) return true;
 423         if (STAT(FROZEN, player)) return true;
 424         if (MUTATOR_CALLHOOK(ForbidWeaponUse, player)) return true;
 425         return false;
 426 }
 427
 428 .bool hook_switchweapon;
 429
 430 void W_WeaponFrame(Player actor, .entity weaponentity)
 431 {
 432     TC(Player, actor);
 433     TC(PlayerState, PS(actor));
 434         entity this = actor.(weaponentity);
 435         if (frametime) this.weapon_frametime = frametime;
 436
 437         if (!this || actor.health < 1) return;  // Dead player can't use weapons and injure impulse commands
 438
 439         int button_atck = PHYS_INPUT_BUTTON_ATCK(actor);
 440         int button_atck2 = PHYS_INPUT_BUTTON_ATCK2(actor);
 441
 442         if (round_handler_IsActive() && !round_handler_IsRoundStarted())
 443                 button_atck = button_atck2 = 0; // forbid primary and secondary fire, switching is allowed
 444
 445         if (forbidWeaponUse(actor))
 446         {
 447                 if (this.state != WS_CLEAR)
 448                 {
 449                         Weapon wpn = this.m_weapon;
 450                         w_ready(wpn, actor, weaponentity, button_atck | (button_atck2 << 1));
 451                         return;
 452                 }
 453         }
 454
 455         if(autocvar_g_weaponswitch_debug == 2 && weaponslot(weaponentity) > 0)
 456         {
 457                 .entity wepe1 = weaponentities[0];
 458                 entity wep1 = actor.(wepe1);
 459                 this.m_switchweapon = wep1.m_switchweapon;
 460                 if(!(this.m_switchweapon.spawnflags & WEP_FLAG_DUALWIELD))
 461                 {
 462                         this.m_weapon = WEP_Null;
 463                         this.m_switchingweapon = WEP_Null;
 464                         this.m_switchweapon = WEP_Null;
 465                         this.state = WS_CLEAR;
 466                         this.weaponname = "";
 467                         return;
 468                 }
 469         }
 470
 471         if (this.m_switchweapon == WEP_Null)
 472         {
 473                 this.m_weapon = WEP_Null;
 474                 this.m_switchingweapon = WEP_Null;
 475                 this.state = WS_CLEAR;
 476                 this.weaponname = "";
 477                 return;
 478         }
 479
 480         makevectors(actor.v_angle);
 481         vector fo = v_forward;  // save them in case the weapon think functions change it
 482         vector ri = v_right;
 483         vector up = v_up;
 484
 485         // Change weapon
 486         if (this.m_weapon != this.m_switchweapon)
 487         {
 488                 switch (this.state)
 489                 {
 490                         default:
 491                                 LOG_WARNF("unhandled weaponentity (%i) state for player (%i): %d", this, actor, this.state);
 492                                 break;
 493                         case WS_INUSE:
 494                         case WS_RAISE:
 495                                 break;
 496                         case WS_CLEAR:
 497                         {
 498                                 // end switching!
 499                                 Weapon newwep = this.m_switchweapon;
 500                                 this.m_switchingweapon = newwep;
 501
 502                                 // the two weapon entities will notice this has changed and update their models
 503                                 this.m_weapon = newwep;
 504                                 this.weaponname = newwep.mdl;
 505                                 this.bulletcounter = 0;
 506                                 newwep.wr_setup(newwep, actor, weaponentity);
 507                                 this.state = WS_RAISE;
 508
 509                                 // set our clip load to the load of the weapon we switched to, if it's reloadable
 510                                 if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
 511                                 {
 512                                         this.clip_load = this.(weapon_load[this.m_switchweapon.m_id]);
 513                                         this.clip_size = newwep.reloading_ammo;
 514                                 }
 515                                 else
 516                                 {
 517                                         this.clip_load = this.clip_size = 0;
 518                                 }
 519
 520                                 weapon_thinkf(actor, weaponentity, WFRAME_IDLE, newwep.switchdelay_raise, w_ready);
 521                                 break;
 522                         }
 523                         case WS_DROP:
 524                         {
 525                                 // in dropping phase we can switch at any time
 526                                 this.m_switchingweapon = this.m_switchweapon;
 527                                 break;
 528                         }
 529                         case WS_READY:
 530                         {
 531                                 // start switching!
 532                                 this.m_switchingweapon = this.m_switchweapon;
 533                                 entity oldwep = this.m_weapon;
 534
 535                                 // set up weapon switch think in the future, and start drop anim
 536                                 if (INDEPENDENT_ATTACK_FINISHED || ATTACK_FINISHED(actor, weaponslot(weaponentity)) <= time + this.weapon_frametime * 0.5)
 537                                 {
 538                                         sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
 539                                         this.state = WS_DROP;
 540                                         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
 541                                 }
 542                                 break;
 543                         }
 544                 }
 545         }
 546
 547         // LordHavoc: network timing test code
 548         // if (actor.button0)
 549         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, slot)), " >= ", ftos(this.weapon_nextthink), "\n");
 550
 551         Weapon w = this.m_weapon;
 552
 553         // call the think code which may fire the weapon
 554         // and do so multiple times to resolve framerate dependency issues if the
 555         // server framerate is very low and the weapon fire rate very high
 556         for (int c = 0; c < W_TICSPERFRAME; ++c)
 557         {
 558                 if (w != WEP_Null && !(actor.weapons & WepSet_FromWeapon(w)))
 559                 {
 560                         if (this.m_weapon == this.m_switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 561                         w = WEP_Null;
 562                 }
 563
 564                 v_forward = fo;
 565                 v_right = ri;
 566                 v_up = up;
 567
 568                 bool block_weapon = false;
 569                 {
 570                         bool key_pressed = PHYS_INPUT_BUTTON_HOOK(actor) && !actor.vehicle;
 571                         if (round_handler_IsActive() && !round_handler_IsRoundStarted())
 572                                 key_pressed = false;
 573
 574                         Weapon off = actor.offhand;
 575                         if (off && !(actor.weapons & WEPSET(HOOK)))
 576                         {
 577                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
 578                         }
 579                         else
 580                         {
 581                                 if (key_pressed && this.m_switchweapon != WEP_HOOK && !actor.hook_switchweapon)
 582                                         W_SwitchWeapon(actor, WEP_HOOK, weaponentity);
 583                                 actor.hook_switchweapon = key_pressed;
 584                                 Weapon h = WEP_HOOK;
 585                                 block_weapon = (this.m_weapon == h && (button_atck || key_pressed));
 586                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
 587                         }
 588                 }
 589
 590                 v_forward = fo;
 591                 v_right = ri;
 592                 v_up = up;
 593
 594                 if (!block_weapon)
 595                 {
 596             Weapon e = this.m_weapon;
 597             TC(Weapon, e);
 598                         if (w != WEP_Null)
 599                         {
 600                                 e.wr_think(e, actor, weaponentity, button_atck | (button_atck2 << 1));
 601                         }
 602                         else if (e)
 603                         {
 604                                 e.wr_gonethink(e, actor, weaponentity);
 605                         }
 606                 }
 607
 608                 if (time + this.weapon_frametime * 0.5 >= this.weapon_nextthink)
 609                 {
 610                         if (this.weapon_think)
 611                         {
 612                                 v_forward = fo;
 613                                 v_right = ri;
 614                                 v_up = up;
 615                                 Weapon wpn = this.m_weapon;
 616                                 this.weapon_think(wpn, actor, weaponentity,
 617                                         button_atck | (button_atck2 << 1));
 618                         }
 619                         else
 620                         {
 621                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
 622                         }
 623                 }
 624         }
 625 }
 626
 627 void W_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 628 {
 629         flash.owner = actor;
 630         flash.angles_z = random() * 360;
 631
 632         entity view = actor.(weaponentity);
 633         entity exterior = actor.exteriorweaponentity;
 634
 635         if (gettagindex(view, "shot")) setattachment(flash, view, "shot");
 636         else setattachment(flash, view, "tag_shot");
 637         setorigin(flash, offset);
 638
 639         entity xflash = spawn();
 640         copyentity(flash, xflash);
 641
 642         flash.viewmodelforclient = actor;
 643
 644         if (view.oldorigin.x > 0)
 645         {
 646                 setattachment(xflash, exterior, "");
 647                 setorigin(xflash, view.oldorigin + offset);
 648         }
 649         else
 650         {
 651                 if (gettagindex(exterior, "shot")) setattachment(xflash, exterior, "shot");
 652                 else setattachment(xflash, exterior, "tag_shot");
 653                 setorigin(xflash, offset);
 654         }
 655 }
 656
 657 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use, .entity weaponentity)
 658 {
 659         if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor, actor.(weaponentity))) return;
 660         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
 661
 662         entity w_ent = actor.(weaponentity);
 663
 664         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 665         if (wep.reloading_ammo)
 666         {
 667                 w_ent.clip_load -= ammo_use;
 668                 w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
 669         }
 670         else if (wep.ammo_field != ammo_none)
 671         {
 672                 actor.(wep.ammo_field) -= ammo_use;
 673                 if (actor.(wep.ammo_field) < 0)
 674                 {
 675                         backtrace(sprintf(
 676                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
 677                                 "Please notify Samual immediately with a copy of this backtrace!\n",
 678                                 ammo_use,
 679                                 wep.netname,
 680                                 GetAmmoPicture(wep.ammo_field),
 681                                 actor.netname,
 682                                 actor.(wep.ammo_field)
 683                                              ));
 684                 }
 685         }
 686 }
 687
 688 // weapon reloading code
 689
 690 .float reload_ammo_amount, reload_ammo_min, reload_time;
 691 .float reload_complain;
 692 .string reload_sound;
 693
 694 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 695 {
 696         // finish the reloading process, and do the ammo transfer
 697
 698         entity w_ent = actor.(weaponentity);
 699         Weapon wpn = w_ent.m_weapon;
 700
 701         w_ent.clip_load = w_ent.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
 702
 703         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
 704         if (!w_ent.reload_ammo_min || (actor.items & IT_UNLIMITED_WEAPON_AMMO) || wpn.ammo_field == ammo_none)
 705         {
 706                 w_ent.clip_load = w_ent.reload_ammo_amount;
 707         }
 708         else
 709         {
 710                 // make sure we don't add more ammo than we have
 711                 float load = min(w_ent.reload_ammo_amount - w_ent.clip_load, actor.(wpn.ammo_field));
 712                 w_ent.clip_load += load;
 713                 actor.(wpn.ammo_field) -= load;
 714         }
 715         w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
 716
 717         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 718         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 719         // so your weapon is disabled for a few seconds without reason
 720
 721         // ATTACK_FINISHED(actor, slot) -= w_ent.reload_time - 1;
 722
 723         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 724 }
 725
 726 void W_Reload(entity actor, .entity weaponentity, float sent_ammo_min, Sound sent_sound)
 727 {
 728     TC(Sound, sent_sound);
 729         // set global values to work with
 730         entity this = actor.(weaponentity);
 731         Weapon e = this.m_weapon;
 732
 733         if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
 734
 735         this.reload_ammo_min = sent_ammo_min;
 736         this.reload_ammo_amount = e.reloading_ammo;
 737         this.reload_time = e.reloading_time;
 738         if (actor.reload_sound) strunzone(actor.reload_sound);
 739         actor.reload_sound = strzone(Sound_fixpath(sent_sound));
 740
 741         // don't reload weapons that don't have the RELOADABLE flag
 742         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
 743         {
 744                 LOG_TRACE(
 745                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
 746                 return;
 747         }
 748
 749         // return if reloading is disabled for this weapon
 750         if (!this.reload_ammo_amount) return;
 751
 752         // our weapon is fully loaded, no need to reload
 753         if (this.clip_load >= this.reload_ammo_amount) return;
 754
 755         // no ammo, so nothing to load
 756         if (e.ammo_field != ammo_none)
 757         {
 758                 if (!actor.(e.ammo_field) && this.reload_ammo_min)
 759                 {
 760                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 761                         {
 762                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
 763                                 {
 764                                         play2(actor, SND(UNAVAILABLE));
 765                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", this.m_weapon.m_name, "\n"));
 766                                         actor.reload_complain = time + 1;
 767                                 }
 768                                 // switch away if the amount of ammo is not enough to keep using this weapon
 769                                 if (!(e.wr_checkammo1(e, actor, weaponentity) + e.wr_checkammo2(e, actor, weaponentity)))
 770                                 {
 771                                         this.clip_load = -1;  // reload later
 772                                         W_SwitchToOtherWeapon(actor, weaponentity);
 773                                 }
 774                                 return;
 775                         }
 776                 }
 777         }
 778
 779         if (this)
 780         {
 781                 if (this.wframe == WFRAME_RELOAD) return;
 782
 783                 // allow switching away while reloading, but this will cause a new reload!
 784                 this.state = WS_READY;
 785         }
 786
 787         // now begin the reloading process
 788
 789         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
 790
 791         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 792         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 793         // so your weapon is disabled for a few seconds without reason
 794
 795         // ATTACK_FINISHED(actor, slot) = max(time, ATTACK_FINISHED(actor, slot)) + this.reload_time + 1;
 796
 797         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, this.reload_time, W_ReloadedAndReady);
 798
 799         if (this.clip_load < 0) this.clip_load = 0;
 800         this.old_clip_load = this.clip_load;
 801         this.clip_load = this.(weapon_load[this.m_weapon.m_id]) = -1;
 802 }
 803
 804 void W_DropEvent(.void(Weapon, entity actor, .entity) event, entity player, float weapon_type, entity weapon_item, .entity weaponentity)
 805 {
 806         Weapon w = Weapons_from(weapon_type);
 807         weapon_dropevent_item = weapon_item;
 808         w.event(w, player, weaponentity);
 809 }