qcsrc/server/world.qc

   1 #include "world.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/gamemodes/sv_rules.qh>
   7 #include <common/items/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/target/music.qh>
  10 #include <common/mapobjects/trigger/hurt.qh>
  11 #include <common/mapobjects/trigger/secret.qh>
  12 #include <common/mapobjects/triggers.qh>
  13 #include <common/monsters/_mod.qh>
  14 #include <common/monsters/sv_monsters.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/notifications/all.qh>
  17 #include <common/physics/player.qh>
  18 #include <common/playerstats.qh>
  19 #include <common/state.qh>
  20 #include <common/stats.qh>
  21 #include <common/teams.qh>
  22 #include <common/util.qh>
  23 #include <common/vehicles/all.qh>
  24 #include <common/weapons/_all.qh>
  25 #include <server/anticheat.qh>
  26 #include <server/antilag.qh>
  27 #include <server/bot/api.qh>
  28 #include <server/campaign.qh>
  29 #include <server/cheats.qh>
  30 #include <server/client.qh>
  31 #include <server/command/common.qh>
  32 #include <server/command/getreplies.qh>
  33 #include <server/command/sv_cmd.qh>
  34 #include <server/command/vote.qh>
  35 #include <server/damage.qh>
  36 #include <server/gamelog.qh>
  37 #include <server/hook.qh>
  38 #include <server/intermission.qh>
  39 #include <server/ipban.qh>
  40 #include <server/items/items.qh>
  41 #include <server/main.qh>
  42 #include <server/mapvoting.qh>
  43 #include <server/mutators/_mod.qh>
  44 #include <server/race.qh>
  45 #include <server/scores.qh>
  46 #include <server/scores_rules.qh>
  47 #include <server/spawnpoints.qh>
  48 #include <server/teamplay.qh>
  49 #include <server/weapons/common.qh>
  50 #include <server/weapons/weaponstats.qh>
  51
  52 const float LATENCY_THINKRATE = 10;
  53 .float latency_sum;
  54 .float latency_cnt;
  55 .float latency_time;
  56 entity pingplreport;
  57 void PingPLReport_Think(entity this)
  58 {
  59         float delta;
  60         entity e;
  61
  62         delta = 3 / maxclients;
  63         if(delta < sys_frametime)
  64                 delta = 0;
  65         this.nextthink = time + delta;
  66
  67         e = edict_num(this.cnt + 1);
  68         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  69         {
  70                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  71                 WriteByte(MSG_BROADCAST, this.cnt);
  72                 WriteShort(MSG_BROADCAST, bound(1, rint(CS(e).ping), 32767));
  73                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  74                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  75
  76                 // record latency times for clients throughout the match so we can report it to playerstats
  77                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  78                 {
  79                         CS(e).latency_sum += CS(e).ping;
  80                         CS(e).latency_cnt += 1;
  81                         CS(e).latency_time = time;
  82                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  83                 }
  84         }
  85         else
  86         {
  87                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  88                 WriteByte(MSG_BROADCAST, this.cnt);
  89                 WriteShort(MSG_BROADCAST, 0);
  90                 WriteByte(MSG_BROADCAST, 0);
  91                 WriteByte(MSG_BROADCAST, 0);
  92         }
  93         this.cnt = (this.cnt + 1) % maxclients;
  94 }
  95 void PingPLReport_Spawn()
  96 {
  97         pingplreport = new_pure(pingplreport);
  98         setthink(pingplreport, PingPLReport_Think);
  99         pingplreport.nextthink = time;
 100 }
 101
 102 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
 103
 104 void SetDefaultAlpha()
 105 {
 106         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 107         {
 108                 default_player_alpha = autocvar_g_player_alpha;
 109                 if(default_player_alpha == 0)
 110                         default_player_alpha = 1;
 111                 default_weapon_alpha = default_player_alpha;
 112         }
 113 }
 114
 115 void GotoFirstMap(entity this)
 116 {
 117         float n;
 118         if(autocvar__sv_init)
 119         {
 120                 // cvar_set("_sv_init", "0");
 121                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 122                 // to this "init" map on a dedicated server will cause no permanent
 123                 // harm
 124                 if(autocvar_g_maplist_shuffle)
 125                         ShuffleMaplist();
 126                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 127                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 128
 129                 MapInfo_Enumerate();
 130                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 131
 132                 if(!DoNextMapOverride(1))
 133                         GotoNextMap(1);
 134
 135                 return;
 136         }
 137
 138         if(time < 5)
 139         {
 140                 this.nextthink = time;
 141         }
 142         else
 143         {
 144                 this.nextthink = time + 1;
 145                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 146         }
 147 }
 148
 149 void cvar_changes_init()
 150 {
 151         float h;
 152         string k, v, d;
 153         float n, i, adding, pureadding;
 154
 155         strfree(cvar_changes);
 156         strfree(cvar_purechanges);
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = true;
 164         pureadding = true;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173 #define BADVALUE(p, val) if (k == p && v == val) continue
 174
 175                 // general excludes and namespaces for server admin used cvars
 176                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 177
 178                 // internal
 179                 BADPREFIX("csqc_");
 180                 BADPREFIX("cvar_check_");
 181                 BADCVAR("gamecfg");
 182                 BADCVAR("g_configversion");
 183                 BADCVAR("halflifebsp");
 184                 BADCVAR("sv_mapformat_is_quake2");
 185                 BADCVAR("sv_mapformat_is_quake3");
 186                 BADPREFIX("sv_world");
 187
 188                 // client
 189                 BADPREFIX("chase_");
 190                 BADPREFIX("cl_");
 191                 BADPREFIX("con_");
 192                 BADPREFIX("scoreboard_");
 193                 BADPREFIX("g_campaign");
 194                 BADPREFIX("g_waypointsprite_");
 195                 BADPREFIX("gl_");
 196                 BADPREFIX("joy");
 197                 BADPREFIX("hud_");
 198                 BADPREFIX("m_");
 199                 BADPREFIX("menu_");
 200                 BADPREFIX("net_slist_");
 201                 BADPREFIX("r_");
 202                 BADPREFIX("sbar_");
 203                 BADPREFIX("scr_");
 204                 BADPREFIX("snd_");
 205                 BADPREFIX("show");
 206                 BADPREFIX("sensitivity");
 207                 BADPREFIX("userbind");
 208                 BADPREFIX("v_");
 209                 BADPREFIX("vid_");
 210                 BADPREFIX("crosshair");
 211                 BADCVAR("mod_q3bsp_lightmapmergepower");
 212                 BADCVAR("mod_q3bsp_nolightmaps");
 213                 BADCVAR("fov");
 214                 BADCVAR("mastervolume");
 215                 BADCVAR("volume");
 216                 BADCVAR("bgmvolume");
 217                 BADCVAR("in_pitch_min");
 218                 BADCVAR("in_pitch_max");
 219
 220                 // private
 221                 BADCVAR("developer");
 222                 BADCVAR("log_dest_udp");
 223                 BADCVAR("net_address");
 224                 BADCVAR("net_address_ipv6");
 225                 BADCVAR("port");
 226                 BADCVAR("savedgamecfg");
 227                 BADCVAR("serverconfig");
 228                 BADCVAR("sv_autoscreenshot");
 229                 BADCVAR("sv_heartbeatperiod");
 230                 BADCVAR("sv_vote_master_password");
 231                 BADCVAR("sys_colortranslation");
 232                 BADCVAR("sys_specialcharactertranslation");
 233                 BADCVAR("timeformat");
 234                 BADCVAR("timestamps");
 235                 BADCVAR("g_require_stats");
 236                 BADPREFIX("developer_");
 237                 BADPREFIX("g_ban_");
 238                 BADPREFIX("g_banned_list");
 239                 BADPREFIX("g_require_stats_");
 240                 BADPREFIX("g_chat_flood_");
 241                 BADPREFIX("g_ghost_items");
 242                 BADPREFIX("g_playerstats_");
 243                 BADPREFIX("g_voice_flood_");
 244                 BADPREFIX("log_file");
 245                 BADPREFIX("quit_");
 246                 BADPREFIX("rcon_");
 247                 BADPREFIX("sv_allowdownloads");
 248                 BADPREFIX("sv_autodemo");
 249                 BADPREFIX("sv_curl_");
 250                 BADPREFIX("sv_eventlog");
 251                 BADPREFIX("sv_logscores_");
 252                 BADPREFIX("sv_master");
 253                 BADPREFIX("sv_weaponstats_");
 254                 BADPREFIX("sv_waypointsprite_");
 255                 BADCVAR("rescan_pending");
 256
 257                 // these can contain player IDs, so better hide
 258                 BADPREFIX("g_forced_team_");
 259                 BADCVAR("sv_muteban_list");
 260                 BADCVAR("sv_voteban_list");
 261                 BADCVAR("sv_allow_customplayermodels_idlist");
 262                 BADCVAR("sv_allow_customplayermodels_speciallist");
 263
 264                 // mapinfo
 265                 BADCVAR("fraglimit");
 266                 BADCVAR("g_arena");
 267                 BADCVAR("g_assault");
 268                 BADCVAR("g_ca");
 269                 BADCVAR("g_ca_teams");
 270                 BADCVAR("g_conquest");
 271                 BADCVAR("g_conquest_teams");
 272                 BADCVAR("g_ctf");
 273                 BADCVAR("g_cts");
 274                 BADCVAR("g_dotc");
 275                 BADCVAR("g_dm");
 276                 BADCVAR("g_domination");
 277                 BADCVAR("g_domination_default_teams");
 278                 BADCVAR("g_duel");
 279                 BADCVAR("g_duel_not_dm_maps");
 280                 BADCVAR("g_freezetag");
 281                 BADCVAR("g_freezetag_teams");
 282                 BADCVAR("g_invasion_type");
 283                 BADCVAR("g_jailbreak");
 284                 BADCVAR("g_jailbreak_teams");
 285                 BADCVAR("g_keepaway");
 286                 BADCVAR("g_keyhunt");
 287                 BADCVAR("g_keyhunt_teams");
 288                 BADCVAR("g_lms");
 289                 BADCVAR("g_nexball");
 290                 BADCVAR("g_onslaught");
 291                 BADCVAR("g_race");
 292                 BADCVAR("g_race_laps_limit");
 293                 BADCVAR("g_race_qualifying_timelimit");
 294                 BADCVAR("g_race_qualifying_timelimit_override");
 295                 BADCVAR("g_runematch");
 296                 BADCVAR("g_shootfromeye");
 297                 BADCVAR("g_snafu");
 298                 BADCVAR("g_survival");
 299                 BADCVAR("g_survival_not_dm_maps");
 300                 BADCVAR("g_tdm");
 301                 BADCVAR("g_tdm_on_dm_maps");
 302                 BADCVAR("g_tdm_teams");
 303                 BADCVAR("g_vip");
 304                 BADCVAR("leadlimit");
 305                 BADCVAR("nextmap");
 306                 BADCVAR("teamplay");
 307                 BADCVAR("timelimit");
 308                 BADCVAR("g_mapinfo_settemp_acl");
 309                 BADCVAR("g_mapinfo_ignore_warnings");
 310                 BADCVAR("g_maplist_ignore_sizes");
 311                 BADCVAR("g_maplist_sizes_count_bots");
 312
 313                 // long
 314                 BADCVAR("hostname");
 315                 BADCVAR("g_maplist");
 316                 BADCVAR("g_maplist_mostrecent");
 317                 BADCVAR("sv_motd");
 318
 319                 v = cvar_string(k);
 320                 d = cvar_defstring(k);
 321                 if(v == d)
 322                         continue;
 323
 324                 if(adding)
 325                 {
 326                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 327                         if(strlen(cvar_changes) > 16384)
 328                         {
 329                                 cvar_changes = "// too many settings have been changed to show them here\n";
 330                                 adding = 0;
 331                         }
 332                 }
 333
 334                 // now check if the changes are actually gameplay relevant
 335
 336                 // does nothing gameplay relevant
 337                 BADCVAR("captureleadlimit_override");
 338                 BADCVAR("condump_stripcolors");
 339                 BADCVAR("gameversion");
 340                 BADCVAR("fs_gamedir");
 341                 BADCVAR("g_allow_oldvortexbeam");
 342                 BADCVAR("g_balance_kill_delay");
 343                 BADCVAR("g_buffs_pickup_anyway");
 344                 BADCVAR("g_buffs_randomize");
 345                 BADCVAR("g_buffs_randomize_teamplay");
 346                 BADCVAR("g_campcheck_distance");
 347                 BADCVAR("g_chatsounds");
 348                 BADCVAR("g_ca_point_leadlimit");
 349                 BADCVAR("g_ca_point_limit");
 350                 BADCVAR("g_ca_spectate_enemies");
 351                 BADCVAR("g_ctf_captimerecord_always");
 352                 BADCVAR("g_ctf_flag_glowtrails");
 353                 BADCVAR("g_ctf_dynamiclights");
 354                 BADCVAR("g_ctf_flag_pickup_verbosename");
 355                 BADCVAR("g_ctf_flagcarrier_auto_helpme_damage");
 356                 BADPRESUFFIX("g_ctf_flag_", "_model");
 357                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 358                 BADCVAR("g_domination_point_leadlimit");
 359                 BADCVAR("g_forced_respawn");
 360                 BADCVAR("g_freezetag_point_leadlimit");
 361                 BADCVAR("g_freezetag_point_limit");
 362                 BADCVAR("g_glowtrails");
 363                 BADCVAR("g_hats");
 364                 BADCVAR("g_casings");
 365                 BADCVAR("g_invasion_point_limit");
 366                 BADCVAR("g_jump_grunt");
 367                 BADCVAR("g_keepaway_ballcarrier_effects");
 368                 BADCVAR("g_keepawayball_effects");
 369                 BADCVAR("g_keyhunt_point_leadlimit");
 370                 BADCVAR("g_nexball_goalleadlimit");
 371                 BADCVAR("g_new_toys_autoreplace");
 372                 BADCVAR("g_new_toys_use_pickupsound");
 373                 BADCVAR("g_physics_predictall");
 374                 BADCVAR("g_piggyback");
 375                 BADCVAR("g_playerclip_collisions");
 376                 BADCVAR("g_spawn_alloweffects");
 377                 BADCVAR("g_tdm_point_leadlimit");
 378                 BADCVAR("g_tdm_point_limit");
 379                 BADCVAR("leadlimit_and_fraglimit");
 380                 BADCVAR("leadlimit_override");
 381                 BADCVAR("pausable");
 382                 BADCVAR("sv_announcer");
 383                 BADCVAR("sv_checkforpacketsduringsleep");
 384                 BADCVAR("sv_damagetext");
 385                 BADCVAR("sv_db_saveasdump");
 386                 BADCVAR("sv_intermission_cdtrack");
 387                 BADCVAR("sv_mapchange_delay");
 388                 BADCVAR("sv_minigames");
 389                 BADCVAR("sv_namechangetimer");
 390                 BADCVAR("sv_precacheplayermodels");
 391                 BADCVAR("sv_qcphysics");
 392                 BADCVAR("sv_radio");
 393                 BADCVAR("sv_stepheight");
 394                 BADCVAR("sv_timeout");
 395                 BADCVAR("sv_weapons_modeloverride");
 396                 BADCVAR("w_prop_interval");
 397                 BADPREFIX("chat_");
 398                 BADPREFIX("crypto_");
 399                 BADPREFIX("gameversion_");
 400                 BADPREFIX("g_chat_");
 401                 BADPREFIX("g_ctf_captimerecord_");
 402                 BADPREFIX("g_hats_");
 403                 BADPREFIX("g_maplist_");
 404                 BADPREFIX("g_mod_");
 405                 BADPREFIX("g_respawn_");
 406                 BADPREFIX("net_");
 407                 BADPREFIX("notification_");
 408                 BADPREFIX("prvm_");
 409                 BADPREFIX("skill_");
 410                 BADPREFIX("sv_allow_");
 411                 BADPREFIX("sv_cullentities_");
 412                 BADPREFIX("sv_maxidle");
 413                 BADPREFIX("sv_minigames_");
 414                 BADPREFIX("sv_radio_");
 415                 BADPREFIX("sv_timeout_");
 416                 BADPREFIX("sv_vote_");
 417                 BADPREFIX("timelimit_");
 418
 419                 // allowed changes to server admins (please sync this to server.cfg)
 420                 // vi commands:
 421                 //   :/"impure"/,$d
 422                 //   :g!,^\/\/[^ /],d
 423                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 424                 //   :%!sort
 425                 // yes, this does contain some redundant stuff, don't really care
 426                 BADPREFIX("bot_ai_");
 427                 BADCVAR("bot_config_file");
 428                 BADCVAR("bot_number");
 429                 BADCVAR("bot_prefix");
 430                 BADCVAR("bot_suffix");
 431                 BADCVAR("capturelimit_override");
 432                 BADCVAR("fraglimit_override");
 433                 BADCVAR("gametype");
 434                 BADCVAR("g_antilag");
 435                 BADCVAR("g_balance_teams");
 436                 BADCVAR("g_balance_teams_prevent_imbalance");
 437                 BADCVAR("g_balance_teams_scorefactor");
 438                 BADCVAR("g_ban_sync_trusted_servers");
 439                 BADCVAR("g_ban_sync_uri");
 440                 BADCVAR("g_buffs");
 441                 BADCVAR("g_ca_teams_override");
 442                 BADCVAR("g_ctf_fullbrightflags");
 443                 BADCVAR("g_ctf_ignore_frags");
 444                 BADCVAR("g_ctf_leaderboard");
 445                 BADCVAR("g_domination_point_limit");
 446                 BADCVAR("g_domination_teams_override");
 447                 BADCVAR("g_freezetag_revive_spawnshield");
 448                 BADCVAR("g_freezetag_teams_override");
 449                 BADCVAR("g_friendlyfire");
 450                 BADCVAR("g_fullbrightitems");
 451                 BADCVAR("g_fullbrightplayers");
 452                 BADCVAR("g_keyhunt_point_limit");
 453                 BADCVAR("g_keyhunt_teams_override");
 454                 BADCVAR("g_lms_lives_override");
 455                 BADCVAR("g_maplist");
 456                 BADCVAR("g_maxplayers");
 457                 BADCVAR("g_mirrordamage");
 458                 BADCVAR("g_nexball_goallimit");
 459                 BADCVAR("g_norecoil");
 460                 BADCVAR("g_physics_clientselect");
 461                 BADCVAR("g_pinata");
 462                 BADCVAR("g_powerups");
 463                 BADCVAR("g_powerups_drop_ondeath");
 464                 BADCVAR("g_player_brightness");
 465                 BADCVAR("g_rocket_flying");
 466                 BADCVAR("g_rocket_flying_disabledelays");
 467                 BADPREFIX("g_spawnshield");
 468                 BADCVAR("g_start_delay");
 469                 BADCVAR("g_superspectate");
 470                 BADCVAR("g_tdm_teams_override");
 471                 BADCVAR("g_warmup");
 472                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 473                 BADCVAR("hostname");
 474                 BADCVAR("log_file");
 475                 BADCVAR("maxplayers");
 476                 BADCVAR("minplayers");
 477                 BADCVAR("minplayers_per_team");
 478                 BADCVAR("net_address");
 479                 BADCVAR("port");
 480                 BADCVAR("rcon_password");
 481                 BADCVAR("rcon_restricted_commands");
 482                 BADCVAR("rcon_restricted_password");
 483                 BADCVAR("skill");
 484                 BADCVAR("sv_adminnick");
 485                 BADCVAR("sv_autoscreenshot");
 486                 BADCVAR("sv_autotaunt");
 487                 BADCVAR("sv_curl_defaulturl");
 488                 BADCVAR("sv_defaultcharacter");
 489                 BADCVAR("sv_defaultcharacterskin");
 490                 BADCVAR("sv_defaultplayercolors");
 491                 BADCVAR("sv_defaultplayermodel");
 492                 BADCVAR("sv_defaultplayerskin");
 493                 BADCVAR("sv_maxrate");
 494                 BADCVAR("sv_motd");
 495                 BADCVAR("sv_public");
 496                 BADCVAR("sv_showfps");
 497                 BADCVAR("sv_showspectators");
 498                 BADCVAR("sv_status_privacy");
 499                 BADCVAR("sv_taunt");
 500                 BADCVAR("sv_vote_call");
 501                 BADCVAR("sv_vote_commands");
 502                 BADCVAR("sv_vote_majority_factor");
 503                 BADCVAR("sv_vote_master");
 504                 BADCVAR("sv_vote_master_commands");
 505                 BADCVAR("sv_vote_master_password");
 506                 BADCVAR("sv_vote_simple_majority_factor");
 507                 BADVALUE("sys_ticrate", "0.0166667");
 508                 BADVALUE("sys_ticrate", "0.0333333");
 509                 BADCVAR("teamplay_mode");
 510                 BADCVAR("timelimit_override");
 511                 BADPREFIX("g_warmup_");
 512                 BADPREFIX("sv_info_");
 513                 BADPREFIX("sv_ready_restart_");
 514
 515                 // mutators that announce themselves properly to the server browser
 516                 BADCVAR("g_instagib");
 517                 BADCVAR("g_new_toys");
 518                 BADCVAR("g_nix");
 519                 BADCVAR("g_grappling_hook");
 520                 BADCVAR("g_jetpack");
 521
 522                 // temporary for testing
 523                 // TODO remove before 0.8.3 release
 524                 BADCVAR("g_ca_weaponarena");
 525                 BADCVAR("g_freezetag_weaponarena");
 526                 BADCVAR("g_lms_weaponarena");
 527                 BADCVAR("g_ctf_stalemate_time");
 528
 529 #undef BADPRESUFFIX
 530 #undef BADPREFIX
 531 #undef BADCVAR
 532 #undef BADVALUE
 533
 534                 if(pureadding)
 535                 {
 536                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 537                         if(strlen(cvar_purechanges) > 16384)
 538                         {
 539                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 540                                 pureadding = 0;
 541                         }
 542                 }
 543                 ++cvar_purechanges_count;
 544                 // WARNING: this variable is used for the server list
 545                 // NEVER dare to skip this code!
 546                 // Hacks to intentionally appearing as "pure server" even though you DO have
 547                 // modified settings may be punished by removal from the server list.
 548                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 549                 // though.
 550         }
 551         buf_del(h);
 552         if(cvar_changes == "")
 553                 cvar_changes = "// this server runs at default server settings\n";
 554         else
 555                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 556         cvar_changes = strzone(cvar_changes);
 557         if(cvar_purechanges == "")
 558                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 559         else
 560                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 561         cvar_purechanges = strzone(cvar_purechanges);
 562 }
 563
 564 entity randomseed;
 565 bool RandomSeed_Send(entity this, entity to, int sf)
 566 {
 567         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 568         WriteShort(MSG_ENTITY, this.cnt);
 569         return true;
 570 }
 571 void RandomSeed_Think(entity this)
 572 {
 573         this.cnt = bound(0, floor(random() * 65536), 65535);
 574         this.nextthink = time + 5;
 575
 576         this.SendFlags |= 1;
 577 }
 578 void RandomSeed_Spawn()
 579 {
 580         randomseed = new_pure(randomseed);
 581         setthink(randomseed, RandomSeed_Think);
 582         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 583
 584         getthink(randomseed)(randomseed); // sets random seed and nextthink
 585 }
 586
 587 spawnfunc(__init_dedicated_server)
 588 {
 589         // handler for _init/_init map (only for dedicated server initialization)
 590
 591         world_initialized = -1; // don't complain
 592
 593         delete_fn = remove_unsafely;
 594
 595         entity e = new(GotoFirstMap);
 596         setthink(e, GotoFirstMap);
 597         e.nextthink = time; // this is usually 1 at this point
 598
 599         e = new(info_player_deathmatch);  // safeguard against player joining
 600
 601     // assign reflectively to avoid "assignment to world" warning
 602     for (int i = 0, n = numentityfields(); i < n; ++i) {
 603         string k = entityfieldname(i);
 604         if (k == "classname") {
 605             // safeguard against various stuff ;)
 606             putentityfieldstring(i, this, "worldspawn");
 607             break;
 608         }
 609     }
 610
 611         // needs to be done so early because of the constants they create
 612         static_init();
 613         static_init_late();
 614         static_init_precache();
 615
 616         IL_PUSH(g_spawnpoints, e); // just incase
 617
 618         MapInfo_Enumerate();
 619         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 620 }
 621
 622 void __init_dedicated_server_shutdown() {
 623         MapInfo_Shutdown();
 624 }
 625
 626 STATIC_INIT_EARLY(maxclients)
 627 {
 628         maxclients = 0;
 629         for (entity head = nextent(NULL); head; head = nextent(head)) {
 630                 ++maxclients;
 631         }
 632 }
 633
 634 void GameplayMode_DelayedInit(entity this)
 635 {
 636         if(!scores_initialized)
 637                 ScoreRules_generic();
 638 }
 639
 640 void InitGameplayMode()
 641 {
 642         VoteReset();
 643
 644         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 645         get_mi_min_max(1);
 646         // assign reflectively to avoid "assignment to world" warning
 647         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 648             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 649             if (v) {
 650             putentityfieldstring(i, world, sprintf("%v", v));
 651             if (++done == 2) break;
 652         }
 653         }
 654         // currently, NetRadiant's limit is 131072 qu for each side
 655         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 656         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 657         // in case somebody makes extremely large maps
 658         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 659
 660         MapInfo_LoadMapSettings(mapname);
 661         GameRules_teams(false);
 662
 663         if (!cvar_value_issafe(world.fog))
 664         {
 665                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 666                 world.fog = string_null;
 667         }
 668         if(MapInfo_Map_fog != "")
 669         {
 670                 if(MapInfo_Map_fog == "none")
 671                         world.fog = string_null;
 672                 else
 673                         world.fog = strzone(MapInfo_Map_fog);
 674         }
 675         clientstuff = strzone(MapInfo_Map_clientstuff);
 676
 677         MapInfo_ClearTemps();
 678
 679         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 680
 681         cache_mutatormsg = strzone("");
 682         cache_lastmutatormsg = strzone("");
 683
 684         InitializeEntity(NULL, GameplayMode_DelayedInit, INITPRIO_GAMETYPE_FALLBACK);
 685 }
 686
 687 bool world_already_spawned;
 688 spawnfunc(worldspawn)
 689 {
 690         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 691
 692         if (autocvar_sv_termsofservice_url && autocvar_sv_termsofservice_url != "")
 693         {
 694                 strcpy(sv_termsofservice_url_escaped, strreplace(":", "|", autocvar_sv_termsofservice_url));
 695         }
 696         else
 697         {
 698                 strcpy(sv_termsofservice_url_escaped, "INVALID");
 699         }
 700
 701         bool wantrestart = false;
 702         {
 703                 if (!server_is_dedicated)
 704                 {
 705                         // force unloading of server pk3 files when starting a listen server
 706                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 707                         // restore csqc_progname too
 708                         string expect = "csprogs.dat";
 709                         wantrestart = cvar_string("csqc_progname") != expect;
 710                         cvar_set("csqc_progname", expect);
 711                 }
 712                 else
 713                 {
 714                         // Try to use versioned csprogs from pk3
 715                         // Only ever use versioned csprogs.dat files on dedicated servers;
 716                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 717                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 718                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 719                         string select = "csprogs.dat";
 720                         if (fexists(pk3csprogs)) select = pk3csprogs;
 721                         if (cvar_string("csqc_progname") != select)
 722                         {
 723                                 cvar_set("csqc_progname", select);
 724                                 wantrestart = true;
 725                         }
 726                         // Check for updates on startup
 727                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 728                         int sentinel = fopen("progs.txt", FILE_READ);
 729                         if (sentinel >= 0)
 730                         {
 731                                 string switchversion = fgets(sentinel);
 732                                 fclose(sentinel);
 733                                 if (switchversion != "" && switchversion != WATERMARK)
 734                                 {
 735                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 736                                         // if it doesn't exist, assume either:
 737                                         //   a) the current program was overwritten
 738                                         //   b) this is a client only update
 739                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 740                                         if (fexists(newprogs))
 741                                         {
 742                                                 cvar_set("sv_progs", newprogs);
 743                                                 wantrestart = true;
 744                                         }
 745                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 746                                         if (fexists(newcsprogs))
 747                                         {
 748                                                 cvar_set("csqc_progname", newcsprogs);
 749                                                 wantrestart = true;
 750                                         }
 751                                 }
 752                         }
 753                 }
 754                 if (wantrestart)
 755                 {
 756                         LOG_INFO("Restart requested");
 757                         changelevel(mapname);
 758                         // let initialization continue, shutdown depends on it
 759                 }
 760         }
 761
 762         if(world_already_spawned)
 763                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 764         world_already_spawned = true;
 765
 766         delete_fn = remove_safely; // during spawning, watch what you remove!
 767
 768         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 769
 770         // default to RACE_RECORD, can be overwritten by gamemodes
 771         record_type = RACE_RECORD;
 772
 773         // needs to be done so early because of the constants they create
 774         static_init();
 775
 776         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 777
 778         TemporaryDB = db_create();
 779
 780         // 0 normal
 781         lightstyle(0, "m");
 782
 783         // 1 FLICKER (first variety)
 784         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 785
 786         // 2 SLOW STRONG PULSE
 787         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 788
 789         // 3 CANDLE (first variety)
 790         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 791
 792         // 4 FAST STROBE
 793         lightstyle(4, "mamamamamama");
 794
 795         // 5 GENTLE PULSE 1
 796         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 797
 798         // 6 FLICKER (second variety)
 799         lightstyle(6, "nmonqnmomnmomomno");
 800
 801         // 7 CANDLE (second variety)
 802         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 803
 804         // 8 CANDLE (third variety)
 805         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 806
 807         // 9 SLOW STROBE (fourth variety)
 808         lightstyle(9, "aaaaaaaazzzzzzzz");
 809
 810         // 10 FLUORESCENT FLICKER
 811         lightstyle(10, "mmamammmmammamamaaamammma");
 812
 813         // 11 SLOW PULSE NOT FADE TO BLACK
 814         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 815
 816         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 817
 818         // 63 testing
 819         lightstyle(63, "a");
 820
 821         if(autocvar_g_campaign)
 822                 CampaignPreInit();
 823         else
 824                 PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 825
 826         Map_MarkAsRecent(mapname);
 827
 828         InitGameplayMode();
 829         static_init_late();
 830         static_init_precache();
 831         readlevelcvars();
 832
 833         GameRules_limit_fallbacks();
 834
 835         if(warmup_limit == 0)
 836                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 837
 838         player_count = 0;
 839         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 840         if(bot_waypoints_for_items == 1)
 841                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 842                         bot_waypoints_for_items = 0;
 843
 844         WaypointSprite_Init();
 845
 846         GameLogInit(); // prepare everything
 847         // NOTE for matchid:
 848         // changing the logic generating it is okay. But:
 849         // it HAS to stay <= 64 chars
 850         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 851         if(autocvar_sv_eventlog)
 852         {
 853                 string num = strftime_s(); // strftime(false, "%s") isn't reliable, see strftime_s description
 854                 string s = sprintf("%s.%s.%06d", itos(autocvar_sv_eventlog_files_counter), num, floor(random() * 1000000));
 855                 matchid = strzone(s);
 856
 857                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 858                 s = ":gameinfo:mutators:LIST";
 859
 860                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 861                 s = M_ARGV(0, string);
 862
 863                 // initialiation stuff, not good in the mutator system
 864                 if(!autocvar_g_use_ammunition)
 865                         s = strcat(s, ":no_use_ammunition");
 866
 867                 // initialiation stuff, not good in the mutator system
 868                 if(autocvar_g_pickup_items == 0)
 869                         s = strcat(s, ":no_pickup_items");
 870                 if(autocvar_g_pickup_items > 0)
 871                         s = strcat(s, ":pickup_items");
 872
 873                 // initialiation stuff, not good in the mutator system
 874                 if(autocvar_g_weaponarena != "0")
 875                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 876
 877                 // TODO to mutator system
 878                 if(autocvar_g_norecoil)
 879                         s = strcat(s, ":norecoil");
 880
 881                 GameLogEcho(s);
 882                 GameLogEcho(":gameinfo:end");
 883         }
 884         else
 885                 matchid = strzone(ftos(random()));
 886
 887         cvar_set("nextmap", "");
 888
 889         SetDefaultAlpha();
 890
 891         if(autocvar_g_campaign)
 892                 CampaignPostInit();
 893
 894         Ban_LoadBans();
 895
 896         MapInfo_Enumerate();
 897         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 898
 899         q3compat = BITSET(q3compat, Q3COMPAT_ARENA, fexists(strcat("scripts/", mapname, ".arena")));
 900         q3compat = BITSET(q3compat, Q3COMPAT_DEFI, fexists(strcat("scripts/", mapname, ".defi")));
 901
 902         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 903         {
 904                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 905                 if(fd != -1)
 906                 {
 907                         string s;
 908                         while((s = fgets(fd)))
 909                         {
 910                                 int l = tokenize_console(s);
 911                                 if(l < 2)
 912                                         continue;
 913                                 if(argv(0) == "cd")
 914                                 {
 915                                         string trackname = argv(2);
 916                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 917                                         LOG_INFO("  cdtrack ", trackname);
 918                                         if (cvar_value_issafe(trackname))
 919                                         {
 920                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 921                                                 strcpy(clientstuff, newstuff);
 922                                         }
 923                                 }
 924                                 else if(argv(0) == "fog")
 925                                 {
 926                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 927                                         LOG_INFO("  \"fog\" \"", s, "\"");
 928                                 }
 929                                 else if(argv(0) == "set")
 930                                 {
 931                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 932                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 933                                 }
 934                                 else if(argv(0) != "//")
 935                                 {
 936                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 937                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 938                                 }
 939                         }
 940                         fclose(fd);
 941                 }
 942         }
 943
 944         WeaponStats_Init();
 945
 946         Nagger_Init();
 947
 948         // set up information replies for clients and server to use
 949         maplist_reply = strzone(getmaplist());
 950         lsmaps_reply = strzone(getlsmaps());
 951         monsterlist_reply = strzone(getmonsterlist());
 952         bool records_available = false;
 953         for(int i = 0; i < 10; ++i)
 954         {
 955                 string s = getrecords(i);
 956                 if (s != "")
 957                 {
 958                         records_reply[i] = strzone(s);
 959                         records_available = true;
 960                 }
 961         }
 962         if (!records_available)
 963                 records_reply[0] = "No records available for the current game mode.\n";
 964         ladder_reply = strzone(getladder());
 965         rankings_reply = strzone(getrankings());
 966
 967         // begin other init
 968         ClientInit_Spawn();
 969         RandomSeed_Spawn();
 970         PingPLReport_Spawn();
 971
 972         CheatInit();
 973
 974         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 975
 976         // fill sv_curl_serverpackages from .serverpackage files
 977         if (autocvar_sv_curl_serverpackages_auto)
 978         {
 979                 string s = "csprogs-" WATERMARK ".dat";
 980                 // remove automatically managed files from the list to prevent duplicates
 981                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 982                 {
 983                         string pkg = argv(i);
 984                         if (startsWith(pkg, "csprogs-")) continue;
 985                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 986                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 987                         s = cons(s, pkg);
 988                 }
 989                 // add automatically managed files to the list
 990                 #define X(match) MACRO_BEGIN \
 991                         int fd = search_begin(match, true, false); \
 992                         if (fd >= 0) \
 993                         { \
 994                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 995                                 { \
 996                                         s = cons(s, search_getfilename(fd, i)); \
 997                                 } \
 998                                 search_end(fd); \
 999                         } \
1000                 MACRO_END
1001                 X("*-serverpackage.txt");
1002                 X("*.serverpackage");
1003                 #undef X
1004                 cvar_set("sv_curl_serverpackages", s);
1005         }
1006
1007         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
1008         modname = "Xonotic";
1009         // physics/balance/config changes that count as mod
1010         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
1011                 modname = cvar_string("g_mod_physics");
1012         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
1013                 modname = cvar_string("g_mod_balance");
1014         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
1015                 modname = cvar_string("g_mod_config");
1016         // extra mutators that deserve to count as mod
1017         MUTATOR_CALLHOOK(SetModname, modname);
1018         modname = M_ARGV(0, string);
1019
1020         // save it for later
1021         modname = strzone(modname);
1022
1023         WinningConditionHelper(this); // set worldstatus
1024
1025         world_initialized = 1;
1026         __spawnfunc_spawn_all();
1027 }
1028
1029 spawnfunc(light)
1030 {
1031         //makestatic (this); // Who the f___ did that?
1032         delete(this);
1033 }
1034
1035 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance, bool frompos)
1036 {
1037     float m = e.dphitcontentsmask;
1038     e.dphitcontentsmask = goodcontents | badcontents;
1039
1040     vector org = boundmin;
1041     vector delta = boundmax - boundmin;
1042
1043     vector start, end;
1044     start = end = org;
1045     int j; // used after the loop
1046     for(j = 0; j < attempts; ++j)
1047     {
1048         start.x = org.x + random() * delta.x;
1049         start.y = org.y + random() * delta.y;
1050         start.z = org.z + random() * delta.z;
1051
1052         // rule 1: start inside world bounds, and outside
1053         // solid, and don't start from somewhere where you can
1054         // fall down to evil
1055         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1056         if (trace_fraction >= 1)
1057             continue;
1058         if (trace_startsolid)
1059             continue;
1060         if (trace_dphitcontents & badcontents)
1061             continue;
1062         if (trace_dphitq3surfaceflags & badsurfaceflags)
1063             continue;
1064
1065         // rule 2: if we are too high, lower the point
1066         if (trace_fraction * delta.z > maxaboveground)
1067             start = trace_endpos + '0 0 1' * maxaboveground;
1068         vector enddown = trace_endpos;
1069
1070         // rule 3: make sure we aren't outside the map. This only works
1071         // for somewhat well formed maps. A good rule of thumb is that
1072         // the map should have a convex outside hull.
1073         // these can be traceLINES as we already verified the starting box
1074         vector mstart = start + 0.5 * (e.mins + e.maxs);
1075         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1076         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1077             continue;
1078         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1079         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1080             continue;
1081         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1082         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1083             continue;
1084         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1085         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1086             continue;
1087         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1088         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1089             continue;
1090
1091                 // rule 4: we must "see" some spawnpoint or item
1092                 entity sp = NULL;
1093                 if(frompos)
1094                 {
1095                         if((traceline(mstart, e.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1096                                 sp = e;
1097                 }
1098                 if(!sp)
1099                 {
1100                         IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1101                         {
1102                                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1103                                 {
1104                                         sp = it;
1105                                         break;
1106                                 }
1107                         });
1108                 }
1109                 if(!sp)
1110                 {
1111                         int items_checked = 0;
1112                         IL_EACH(g_items, checkpvs(mstart, it),
1113                         {
1114                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1115                                 {
1116                                         sp = it;
1117                                         break;
1118                                 }
1119
1120                                 ++items_checked;
1121                                 if(items_checked >= attempts)
1122                                         break; // sanity
1123                         });
1124
1125                         if(!sp)
1126                                 continue;
1127                 }
1128
1129         // find a random vector to "look at"
1130         end.x = org.x + random() * delta.x;
1131         end.y = org.y + random() * delta.y;
1132         end.z = org.z + random() * delta.z;
1133         end = start + normalize(end - start) * vlen(delta);
1134
1135         // rule 4: start TO end must not be too short
1136         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1137         if(trace_startsolid)
1138             continue;
1139         if(trace_fraction < minviewdistance / vlen(delta))
1140             continue;
1141
1142         // rule 5: don't want to look at sky
1143         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1144             continue;
1145
1146         // rule 6: we must not end up in trigger_hurt
1147         if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1148             continue;
1149
1150         break;
1151     }
1152
1153     e.dphitcontentsmask = m;
1154
1155     if(j < attempts)
1156     {
1157         setorigin(e, start);
1158         e.angles = vectoangles(end - start);
1159         LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1160         return true;
1161     }
1162     return false;
1163 }
1164
1165 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1166 {
1167         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance, false);
1168 }
1169
1170 /*
1171 ===============================================================================
1172
1173 RULES
1174
1175 ===============================================================================
1176 */
1177
1178 void DumpStats(float final)
1179 {
1180         float file;
1181         string s;
1182         float to_console;
1183         float to_eventlog;
1184         float to_file;
1185         float i;
1186
1187         to_console = autocvar_sv_logscores_console;
1188         to_eventlog = autocvar_sv_eventlog;
1189         to_file = autocvar_sv_logscores_file;
1190
1191         if(!final)
1192         {
1193                 to_console = true; // always print printstats replies
1194                 to_eventlog = false; // but never print them to the event log
1195         }
1196
1197         if(to_eventlog)
1198                 if(autocvar_sv_eventlog_console)
1199                         to_console = false; // otherwise we get the output twice
1200
1201         if(final)
1202                 s = ":scores:";
1203         else
1204                 s = ":status:";
1205         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1206
1207         if(to_console)
1208                 LOG_HELP(s);
1209         if(to_eventlog)
1210                 GameLogEcho(s);
1211
1212         file = -1;
1213         if(to_file)
1214         {
1215                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1216                 if(file == -1)
1217                         to_file = false;
1218                 else
1219                         fputs(file, strcat(s, "\n"));
1220         }
1221
1222         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1223         if(to_console)
1224                 LOG_HELP(s);
1225         if(to_eventlog)
1226                 GameLogEcho(s);
1227         if(to_file)
1228                 fputs(file, strcat(s, "\n"));
1229
1230         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1231                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1232                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1233                 if(IS_PLAYER(it) || INGAME_JOINED(it))
1234                         s = strcat(s, ftos(it.team), ":");
1235                 else
1236                         s = strcat(s, "spectator:");
1237
1238                 if(to_console)
1239                         LOG_HELP(s, playername(it.netname, it.team, false));
1240                 if(to_eventlog)
1241                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it.netname, it.team, false)));
1242                 if(to_file)
1243                         fputs(file, strcat(s, playername(it.netname, it.team, false), "\n"));
1244         });
1245
1246         if(teamplay)
1247         {
1248                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1249                 if(to_console)
1250                         LOG_HELP(s);
1251                 if(to_eventlog)
1252                         GameLogEcho(s);
1253                 if(to_file)
1254                         fputs(file, strcat(s, "\n"));
1255
1256                 for(i = 1; i < 16; ++i)
1257                 {
1258                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1259                         s = strcat(s, ":", ftos(i));
1260                         if(to_console)
1261                                 LOG_HELP(s);
1262                         if(to_eventlog)
1263                                 GameLogEcho(s);
1264                         if(to_file)
1265                                 fputs(file, strcat(s, "\n"));
1266                 }
1267         }
1268
1269         if(to_console)
1270                 LOG_HELP(":end");
1271         if(to_eventlog)
1272                 GameLogEcho(":end");
1273         if(to_file)
1274         {
1275                 fputs(file, ":end\n");
1276                 fclose(file);
1277         }
1278 }
1279
1280 /*
1281 go to the next level for deathmatch
1282 only called if a time or frag limit has expired
1283 */
1284 void NextLevel()
1285 {
1286         cvar_set("_endmatch", "0");
1287         game_stopped = true;
1288         intermission_running = true; // game over
1289
1290         // enforce a wait time before allowing changelevel
1291         if(player_count > 0)
1292                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1293         else
1294                 intermission_exittime = -1;
1295
1296         /*
1297         WriteByte (MSG_ALL, SVC_CDTRACK);
1298         WriteByte (MSG_ALL, 3);
1299         WriteByte (MSG_ALL, 3);
1300         // done in FixIntermission
1301         */
1302
1303         //pos = FindIntermission ();
1304
1305         VoteReset();
1306
1307         DumpStats(true);
1308
1309         // send statistics
1310         PlayerStats_GameReport(true);
1311         WeaponStats_Shutdown();
1312
1313         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1314
1315         if(autocvar_sv_eventlog)
1316                 GameLogEcho(":gameover");
1317
1318         GameLogClose();
1319
1320         int winner_team = 0;
1321         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1322                 FixIntermissionClient(it);
1323                 if(it.winning)
1324                 {
1325                         if (teamplay && !winner_team)
1326                         {
1327                                 winner_team = it.team;
1328                                 bprint(Team_ColorCode(winner_team), Team_ColorName_Upper(winner_team), "^7 team wins the match\n");
1329                         }
1330                         bprint(playername(it.netname, it.team, false), " ^7wins\n");
1331                 }
1332         });
1333
1334         target_music_kill();
1335
1336         if(autocvar_g_campaign)
1337                 CampaignPreIntermission();
1338
1339         MUTATOR_CALLHOOK(MatchEnd);
1340
1341         localcmd("\nsv_hook_gameend\n");
1342 }
1343
1344
1345 int InitiateSuddenDeath()
1346 {
1347         // Check first whether normal overtimes could be added before initiating suddendeath mode
1348         // - for this timelimit_overtime needs to be >0 of course
1349         // - also check the winning condition calculated in the previous frame and only add normal overtime
1350         //   again, if at the point at which timelimit would be extended again, still no winner was found
1351         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1352                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1353                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1354         {
1355                 return 1; // need to call InitiateOvertime later
1356         }
1357         else
1358         {
1359                 if(!checkrules_suddendeathend)
1360                 {
1361                         if(autocvar_g_campaign)
1362                         {
1363                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1364                         }
1365                         else
1366                         {
1367                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1368                                 overtimes = -1;
1369                         }
1370                         if(g_race && !g_race_qualifying)
1371                                 race_StartCompleting();
1372                 }
1373                 return 0;
1374         }
1375 }
1376
1377 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1378 {
1379         ++checkrules_overtimesadded;
1380         overtimes = checkrules_overtimesadded;
1381         //add one more overtime by simply extending the timelimit
1382         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1383         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1384 }
1385
1386 float GetWinningCode(float fraglimitreached, float equality)
1387 {
1388         if(autocvar_g_campaign == 1)
1389         {
1390                 if(fraglimitreached)
1391                         return WINNING_YES;
1392                 else
1393                         return WINNING_NO;
1394         }
1395         else
1396         {
1397                 if(equality)
1398                 {
1399                         if(fraglimitreached)
1400                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1401                         else
1402                                 return WINNING_NEVER;
1403                 }
1404                 else
1405                 {
1406                         if(fraglimitreached)
1407                                 return WINNING_YES;
1408                         else
1409                                 return WINNING_NO;
1410                 }
1411         }
1412 }
1413
1414 // set the .winning flag for exactly those players with a given field value
1415 void SetWinners(.float field, float value)
1416 {
1417         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = (it.(field) == value); });
1418 }
1419
1420 // set the .winning flag for those players with a given field value
1421 void AddWinners(.float field, float value)
1422 {
1423         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1424                 if(it.(field) == value)
1425                         it.winning = 1;
1426         });
1427 }
1428
1429 // clear the .winning flags
1430 void ClearWinners()
1431 {
1432         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = 0; });
1433 }
1434
1435 int fragsleft_last;
1436 float WinningCondition_Scores(float limit, float leadlimit)
1437 {
1438         // TODO make everything use THIS winning condition (except LMS)
1439         WinningConditionHelper(NULL);
1440
1441         if(teamplay)
1442         {
1443                 for (int i = 1; i < 5; ++i)
1444                 {
1445                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1446                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1447                 }
1448         }
1449
1450         ClearWinners();
1451         if(WinningConditionHelper_winner)
1452                 WinningConditionHelper_winner.winning = 1;
1453         if(WinningConditionHelper_winnerteam >= 0)
1454                 SetWinners(team, WinningConditionHelper_winnerteam);
1455
1456         if(WinningConditionHelper_lowerisbetter)
1457         {
1458                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1459                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1460                 limit = -limit;
1461         }
1462
1463         if(WinningConditionHelper_zeroisworst)
1464                 leadlimit = 0; // not supported in this mode
1465
1466         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1467         {
1468                 float fragsleft;
1469                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1470                 {
1471                         fragsleft = 1;
1472                 }
1473                 else
1474                 {
1475                         fragsleft = FLOAT_MAX;
1476                         float leadingfragsleft = FLOAT_MAX;
1477                         if (limit)
1478                                 fragsleft = limit - WinningConditionHelper_topscore;
1479                         if (leadlimit)
1480                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1481
1482                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1483                                 fragsleft = max(fragsleft, leadingfragsleft);
1484                         else
1485                                 fragsleft = min(fragsleft, leadingfragsleft);
1486                 }
1487
1488                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1489                 {
1490                         if (fragsleft == 1)
1491                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1492                         else if (fragsleft == 2)
1493                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1494                         else if (fragsleft == 3)
1495                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1496
1497                         fragsleft_last = fragsleft;
1498                 }
1499         }
1500
1501         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1502         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1503
1504         bool limit_reached;
1505         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1506         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1507                 limit_reached = (fraglimit_reached && leadlimit_reached);
1508         else
1509                 limit_reached = (fraglimit_reached || leadlimit_reached);
1510
1511         return GetWinningCode(
1512                 WinningConditionHelper_topscore && limit_reached,
1513                 WinningConditionHelper_equality
1514         );
1515 }
1516
1517 float WinningCondition_RanOutOfSpawns()
1518 {
1519         if(have_team_spawns <= 0)
1520                 return WINNING_NO;
1521
1522         if(!autocvar_g_spawn_useallspawns)
1523                 return WINNING_NO;
1524
1525         if(!some_spawn_has_been_used)
1526                 return WINNING_NO;
1527
1528         for (int i = 1; i < 5; ++i)
1529         {
1530                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1531         }
1532
1533         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1534         {
1535                 if (Team_IsValidTeam(it.team))
1536                 {
1537                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1538                 }
1539         });
1540
1541         IL_EACH(g_spawnpoints, true,
1542         {
1543                 if (Team_IsValidTeam(it.team))
1544                 {
1545                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1546                 }
1547         });
1548
1549         ClearWinners();
1550         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1551         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1552         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1553         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1554         if(team1_score + team2_score + team3_score + team4_score == 0)
1555         {
1556                 checkrules_equality = true;
1557                 return WINNING_YES;
1558         }
1559         else if(team1_score + team2_score + team3_score + team4_score == 1)
1560         {
1561                 float t, i;
1562                 if(team1_score)
1563                         t = 1;
1564                 else if(team2_score)
1565                         t = 2;
1566                 else if(team3_score)
1567                         t = 3;
1568                 else // if(team4_score)
1569                         t = 4;
1570                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1571                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1572                 {
1573                         for (int j = 1; j <= NUM_TEAMS; ++j)
1574                         {
1575                                 if (t == j)
1576                                 {
1577                                         continue;
1578                                 }
1579                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1580                                 {
1581                                         continue;
1582                                 }
1583                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1584                         }
1585                 }
1586
1587                 AddWinners(team, t);
1588                 return WINNING_YES;
1589         }
1590         else
1591                 return WINNING_NO;
1592 }
1593
1594 /*
1595 ============
1596 CheckRules_World
1597
1598 Exit deathmatch games upon conditions
1599 ============
1600 */
1601 void CheckRules_World()
1602 {
1603         VoteThink();
1604         MapVote_Think();
1605
1606         SetDefaultAlpha();
1607
1608         if (intermission_running) // someone else quit the game already
1609         {
1610                 if(player_count == 0) // Nobody there? Then let's go to the next map
1611                         MapVote_Start();
1612                         // this will actually check the player count in the next frame
1613                         // again, but this shouldn't hurt
1614                 return;
1615         }
1616
1617         float timelimit = autocvar_timelimit * 60;
1618         float fraglimit = autocvar_fraglimit;
1619         float leadlimit = autocvar_leadlimit;
1620         if (leadlimit < 0) leadlimit = 0;
1621
1622         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1623         {
1624                 if(timelimit > 0)
1625                         timelimit = 0; // timelimit is not made for warmup
1626                 if(fraglimit > 0)
1627                         fraglimit = 0; // no fraglimit for now
1628                 leadlimit = 0; // no leadlimit for now
1629         }
1630
1631         if (autocvar__endmatch || timelimit < 0)
1632         {
1633                 // endmatch
1634                 NextLevel();
1635                 return;
1636         }
1637
1638         if(timelimit > 0)
1639                 timelimit += game_starttime;
1640
1641         int overtimes_prev = overtimes;
1642         int wantovertime = 0;
1643
1644         if(checkrules_suddendeathend)
1645         {
1646                 if(!checkrules_suddendeathwarning)
1647                 {
1648                         checkrules_suddendeathwarning = true;
1649                         if(g_race && !g_race_qualifying)
1650                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1651                         else
1652                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1653                 }
1654         }
1655         else
1656         {
1657                 if (timelimit && time >= timelimit)
1658                 {
1659                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1660                         {
1661                                 float totalplayers;
1662                                 float playerswithlaps;
1663                                 float readyplayers;
1664                                 totalplayers = playerswithlaps = readyplayers = 0;
1665                                 FOREACH_CLIENT(IS_PLAYER(it), {
1666                                         ++totalplayers;
1667                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1668                                                 ++playerswithlaps;
1669                                         if(it.ready)
1670                                                 ++readyplayers;
1671                                 });
1672
1673                                 // at least 2 of the players have completed a lap: start the RACE
1674                                 // otherwise, the players should end the qualifying on their own
1675                                 if(readyplayers || playerswithlaps >= 2)
1676                                 {
1677                                         checkrules_suddendeathend = 0;
1678                                         ReadyRestart(true); // go to race
1679                                         return;
1680                                 }
1681                                 else
1682                                         wantovertime |= InitiateSuddenDeath();
1683                         }
1684                         else
1685                                 wantovertime |= InitiateSuddenDeath();
1686                 }
1687         }
1688
1689         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1690         {
1691                 NextLevel();
1692                 return;
1693         }
1694
1695         int checkrules_status = WinningCondition_RanOutOfSpawns();
1696         if(checkrules_status == WINNING_YES)
1697                 bprint("Hey! Someone ran out of spawns!\n");
1698         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1699                 checkrules_status = M_ARGV(0, float);
1700         else
1701                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1702
1703         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1704         {
1705                 checkrules_status = WINNING_NEVER;
1706                 checkrules_overtimesadded = -1;
1707                 wantovertime |= InitiateSuddenDeath();
1708         }
1709
1710         if(checkrules_status == WINNING_NEVER)
1711                 // equality cases! Nobody wins if the overtime ends in a draw.
1712                 ClearWinners();
1713
1714         if(wantovertime)
1715         {
1716                 if(checkrules_status == WINNING_NEVER)
1717                         InitiateOvertime();
1718                 else
1719                         checkrules_status = WINNING_YES;
1720         }
1721
1722         if(checkrules_suddendeathend)
1723                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1724                         checkrules_status = WINNING_YES;
1725
1726         if(checkrules_status == WINNING_YES)
1727         {
1728                 if (overtimes == -1 && overtimes != overtimes_prev)
1729                 {
1730                         // if suddendeathend overtime has just begun, revert it
1731                         checkrules_suddendeathend = 0;
1732                         overtimes = overtimes_prev;
1733                 }
1734                 //print("WINNING\n");
1735                 NextLevel();
1736         }
1737 }
1738
1739 float want_weapon(entity weaponinfo, float allguns)
1740 {
1741         int d = 0;
1742         bool allow_mutatorblocked = false;
1743
1744         if(!weaponinfo.m_id)
1745                 return 0;
1746
1747         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
1748         d = M_ARGV(1, float);
1749         allguns = M_ARGV(2, bool);
1750         allow_mutatorblocked = M_ARGV(3, bool);
1751
1752         if(allguns)
1753                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
1754         else if(!mutator_returnvalue)
1755                 d = !(!weaponinfo.weaponstart);
1756
1757         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
1758                 d = 0;
1759
1760         float t = weaponinfo.weaponstartoverride;
1761
1762         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
1763
1764         // bit order in t:
1765         // 1: want or not
1766         // 2: is default?
1767         // 4: is set by default?
1768         if(t < 0)
1769                 t = 4 | (3 * d);
1770         else
1771                 t |= (2 * d);
1772
1773         return t;
1774 }
1775
1776 /// Weapons the player normally starts with outside weapon arena.
1777 WepSet weapons_start()
1778 {
1779         WepSet ret = '0 0 0';
1780         FOREACH(Weapons, it != WEP_Null, {
1781                 int w = want_weapon(it, false);
1782                 if (w & 1)
1783                         ret |= it.m_wepset;
1784         });
1785         return ret;
1786 }
1787
1788 WepSet weapons_all()
1789 {
1790         WepSet ret = '0 0 0';
1791         FOREACH(Weapons, it != WEP_Null, {
1792                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
1793                         ret |= it.m_wepset;
1794         });
1795         return ret;
1796 }
1797
1798 WepSet weapons_devall()
1799 {
1800         WepSet ret = '0 0 0';
1801         FOREACH(Weapons, it != WEP_Null,
1802         {
1803                 ret |= it.m_wepset;
1804         });
1805         return ret;
1806 }
1807
1808 WepSet weapons_most()
1809 {
1810         WepSet ret = '0 0 0';
1811         FOREACH(Weapons, it != WEP_Null, {
1812                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
1813                         ret |= it.m_wepset;
1814         });
1815         return ret;
1816 }
1817
1818 void weaponarena_available_all_update(entity this)
1819 {
1820         if (weaponsInMapAll)
1821         {
1822                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
1823         }
1824         else
1825         {
1826                 // if no weapons are available on the map, just fall back to all weapons arena
1827                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
1828         }
1829 }
1830
1831 void weaponarena_available_devall_update(entity this)
1832 {
1833         if (weaponsInMapAll)
1834         {
1835                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
1836         }
1837         else
1838         {
1839                 // if no weapons are available on the map, just fall back to devall weapons arena
1840                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
1841         }
1842 }
1843
1844 void weaponarena_available_most_update(entity this)
1845 {
1846         if (weaponsInMapAll)
1847         {
1848                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
1849         }
1850         else
1851         {
1852                 // if no weapons are available on the map, just fall back to most weapons arena
1853                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
1854         }
1855 }
1856
1857 void readplayerstartcvars()
1858 {
1859         // initialize starting values for players
1860         start_weapons = '0 0 0';
1861         start_weapons_default = '0 0 0';
1862         start_weapons_defaultmask = '0 0 0';
1863         start_items = 0;
1864         start_ammo_shells = 0;
1865         start_ammo_nails = 0;
1866         start_ammo_rockets = 0;
1867         start_ammo_cells = 0;
1868         start_ammo_plasma = 0;
1869         if (random_start_ammo == NULL)
1870         {
1871                 random_start_ammo = new_pure(random_start_ammo);
1872         }
1873         start_health = cvar("g_balance_health_start");
1874         start_armorvalue = cvar("g_balance_armor_start");
1875
1876         g_weaponarena = 0;
1877         g_weaponarena_weapons = '0 0 0';
1878
1879         string s = cvar_string("g_weaponarena");
1880
1881         MUTATOR_CALLHOOK(SetWeaponArena, s);
1882         s = M_ARGV(0, string);
1883
1884         if (s == "0" || s == "")
1885         {
1886                 // no arena
1887         }
1888         else if (s == "off")
1889         {
1890                 // forcibly turn off weaponarena
1891         }
1892         else if (s == "all" || s == "1")
1893         {
1894                 g_weaponarena = 1;
1895                 g_weaponarena_list = "All Weapons Arena";
1896                 g_weaponarena_weapons = weapons_all();
1897         }
1898         else if (s == "devall")
1899         {
1900                 g_weaponarena = 1;
1901                 g_weaponarena_list = "Dev All Weapons Arena";
1902                 g_weaponarena_weapons = weapons_devall();
1903         }
1904         else if (s == "most")
1905         {
1906                 g_weaponarena = 1;
1907                 g_weaponarena_list = "Most Weapons Arena";
1908                 g_weaponarena_weapons = weapons_most();
1909         }
1910         else if (s == "all_available")
1911         {
1912                 g_weaponarena = 1;
1913                 g_weaponarena_list = "All Available Weapons Arena";
1914
1915                 // this needs to run after weaponsInMapAll is initialized
1916                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
1917         }
1918         else if (s == "devall_available")
1919         {
1920                 g_weaponarena = 1;
1921                 g_weaponarena_list = "Dev All Available Weapons Arena";
1922
1923                 // this needs to run after weaponsInMapAll is initialized
1924                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
1925         }
1926         else if (s == "most_available")
1927         {
1928                 g_weaponarena = 1;
1929                 g_weaponarena_list = "Most Available Weapons Arena";
1930
1931                 // this needs to run after weaponsInMapAll is initialized
1932                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
1933         }
1934         else if (s == "none")
1935         {
1936                 g_weaponarena = 1;
1937                 g_weaponarena_list = "No Weapons Arena";
1938         }
1939         else
1940         {
1941                 g_weaponarena = 1;
1942                 float t = tokenize_console(s);
1943                 g_weaponarena_list = "";
1944                 for (int j = 0; j < t; ++j)
1945                 {
1946                         s = argv(j);
1947                         Weapon wep = Weapon_from_name(s);
1948                         if(wep != WEP_Null)
1949                         {
1950                                 g_weaponarena_weapons |= (wep.m_wepset);
1951                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.netname, " & ");
1952                         }
1953                 }
1954                 if (g_weaponarena_list != "") // remove trailing " & "
1955                         g_weaponarena_list = substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3);
1956                 else // no valid weapon found
1957                         g_weaponarena_list = "No Weapons Arena";
1958         }
1959
1960         if (g_weaponarena)
1961         {
1962                 g_weapon_stay = 0; // incompatible
1963                 start_weapons = g_weaponarena_weapons;
1964                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1965                 g_weaponarena_list = strzone(g_weaponarena_list);
1966         }
1967         else
1968         {
1969                 FOREACH(Weapons, it != WEP_Null, {
1970                         int w = want_weapon(it, false);
1971                         WepSet s = it.m_wepset;
1972                         if(w & 1)
1973                                 start_weapons |= s;
1974                         if(w & 2)
1975                                 start_weapons_default |= s;
1976                         if(w & 4)
1977                                 start_weapons_defaultmask |= s;
1978                 });
1979         }
1980
1981         if(cvar("g_balance_superweapons_time") < 0)
1982                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
1983
1984         if(!cvar("g_use_ammunition"))
1985                 start_items |= IT_UNLIMITED_AMMO;
1986
1987         if(start_items & IT_UNLIMITED_AMMO)
1988         {
1989                 start_ammo_shells = 999;
1990                 start_ammo_nails = 999;
1991                 start_ammo_rockets = 999;
1992                 start_ammo_cells = 999;
1993                 start_ammo_plasma = 999;
1994                 start_ammo_fuel = 999;
1995         }
1996         else
1997         {
1998                 start_ammo_shells = cvar("g_start_ammo_shells");
1999                 start_ammo_nails = cvar("g_start_ammo_nails");
2000                 start_ammo_rockets = cvar("g_start_ammo_rockets");
2001                 start_ammo_cells = cvar("g_start_ammo_cells");
2002                 start_ammo_plasma = cvar("g_start_ammo_plasma");
2003                 start_ammo_fuel = cvar("g_start_ammo_fuel");
2004                 random_start_weapons_count = cvar("g_random_start_weapons_count");
2005                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
2006                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
2007                 SetResource(random_start_ammo, RES_ROCKETS, cvar("g_random_start_rockets"));
2008                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
2009                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
2010         }
2011
2012         warmup_start_ammo_shells = start_ammo_shells;
2013         warmup_start_ammo_nails = start_ammo_nails;
2014         warmup_start_ammo_rockets = start_ammo_rockets;
2015         warmup_start_ammo_cells = start_ammo_cells;
2016         warmup_start_ammo_plasma = start_ammo_plasma;
2017         warmup_start_ammo_fuel = start_ammo_fuel;
2018         warmup_start_health = start_health;
2019         warmup_start_armorvalue = start_armorvalue;
2020         warmup_start_weapons = start_weapons;
2021         warmup_start_weapons_default = start_weapons_default;
2022         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
2023
2024         if (!g_weaponarena)
2025         {
2026                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
2027                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
2028                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
2029                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
2030                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
2031                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
2032                 warmup_start_health = cvar("g_warmup_start_health");
2033                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
2034                 warmup_start_weapons = '0 0 0';
2035                 warmup_start_weapons_default = '0 0 0';
2036                 warmup_start_weapons_defaultmask = '0 0 0';
2037                 FOREACH(Weapons, it != WEP_Null, {
2038                         int w = want_weapon(it, autocvar_g_warmup_allguns);
2039                         WepSet s = it.m_wepset;
2040                         if(w & 1)
2041                                 warmup_start_weapons |= s;
2042                         if(w & 2)
2043                                 warmup_start_weapons_default |= s;
2044                         if(w & 4)
2045                                 warmup_start_weapons_defaultmask |= s;
2046                 });
2047         }
2048
2049         if (autocvar_g_jetpack)
2050                 start_items |= ITEM_Jetpack.m_itemid;
2051
2052         MUTATOR_CALLHOOK(SetStartItems);
2053
2054         if (start_items & ITEM_Jetpack.m_itemid)
2055         {
2056                 start_items |= ITEM_JetpackRegen.m_itemid;
2057                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2058                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2059         }
2060
2061         start_ammo_shells = max(0, start_ammo_shells);
2062         start_ammo_nails = max(0, start_ammo_nails);
2063         start_ammo_rockets = max(0, start_ammo_rockets);
2064         start_ammo_cells = max(0, start_ammo_cells);
2065         start_ammo_plasma = max(0, start_ammo_plasma);
2066         start_ammo_fuel = max(0, start_ammo_fuel);
2067         SetResource(random_start_ammo, RES_SHELLS, max(0, GetResource(random_start_ammo, RES_SHELLS)));
2068         SetResource(random_start_ammo, RES_BULLETS, max(0, GetResource(random_start_ammo, RES_BULLETS)));
2069         SetResource(random_start_ammo, RES_ROCKETS, max(0, GetResource(random_start_ammo, RES_ROCKETS)));
2070         SetResource(random_start_ammo, RES_CELLS, max(0, GetResource(random_start_ammo, RES_CELLS)));
2071         SetResource(random_start_ammo, RES_PLASMA, max(0, GetResource(random_start_ammo, RES_PLASMA)));
2072
2073         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
2074         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
2075         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
2076         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
2077         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
2078         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
2079 }
2080
2081 void readlevelcvars()
2082 {
2083         if(cvar("sv_allow_fullbright"))
2084                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
2085
2086         sv_ready_restart_after_countdown = cvar("sv_ready_restart_after_countdown");
2087
2088         warmup_stage = cvar("g_warmup");
2089         warmup_limit = cvar("g_warmup_limit");
2090
2091         if(cvar("g_campaign"))
2092                 warmup_stage = 0; // no warmup during campaign
2093
2094         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
2095         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
2096         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
2097         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
2098         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
2099         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
2100         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
2101         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
2102         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
2103         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
2104         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
2105         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
2106         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
2107         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
2108
2109         g_pickup_shells = cvar("g_pickup_shells");
2110         g_pickup_shells_max = cvar("g_pickup_shells_max");
2111         g_pickup_nails = cvar("g_pickup_nails");
2112         g_pickup_nails_max = cvar("g_pickup_nails_max");
2113         g_pickup_rockets = cvar("g_pickup_rockets");
2114         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
2115         g_pickup_cells = cvar("g_pickup_cells");
2116         g_pickup_cells_max = cvar("g_pickup_cells_max");
2117         g_pickup_plasma = cvar("g_pickup_plasma");
2118         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
2119         g_pickup_fuel = cvar("g_pickup_fuel");
2120         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
2121         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
2122         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
2123         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
2124         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
2125         g_pickup_armormedium = cvar("g_pickup_armormedium");
2126         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
2127         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
2128         g_pickup_armorbig = cvar("g_pickup_armorbig");
2129         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
2130         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
2131         g_pickup_armormega = cvar("g_pickup_armormega");
2132         g_pickup_armormega_max = cvar("g_pickup_armormega_max");
2133         g_pickup_armormega_anyway = cvar("g_pickup_armormega_anyway");
2134         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
2135         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
2136         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
2137         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
2138         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
2139         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
2140         g_pickup_healthbig = cvar("g_pickup_healthbig");
2141         g_pickup_healthbig_max = cvar("g_pickup_healthbig_max");
2142         g_pickup_healthbig_anyway = cvar("g_pickup_healthbig_anyway");
2143         g_pickup_healthmega = cvar("g_pickup_healthmega");
2144         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
2145         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
2146
2147         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
2148         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
2149
2150     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
2151     if(!g_weapon_stay)
2152         g_weapon_stay = cvar("g_weapon_stay");
2153
2154     MUTATOR_CALLHOOK(ReadLevelCvars);
2155
2156         if (!warmup_stage && !autocvar_g_campaign)
2157                 game_starttime = time + cvar("g_start_delay");
2158
2159         FOREACH(Weapons, it != WEP_Null, { it.wr_init(it); });
2160
2161         readplayerstartcvars();
2162 }
2163
2164 void InitializeEntity(entity e, void(entity this) func, int order)
2165 {
2166     entity prev, cur;
2167
2168     if (!e || e.initialize_entity)
2169     {
2170         // make a proxy initializer entity
2171         entity e_old = e;
2172         e = new(initialize_entity);
2173         e.enemy = e_old;
2174     }
2175
2176     e.initialize_entity = func;
2177     e.initialize_entity_order = order;
2178
2179     cur = initialize_entity_first;
2180     prev = NULL;
2181     for (;;)
2182     {
2183         if (!cur || cur.initialize_entity_order > order)
2184         {
2185             // insert between prev and cur
2186             if (prev)
2187                 prev.initialize_entity_next = e;
2188             else
2189                 initialize_entity_first = e;
2190             e.initialize_entity_next = cur;
2191             return;
2192         }
2193         prev = cur;
2194         cur = cur.initialize_entity_next;
2195     }
2196 }
2197 void InitializeEntitiesRun()
2198 {
2199     entity startoflist = initialize_entity_first;
2200     initialize_entity_first = NULL;
2201     delete_fn = remove_except_protected;
2202     for (entity e = startoflist; e; e = e.initialize_entity_next)
2203     {
2204                 e.remove_except_protected_forbidden = 1;
2205     }
2206     for (entity e = startoflist; e; )
2207     {
2208                 e.remove_except_protected_forbidden = 0;
2209         e.initialize_entity_order = 0;
2210         entity next = e.initialize_entity_next;
2211         e.initialize_entity_next = NULL;
2212         var void(entity this) func = e.initialize_entity;
2213         e.initialize_entity = func_null;
2214         if (e.classname == "initialize_entity")
2215         {
2216             entity wrappee = e.enemy;
2217             builtin_remove(e);
2218             e = wrappee;
2219         }
2220         //dprint("Delayed initialization: ", e.classname, "\n");
2221         if (func)
2222         {
2223                 func(e);
2224         }
2225         else
2226         {
2227             eprint(e);
2228             backtrace(strcat("Null function in: ", e.classname, "\n"));
2229         }
2230         e = next;
2231     }
2232     delete_fn = remove_unsafely;
2233 }
2234
2235 // deferred dropping
2236 void DropToFloor_Handler(entity this)
2237 {
2238         WITHSELF(this, builtin_droptofloor());
2239         this.dropped_origin = this.origin;
2240 }
2241
2242 void droptofloor(entity this)
2243 {
2244         InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
2245 }
2246
2247 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2248 void RunThink(entity this, float dt)
2249 {
2250         // don't let things stay in the past.
2251         // it is possible to start that way by a trigger with a local time.
2252         if(this.nextthink <= 0 || this.nextthink > time + dt)
2253                 return;
2254
2255         float oldtime = time; // do we need to save this?
2256
2257         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2258         {
2259                 time = max(oldtime, this.nextthink);
2260                 this.nextthink = 0;
2261
2262                 if(getthink(this))
2263                         getthink(this)(this);
2264                 // mods often set nextthink to time to cause a think every frame,
2265                 // we don't want to loop in that case, so exit if the new nextthink is
2266                 // <= the time the qc was told, also exit if it is past the end of the
2267                 // frame
2268                 if(this.nextthink <= time || this.nextthink > oldtime + dt || !autocvar_sv_gameplayfix_multiplethinksperframe)
2269                         break;
2270         }
2271
2272         time = oldtime;
2273 }
2274
2275 bool autocvar_sv_freezenonclients;
2276 void Physics_Frame()
2277 {
2278         if(autocvar_sv_freezenonclients)
2279                 return;
2280
2281         IL_EACH(g_moveables, true,
2282         {
2283                 if(IS_CLIENT(it) || it.move_movetype == MOVETYPE_PHYSICS)
2284                         continue;
2285
2286                 //set_movetype(it, it.move_movetype);
2287                 // inline the set_movetype function, since this is called a lot
2288                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2289
2290                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2291                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2292
2293                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2294                 {
2295                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2296                                 continue; // these movetypes have no regular think function
2297                         // handle thinking here
2298                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + PHYS_INPUT_TIMELENGTH)
2299                                 RunThink(it, PHYS_INPUT_TIMELENGTH);
2300                 }
2301         });
2302
2303         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2304                 return;
2305
2306         // make a second pass to see if any ents spawned this frame and make
2307         // sure they run their move/think. this is verified by checking .move_time, which will never be 0 if the entity has moved
2308         // MOVETYPE_NONE is also checked as .move_time WILL be 0 with that movetype
2309         IL_EACH(g_moveables, it.move_qcphysics,
2310         {
2311                 if(IS_CLIENT(it) || it.move_time || it.move_movetype == MOVETYPE_NONE || it.move_movetype == MOVETYPE_PHYSICS)
2312                         continue;
2313                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2314         });
2315 }
2316
2317 void systems_update();
2318 void EndFrame()
2319 {
2320         anticheat_endframe();
2321
2322         Physics_Frame();
2323
2324         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2325                 entity e = IS_SPEC(it) ? it.enemy : it;
2326                 if (e.typehitsound) {
2327                         STAT(TYPEHIT_TIME, it) = time;
2328                 } else if (e.killsound) {
2329                         STAT(KILL_TIME, it) = time;
2330                 } else if (e.hitsound_damage_dealt) {
2331                         STAT(HIT_TIME, it) = time;
2332                         // NOTE: this is not accurate as client code doesn't need so much accuracy for its purposes
2333                         STAT(HITSOUND_DAMAGE_DEALT_TOTAL, it) += ceil(e.hitsound_damage_dealt);
2334                 }
2335         });
2336         // add 1 frametime because after this, engine SV_Physics
2337         // increases time by a frametime and then networks the frame
2338         // add another frametime because client shows everything with
2339         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2340         // needed!
2341         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2342         FOREACH_CLIENT(true, {
2343                 it.typehitsound = false;
2344                 it.hitsound_damage_dealt = 0;
2345                 it.killsound = false;
2346                 antilag_record(it, CS(it), altime);
2347         });
2348         IL_EACH(g_monsters, true,
2349         {
2350                 antilag_record(it, it, altime);
2351         });
2352         IL_EACH(g_projectiles, it.classname == "nade",
2353         {
2354                 antilag_record(it, it, altime);
2355         });
2356         systems_update();
2357         IL_ENDFRAME();
2358 }
2359
2360
2361 /*
2362  * RedirectionThink:
2363  * returns true if redirecting
2364  */
2365 float redirection_timeout;
2366 float redirection_nextthink;
2367 float RedirectionThink()
2368 {
2369         float clients_found;
2370
2371         if(redirection_target == "")
2372                 return false;
2373
2374         if(!redirection_timeout)
2375         {
2376                 cvar_set("sv_public", "-2");
2377                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2378                 if(redirection_target == "self")
2379                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2380                 else
2381                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2382         }
2383
2384         if(time < redirection_nextthink)
2385                 return true;
2386
2387         redirection_nextthink = time + 1;
2388
2389         clients_found = 0;
2390         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2391                 // TODO add timer
2392                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2393                 if(redirection_target == "self")
2394                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2395                 else
2396                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2397                 ++clients_found;
2398         });
2399
2400         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2401
2402         if(time > redirection_timeout || clients_found == 0)
2403                 localcmd("\nwait; wait; wait; quit\n");
2404
2405         return true;
2406 }
2407
2408 void RestoreGame()
2409 {
2410         // Loaded from a save game
2411         // some things then break, so let's work around them...
2412
2413         // Progs DB (capture records)
2414         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2415
2416         // Mapinfo
2417         MapInfo_Shutdown();
2418         MapInfo_Enumerate();
2419         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2420         WeaponStats_Init();
2421
2422         TargetMusic_RestoreGame();
2423 }
2424
2425 void Shutdown()
2426 {
2427         game_stopped = 2;
2428
2429         if(world_initialized > 0)
2430         {
2431                 world_initialized = 0;
2432
2433                 // if a timeout is active, reset the slowmo value to normal
2434                 if(timeout_status == TIMEOUT_ACTIVE)
2435                         cvar_set("slowmo", ftos(orig_slowmo));
2436
2437                 LOG_TRACE("Saving persistent data...");
2438                 Ban_SaveBans();
2439
2440                 // playerstats with unfinished match
2441                 PlayerStats_GameReport(false);
2442
2443                 if(!cheatcount_total)
2444                 {
2445                         if(autocvar_sv_db_saveasdump)
2446                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2447                         else
2448                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2449                 }
2450                 if(autocvar_developer > 0)
2451                 {
2452                         if(autocvar_sv_db_saveasdump)
2453                                 db_dump(TemporaryDB, "server-temp.db");
2454                         else
2455                                 db_save(TemporaryDB, "server-temp.db");
2456                 }
2457                 CheatShutdown(); // must be after cheatcount check
2458                 db_close(ServerProgsDB);
2459                 db_close(TemporaryDB);
2460                 LOG_TRACE("Saving persistent data... done!");
2461                 // tell the bot system the game is ending now
2462                 bot_endgame();
2463
2464                 WeaponStats_Shutdown();
2465                 MapInfo_Shutdown();
2466
2467                 strfree(sv_termsofservice_url_escaped);
2468         }
2469         else if(world_initialized == 0)
2470         {
2471                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2472         }
2473         else
2474         {
2475                 __init_dedicated_server_shutdown();
2476         }
2477 }