qcsrc/server/weapons/weaponsystem.qc

   1 #include "weaponsystem.qh"
   2
   3 #include "selection.qh"
   4
   5 #include "../command/common.qh"
   6 #include <server/mutators/_mod.qh>
   7 #include "../round_handler.qh"
   8 #include <server/cheats.qh>
   9 #include <server/resources.qh>
  10 #include <common/t_items.qh>
  11 #include <common/animdecide.qh>
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/monsters/_mod.qh>
  15 #include <common/notifications/all.qh>
  16 #include <common/util.qh>
  17 #include <common/weapons/_all.qh>
  18 #include <common/state.qh>
  19 #include <lib/csqcmodel/sv_model.qh>
  20 #include <common/wepent.qh>
  21
  22 .int state;
  23
  24 .float weapon_frametime;
  25
  26 float W_WeaponRateFactor(entity this)
  27 {
  28         float t = 1;
  29         if(g_weaponratefactor > 0)
  30                 t = 1.0 / g_weaponratefactor;
  31
  32         MUTATOR_CALLHOOK(WeaponRateFactor, t, this);
  33         t = M_ARGV(0, float);
  34
  35         return t;
  36 }
  37
  38 float W_WeaponSpeedFactor(entity this)
  39 {
  40         float t = 1.0 * g_weaponspeedfactor;
  41
  42         MUTATOR_CALLHOOK(WeaponSpeedFactor, t, this);
  43         t = M_ARGV(0, float);
  44
  45         return t;
  46 }
  47
  48
  49 bool CL_Weaponentity_CustomizeEntityForClient(entity this, entity client)
  50 {
  51         this.viewmodelforclient = this.owner;
  52         if (IS_SPEC(client) && client.enemy == this.owner) this.viewmodelforclient = client;
  53         return true;
  54 }
  55
  56 vector CL_Weapon_GetShotOrg(int wpn)
  57 {
  58         entity wi = Weapons_from(wpn);
  59         entity e = spawn();
  60         CL_WeaponEntity_SetModel(e, wi.mdl, false);
  61         vector ret = e.movedir;
  62         CL_WeaponEntity_SetModel(e, "", false);
  63         delete(e);
  64         return ret;
  65 }
  66
  67 .float m_alpha;
  68 .string w_weaponname;
  69 .int w_dmg;
  70 .int w_deadflag;
  71
  72 void CL_Weaponentity_Think(entity this)
  73 {
  74         this.nextthink = time;
  75         if (game_stopped) this.frame = this.anim_idle.x;
  76         .entity weaponentity = this.weaponentity_fld;
  77         if (this.owner.(weaponentity) != this)
  78         {
  79                 // owner has new gun; remove old one
  80                 if (this.weaponchild) delete(this.weaponchild);
  81                 if (this.hook) delete(this.hook);
  82                 delete(this);
  83                 return;
  84         }
  85         if (IS_DEAD(this.owner))
  86         {
  87                 // owner died; disappear
  88                 this.model = "";
  89                 if (this.weaponchild) this.weaponchild.model = "";
  90                 return;
  91         }
  92         if (this.w_weaponname != this.weaponname
  93             || this.w_dmg != this.modelindex
  94             || this.w_deadflag != this.deadflag)
  95         {
  96                 // owner changed weapons; update appearance
  97                 this.w_weaponname = this.weaponname;
  98                 this.w_dmg = this.modelindex;
  99                 this.w_deadflag = this.deadflag;
 100
 101                 CL_WeaponEntity_SetModel(this, this.weaponname, true);
 102         }
 103
 104         this.alpha = -1;  // TODO: don't render this entity at all
 105
 106         if (this.owner.alpha == default_player_alpha) this.m_alpha = default_weapon_alpha;
 107         else if (this.owner.alpha != 0) this.m_alpha = this.owner.alpha;
 108         else this.m_alpha  = 1;
 109
 110         if (this.weaponchild)
 111         {
 112                 this.weaponchild.alpha = this.alpha;
 113                 this.weaponchild.effects = this.effects;
 114         }
 115 }
 116
 117 void CL_ExteriorWeaponentity_Think(entity this)
 118 {
 119         this.nextthink = time;
 120         .entity weaponentity = this.weaponentity_fld;
 121         entity w_ent = this.owner.(weaponentity);
 122         if (this.owner.exteriorweaponentity != this)
 123         {
 124                 delete(this);
 125                 return;
 126         }
 127         if (IS_DEAD(this.owner))
 128         {
 129                 this.model = "";
 130                 return;
 131         }
 132         if (this.weaponname != w_ent.weaponname || this.dmg != w_ent.modelindex
 133             || this.deadflag != w_ent.deadflag)
 134         {
 135                 this.weaponname = w_ent.weaponname;
 136                 this.dmg = w_ent.modelindex;
 137                 this.deadflag = w_ent.deadflag;
 138                 if (w_ent.weaponname != "")
 139                 {
 140                         _setmodel(this, W_Model(strcat("v_", w_ent.weaponname, ".md3")));
 141                         setsize(this, '0 0 0', '0 0 0');
 142                 }
 143                 else this.model = "";
 144
 145                 int tag_found;
 146                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
 147                 {
 148                         this.tag_index = tag_found;
 149                         this.tag_entity = this.owner;
 150                 }
 151                 else
 152                 {
 153                         setattachment(this, this.owner, "bip01 r hand");
 154                 }
 155         }
 156         this.effects = this.owner.effects;
 157         this.effects |= EF_LOWPRECISION;
 158         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
 159         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 160         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 161         else this.alpha = 1;
 162
 163     Weapon wep = this.owner.(weaponentity).m_weapon;
 164         if (wep) this.glowmod = weaponentity_glowmod(wep, this.owner, this.owner.clientcolors, this.owner.(weaponentity));
 165         this.colormap = this.owner.colormap;
 166
 167         CSQCMODEL_AUTOUPDATE(this);
 168 }
 169
 170 // spawning weaponentity for client
 171 void CL_SpawnWeaponentity(entity actor, .entity weaponentity)
 172 {
 173         entity view = actor.(weaponentity) = new(weaponentity);
 174         view.solid = SOLID_NOT;
 175         view.owner = actor;
 176         setmodel(view, MDL_Null);  // precision set when changed
 177         setorigin(view, '0 0 0');
 178         view.weaponentity_fld = weaponentity;
 179         setthink(view, CL_Weaponentity_Think);
 180         view.nextthink = time;
 181         view.viewmodelforclient = actor;
 182         view.nodrawtoclient = actor;
 183         view.draggable = drag_undraggable;
 184         setcefc(view, CL_Weaponentity_CustomizeEntityForClient);
 185
 186         wepent_link(view);
 187
 188         if (weaponentity == weaponentities[0]) // only one exterior model, thank you very much
 189         {
 190                 entity exterior = actor.exteriorweaponentity = new(exteriorweaponentity);
 191                 exterior.solid = SOLID_NOT;
 192                 exterior.owner = actor;
 193                 exterior.draggable = drag_undraggable;
 194                 exterior.weaponentity_fld = weaponentity;
 195                 setorigin(exterior, '0 0 0');
 196                 setthink(exterior, CL_ExteriorWeaponentity_Think);
 197                 exterior.nextthink = time;
 198
 199                 CSQCMODEL_AUTOINIT(exterior);
 200         }
 201 }
 202
 203 // Weapon subs
 204 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 205 {
 206         actor.(weaponentity).m_weapon = WEP_Null;
 207         actor.(weaponentity).m_switchingweapon = WEP_Null;
 208         entity this = actor.(weaponentity);
 209         if (this)
 210         {
 211                 this.state = WS_CLEAR;
 212                 this.effects = 0;
 213         }
 214 }
 215
 216 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 217 {
 218         entity this = actor.(weaponentity);
 219         if (this) this.state = WS_READY;
 220         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
 221 }
 222
 223 .float prevdryfire;
 224 .float prevwarntime;
 225 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary, .entity weaponentity)
 226 {
 227         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
 228         bool ammo = false;
 229         if (secondary) ammo = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
 230         else ammo = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
 231         if (ammo) return true;
 232         // always keep the Mine Layer if we placed mines, so that we can detonate them
 233         if (thiswep == WEP_MINE_LAYER)
 234         {
 235                 IL_EACH(g_mines, it.owner == actor && it.weaponentity_fld == weaponentity,
 236                 {
 237                         return false;
 238                 });
 239         }
 240
 241         if (thiswep == WEP_SHOTGUN)
 242                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;           // no clicking, just allow
 243
 244         if (thiswep == actor.(weaponentity).m_switchweapon && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 245         {
 246                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
 247                 actor.prevdryfire = time;
 248         }
 249
 250         // check if the other firing mode has enough ammo
 251         bool ammo_other = false;
 252         if (secondary) ammo_other = thiswep.wr_checkammo1(thiswep, actor, weaponentity);
 253         else ammo_other = thiswep.wr_checkammo2(thiswep, actor, weaponentity);
 254         if (ammo_other)
 255         {
 256                 if (time - actor.prevwarntime > 1)
 257                 {
 258                         Send_Notification(
 259                                 NOTIF_ONE,
 260                                 actor,
 261                                 MSG_MULTI,
 262                                 ITEM_WEAPON_PRIMORSEC,
 263                                 thiswep.m_id,
 264                                 secondary,
 265                                 (1 - secondary)
 266                                          );
 267                 }
 268                 actor.prevwarntime = time;
 269         }
 270         else  // this weapon is totally unable to fire, switch to another one
 271         {
 272                 W_SwitchToOtherWeapon(actor, weaponentity);
 273         }
 274
 275         return false;
 276 }
 277
 278 .float race_penalty;
 279 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 280 {
 281         if (actor.weaponentity == NULL) return true;
 282         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary, weaponentity)) return false;
 283
 284         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 285         // if all players readied up and the countdown is running
 286         if (time < game_starttime || time < actor.race_penalty) return false;
 287
 288         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
 289                 return false;
 290
 291         // do not even think about shooting if switching
 292         if (actor.(weaponentity).m_switchweapon != actor.(weaponentity).m_weapon) return false;
 293
 294         if (attacktime >= 0)
 295         {
 296                 int slot = weaponslot(weaponentity);
 297                 // don't fire if previous attack is not finished
 298                 if (ATTACK_FINISHED(actor, slot) > time + actor.(weaponentity).weapon_frametime * 0.5) return false;
 299                 entity this = actor.(weaponentity);
 300                 // don't fire while changing weapon
 301                 if (this.state != WS_READY) return false;
 302         }
 303         return true;
 304 }
 305
 306 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
 307 {
 308         entity this = actor.(weaponentity);
 309         if (this == NULL) return;
 310         this.state = WS_INUSE;
 311
 312         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
 313
 314         // if the weapon hasn't been firing continuously, reset the timer
 315         if (attacktime >= 0)
 316         {
 317                 int slot = weaponslot(weaponentity);
 318                 if (ATTACK_FINISHED(actor, slot) < time - this.weapon_frametime * 1.5)
 319                 {
 320                         ATTACK_FINISHED(actor, slot) = time;
 321                         // dprint("resetting attack finished to ", ftos(time), "\n");
 322                 }
 323                 ATTACK_FINISHED(actor, slot) = ATTACK_FINISHED(actor, slot) + attacktime * W_WeaponRateFactor(actor);
 324         }
 325         this.bulletcounter += 1;
 326         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, slot)), "\n");
 327 }
 328
 329 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 330 {
 331         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
 332         {
 333                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
 334                 return true;
 335         }
 336         return false;
 337 }
 338
 339 /**
 340  * @param t defer thinking until time + t
 341  * @param func next think function
 342  */
 343 void weapon_thinkf(entity actor, .entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,
 344         .entity weaponentity, int fire) func)
 345 {
 346         entity this = actor.(weaponentity);
 347         if (this == NULL) return;
 348         bool restartanim;
 349         if (fr == WFRAME_DONTCHANGE)
 350         {
 351                 fr = this.wframe;
 352                 restartanim = false;
 353         }
 354         else
 355         {
 356                 restartanim = fr != WFRAME_IDLE;
 357         }
 358
 359         vector of = v_forward;
 360         vector or = v_right;
 361         vector ou = v_up;
 362
 363         vector a = '0 0 0';
 364     this.wframe = fr;
 365     if (fr == WFRAME_IDLE) a = this.anim_idle;
 366     else if (fr == WFRAME_FIRE1) a = this.anim_fire1;
 367     else if (fr == WFRAME_FIRE2) a = this.anim_fire2;
 368     else  // if (fr == WFRAME_RELOAD)
 369         a = this.anim_reload;
 370     a.z *= g_weaponratefactor;
 371
 372         v_forward = of;
 373         v_right = or;
 374         v_up = ou;
 375
 376         if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE) backtrace(
 377                         "Tried to override initial weapon think function - should this really happen?");
 378
 379         t *= W_WeaponRateFactor(actor);
 380
 381         // VorteX: haste can be added here
 382         if (this.weapon_think == w_ready)
 383         {
 384                 this.weapon_nextthink = time;
 385                 // dprint("started firing at ", ftos(time), "\n");
 386         }
 387         if (this.weapon_nextthink < time - this.weapon_frametime * 1.5
 388             || this.weapon_nextthink > time + this.weapon_frametime * 1.5)
 389         {
 390                 this.weapon_nextthink = time;
 391                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
 392         }
 393         this.weapon_nextthink += t;
 394         this.weapon_think = func;
 395         // dprint("next ", ftos(this.weapon_nextthink), "\n");
 396
 397         if (this)
 398         {
 399                 FOREACH_CLIENT(true, {
 400                         if(it == actor || (IS_SPEC(it) && it.enemy == actor))
 401                                 wframe_send(it, this, a, restartanim);
 402                 });
 403         }
 404
 405         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 406         {
 407                 bool primary_melee = boolean(fr == WFRAME_FIRE1 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_PRI));
 408                 bool secondary_melee = boolean(fr == WFRAME_FIRE2 && (this.m_weapon.spawnflags & WEP_TYPE_MELEE_SEC));
 409                 int act = (primary_melee || secondary_melee)
 410                         ? ANIMACTION_MELEE
 411                         : ANIMACTION_SHOOT
 412                         ;
 413                 animdecide_setaction(actor, act, restartanim);
 414         }
 415         else if (actor.anim_upper_action == ANIMACTION_SHOOT || actor.anim_upper_action == ANIMACTION_MELEE)
 416         {
 417                 actor.anim_upper_action = 0;
 418         }
 419 }
 420
 421 bool forbidWeaponUse(entity player)
 422 {
 423         if (time < game_starttime && !sv_ready_restart_after_countdown) return true;
 424         if (player.player_blocked) return true;
 425         if (game_stopped) return true;
 426         if (STAT(FROZEN, player)) return true;
 427         if (MUTATOR_CALLHOOK(ForbidWeaponUse, player)) return true;
 428         return false;
 429 }
 430
 431 .bool hook_switchweapon;
 432
 433 void W_WeaponFrame(Player actor, .entity weaponentity)
 434 {
 435         TC(Player, actor);
 436         TC(PlayerState, PS(actor));
 437         entity this = actor.(weaponentity);
 438         if (frametime) this.weapon_frametime = frametime;
 439
 440         if (!this || GetResourceAmount(actor, RESOURCE_HEALTH) < 1) return;  // Dead player can't use weapons and injure impulse commands
 441
 442         int button_atck = PHYS_INPUT_BUTTON_ATCK(actor);
 443         int button_atck2 = PHYS_INPUT_BUTTON_ATCK2(actor);
 444
 445         if (round_handler_IsActive() && !round_handler_IsRoundStarted())
 446                 button_atck = button_atck2 = 0; // forbid primary and secondary fire, switching is allowed
 447
 448         if (forbidWeaponUse(actor))
 449         {
 450                 if (this.state != WS_CLEAR)
 451                 {
 452                         Weapon wpn = this.m_weapon;
 453                         w_ready(wpn, actor, weaponentity, button_atck | (button_atck2 << 1));
 454                         return;
 455                 }
 456         }
 457
 458         if(autocvar_g_weaponswitch_debug == 2 && weaponslot(weaponentity) > 0)
 459         {
 460                 .entity wepe1 = weaponentities[0];
 461                 entity wep1 = actor.(wepe1);
 462                 this.m_switchweapon = wep1.m_switchweapon;
 463                 entity store = IS_PLAYER(actor) ? PS(actor) : actor;
 464                 if(!(this.m_switchweapon.spawnflags & WEP_FLAG_DUALWIELD) && !(store.dual_weapons & wep1.m_switchweapon.m_wepset))
 465                 {
 466                         this.m_weapon = WEP_Null;
 467                         this.m_switchingweapon = WEP_Null;
 468                         this.m_switchweapon = WEP_Null;
 469                         this.state = WS_CLEAR;
 470                         this.weaponname = "";
 471                         return;
 472                 }
 473         }
 474
 475         if (this.m_switchweapon == WEP_Null)
 476         {
 477                 if (this.state != WS_CLEAR)
 478                         w_ready(this.m_weapon, actor, weaponentity, button_atck | (button_atck2 << 1));
 479                 this.m_weapon = WEP_Null;
 480                 this.m_switchingweapon = WEP_Null;
 481                 this.state = WS_CLEAR;
 482                 this.weaponname = "";
 483                 return;
 484         }
 485
 486         makevectors(actor.v_angle);
 487         vector fo = v_forward;  // save them in case the weapon think functions change it
 488         vector ri = v_right;
 489         vector up = v_up;
 490
 491         // Change weapon
 492         if (this.m_weapon != this.m_switchweapon)
 493         {
 494                 switch (this.state)
 495                 {
 496                         default:
 497                                 LOG_WARNF("unhandled weaponentity (%i) state for player (%i): %d", this, actor, this.state);
 498                                 break;
 499                         case WS_INUSE:
 500                         case WS_RAISE:
 501                                 break;
 502                         case WS_CLEAR:
 503                         {
 504                                 // end switching!
 505                                 Weapon newwep = this.m_switchweapon;
 506                                 this.m_switchingweapon = newwep;
 507
 508                                 // the two weapon entities will notice this has changed and update their models
 509                                 this.m_weapon = newwep;
 510                                 this.weaponname = newwep.mdl;
 511                                 this.bulletcounter = 0;
 512                                 newwep.wr_setup(newwep, actor, weaponentity);
 513                                 this.state = WS_RAISE;
 514
 515                                 // set our clip load to the load of the weapon we switched to, if it's reloadable
 516                                 if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
 517                                 {
 518                                         this.clip_load = this.(weapon_load[this.m_switchweapon.m_id]);
 519                                         this.clip_size = newwep.reloading_ammo;
 520                                 }
 521                                 else
 522                                 {
 523                                         this.clip_load = this.clip_size = 0;
 524                                 }
 525
 526                                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, newwep.switchdelay_raise, w_ready);
 527                                 break;
 528                         }
 529                         case WS_DROP:
 530                         {
 531                                 // in dropping phase we can switch at any time
 532                                 this.m_switchingweapon = this.m_switchweapon;
 533                                 break;
 534                         }
 535                         case WS_READY:
 536                         {
 537                                 // start switching!
 538                                 this.m_switchingweapon = this.m_switchweapon;
 539                                 entity oldwep = this.m_weapon;
 540
 541                                 // set up weapon switch think in the future, and start drop anim
 542                                 if (INDEPENDENT_ATTACK_FINISHED || ATTACK_FINISHED(actor, weaponslot(weaponentity)) <= time + this.weapon_frametime * 0.5)
 543                                 {
 544                                         sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
 545                                         this.state = WS_DROP;
 546                                         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
 547                                 }
 548                                 break;
 549                         }
 550                 }
 551         }
 552
 553         // LordHavoc: network timing test code
 554         // if (actor.button0)
 555         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, slot)), " >= ", ftos(this.weapon_nextthink), "\n");
 556
 557         Weapon w = this.m_weapon;
 558
 559         // call the think code which may fire the weapon
 560         // and do so multiple times to resolve framerate dependency issues if the
 561         // server framerate is very low and the weapon fire rate very high
 562         for (int c = 0; c < W_TICSPERFRAME; ++c)
 563         {
 564                 if (w != WEP_Null && !(STAT(WEAPONS, actor) & WepSet_FromWeapon(w)))
 565                 {
 566                         if (this.m_weapon == this.m_switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
 567                         w = WEP_Null;
 568                 }
 569
 570                 v_forward = fo;
 571                 v_right = ri;
 572                 v_up = up;
 573
 574                 bool block_weapon = false;
 575                 {
 576                         bool key_pressed = PHYS_INPUT_BUTTON_HOOK(actor) && !actor.vehicle;
 577                         if (round_handler_IsActive() && !round_handler_IsRoundStarted())
 578                                 key_pressed = false;
 579
 580                         Weapon off = actor.offhand;
 581                         if (off && (!(STAT(WEAPONS, actor) & WEPSET(HOOK)) || off != OFFHAND_HOOK))
 582                         {
 583                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
 584                         }
 585                         else
 586                         {
 587                                 if (key_pressed && this.m_switchweapon != WEP_HOOK && !actor.hook_switchweapon)
 588                                         W_SwitchWeapon(actor, WEP_HOOK, weaponentity);
 589                                 actor.hook_switchweapon = key_pressed;
 590                                 Weapon h = WEP_HOOK;
 591                                 block_weapon = (this.m_weapon == h && (button_atck || key_pressed));
 592                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
 593                         }
 594                 }
 595
 596                 v_forward = fo;
 597                 v_right = ri;
 598                 v_up = up;
 599
 600                 if (!block_weapon)
 601                 {
 602                         Weapon e = this.m_weapon;
 603                         TC(Weapon, e);
 604                         if (w != WEP_Null)
 605                         {
 606                                 e.wr_think(e, actor, weaponentity, button_atck | (button_atck2 << 1));
 607                         }
 608                         else if (e)
 609                         {
 610                                 e.wr_gonethink(e, actor, weaponentity);
 611                         }
 612                 }
 613
 614                 if (time + this.weapon_frametime * 0.5 >= this.weapon_nextthink)
 615                 {
 616                         if (this.weapon_think)
 617                         {
 618                                 v_forward = fo;
 619                                 v_right = ri;
 620                                 v_up = up;
 621                                 Weapon wpn = this.m_weapon;
 622                                 this.weapon_think(wpn, actor, weaponentity,
 623                                         button_atck | (button_atck2 << 1));
 624                         }
 625                         else
 626                         {
 627                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
 628                         }
 629                 }
 630         }
 631 }
 632
 633 void W_AttachToShotorg(entity actor, .entity weaponentity, entity flash, vector offset)
 634 {
 635         flash.owner = actor;
 636         flash.angles_z = random() * 360;
 637
 638         entity view = actor.(weaponentity);
 639         entity exterior = actor.exteriorweaponentity;
 640
 641         if (gettagindex(view, "shot")) setattachment(flash, view, "shot");
 642         else setattachment(flash, view, "tag_shot");
 643         setorigin(flash, offset);
 644
 645         entity xflash = spawn();
 646         copyentity(flash, xflash);
 647
 648         flash.viewmodelforclient = actor;
 649
 650         if (view.oldorigin.x > 0)
 651         {
 652                 setattachment(xflash, exterior, "");
 653                 setorigin(xflash, view.oldorigin + offset);
 654         }
 655         else
 656         {
 657                 if (gettagindex(exterior, "shot")) setattachment(xflash, exterior, "shot");
 658                 else setattachment(xflash, exterior, "tag_shot");
 659                 setorigin(xflash, offset);
 660         }
 661 }
 662
 663 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use, .entity weaponentity)
 664 {
 665         if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor, actor.(weaponentity), ammo_use)) return;
 666         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
 667
 668         ammo_use = M_ARGV(2, float);
 669
 670         entity w_ent = actor.(weaponentity);
 671
 672         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 673         if (wep.reloading_ammo)
 674         {
 675                 w_ent.clip_load -= ammo_use;
 676                 w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
 677         }
 678         else if (wep.ammo_type != RESOURCE_NONE)
 679         {
 680                 float ammo = GetResourceAmount(actor, wep.ammo_type);
 681                 if (ammo < ammo_use)
 682                 {
 683                         backtrace(sprintf(
 684                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
 685                                 "Please notify Samual immediately with a copy of this backtrace!\n",
 686                                 ammo_use,
 687                                 wep.netname,
 688                                 GetAmmoPicture(wep.ammo_type),
 689                                 actor.netname,
 690                                 ammo
 691                                              ));
 692                 }
 693                 SetResourceAmount(actor, wep.ammo_type, ammo - ammo_use);
 694         }
 695 }
 696
 697 // weapon reloading code
 698
 699 .float reload_ammo_amount, reload_ammo_min, reload_time;
 700 .float reload_complain;
 701 .string reload_sound;
 702
 703 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 704 {
 705         // finish the reloading process, and do the ammo transfer
 706
 707         entity w_ent = actor.(weaponentity);
 708         Weapon wpn = w_ent.m_weapon;
 709
 710         w_ent.clip_load = w_ent.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
 711
 712         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
 713         if (!w_ent.reload_ammo_min || (actor.items & IT_UNLIMITED_WEAPON_AMMO) || wpn.ammo_type == RESOURCE_NONE)
 714         {
 715                 w_ent.clip_load = w_ent.reload_ammo_amount;
 716         }
 717         else
 718         {
 719                 // make sure we don't add more ammo than we have
 720                 float ammo = GetResourceAmount(actor, wpn.ammo_type);
 721                 float load = min(w_ent.reload_ammo_amount - w_ent.clip_load, ammo);
 722                 w_ent.clip_load += load;
 723                 SetResourceAmount(actor, wpn.ammo_type, ammo - load);
 724         }
 725         w_ent.(weapon_load[w_ent.m_weapon.m_id]) = w_ent.clip_load;
 726
 727         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 728         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 729         // so your weapon is disabled for a few seconds without reason
 730
 731         // ATTACK_FINISHED(actor, slot) -= w_ent.reload_time - 1;
 732
 733         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 734 }
 735
 736 void W_Reload(entity actor, .entity weaponentity, float sent_ammo_min, Sound sent_sound)
 737 {
 738         TC(Sound, sent_sound);
 739         // set global values to work with
 740         entity this = actor.(weaponentity);
 741         Weapon e = this.m_weapon;
 742
 743         if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
 744
 745         this.reload_ammo_min = sent_ammo_min;
 746         this.reload_ammo_amount = e.reloading_ammo;
 747         this.reload_time = e.reloading_time;
 748         strcpy(actor.reload_sound, Sound_fixpath(sent_sound));
 749
 750         // don't reload weapons that don't have the RELOADABLE flag
 751         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
 752         {
 753                 LOG_TRACE(
 754                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
 755                 return;
 756         }
 757
 758         // return if reloading is disabled for this weapon
 759         if (!this.reload_ammo_amount) return;
 760
 761         // our weapon is fully loaded, no need to reload
 762         if (this.clip_load >= this.reload_ammo_amount) return;
 763
 764         // no ammo, so nothing to load
 765         if (e.ammo_type != RESOURCE_NONE)
 766         {
 767                 if (!GetResourceAmount(actor, e.ammo_type) && this.reload_ammo_min)
 768                 {
 769                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 770                         {
 771                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
 772                                 {
 773                                         play2(actor, SND(UNAVAILABLE));
 774                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", this.m_weapon.m_name, "\n"));
 775                                         actor.reload_complain = time + 1;
 776                                 }
 777                                 // switch away if the amount of ammo is not enough to keep using this weapon
 778                                 if (!(e.wr_checkammo1(e, actor, weaponentity) + e.wr_checkammo2(e, actor, weaponentity)))
 779                                 {
 780                                         this.clip_load = -1;  // reload later
 781                                         W_SwitchToOtherWeapon(actor, weaponentity);
 782                                 }
 783                                 return;
 784                         }
 785                 }
 786         }
 787
 788         if (this)
 789         {
 790                 if (this.wframe == WFRAME_RELOAD) return;
 791
 792                 // allow switching away while reloading, but this will cause a new reload!
 793                 this.state = WS_READY;
 794         }
 795
 796         // now begin the reloading process
 797
 798         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
 799
 800         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 801         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 802         // so your weapon is disabled for a few seconds without reason
 803
 804         // ATTACK_FINISHED(actor, slot) = max(time, ATTACK_FINISHED(actor, slot)) + this.reload_time + 1;
 805
 806         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, this.reload_time, W_ReloadedAndReady);
 807
 808         if (this.clip_load < 0) this.clip_load = 0;
 809         this.old_clip_load = this.clip_load;
 810         this.clip_load = this.(weapon_load[this.m_weapon.m_id]) = -1;
 811 }
 812
 813 void W_DropEvent(.void(Weapon, entity actor, .entity) event, entity player, float weapon_type, entity weapon_item, .entity weaponentity)
 814 {
 815         Weapon w = Weapons_from(weapon_type);
 816         weapon_dropevent_item = weapon_item;
 817         w.event(w, player, weaponentity);
 818 }