qcsrc/server/weapons/weaponsystem.qc

   1 #include "weaponsystem.qh"
   2
   3 #include "selection.qh"
   4
   5 #include "../command/common.qh"
   6 #include "../mutators/_mod.qh"
   7 #include "../round_handler.qh"
   8 #include <common/t_items.qh>
   9 #include <common/animdecide.qh>
  10 #include <common/constants.qh>
  11 #include <common/net_linked.qh>
  12 #include <common/monsters/_mod.qh>
  13 #include <common/notifications/all.qh>
  14 #include <common/util.qh>
  15 #include <common/weapons/_all.qh>
  16 #include <common/state.qh>
  17 #include <lib/csqcmodel/sv_model.qh>
  18
  19 .int state;
  20
  21 .float weapon_frametime;
  22
  23 float W_WeaponRateFactor(entity this)
  24 {
  25         float t = 1;
  26         if(g_weaponratefactor > 0)
  27                 t = 1.0 / g_weaponratefactor;
  28
  29         MUTATOR_CALLHOOK(WeaponRateFactor, t, this);
  30         t = M_ARGV(0, float);
  31
  32         return t;
  33 }
  34
  35 float W_WeaponSpeedFactor(entity this)
  36 {
  37         float t = 1.0 * g_weaponspeedfactor;
  38
  39         MUTATOR_CALLHOOK(WeaponSpeedFactor, t, this);
  40         t = M_ARGV(0, float);
  41
  42         return t;
  43 }
  44
  45
  46 bool CL_Weaponentity_CustomizeEntityForClient(entity this, entity client)
  47 {
  48         this.viewmodelforclient = this.owner;
  49         if (IS_SPEC(client) && client.enemy == this.owner) this.viewmodelforclient = client;
  50         return true;
  51 }
  52
  53 vector CL_Weapon_GetShotOrg(int wpn)
  54 {
  55         entity wi = Weapons_from(wpn);
  56         entity e = spawn();
  57         CL_WeaponEntity_SetModel(e, wi.mdl, false);
  58         vector ret = e.movedir;
  59         CL_WeaponEntity_SetModel(e, "", false);
  60         delete(e);
  61         return ret;
  62 }
  63
  64 ..entity weaponentity_fld;
  65 .float m_alpha;
  66
  67 void CL_Weaponentity_Think(entity this)
  68 {
  69         this.nextthink = time;
  70         if (gameover) this.frame = this.anim_idle.x;
  71         .entity weaponentity = this.weaponentity_fld;
  72         if (this.owner.(weaponentity) != this)
  73         {
  74                 // owner has new gun; remove old one
  75                 if (this.weaponchild) delete(this.weaponchild);
  76                 delete(this);
  77                 return;
  78         }
  79         if (IS_DEAD(this.owner))
  80         {
  81                 // owner died; disappear
  82                 this.model = "";
  83                 if (this.weaponchild) this.weaponchild.model = "";
  84                 return;
  85         }
  86         if (this.weaponname != this.owner.weaponname
  87             || this.dmg != this.owner.modelindex
  88             || this.deadflag != this.owner.deadflag)
  89         {
  90                 // owner changed weapons; update appearance
  91                 this.weaponname = this.owner.weaponname;
  92                 this.dmg = this.owner.modelindex;
  93                 this.deadflag = this.owner.deadflag;
  94
  95                 CL_WeaponEntity_SetModel(this, this.owner.weaponname, true);
  96         }
  97
  98         this.alpha = -1;  // TODO: don't render this entity at all
  99
 100         if (this.owner.alpha == default_player_alpha) this.m_alpha = default_weapon_alpha;
 101         else if (this.owner.alpha != 0) this.m_alpha = this.owner.alpha;
 102         else this.m_alpha  = 1;
 103
 104         if (this.weaponchild)
 105         {
 106                 this.weaponchild.alpha = this.alpha;
 107                 this.weaponchild.effects = this.effects;
 108         }
 109 }
 110
 111 void CL_ExteriorWeaponentity_Think(entity this)
 112 {
 113         this.nextthink = time;
 114         if (this.owner.exteriorweaponentity != this)
 115         {
 116                 delete(this);
 117                 return;
 118         }
 119         if (IS_DEAD(this.owner))
 120         {
 121                 this.model = "";
 122                 return;
 123         }
 124         if (this.weaponname != this.owner.weaponname || this.dmg != this.owner.modelindex
 125             || this.deadflag != this.owner.deadflag)
 126         {
 127                 this.weaponname = this.owner.weaponname;
 128                 this.dmg = this.owner.modelindex;
 129                 this.deadflag = this.owner.deadflag;
 130                 if (this.owner.weaponname != "")
 131                 {
 132                         _setmodel(this, W_Model(strcat("v_", this.owner.weaponname, ".md3")));
 133                         setsize(this, '0 0 0', '0 0 0');
 134                 }
 135                 else this.model = "";
 136
 137                 int tag_found;
 138                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
 139                 {
 140                         this.tag_index = tag_found;
 141                         this.tag_entity = this.owner;
 142                 }
 143                 else
 144                 {
 145                         setattachment(this, this.owner, "bip01 r hand");
 146                 }
 147         }
 148         this.effects = this.owner.effects;
 149         this.effects |= EF_LOWPRECISION;
 150         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
 151         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 152         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 153         else this.alpha = 1;
 154
 155     Weapon wep = PS(this.owner).m_weapon;
 156         if (wep) this.glowmod = weaponentity_glowmod(wep, this.owner, this.owner.clientcolors);
 157         this.colormap = this.owner.colormap;
 158
 159         CSQCMODEL_AUTOUPDATE(this);
 160 }
 161
 162 // spawning weaponentity for client
 163 void CL_SpawnWeaponentity(entity actor, .entity weaponentity)
 164 {
 165         entity view = actor.(weaponentity) = new(weaponentity);
 166         view.solid = SOLID_NOT;
 167         view.owner = actor;
 168         setmodel(view, MDL_Null);  // precision set when changed
 169         setorigin(view, '0 0 0');
 170         view.weaponentity_fld = weaponentity;
 171         setthink(view, CL_Weaponentity_Think);
 172         view.nextthink = time;
 173         view.viewmodelforclient = actor;
 174         setcefc(view, CL_Weaponentity_CustomizeEntityForClient);
 175
 176         if (weaponentity == weaponentities[0])
 177         {
 178                 entity exterior = actor.exteriorweaponentity = new(exteriorweaponentity);
 179                 exterior.solid = SOLID_NOT;
 180                 exterior.owner = actor;
 181                 setorigin(exterior, '0 0 0');
 182                 setthink(exterior, CL_ExteriorWeaponentity_Think);
 183                 exterior.nextthink = time;
 184
 185                 CSQCMODEL_AUTOINIT(exterior);
 186         }
 187 }
 188
 189 // Weapon subs
 190 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 191 {
 192         PS(actor).m_weapon = WEP_Null;
 193         PS(actor).m_switchingweapon = WEP_Null;
 194         entity this = actor.(weaponentity);
 195         if (this)
 196         {
 197                 this.state = WS_CLEAR;
 198                 this.effects = 0;
 199         }
 200 }
 201
 202 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 203 {
 204         entity this = actor.(weaponentity);
 205         if (this) this.state = WS_READY;
 206         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
 207 }
 208
 209 .float prevdryfire;
 210 .float prevwarntime;
 211 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary)
 212 {
 213         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
 214         bool ammo = false;
 215         if (secondary) ammo = thiswep.wr_checkammo2(thiswep, actor);
 216         else ammo = thiswep.wr_checkammo1(thiswep, actor);
 217         if (ammo) return true;
 218         // always keep the Mine Layer if we placed mines, so that we can detonate them
 219         if (thiswep == WEP_MINE_LAYER)
 220         {
 221                 IL_EACH(g_mines, it.owner == actor,
 222                 {
 223                         return false;
 224                 });
 225         }
 226
 227         if (thiswep == WEP_SHOTGUN)
 228                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;           // no clicking, just allow
 229
 230         if (thiswep == PS(actor).m_switchweapon && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 231         {
 232                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
 233                 actor.prevdryfire = time;
 234         }
 235
 236         // check if the other firing mode has enough ammo
 237         bool ammo_other = false;
 238         if (secondary) ammo_other = thiswep.wr_checkammo1(thiswep, actor);
 239         else ammo_other = thiswep.wr_checkammo2(thiswep, actor);
 240         if (ammo_other)
 241         {
 242                 if (time - actor.prevwarntime > 1)
 243                 {
 244                         Send_Notification(
 245                                 NOTIF_ONE,
 246                                 actor,
 247                                 MSG_MULTI,
 248                                 ITEM_WEAPON_PRIMORSEC,
 249                                 thiswep.m_id,
 250                                 secondary,
 251                                 (1 - secondary)
 252                                          );
 253                 }
 254                 actor.prevwarntime = time;
 255         }
 256         else  // this weapon is totally unable to fire, switch to another one
 257         {
 258                 W_SwitchToOtherWeapon(actor);
 259         }
 260
 261         return false;
 262 }
 263
 264 .float race_penalty;
 265 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 266 {
 267         if (actor.weaponentity == NULL) return true;
 268         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary)) return false;
 269
 270         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 271         // if all players readied up and the countdown is running
 272         if (time < game_starttime || time < actor.race_penalty) return false;
 273
 274         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
 275                 return false;
 276
 277         // do not even think about shooting if switching
 278         if (PS(actor).m_switchweapon != PS(actor).m_weapon) return false;
 279
 280         if (attacktime >= 0)
 281         {
 282                 int slot = weaponslot(weaponentity);
 283                 // don't fire if previous attack is not finished
 284                 if (ATTACK_FINISHED(actor, slot) > time + actor.weapon_frametime * 0.5) return false;
 285                 entity this = actor.(weaponentity);
 286                 // don't fire while changing weapon
 287                 if (this.state != WS_READY) return false;
 288         }
 289         return true;
 290 }
 291
 292 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
 293 {
 294         entity this = actor.(weaponentity);
 295         if (this == NULL) return;
 296         this.state = WS_INUSE;
 297
 298         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
 299
 300         // if the weapon hasn't been firing continuously, reset the timer
 301         if (attacktime >= 0)
 302         {
 303                 int slot = weaponslot(weaponentity);
 304                 if (ATTACK_FINISHED(actor, slot) < time - actor.weapon_frametime * 1.5)
 305                 {
 306                         ATTACK_FINISHED(actor, slot) = time;
 307                         // dprint("resetting attack finished to ", ftos(time), "\n");
 308                 }
 309                 ATTACK_FINISHED(actor, slot) = ATTACK_FINISHED(actor, slot) + attacktime * W_WeaponRateFactor(actor);
 310         }
 311         actor.bulletcounter += 1;
 312         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, slot)), "\n");
 313 }
 314
 315 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 316 {
 317         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
 318         {
 319                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
 320                 return true;
 321         }
 322         return false;
 323 }
 324
 325 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim);
 326
 327 /**
 328  * @param t defer thinking until time + t
 329  * @param func next think function
 330  */
 331 void weapon_thinkf(entity actor, .entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,
 332         .entity weaponentity, int fire) func)
 333 {
 334         entity this = actor.(weaponentity);
 335         if (this == NULL) return;
 336         bool restartanim;
 337         if (fr == WFRAME_DONTCHANGE)
 338         {
 339                 fr = this.wframe;
 340                 restartanim = false;
 341         }
 342         else
 343         {
 344                 restartanim = fr != WFRAME_IDLE;
 345         }
 346
 347         vector of = v_forward;
 348         vector or = v_right;
 349         vector ou = v_up;
 350
 351         vector a = '0 0 0';
 352     this.wframe = fr;
 353     if (fr == WFRAME_IDLE) a = this.anim_idle;
 354     else if (fr == WFRAME_FIRE1) a = this.anim_fire1;
 355     else if (fr == WFRAME_FIRE2) a = this.anim_fire2;
 356     else  // if (fr == WFRAME_RELOAD)
 357         a = this.anim_reload;
 358     a.z *= g_weaponratefactor;
 359
 360         v_forward = of;
 361         v_right = or;
 362         v_up = ou;
 363
 364         if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE) backtrace(
 365                         "Tried to override initial weapon think function - should this really happen?");
 366
 367         t *= W_WeaponRateFactor(actor);
 368
 369         // VorteX: haste can be added here
 370         if (this.weapon_think == w_ready)
 371         {
 372                 this.weapon_nextthink = time;
 373                 // dprint("started firing at ", ftos(time), "\n");
 374         }
 375         if (this.weapon_nextthink < time - actor.weapon_frametime * 1.5
 376             || this.weapon_nextthink > time + actor.weapon_frametime * 1.5)
 377         {
 378                 this.weapon_nextthink = time;
 379                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
 380         }
 381         this.weapon_nextthink += t;
 382         if (weaponentity == weaponentities[0]) STAT(WEAPON_NEXTTHINK, actor) = this.weapon_nextthink;
 383         this.weapon_think = func;
 384         // dprint("next ", ftos(this.weapon_nextthink), "\n");
 385
 386         if (this)
 387         {
 388                 FOREACH_CLIENT(true, LAMBDA(
 389                         if(it == actor || (IS_SPEC(it) && it.enemy == actor))
 390                                 wframe_send(it, this, a, restartanim);
 391                 ));
 392         }
 393
 394         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 395         {
 396                 bool primary_melee = boolean(fr == WFRAME_FIRE1 && (PS(actor).m_weapon.spawnflags & WEP_TYPE_MELEE_PRI));
 397                 bool secondary_melee = boolean(fr == WFRAME_FIRE2 && (PS(actor).m_weapon.spawnflags & WEP_TYPE_MELEE_SEC));
 398                 int act = (primary_melee || secondary_melee)
 399                         ? ANIMACTION_MELEE
 400                         : ANIMACTION_SHOOT
 401                         ;
 402                 animdecide_setaction(actor, act, restartanim);
 403         }
 404         else if (actor.anim_upper_action == ANIMACTION_SHOOT || actor.anim_upper_action == ANIMACTION_MELEE)
 405         {
 406                 actor.anim_upper_action = 0;
 407         }
 408 }
 409
 410 bool forbidWeaponUse(entity player)
 411 {
 412         if (time < game_starttime && !autocvar_sv_ready_restart_after_countdown) return true;
 413         if (round_handler_IsActive() && !round_handler_IsRoundStarted()) return true;
 414         if (player.player_blocked) return true;
 415         if (gameover) return true;
 416         if (STAT(FROZEN, player)) return true;
 417         if (player.weapon_blocked) return true;
 418         if (MUTATOR_CALLHOOK(ForbidWeaponUse, player)) return true;
 419         return false;
 420 }
 421
 422 .bool hook_switchweapon;
 423
 424 void W_WeaponFrame(Player actor, .entity weaponentity)
 425 {
 426     TC(Player, actor);
 427     TC(PlayerState, PS(actor));
 428         entity this = actor.(weaponentity);
 429         if (frametime) actor.weapon_frametime = frametime;
 430
 431         if (!this || actor.health < 1) return;  // Dead player can't use weapons and injure impulse commands
 432
 433
 434         if (forbidWeaponUse(actor))
 435         {
 436                 if (actor.(weaponentity).state != WS_CLEAR)
 437                 {
 438                         Weapon wpn = PS(actor).m_weapon;
 439                         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 440                         return;
 441                 }
 442         }
 443
 444         if (PS(actor).m_switchweapon == WEP_Null)
 445         {
 446                 PS(actor).m_weapon = WEP_Null;
 447                 PS(actor).m_switchingweapon = WEP_Null;
 448                 this.state = WS_CLEAR;
 449                 actor.weaponname = "";
 450                 return;
 451         }
 452
 453         makevectors(actor.v_angle);
 454         vector fo = v_forward;  // save them in case the weapon think functions change it
 455         vector ri = v_right;
 456         vector up = v_up;
 457
 458         // Change weapon
 459         if (PS(actor).m_weapon != PS(actor).m_switchweapon)
 460         {
 461                 switch (this.state)
 462                 {
 463                         default:
 464                                 LOG_WARNF("unhandled weaponentity (%i) state for player (%i): %d", this, actor, this.state);
 465                                 break;
 466                         case WS_INUSE:
 467                         case WS_RAISE:
 468                                 break;
 469                         case WS_CLEAR:
 470                         {
 471                                 // end switching!
 472                                 Weapon newwep = PS(actor).m_switchweapon;
 473                                 PS(actor).m_switchingweapon = newwep;
 474
 475                                 // the two weapon entities will notice this has changed and update their models
 476                                 PS(actor).m_weapon = newwep;
 477                                 actor.weaponname = newwep.mdl;
 478                                 actor.bulletcounter = 0;
 479                                 actor.ammo_field = newwep.ammo_field;
 480                                 newwep.wr_setup(newwep, actor);
 481                                 this.state = WS_RAISE;
 482
 483                                 // set our clip load to the load of the weapon we switched to, if it's reloadable
 484                                 if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
 485                                 {
 486                                         actor.clip_load = actor.(weapon_load[PS(actor).m_switchweapon.m_id]);
 487                                         actor.clip_size = newwep.reloading_ammo;
 488                                 }
 489                                 else
 490                                 {
 491                                         actor.clip_load = actor.clip_size = 0;
 492                                 }
 493
 494                                 weapon_thinkf(actor, weaponentity, WFRAME_IDLE, newwep.switchdelay_raise, w_ready);
 495                                 break;
 496                         }
 497                         case WS_DROP:
 498                         {
 499                                 // in dropping phase we can switch at any time
 500                                 PS(actor).m_switchingweapon = PS(actor).m_switchweapon;
 501                                 break;
 502                         }
 503                         case WS_READY:
 504                         {
 505                                 // start switching!
 506                                 PS(actor).m_switchingweapon = PS(actor).m_switchweapon;
 507                                 entity oldwep = PS(actor).m_weapon;
 508
 509                                 // set up weapon switch think in the future, and start drop anim
 510                                 if (INDEPENDENT_ATTACK_FINISHED || ATTACK_FINISHED(actor, weaponslot(weaponentity)) <= time + actor.weapon_frametime * 0.5)
 511                                 {
 512                                         sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
 513                                         this.state = WS_DROP;
 514                                         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
 515                                 }
 516                                 break;
 517                         }
 518                 }
 519         }
 520
 521         // LordHavoc: network timing test code
 522         // if (actor.button0)
 523         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, slot)), " >= ", ftos(this.weapon_nextthink), "\n");
 524
 525         Weapon w = PS(actor).m_weapon;
 526
 527         // call the think code which may fire the weapon
 528         // and do so multiple times to resolve framerate dependency issues if the
 529         // server framerate is very low and the weapon fire rate very high
 530         for (int c = 0; c < W_TICSPERFRAME; ++c)
 531         {
 532                 if (w != WEP_Null && !(actor.weapons & WepSet_FromWeapon(w)))
 533                 {
 534                         if (PS(actor).m_weapon == PS(actor).m_switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
 535                         w = WEP_Null;
 536                 }
 537
 538                 v_forward = fo;
 539                 v_right = ri;
 540                 v_up = up;
 541
 542                 bool block_weapon = false;
 543                 {
 544                         bool key_pressed = PHYS_INPUT_BUTTON_HOOK(actor) && !actor.vehicle;
 545                         Weapon off = actor.offhand;
 546                         if (off && !(actor.weapons & WEPSET(HOOK)))
 547                         {
 548                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
 549                         }
 550                         else
 551                         {
 552                                 if (key_pressed && PS(actor).m_switchweapon != WEP_HOOK && !actor.hook_switchweapon)
 553                                         W_SwitchWeapon(actor, WEP_HOOK);
 554                                 actor.hook_switchweapon = key_pressed;
 555                                 Weapon h = WEP_HOOK;
 556                                 block_weapon = (PS(actor).m_weapon == h && (PHYS_INPUT_BUTTON_ATCK(actor) || key_pressed));
 557                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
 558                         }
 559                 }
 560
 561                 v_forward = fo;
 562                 v_right = ri;
 563                 v_up = up;
 564
 565                 if (!block_weapon)
 566                 {
 567             Weapon e = PS(actor).m_weapon;
 568             TC(Weapon, e);
 569                         if (w != WEP_Null)
 570                         {
 571                                 e.wr_think(e, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 572                         }
 573                         else if (e)
 574                         {
 575                                 e.wr_gonethink(e, actor, weaponentity);
 576                         }
 577                 }
 578
 579                 if (time + actor.weapon_frametime * 0.5 >= this.weapon_nextthink)
 580                 {
 581                         if (this.weapon_think)
 582                         {
 583                                 v_forward = fo;
 584                                 v_right = ri;
 585                                 v_up = up;
 586                                 Weapon wpn = PS(actor).m_weapon;
 587                                 this.weapon_think(wpn, actor, weaponentity,
 588                                         PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 589                         }
 590                         else
 591                         {
 592                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
 593                         }
 594                 }
 595         }
 596 }
 597
 598 void W_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 599 {
 600         flash.owner = actor;
 601         flash.angles_z = random() * 360;
 602
 603         entity view = actor.(weaponentity);
 604         entity exterior = actor.exteriorweaponentity;
 605
 606         if (gettagindex(view, "shot")) setattachment(flash, view, "shot");
 607         else setattachment(flash, view, "tag_shot");
 608         setorigin(flash, offset);
 609
 610         entity xflash = spawn();
 611         copyentity(flash, xflash);
 612
 613         flash.viewmodelforclient = actor;
 614
 615         if (view.oldorigin.x > 0)
 616         {
 617                 setattachment(xflash, exterior, "");
 618                 setorigin(xflash, view.oldorigin + offset);
 619         }
 620         else
 621         {
 622                 if (gettagindex(exterior, "shot")) setattachment(xflash, exterior, "shot");
 623                 else setattachment(xflash, exterior, "tag_shot");
 624                 setorigin(xflash, offset);
 625         }
 626 }
 627
 628 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use)
 629 {
 630         if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor)) return;
 631
 632         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
 633
 634         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 635         if (wep.reloading_ammo)
 636         {
 637                 actor.clip_load -= ammo_use;
 638                 actor.(weapon_load[PS(actor).m_weapon.m_id]) = actor.clip_load;
 639         }
 640         else if (wep.ammo_field != ammo_none)
 641         {
 642                 actor.(wep.ammo_field) -= ammo_use;
 643                 if (actor.(wep.ammo_field) < 0)
 644                 {
 645                         backtrace(sprintf(
 646                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
 647                                 "Please notify Samual immediately with a copy of this backtrace!\n",
 648                                 ammo_use,
 649                                 wep.netname,
 650                                 GetAmmoPicture(wep.ammo_field),
 651                                 actor.netname,
 652                                 actor.(wep.ammo_field)
 653                                              ));
 654                 }
 655         }
 656 }
 657
 658 // weapon reloading code
 659
 660 .float reload_ammo_amount, reload_ammo_min, reload_time;
 661 .float reload_complain;
 662 .string reload_sound;
 663
 664 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 665 {
 666         // finish the reloading process, and do the ammo transfer
 667
 668         actor.clip_load = actor.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
 669
 670         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
 671         if (!actor.reload_ammo_min || actor.items & IT_UNLIMITED_WEAPON_AMMO || actor.ammo_field == ammo_none)
 672         {
 673                 actor.clip_load = actor.reload_ammo_amount;
 674         }
 675         else
 676         {
 677                 // make sure we don't add more ammo than we have
 678                 float load = min(actor.reload_ammo_amount - actor.clip_load, actor.(actor.ammo_field));
 679                 actor.clip_load += load;
 680                 actor.(actor.ammo_field) -= load;
 681         }
 682         actor.(weapon_load[PS(actor).m_weapon.m_id]) = actor.clip_load;
 683
 684         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 685         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 686         // so your weapon is disabled for a few seconds without reason
 687
 688         // ATTACK_FINISHED(actor, slot) -= actor.reload_time - 1;
 689
 690         Weapon wpn = Weapons_from(PS(actor).m_weapon.m_id);
 691         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 692 }
 693
 694 void W_Reload(entity actor, .entity weaponentity, float sent_ammo_min, Sound sent_sound)
 695 {
 696     TC(Sound, sent_sound);
 697         // set global values to work with
 698         Weapon e = PS(actor).m_weapon;
 699
 700         if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
 701
 702         actor.reload_ammo_min = sent_ammo_min;
 703         actor.reload_ammo_amount = e.reloading_ammo;
 704         actor.reload_time = e.reloading_time;
 705         if (actor.reload_sound) strunzone(actor.reload_sound);
 706         actor.reload_sound = strzone(Sound_fixpath(sent_sound));
 707
 708         // don't reload weapons that don't have the RELOADABLE flag
 709         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
 710         {
 711                 LOG_TRACE(
 712                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
 713                 return;
 714         }
 715
 716         // return if reloading is disabled for this weapon
 717         if (!actor.reload_ammo_amount) return;
 718
 719         // our weapon is fully loaded, no need to reload
 720         if (actor.clip_load >= actor.reload_ammo_amount) return;
 721
 722         // no ammo, so nothing to load
 723         if (actor.ammo_field != ammo_none)
 724         {
 725                 if (!actor.(actor.ammo_field) && actor.reload_ammo_min)
 726                 {
 727                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 728                         {
 729                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
 730                                 {
 731                                         play2(actor, SND(UNAVAILABLE));
 732                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", PS(actor).m_weapon.m_name, "\n"));
 733                                         actor.reload_complain = time + 1;
 734                                 }
 735                                 // switch away if the amount of ammo is not enough to keep using this weapon
 736                                 Weapon w = PS(actor).m_weapon;
 737                                 if (!(w.wr_checkammo1(w, actor) + w.wr_checkammo2(w, actor)))
 738                                 {
 739                                         actor.clip_load = -1;  // reload later
 740                                         W_SwitchToOtherWeapon(actor);
 741                                 }
 742                                 return;
 743                         }
 744                 }
 745         }
 746
 747         entity this = actor.(weaponentity);
 748         if (this)
 749         {
 750                 if (this.wframe == WFRAME_RELOAD) return;
 751
 752                 // allow switching away while reloading, but this will cause a new reload!
 753                 this.state = WS_READY;
 754         }
 755
 756         // now begin the reloading process
 757
 758         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
 759
 760         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 761         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 762         // so your weapon is disabled for a few seconds without reason
 763
 764         // ATTACK_FINISHED(actor, slot) = max(time, ATTACK_FINISHED(actor, slot)) + actor.reload_time + 1;
 765
 766         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, actor.reload_time, W_ReloadedAndReady);
 767
 768         if (actor.clip_load < 0) actor.clip_load = 0;
 769         actor.old_clip_load = actor.clip_load;
 770         actor.clip_load = actor.(weapon_load[PS(actor).m_weapon.m_id]) = -1;
 771 }
 772
 773 void W_DropEvent(.void(Weapon, entity actor) event, entity player, float weapon_type, entity weapon_item)
 774 {
 775         Weapon w = Weapons_from(weapon_type);
 776         weapon_dropevent_item = weapon_item;
 777         w.event(w, player);
 778 }