qcsrc/server/weapons/weaponsystem.qc

   1 #include "weaponsystem.qh"
   2
   3 #include "selection.qh"
   4
   5 #include "../command/common.qh"
   6 #include "../mutators/all.qh"
   7 #include "../round_handler.qh"
   8 #include <common/t_items.qh>
   9 #include <common/animdecide.qh>
  10 #include <common/constants.qh>
  11 #include <common/monsters/all.qh>
  12 #include <common/notifications/all.qh>
  13 #include <common/util.qh>
  14 #include <common/weapons/all.qh>
  15 #include <common/state.qh>
  16 #include <lib/csqcmodel/sv_model.qh>
  17
  18 .int state;
  19
  20 .float weapon_frametime;
  21
  22 float W_WeaponRateFactor()
  23 {
  24         float t = 1.0 / g_weaponratefactor;
  25
  26         MUTATOR_CALLHOOK(WeaponRateFactor, t);
  27         t = weapon_rate;
  28
  29         return t;
  30 }
  31
  32 float W_WeaponSpeedFactor()
  33 {
  34         float t = 1.0 * g_weaponspeedfactor;
  35
  36         MUTATOR_CALLHOOK(WeaponSpeedFactor, t);
  37         t = ret_float;
  38
  39         return t;
  40 }
  41
  42
  43 bool CL_Weaponentity_CustomizeEntityForClient()
  44 {
  45         SELFPARAM();
  46         this.viewmodelforclient = this.owner;
  47         if (IS_SPEC(other) && other.enemy == this.owner) this.viewmodelforclient = other;
  48         return true;
  49 }
  50
  51 vector CL_Weapon_GetShotOrg(int wpn)
  52 {
  53         entity wi = Weapons_from(wpn);
  54         entity e = spawn();
  55         CL_WeaponEntity_SetModel(e, wi.mdl);
  56         vector ret = e.movedir;
  57         CL_WeaponEntity_SetModel(e, "");
  58         remove(e);
  59         return ret;
  60 }
  61
  62 ..entity weaponentity_fld;
  63 .float m_alpha;
  64
  65 void CL_Weaponentity_Think()
  66 {
  67         SELFPARAM();
  68         this.nextthink = time;
  69         if (intermission_running) this.frame = this.anim_idle.x;
  70         .entity weaponentity = this.weaponentity_fld;
  71         if (this.owner.(weaponentity) != this)
  72         {
  73                 // owner has new gun; remove self
  74                 if (this.weaponchild) remove(this.weaponchild);
  75                 remove(this);
  76                 return;
  77         }
  78         if (IS_DEAD(self.owner))
  79         {
  80                 // owner died; disappear
  81                 this.model = "";
  82                 if (this.weaponchild) this.weaponchild.model = "";
  83                 return;
  84         }
  85         if (this.weaponname != this.owner.weaponname
  86             || this.dmg != this.owner.modelindex
  87             || this.deadflag != this.owner.deadflag)
  88         {
  89                 // owner changed weapons; update appearance
  90                 this.weaponname = this.owner.weaponname;
  91                 this.dmg = this.owner.modelindex;
  92                 this.deadflag = this.owner.deadflag;
  93
  94                 CL_WeaponEntity_SetModel(this, this.owner.weaponname);
  95         }
  96
  97         this.alpha = -1;  // TODO: don't render this entity at all
  98
  99         if (this.owner.alpha == default_player_alpha) this.m_alpha = default_weapon_alpha;
 100         else if (this.owner.alpha != 0) this.m_alpha = this.owner.alpha;
 101         else this.m_alpha  = 1;
 102
 103         if (this.weaponchild)
 104         {
 105                 this.weaponchild.alpha = this.alpha;
 106                 this.weaponchild.effects = this.effects;
 107         }
 108 }
 109
 110 void CL_ExteriorWeaponentity_Think()
 111 {
 112         SELFPARAM();
 113         this.nextthink = time;
 114         if (this.owner.exteriorweaponentity != this)
 115         {
 116                 remove(this);
 117                 return;
 118         }
 119         if (IS_DEAD(self.owner))
 120         {
 121                 this.model = "";
 122                 return;
 123         }
 124         if (this.weaponname != this.owner.weaponname || this.dmg != this.owner.modelindex
 125             || this.deadflag != this.owner.deadflag)
 126         {
 127                 this.weaponname = this.owner.weaponname;
 128                 this.dmg = this.owner.modelindex;
 129                 this.deadflag = this.owner.deadflag;
 130                 if (this.owner.weaponname != "")
 131                 {
 132                         _setmodel(this, W_Model(strcat("v_", this.owner.weaponname, ".md3")));
 133                         setsize(this, '0 0 0', '0 0 0');
 134                 }
 135                 else this.model = "";
 136
 137                 int tag_found;
 138                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
 139                 {
 140                         this.tag_index = tag_found;
 141                         this.tag_entity = this.owner;
 142                 }
 143                 else
 144                 {
 145                         setattachment(this, this.owner, "bip01 r hand");
 146                 }
 147         }
 148         this.effects = this.owner.effects;
 149         this.effects |= EF_LOWPRECISION;
 150         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
 151         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 152         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 153         else this.alpha = 1;
 154
 155         this.glowmod = weaponentity_glowmod(PS(this.owner).m_weapon, this.owner.clientcolors);
 156         this.colormap = this.owner.colormap;
 157
 158         CSQCMODEL_AUTOUPDATE(this);
 159 }
 160
 161 // spawning weaponentity for client
 162 void CL_SpawnWeaponentity(entity actor, .entity weaponentity)
 163 {
 164         entity view = actor.(weaponentity) = new(weaponentity);
 165         view.solid = SOLID_NOT;
 166         view.owner = actor;
 167         setmodel(view, MDL_Null);  // precision set when changed
 168         setorigin(view, '0 0 0');
 169         view.weaponentity_fld = weaponentity;
 170         view.think = CL_Weaponentity_Think;
 171         view.nextthink = time;
 172         view.viewmodelforclient = actor;
 173         view.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 174
 175         if (weaponentity == weaponentities[0])
 176         {
 177                 entity exterior = actor.exteriorweaponentity = new(exteriorweaponentity);
 178                 exterior.solid = SOLID_NOT;
 179                 exterior.owner = actor;
 180                 setorigin(exterior, '0 0 0');
 181                 exterior.think = CL_ExteriorWeaponentity_Think;
 182                 exterior.nextthink = time;
 183
 184                 CSQCMODEL_AUTOINIT(exterior);
 185         }
 186 }
 187
 188 // Weapon subs
 189 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 190 {
 191         PS(actor).m_weapon = WEP_Null;
 192         PS(actor).m_switchingweapon = WEP_Null;
 193         entity this = actor.(weaponentity);
 194         if (this)
 195         {
 196                 this.state = WS_CLEAR;
 197                 this.effects = 0;
 198         }
 199 }
 200
 201 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 202 {
 203         entity this = actor.(weaponentity);
 204         if (this) this.state = WS_READY;
 205         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
 206 }
 207
 208 .float prevdryfire;
 209 .float prevwarntime;
 210 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary)
 211 {
 212         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
 213         bool ammo = false;
 214         if (secondary) WITH(entity, self, actor, ammo = thiswep.wr_checkammo2(thiswep));
 215         else WITH(entity, self, actor, ammo = thiswep.wr_checkammo1(thiswep));
 216         if (ammo) return true;
 217         // always keep the Mine Layer if we placed mines, so that we can detonate them
 218         if (thiswep == WEP_MINE_LAYER)
 219                 for (entity mine; (mine = find(mine, classname, "mine")); )
 220                         if (mine.owner == actor) return false;
 221
 222         if (thiswep == WEP_SHOTGUN)
 223                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;           // no clicking, just allow
 224
 225         if (thiswep == PS(actor).m_switchweapon && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 226         {
 227                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
 228                 actor.prevdryfire = time;
 229         }
 230
 231         // check if the other firing mode has enough ammo
 232         bool ammo_other = false;
 233         if (secondary) WITH(entity, self, actor, ammo_other = thiswep.wr_checkammo1(thiswep));
 234         else WITH(entity, self, actor, ammo_other = thiswep.wr_checkammo2(thiswep));
 235         if (ammo_other)
 236         {
 237                 if (time - actor.prevwarntime > 1)
 238                 {
 239                         Send_Notification(
 240                                 NOTIF_ONE,
 241                                 actor,
 242                                 MSG_MULTI,
 243                                 ITEM_WEAPON_PRIMORSEC,
 244                                 thiswep.m_id,
 245                                 secondary,
 246                                 (1 - secondary)
 247                                          );
 248                 }
 249                 actor.prevwarntime = time;
 250         }
 251         else  // this weapon is totally unable to fire, switch to another one
 252         {
 253                 W_SwitchToOtherWeapon(actor);
 254         }
 255
 256         return false;
 257 }
 258
 259 .float race_penalty;
 260 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 261 {
 262         if (actor.weaponentity == NULL) return true;
 263         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary)) return false;
 264
 265         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 266         // if all players readied up and the countdown is running
 267         if (time < game_starttime || time < actor.race_penalty) return false;
 268
 269         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
 270                 return false;
 271
 272         // do not even think about shooting if switching
 273         if (PS(actor).m_switchweapon != PS(actor).m_weapon) return false;
 274
 275         if (attacktime >= 0)
 276         {
 277                 int slot = weaponslot(weaponentity);
 278                 // don't fire if previous attack is not finished
 279                 if (ATTACK_FINISHED(actor, slot) > time + actor.weapon_frametime * 0.5) return false;
 280                 entity this = actor.(weaponentity);
 281                 // don't fire while changing weapon
 282                 if (this.state != WS_READY) return false;
 283         }
 284         return true;
 285 }
 286
 287 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
 288 {
 289         entity this = actor.(weaponentity);
 290         if (this == NULL) return;
 291         this.state = WS_INUSE;
 292
 293         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
 294
 295         // if the weapon hasn't been firing continuously, reset the timer
 296         if (attacktime >= 0)
 297         {
 298                 int slot = weaponslot(weaponentity);
 299                 if (ATTACK_FINISHED(actor, slot) < time - actor.weapon_frametime * 1.5)
 300                 {
 301                         ATTACK_FINISHED(actor, slot) = time;
 302                         // dprint("resetting attack finished to ", ftos(time), "\n");
 303                 }
 304                 ATTACK_FINISHED(actor, slot) = ATTACK_FINISHED(actor, slot) + attacktime * W_WeaponRateFactor();
 305         }
 306         actor.bulletcounter += 1;
 307         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, slot)), "\n");
 308 }
 309
 310 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 311 {
 312         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
 313         {
 314                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
 315                 return true;
 316         }
 317         return false;
 318 }
 319
 320 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim);
 321
 322 /**
 323  * @param t defer thinking until time + t
 324  * @param func next think function
 325  */
 326 void weapon_thinkf(entity actor, .entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,
 327         .entity weaponentity, int fire) func)
 328 {
 329         entity this = actor.(weaponentity);
 330         if (this == NULL) return;
 331         bool restartanim;
 332         if (fr == WFRAME_DONTCHANGE)
 333         {
 334                 fr = this.wframe;
 335                 restartanim = false;
 336         }
 337         else
 338         {
 339                 restartanim = fr != WFRAME_IDLE;
 340         }
 341
 342         vector of = v_forward;
 343         vector or = v_right;
 344         vector ou = v_up;
 345
 346         vector a = '0 0 0';
 347     this.wframe = fr;
 348     if (fr == WFRAME_IDLE) a = this.anim_idle;
 349     else if (fr == WFRAME_FIRE1) a = this.anim_fire1;
 350     else if (fr == WFRAME_FIRE2) a = this.anim_fire2;
 351     else  // if (fr == WFRAME_RELOAD)
 352         a = this.anim_reload;
 353     a.z *= g_weaponratefactor;
 354
 355         v_forward = of;
 356         v_right = or;
 357         v_up = ou;
 358
 359         if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE) backtrace(
 360                         "Tried to override initial weapon think function - should this really happen?");
 361
 362         t *= W_WeaponRateFactor();
 363
 364         // VorteX: haste can be added here
 365         if (this.weapon_think == w_ready)
 366         {
 367                 this.weapon_nextthink = time;
 368                 // dprint("started firing at ", ftos(time), "\n");
 369         }
 370         if (this.weapon_nextthink < time - actor.weapon_frametime * 1.5
 371             || this.weapon_nextthink > time + actor.weapon_frametime * 1.5)
 372         {
 373                 this.weapon_nextthink = time;
 374                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
 375         }
 376         this.weapon_nextthink += t;
 377         if (weaponentity == weaponentities[0]) STAT(WEAPON_NEXTTHINK, actor) = this.weapon_nextthink;
 378         this.weapon_think = func;
 379         // dprint("next ", ftos(this.weapon_nextthink), "\n");
 380
 381         if (this)
 382         {
 383                 FOREACH_CLIENT(true, LAMBDA(
 384                         if(it == actor || (IS_SPEC(it) && it.enemy == actor))
 385                                 wframe_send(it, this, a, restartanim);
 386                 ));
 387         }
 388
 389         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 390         {
 391                 int act = (fr == WFRAME_FIRE2 && (PS(actor).m_weapon == WEP_SHOCKWAVE || PS(actor).m_weapon == WEP_SHOTGUN))
 392                         ? ANIMACTION_MELEE
 393                         : ANIMACTION_SHOOT
 394                         ;
 395                 animdecide_setaction(actor, act, restartanim);
 396         }
 397         else if (actor.anim_upper_action == ANIMACTION_SHOOT || actor.anim_upper_action == ANIMACTION_MELEE)
 398         {
 399                 actor.anim_upper_action = 0;
 400         }
 401 }
 402
 403 bool forbidWeaponUse(entity player)
 404 {
 405         if (time < game_starttime && !autocvar_sv_ready_restart_after_countdown) return true;
 406         if (round_handler_IsActive() && !round_handler_IsRoundStarted()) return true;
 407         if (player.player_blocked) return true;
 408         if (STAT(FROZEN, player)) return true;
 409         if (player.weapon_blocked) return true;
 410         return false;
 411 }
 412
 413 .bool hook_switchweapon;
 414
 415 void W_WeaponFrame(entity actor)
 416 {
 417         .entity weaponentity = weaponentities[0];  // TODO: unhardcode
 418         entity this = actor.(weaponentity);
 419         if (frametime) actor.weapon_frametime = frametime;
 420
 421         if (!this || actor.health < 1) return;  // Dead player can't use weapons and injure impulse commands
 422
 423
 424         if (forbidWeaponUse(actor))
 425         {
 426                 if (actor.(weaponentity).state != WS_CLEAR)
 427                 {
 428                         Weapon wpn = PS(actor).m_weapon;
 429                         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 430                         return;
 431                 }
 432         }
 433
 434         if (PS(actor).m_switchweapon == WEP_Null)
 435         {
 436                 PS(actor).m_weapon = WEP_Null;
 437                 PS(actor).m_switchingweapon = WEP_Null;
 438                 this.state = WS_CLEAR;
 439                 actor.weaponname = "";
 440                 // actor.items &= ~IT_AMMO;
 441                 return;
 442         }
 443
 444         makevectors(actor.v_angle);
 445         vector fo = v_forward;  // save them in case the weapon think functions change it
 446         vector ri = v_right;
 447         vector up = v_up;
 448
 449         // Change weapon
 450         if (PS(actor).m_weapon != PS(actor).m_switchweapon)
 451         {
 452                 switch (this.state)
 453                 {
 454                         default:
 455                                 LOG_WARNINGF("unhandled weaponentity (%i) state for player (%i): %d\n", this, actor, this.state);
 456                                 break;
 457                         case WS_INUSE:
 458                         case WS_RAISE:
 459                                 break;
 460                         case WS_CLEAR:
 461                         {
 462                                 // end switching!
 463                                 Weapon newwep = PS(actor).m_switchweapon;
 464                                 PS(actor).m_switchingweapon = newwep;
 465
 466                                 // the two weapon entities will notice this has changed and update their models
 467                                 PS(actor).m_weapon = newwep;
 468                                 actor.weaponname = newwep.mdl;
 469                                 actor.bulletcounter = 0;
 470                                 actor.ammo_field = newwep.ammo_field;
 471                                 newwep.wr_setup(newwep);
 472                                 this.state = WS_RAISE;
 473
 474                                 // set our clip load to the load of the weapon we switched to, if it's reloadable
 475                                 if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
 476                                 {
 477                                         actor.clip_load = actor.(weapon_load[PS(actor).m_switchweapon.m_id]);
 478                                         actor.clip_size = newwep.reloading_ammo;
 479                                 }
 480                                 else
 481                                 {
 482                                         actor.clip_load = actor.clip_size = 0;
 483                                 }
 484
 485                                 weapon_thinkf(actor, weaponentity, WFRAME_IDLE, newwep.switchdelay_raise, w_ready);
 486                                 break;
 487                         }
 488                         case WS_DROP:
 489                         {
 490                                 // in dropping phase we can switch at any time
 491                                 PS(actor).m_switchingweapon = PS(actor).m_switchweapon;
 492                                 break;
 493                         }
 494                         case WS_READY:
 495                         {
 496                                 // start switching!
 497                                 PS(actor).m_switchingweapon = PS(actor).m_switchweapon;
 498                                 entity oldwep = PS(actor).m_weapon;
 499
 500                                 // set up weapon switch think in the future, and start drop anim
 501                                 if (INDEPENDENT_ATTACK_FINISHED || ATTACK_FINISHED(actor, weaponslot(weaponentity)) <= time + actor.weapon_frametime * 0.5)
 502                                 {
 503                                         sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
 504                                         this.state = WS_DROP;
 505                                         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
 506                                 }
 507                                 break;
 508                         }
 509                 }
 510         }
 511
 512         // LordHavoc: network timing test code
 513         // if (actor.button0)
 514         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, slot)), " >= ", ftos(this.weapon_nextthink), "\n");
 515
 516         Weapon w = PS(actor).m_weapon;
 517
 518         // call the think code which may fire the weapon
 519         // and do so multiple times to resolve framerate dependency issues if the
 520         // server framerate is very low and the weapon fire rate very high
 521         for (int c = 0; c < W_TICSPERFRAME; ++c)
 522         {
 523                 if (w != WEP_Null && !(actor.weapons & WepSet_FromWeapon(w)))
 524                 {
 525                         if (PS(actor).m_weapon == PS(actor).m_switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
 526                         w = WEP_Null;
 527                 }
 528
 529                 v_forward = fo;
 530                 v_right = ri;
 531                 v_up = up;
 532
 533                 bool block_weapon = false;
 534                 {
 535                         bool key_pressed = PHYS_INPUT_BUTTON_HOOK(actor) && !actor.vehicle;
 536                         Weapon off = actor.offhand;
 537                         if (off && !(actor.weapons & WEPSET(HOOK)))
 538                         {
 539                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
 540                         }
 541                         else
 542                         {
 543                                 if (key_pressed && PS(actor).m_switchweapon != WEP_HOOK && !actor.hook_switchweapon)
 544                                         W_SwitchWeapon(WEP_HOOK);
 545                                 actor.hook_switchweapon = key_pressed;
 546                                 Weapon h = WEP_HOOK;
 547                                 block_weapon = (PS(actor).m_weapon == h && (PHYS_INPUT_BUTTON_ATCK(actor) || key_pressed));
 548                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
 549                         }
 550                 }
 551
 552                 v_forward = fo;
 553                 v_right = ri;
 554                 v_up = up;
 555
 556                 if (!block_weapon)
 557                 {
 558             Weapon e = PS(actor).m_weapon;
 559                         if (w != WEP_Null)
 560                         {
 561                                 e.wr_think(e, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 562                         }
 563                         else
 564                         {
 565                                 e.wr_gonethink(e);
 566                         }
 567                 }
 568
 569                 if (time + actor.weapon_frametime * 0.5 >= this.weapon_nextthink)
 570                 {
 571                         if (this.weapon_think)
 572                         {
 573                                 v_forward = fo;
 574                                 v_right = ri;
 575                                 v_up = up;
 576                                 Weapon wpn = PS(actor).m_weapon;
 577                                 this.weapon_think(wpn, actor, weaponentity,
 578                                         PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 579                         }
 580                         else
 581                         {
 582                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
 583                         }
 584                 }
 585         }
 586 }
 587
 588 void W_AttachToShotorg(entity actor, entity flash, vector offset)
 589 {
 590         .entity weaponentity = weaponentities[0];
 591         flash.owner = actor;
 592         flash.angles_z = random() * 360;
 593
 594         entity view = actor.(weaponentity);
 595         entity exterior = actor.exteriorweaponentity;
 596
 597         if (gettagindex(view, "shot")) setattachment(flash, view, "shot");
 598         else setattachment(flash, view, "tag_shot");
 599         setorigin(flash, offset);
 600
 601         entity xflash = spawn();
 602         copyentity(flash, xflash);
 603
 604         flash.viewmodelforclient = actor;
 605
 606         if (view.oldorigin.x > 0)
 607         {
 608                 setattachment(xflash, exterior, "");
 609                 setorigin(xflash, view.oldorigin + offset);
 610         }
 611         else
 612         {
 613                 if (gettagindex(exterior, "shot")) setattachment(xflash, exterior, "shot");
 614                 else setattachment(xflash, exterior, "tag_shot");
 615                 setorigin(xflash, offset);
 616         }
 617 }
 618
 619 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use)
 620 {
 621         if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor)) return;
 622
 623         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
 624
 625         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 626         if (wep.reloading_ammo)
 627         {
 628                 actor.clip_load -= ammo_use;
 629                 actor.(weapon_load[PS(actor).m_weapon.m_id]) = actor.clip_load;
 630         }
 631         else if (wep.ammo_field != ammo_none)
 632         {
 633                 actor.(wep.ammo_field) -= ammo_use;
 634                 if (actor.(wep.ammo_field) < 0)
 635                 {
 636                         backtrace(sprintf(
 637                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
 638                                 "Please notify Samual immediately with a copy of this backtrace!\n",
 639                                 ammo_use,
 640                                 wep.netname,
 641                                 GetAmmoPicture(wep.ammo_field),
 642                                 actor.netname,
 643                                 actor.(wep.ammo_field)
 644                                              ));
 645                 }
 646         }
 647 }
 648
 649 // weapon reloading code
 650
 651 .float reload_ammo_amount, reload_ammo_min, reload_time;
 652 .float reload_complain;
 653 .string reload_sound;
 654
 655 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 656 {
 657         // finish the reloading process, and do the ammo transfer
 658
 659         actor.clip_load = actor.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
 660
 661         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
 662         if (!actor.reload_ammo_min || actor.items & IT_UNLIMITED_WEAPON_AMMO || actor.ammo_field == ammo_none)
 663         {
 664                 actor.clip_load = actor.reload_ammo_amount;
 665         }
 666         else
 667         {
 668                 // make sure we don't add more ammo than we have
 669                 float load = min(actor.reload_ammo_amount - actor.clip_load, actor.(actor.ammo_field));
 670                 actor.clip_load += load;
 671                 actor.(actor.ammo_field) -= load;
 672         }
 673         actor.(weapon_load[PS(actor).m_weapon.m_id]) = actor.clip_load;
 674
 675         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 676         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 677         // so your weapon is disabled for a few seconds without reason
 678
 679         // ATTACK_FINISHED(actor, slot) -= actor.reload_time - 1;
 680
 681         Weapon wpn = Weapons_from(PS(actor).m_weapon.m_id);
 682         w_ready(wpn, actor, weaponentity, PHYS_INPUT_BUTTON_ATCK(actor) | (PHYS_INPUT_BUTTON_ATCK2(actor) << 1));
 683 }
 684
 685 void W_Reload(entity actor, float sent_ammo_min, string sent_sound)
 686 {
 687         .entity weaponentity = weaponentities[0];
 688         // set global values to work with
 689         Weapon e = PS(actor).m_weapon;
 690
 691         if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
 692
 693         actor.reload_ammo_min = sent_ammo_min;
 694         actor.reload_ammo_amount = e.reloading_ammo;
 695         actor.reload_time = e.reloading_time;
 696         actor.reload_sound = sent_sound;
 697
 698         // don't reload weapons that don't have the RELOADABLE flag
 699         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
 700         {
 701                 LOG_TRACE(
 702                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
 703                 return;
 704         }
 705
 706         // return if reloading is disabled for this weapon
 707         if (!actor.reload_ammo_amount) return;
 708
 709         // our weapon is fully loaded, no need to reload
 710         if (actor.clip_load >= actor.reload_ammo_amount) return;
 711
 712         // no ammo, so nothing to load
 713         if (actor.ammo_field != ammo_none)
 714         {
 715                 if (!actor.(actor.ammo_field) && actor.reload_ammo_min)
 716                 {
 717                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 718                         {
 719                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
 720                                 {
 721                                         play2(actor, SND(UNAVAILABLE));
 722                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", PS(actor).m_weapon.m_name, "\n"));
 723                                         actor.reload_complain = time + 1;
 724                                 }
 725                                 // switch away if the amount of ammo is not enough to keep using this weapon
 726                                 Weapon w = PS(actor).m_weapon;
 727                                 if (!(w.wr_checkammo1(w) + w.wr_checkammo2(w)))
 728                                 {
 729                                         actor.clip_load = -1;  // reload later
 730                                         W_SwitchToOtherWeapon(actor);
 731                                 }
 732                                 return;
 733                         }
 734                 }
 735         }
 736
 737         entity this = actor.(weaponentity);
 738         if (this)
 739         {
 740                 if (this.wframe == WFRAME_RELOAD) return;
 741
 742                 // allow switching away while reloading, but this will cause a new reload!
 743                 this.state = WS_READY;
 744         }
 745
 746         // now begin the reloading process
 747
 748         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
 749
 750         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 751         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 752         // so your weapon is disabled for a few seconds without reason
 753
 754         // ATTACK_FINISHED(actor, slot) = max(time, ATTACK_FINISHED(actor, slot)) + actor.reload_time + 1;
 755
 756         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, actor.reload_time, W_ReloadedAndReady);
 757
 758         if (actor.clip_load < 0) actor.clip_load = 0;
 759         actor.old_clip_load = actor.clip_load;
 760         actor.clip_load = actor.(weapon_load[PS(actor).m_weapon.m_id]) = -1;
 761 }
 762
 763 void W_DropEvent(.void(Weapon) event, entity player, float weapon_type, entity weapon_item)
 764 {
 765         Weapon w = Weapons_from(weapon_type);
 766         weapon_dropevent_item = weapon_item;
 767         WITH(entity, self, player, w.event(w));
 768 }