qcsrc/server/world.qc

   1 #include "world.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/gamemodes/sv_rules.qh>
   7 #include <common/items/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/target/music.qh>
  10 #include <common/mapobjects/trigger/hurt.qh>
  11 #include <common/mapobjects/trigger/secret.qh>
  12 #include <common/mapobjects/triggers.qh>
  13 #include <common/monsters/_mod.qh>
  14 #include <common/monsters/sv_monsters.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/notifications/all.qh>
  17 #include <common/physics/player.qh>
  18 #include <common/playerstats.qh>
  19 #include <common/state.qh>
  20 #include <common/stats.qh>
  21 #include <common/teams.qh>
  22 #include <common/util.qh>
  23 #include <common/vehicles/all.qh>
  24 #include <common/weapons/_all.qh>
  25 #include <server/anticheat.qh>
  26 #include <server/antilag.qh>
  27 #include <server/bot/api.qh>
  28 #include <server/campaign.qh>
  29 #include <server/cheats.qh>
  30 #include <server/client.qh>
  31 #include <server/command/common.qh>
  32 #include <server/command/getreplies.qh>
  33 #include <server/command/sv_cmd.qh>
  34 #include <server/command/vote.qh>
  35 #include <server/damage.qh>
  36 #include <server/gamelog.qh>
  37 #include <server/hook.qh>
  38 #include <server/intermission.qh>
  39 #include <server/ipban.qh>
  40 #include <server/items/items.qh>
  41 #include <server/main.qh>
  42 #include <server/mapvoting.qh>
  43 #include <server/mutators/_mod.qh>
  44 #include <server/race.qh>
  45 #include <server/scores.qh>
  46 #include <server/scores_rules.qh>
  47 #include <server/spawnpoints.qh>
  48 #include <server/teamplay.qh>
  49 #include <server/weapons/common.qh>
  50 #include <server/weapons/weaponstats.qh>
  51
  52 const float LATENCY_THINKRATE = 10;
  53 .float latency_sum;
  54 .float latency_cnt;
  55 .float latency_time;
  56 entity pingplreport;
  57 void PingPLReport_Think(entity this)
  58 {
  59         float delta;
  60         entity e;
  61
  62         delta = 3 / maxclients;
  63         if(delta < sys_frametime)
  64                 delta = 0;
  65         this.nextthink = time + delta;
  66
  67         e = edict_num(this.cnt + 1);
  68         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  69         {
  70                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  71                 WriteByte(MSG_BROADCAST, this.cnt);
  72                 WriteShort(MSG_BROADCAST, bound(1, rint(CS(e).ping), 32767));
  73                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  74                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  75
  76                 // record latency times for clients throughout the match so we can report it to playerstats
  77                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  78                 {
  79                         CS(e).latency_sum += CS(e).ping;
  80                         CS(e).latency_cnt += 1;
  81                         CS(e).latency_time = time;
  82                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  83                 }
  84         }
  85         else
  86         {
  87                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  88                 WriteByte(MSG_BROADCAST, this.cnt);
  89                 WriteShort(MSG_BROADCAST, 0);
  90                 WriteByte(MSG_BROADCAST, 0);
  91                 WriteByte(MSG_BROADCAST, 0);
  92         }
  93         this.cnt = (this.cnt + 1) % maxclients;
  94 }
  95 void PingPLReport_Spawn()
  96 {
  97         pingplreport = new_pure(pingplreport);
  98         setthink(pingplreport, PingPLReport_Think);
  99         pingplreport.nextthink = time;
 100 }
 101
 102 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
 103
 104 void SetDefaultAlpha()
 105 {
 106         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 107         {
 108                 default_player_alpha = autocvar_g_player_alpha;
 109                 if(default_player_alpha == 0)
 110                         default_player_alpha = 1;
 111                 default_weapon_alpha = default_player_alpha;
 112         }
 113 }
 114
 115 void GotoFirstMap(entity this)
 116 {
 117         float n;
 118         if(autocvar__sv_init)
 119         {
 120                 // cvar_set("_sv_init", "0");
 121                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 122                 // to this "init" map on a dedicated server will cause no permanent
 123                 // harm
 124                 if(autocvar_g_maplist_shuffle)
 125                         ShuffleMaplist();
 126                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 127                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 128
 129                 MapInfo_Enumerate();
 130                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 131
 132                 if(!DoNextMapOverride(1))
 133                         GotoNextMap(1);
 134
 135                 return;
 136         }
 137
 138         if(time < 5)
 139         {
 140                 this.nextthink = time;
 141         }
 142         else
 143         {
 144                 this.nextthink = time + 1;
 145                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 146         }
 147 }
 148
 149 void cvar_changes_init()
 150 {
 151         float h;
 152         string k, v, d;
 153         float n, i, adding, pureadding;
 154
 155         strfree(cvar_changes);
 156         strfree(cvar_purechanges);
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = true;
 164         pureadding = true;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173 #define BADVALUE(p, val) if (k == p && v == val) continue
 174
 175                 // general excludes and namespaces for server admin used cvars
 176                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 177
 178                 // internal
 179                 BADPREFIX("csqc_");
 180                 BADPREFIX("cvar_check_");
 181                 BADCVAR("gamecfg");
 182                 BADCVAR("g_configversion");
 183                 BADCVAR("halflifebsp");
 184                 BADCVAR("sv_mapformat_is_quake2");
 185                 BADCVAR("sv_mapformat_is_quake3");
 186                 BADPREFIX("sv_world");
 187
 188                 // client
 189                 BADPREFIX("chase_");
 190                 BADPREFIX("cl_");
 191                 BADPREFIX("con_");
 192                 BADPREFIX("scoreboard_");
 193                 BADPREFIX("g_campaign");
 194                 BADPREFIX("g_waypointsprite_");
 195                 BADPREFIX("gl_");
 196                 BADPREFIX("joy");
 197                 BADPREFIX("hud_");
 198                 BADPREFIX("m_");
 199                 BADPREFIX("menu_");
 200                 BADPREFIX("net_slist_");
 201                 BADPREFIX("r_");
 202                 BADPREFIX("sbar_");
 203                 BADPREFIX("scr_");
 204                 BADPREFIX("snd_");
 205                 BADPREFIX("show");
 206                 BADPREFIX("sensitivity");
 207                 BADPREFIX("userbind");
 208                 BADPREFIX("v_");
 209                 BADPREFIX("vid_");
 210                 BADPREFIX("crosshair");
 211                 BADCVAR("mod_q3bsp_lightmapmergepower");
 212                 BADCVAR("mod_q3bsp_nolightmaps");
 213                 BADCVAR("fov");
 214                 BADCVAR("mastervolume");
 215                 BADCVAR("volume");
 216                 BADCVAR("bgmvolume");
 217                 BADCVAR("in_pitch_min");
 218                 BADCVAR("in_pitch_max");
 219
 220                 // private
 221                 BADCVAR("developer");
 222                 BADCVAR("log_dest_udp");
 223                 BADCVAR("net_address");
 224                 BADCVAR("net_address_ipv6");
 225                 BADCVAR("port");
 226                 BADCVAR("savedgamecfg");
 227                 BADCVAR("serverconfig");
 228                 BADCVAR("sv_autoscreenshot");
 229                 BADCVAR("sv_heartbeatperiod");
 230                 BADCVAR("sv_vote_master_password");
 231                 BADCVAR("sys_colortranslation");
 232                 BADCVAR("sys_specialcharactertranslation");
 233                 BADCVAR("timeformat");
 234                 BADCVAR("timestamps");
 235                 BADCVAR("g_require_stats");
 236                 BADPREFIX("developer_");
 237                 BADPREFIX("g_ban_");
 238                 BADPREFIX("g_banned_list");
 239                 BADPREFIX("g_require_stats_");
 240                 BADPREFIX("g_chat_flood_");
 241                 BADPREFIX("g_ghost_items");
 242                 BADPREFIX("g_playerstats_");
 243                 BADPREFIX("g_voice_flood_");
 244                 BADPREFIX("log_file");
 245                 BADPREFIX("quit_");
 246                 BADPREFIX("rcon_");
 247                 BADPREFIX("sv_allowdownloads");
 248                 BADPREFIX("sv_autodemo");
 249                 BADPREFIX("sv_curl_");
 250                 BADPREFIX("sv_eventlog");
 251                 BADPREFIX("sv_logscores_");
 252                 BADPREFIX("sv_master");
 253                 BADPREFIX("sv_weaponstats_");
 254                 BADPREFIX("sv_waypointsprite_");
 255                 BADCVAR("rescan_pending");
 256
 257                 // these can contain player IDs, so better hide
 258                 BADPREFIX("g_forced_team_");
 259                 BADCVAR("sv_muteban_list");
 260                 BADCVAR("sv_voteban_list");
 261                 BADCVAR("sv_allow_customplayermodels_idlist");
 262                 BADCVAR("sv_allow_customplayermodels_speciallist");
 263
 264                 // mapinfo
 265                 BADCVAR("fraglimit");
 266                 BADCVAR("g_arena");
 267                 BADCVAR("g_assault");
 268                 BADCVAR("g_ca");
 269                 BADCVAR("g_ca_teams");
 270                 BADCVAR("g_conquest");
 271                 BADCVAR("g_conquest_teams");
 272                 BADCVAR("g_ctf");
 273                 BADCVAR("g_cts");
 274                 BADCVAR("g_dotc");
 275                 BADCVAR("g_dm");
 276                 BADCVAR("g_domination");
 277                 BADCVAR("g_domination_default_teams");
 278                 BADCVAR("g_duel");
 279                 BADCVAR("g_duel_not_dm_maps");
 280                 BADCVAR("g_freezetag");
 281                 BADCVAR("g_freezetag_teams");
 282                 BADCVAR("g_invasion_teams");
 283                 BADCVAR("g_invasion_type");
 284                 BADCVAR("g_jailbreak");
 285                 BADCVAR("g_jailbreak_teams");
 286                 BADCVAR("g_keepaway");
 287                 BADCVAR("g_keyhunt");
 288                 BADCVAR("g_keyhunt_teams");
 289                 BADCVAR("g_lms");
 290                 BADCVAR("g_nexball");
 291                 BADCVAR("g_onslaught");
 292                 BADCVAR("g_race");
 293                 BADCVAR("g_race_laps_limit");
 294                 BADCVAR("g_race_qualifying_timelimit");
 295                 BADCVAR("g_race_qualifying_timelimit_override");
 296                 BADCVAR("g_runematch");
 297                 BADCVAR("g_shootfromeye");
 298                 BADCVAR("g_snafu");
 299                 BADCVAR("g_survival");
 300                 BADCVAR("g_survival_not_dm_maps");
 301                 BADCVAR("g_tdm");
 302                 BADCVAR("g_tdm_on_dm_maps");
 303                 BADCVAR("g_tdm_teams");
 304                 BADCVAR("g_vip");
 305                 BADCVAR("leadlimit");
 306                 BADCVAR("nextmap");
 307                 BADCVAR("teamplay");
 308                 BADCVAR("timelimit");
 309                 BADCVAR("g_mapinfo_settemp_acl");
 310                 BADCVAR("g_mapinfo_ignore_warnings");
 311                 BADCVAR("g_maplist_ignore_sizes");
 312                 BADCVAR("g_maplist_sizes_count_bots");
 313
 314                 // long
 315                 BADCVAR("hostname");
 316                 BADCVAR("g_maplist");
 317                 BADCVAR("g_maplist_mostrecent");
 318                 BADCVAR("sv_motd");
 319
 320                 v = cvar_string(k);
 321                 d = cvar_defstring(k);
 322                 if(v == d)
 323                         continue;
 324
 325                 if(adding)
 326                 {
 327                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 328                         if(strlen(cvar_changes) > 16384)
 329                         {
 330                                 cvar_changes = "// too many settings have been changed to show them here\n";
 331                                 adding = 0;
 332                         }
 333                 }
 334
 335                 // now check if the changes are actually gameplay relevant
 336
 337                 // does nothing gameplay relevant
 338                 BADCVAR("captureleadlimit_override");
 339                 BADCVAR("condump_stripcolors");
 340                 BADCVAR("gameversion");
 341                 BADCVAR("fs_gamedir");
 342                 BADCVAR("g_allow_oldvortexbeam");
 343                 BADCVAR("g_balance_kill_delay");
 344                 BADCVAR("g_buffs_pickup_anyway");
 345                 BADCVAR("g_buffs_randomize");
 346                 BADCVAR("g_buffs_randomize_teamplay");
 347                 BADCVAR("g_campcheck_distance");
 348                 BADCVAR("g_chatsounds");
 349                 BADCVAR("g_ca_point_leadlimit");
 350                 BADCVAR("g_ca_point_limit");
 351                 BADCVAR("g_ca_spectate_enemies");
 352                 BADCVAR("g_ctf_captimerecord_always");
 353                 BADCVAR("g_ctf_flag_glowtrails");
 354                 BADCVAR("g_ctf_dynamiclights");
 355                 BADCVAR("g_ctf_flag_pickup_verbosename");
 356                 BADCVAR("g_ctf_flagcarrier_auto_helpme_damage");
 357                 BADPRESUFFIX("g_ctf_flag_", "_model");
 358                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 359                 BADCVAR("g_domination_point_leadlimit");
 360                 BADCVAR("g_forced_respawn");
 361                 BADCVAR("g_freezetag_point_leadlimit");
 362                 BADCVAR("g_freezetag_point_limit");
 363                 BADCVAR("g_glowtrails");
 364                 BADCVAR("g_hats");
 365                 BADCVAR("g_casings");
 366                 BADCVAR("g_invasion_point_limit");
 367                 BADCVAR("g_jump_grunt");
 368                 BADCVAR("g_keepaway_ballcarrier_effects");
 369                 BADCVAR("g_keepawayball_effects");
 370                 BADCVAR("g_keyhunt_point_leadlimit");
 371                 BADCVAR("g_nexball_goalleadlimit");
 372                 BADCVAR("g_new_toys_autoreplace");
 373                 BADCVAR("g_new_toys_use_pickupsound");
 374                 BADCVAR("g_physics_predictall");
 375                 BADCVAR("g_piggyback");
 376                 BADCVAR("g_playerclip_collisions");
 377                 BADCVAR("g_spawn_alloweffects");
 378                 BADCVAR("g_tdm_point_leadlimit");
 379                 BADCVAR("g_tdm_point_limit");
 380                 BADCVAR("leadlimit_and_fraglimit");
 381                 BADCVAR("leadlimit_override");
 382                 BADCVAR("pausable");
 383                 BADCVAR("sv_announcer");
 384                 BADCVAR("sv_checkforpacketsduringsleep");
 385                 BADCVAR("sv_damagetext");
 386                 BADCVAR("sv_db_saveasdump");
 387                 BADCVAR("sv_intermission_cdtrack");
 388                 BADCVAR("sv_mapchange_delay");
 389                 BADCVAR("sv_minigames");
 390                 BADCVAR("sv_namechangetimer");
 391                 BADCVAR("sv_precacheplayermodels");
 392                 BADCVAR("sv_qcphysics");
 393                 BADCVAR("sv_radio");
 394                 BADCVAR("sv_stepheight");
 395                 BADCVAR("sv_timeout");
 396                 BADCVAR("sv_weapons_modeloverride");
 397                 BADCVAR("w_prop_interval");
 398                 BADPREFIX("chat_");
 399                 BADPREFIX("crypto_");
 400                 BADPREFIX("gameversion_");
 401                 BADPREFIX("g_chat_");
 402                 BADPREFIX("g_ctf_captimerecord_");
 403                 BADPREFIX("g_hats_");
 404                 BADPREFIX("g_maplist_");
 405                 BADPREFIX("g_mod_");
 406                 BADPREFIX("g_respawn_");
 407                 BADPREFIX("net_");
 408                 BADPREFIX("notification_");
 409                 BADPREFIX("prvm_");
 410                 BADPREFIX("skill_");
 411                 BADPREFIX("sv_allow_");
 412                 BADPREFIX("sv_cullentities_");
 413                 BADPREFIX("sv_maxidle");
 414                 BADPREFIX("sv_minigames_");
 415                 BADPREFIX("sv_radio_");
 416                 BADPREFIX("sv_timeout_");
 417                 BADPREFIX("sv_vote_");
 418                 BADPREFIX("timelimit_");
 419
 420                 // allowed changes to server admins (please sync this to server.cfg)
 421                 // vi commands:
 422                 //   :/"impure"/,$d
 423                 //   :g!,^\/\/[^ /],d
 424                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 425                 //   :%!sort
 426                 // yes, this does contain some redundant stuff, don't really care
 427                 BADPREFIX("bot_ai_");
 428                 BADCVAR("bot_config_file");
 429                 BADCVAR("bot_number");
 430                 BADCVAR("bot_prefix");
 431                 BADCVAR("bot_suffix");
 432                 BADCVAR("capturelimit_override");
 433                 BADCVAR("fraglimit_override");
 434                 BADCVAR("gametype");
 435                 BADCVAR("g_antilag");
 436                 BADCVAR("g_balance_teams");
 437                 BADCVAR("g_balance_teams_prevent_imbalance");
 438                 BADCVAR("g_balance_teams_scorefactor");
 439                 BADCVAR("g_ban_sync_trusted_servers");
 440                 BADCVAR("g_ban_sync_uri");
 441                 BADCVAR("g_buffs");
 442                 BADCVAR("g_ca_teams_override");
 443                 BADCVAR("g_ctf_fullbrightflags");
 444                 BADCVAR("g_ctf_ignore_frags");
 445                 BADCVAR("g_ctf_leaderboard");
 446                 BADCVAR("g_domination_point_limit");
 447                 BADCVAR("g_domination_teams_override");
 448                 BADCVAR("g_freezetag_revive_spawnshield");
 449                 BADCVAR("g_freezetag_teams_override");
 450                 BADCVAR("g_friendlyfire");
 451                 BADCVAR("g_fullbrightitems");
 452                 BADCVAR("g_fullbrightplayers");
 453                 BADCVAR("g_keyhunt_point_limit");
 454                 BADCVAR("g_keyhunt_teams_override");
 455                 BADCVAR("g_lms_lives_override");
 456                 BADCVAR("g_maplist");
 457                 BADCVAR("g_maxplayers");
 458                 BADCVAR("g_mirrordamage");
 459                 BADCVAR("g_nexball_goallimit");
 460                 BADCVAR("g_norecoil");
 461                 BADCVAR("g_physics_clientselect");
 462                 BADCVAR("g_pinata");
 463                 BADCVAR("g_powerups");
 464                 BADCVAR("g_powerups_drop_ondeath");
 465                 BADCVAR("g_player_brightness");
 466                 BADCVAR("g_rocket_flying");
 467                 BADCVAR("g_rocket_flying_disabledelays");
 468                 BADPREFIX("g_spawnshield");
 469                 BADCVAR("g_start_delay");
 470                 BADCVAR("g_superspectate");
 471                 BADCVAR("g_tdm_teams_override");
 472                 BADCVAR("g_warmup");
 473                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 474                 BADCVAR("hostname");
 475                 BADCVAR("log_file");
 476                 BADCVAR("maxplayers");
 477                 BADCVAR("minplayers");
 478                 BADCVAR("minplayers_per_team");
 479                 BADCVAR("net_address");
 480                 BADCVAR("port");
 481                 BADCVAR("rcon_password");
 482                 BADCVAR("rcon_restricted_commands");
 483                 BADCVAR("rcon_restricted_password");
 484                 BADCVAR("skill");
 485                 BADCVAR("sv_adminnick");
 486                 BADCVAR("sv_autoscreenshot");
 487                 BADCVAR("sv_autotaunt");
 488                 BADCVAR("sv_curl_defaulturl");
 489                 BADCVAR("sv_defaultcharacter");
 490                 BADCVAR("sv_defaultcharacterskin");
 491                 BADCVAR("sv_defaultplayercolors");
 492                 BADCVAR("sv_defaultplayermodel");
 493                 BADCVAR("sv_defaultplayerskin");
 494                 BADCVAR("sv_maxrate");
 495                 BADCVAR("sv_motd");
 496                 BADCVAR("sv_public");
 497                 BADCVAR("sv_showfps");
 498                 BADCVAR("sv_status_privacy");
 499                 BADCVAR("sv_taunt");
 500                 BADCVAR("sv_vote_call");
 501                 BADCVAR("sv_vote_commands");
 502                 BADCVAR("sv_vote_majority_factor");
 503                 BADCVAR("sv_vote_master");
 504                 BADCVAR("sv_vote_master_commands");
 505                 BADCVAR("sv_vote_master_password");
 506                 BADCVAR("sv_vote_simple_majority_factor");
 507                 BADVALUE("sys_ticrate", "0.0166667");
 508                 BADVALUE("sys_ticrate", "0.0333333");
 509                 BADCVAR("teamplay_mode");
 510                 BADCVAR("timelimit_override");
 511                 BADPREFIX("g_warmup_");
 512                 BADPREFIX("sv_info_");
 513                 BADPREFIX("sv_ready_restart_");
 514
 515                 // mutators that announce themselves properly to the server browser
 516                 BADCVAR("g_instagib");
 517                 BADCVAR("g_new_toys");
 518                 BADCVAR("g_nix");
 519                 BADCVAR("g_grappling_hook");
 520                 BADCVAR("g_jetpack");
 521
 522                 // temporary for testing
 523                 // TODO remove before 0.8.3 release
 524                 BADCVAR("g_ca_weaponarena");
 525                 BADCVAR("g_freezetag_weaponarena");
 526                 BADCVAR("g_lms_weaponarena");
 527                 BADCVAR("g_ctf_stalemate_time");
 528
 529 #undef BADPRESUFFIX
 530 #undef BADPREFIX
 531 #undef BADCVAR
 532 #undef BADVALUE
 533
 534                 if(pureadding)
 535                 {
 536                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 537                         if(strlen(cvar_purechanges) > 16384)
 538                         {
 539                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 540                                 pureadding = 0;
 541                         }
 542                 }
 543                 ++cvar_purechanges_count;
 544                 // WARNING: this variable is used for the server list
 545                 // NEVER dare to skip this code!
 546                 // Hacks to intentionally appearing as "pure server" even though you DO have
 547                 // modified settings may be punished by removal from the server list.
 548                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 549                 // though.
 550         }
 551         buf_del(h);
 552         if(cvar_changes == "")
 553                 cvar_changes = "// this server runs at default server settings\n";
 554         else
 555                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 556         cvar_changes = strzone(cvar_changes);
 557         if(cvar_purechanges == "")
 558                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 559         else
 560                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 561         cvar_purechanges = strzone(cvar_purechanges);
 562 }
 563
 564 entity randomseed;
 565 bool RandomSeed_Send(entity this, entity to, int sf)
 566 {
 567         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 568         WriteShort(MSG_ENTITY, this.cnt);
 569         return true;
 570 }
 571 void RandomSeed_Think(entity this)
 572 {
 573         this.cnt = bound(0, floor(random() * 65536), 65535);
 574         this.nextthink = time + 5;
 575
 576         this.SendFlags |= 1;
 577 }
 578 void RandomSeed_Spawn()
 579 {
 580         randomseed = new_pure(randomseed);
 581         setthink(randomseed, RandomSeed_Think);
 582         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 583
 584         getthink(randomseed)(randomseed); // sets random seed and nextthink
 585 }
 586
 587 spawnfunc(__init_dedicated_server)
 588 {
 589         // handler for _init/_init map (only for dedicated server initialization)
 590
 591         world_initialized = -1; // don't complain
 592
 593         delete_fn = remove_unsafely;
 594
 595         entity e = new(GotoFirstMap);
 596         setthink(e, GotoFirstMap);
 597         e.nextthink = time; // this is usually 1 at this point
 598
 599         e = new(info_player_deathmatch);  // safeguard against player joining
 600
 601     // assign reflectively to avoid "assignment to world" warning
 602     for (int i = 0, n = numentityfields(); i < n; ++i) {
 603         string k = entityfieldname(i);
 604         if (k == "classname") {
 605             // safeguard against various stuff ;)
 606             putentityfieldstring(i, this, "worldspawn");
 607             break;
 608         }
 609     }
 610
 611         // needs to be done so early because of the constants they create
 612         static_init();
 613         static_init_late();
 614         static_init_precache();
 615
 616         IL_PUSH(g_spawnpoints, e); // just incase
 617
 618         MapInfo_Enumerate();
 619         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 620 }
 621
 622 void __init_dedicated_server_shutdown() {
 623         MapInfo_Shutdown();
 624 }
 625
 626 STATIC_INIT_EARLY(maxclients)
 627 {
 628         maxclients = 0;
 629         for (entity head = nextent(NULL); head; head = nextent(head)) {
 630                 ++maxclients;
 631         }
 632 }
 633
 634 void GameplayMode_DelayedInit(entity this)
 635 {
 636         if(!scores_initialized)
 637                 ScoreRules_generic();
 638 }
 639
 640 void InitGameplayMode()
 641 {
 642         VoteReset();
 643
 644         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 645         get_mi_min_max(1);
 646         // assign reflectively to avoid "assignment to world" warning
 647         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 648             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 649             if (v) {
 650             putentityfieldstring(i, world, sprintf("%v", v));
 651             if (++done == 2) break;
 652         }
 653         }
 654         // currently, NetRadiant's limit is 131072 qu for each side
 655         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 656         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 657         // in case somebody makes extremely large maps
 658         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 659
 660         MapInfo_LoadMapSettings(mapname);
 661         GameRules_teams(false);
 662
 663         if (!cvar_value_issafe(world.fog))
 664         {
 665                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 666                 world.fog = string_null;
 667         }
 668         if(MapInfo_Map_fog != "")
 669         {
 670                 if(MapInfo_Map_fog == "none")
 671                         world.fog = string_null;
 672                 else
 673                         world.fog = strzone(MapInfo_Map_fog);
 674         }
 675         clientstuff = strzone(MapInfo_Map_clientstuff);
 676
 677         MapInfo_ClearTemps();
 678
 679         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 680
 681         cache_mutatormsg = strzone("");
 682         cache_lastmutatormsg = strzone("");
 683
 684         InitializeEntity(NULL, GameplayMode_DelayedInit, INITPRIO_GAMETYPE_FALLBACK);
 685 }
 686
 687 bool world_already_spawned;
 688 spawnfunc(worldspawn)
 689 {
 690         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 691
 692         if (autocvar_sv_termsofservice_url && autocvar_sv_termsofservice_url != "")
 693         {
 694                 strcpy(sv_termsofservice_url_escaped, strreplace(":", "|", autocvar_sv_termsofservice_url));
 695         }
 696         else
 697         {
 698                 strcpy(sv_termsofservice_url_escaped, "INVALID");
 699         }
 700
 701         bool wantrestart = false;
 702         {
 703                 if (!server_is_dedicated)
 704                 {
 705                         // force unloading of server pk3 files when starting a listen server
 706                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 707                         // restore csqc_progname too
 708                         string expect = "csprogs.dat";
 709                         wantrestart = cvar_string("csqc_progname") != expect;
 710                         cvar_set("csqc_progname", expect);
 711                 }
 712                 else
 713                 {
 714                         // Try to use versioned csprogs from pk3
 715                         // Only ever use versioned csprogs.dat files on dedicated servers;
 716                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 717                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 718                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 719                         string select = "csprogs.dat";
 720                         if (fexists(pk3csprogs)) select = pk3csprogs;
 721                         if (cvar_string("csqc_progname") != select)
 722                         {
 723                                 cvar_set("csqc_progname", select);
 724                                 wantrestart = true;
 725                         }
 726                         // Check for updates on startup
 727                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 728                         int sentinel = fopen("progs.txt", FILE_READ);
 729                         if (sentinel >= 0)
 730                         {
 731                                 string switchversion = fgets(sentinel);
 732                                 fclose(sentinel);
 733                                 if (switchversion != "" && switchversion != WATERMARK)
 734                                 {
 735                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 736                                         // if it doesn't exist, assume either:
 737                                         //   a) the current program was overwritten
 738                                         //   b) this is a client only update
 739                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 740                                         if (fexists(newprogs))
 741                                         {
 742                                                 cvar_set("sv_progs", newprogs);
 743                                                 wantrestart = true;
 744                                         }
 745                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 746                                         if (fexists(newcsprogs))
 747                                         {
 748                                                 cvar_set("csqc_progname", newcsprogs);
 749                                                 wantrestart = true;
 750                                         }
 751                                 }
 752                         }
 753                 }
 754                 if (wantrestart)
 755                 {
 756                         LOG_INFO("Restart requested");
 757                         changelevel(mapname);
 758                         // let initialization continue, shutdown depends on it
 759                 }
 760         }
 761
 762         if(world_already_spawned)
 763                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 764         world_already_spawned = true;
 765
 766         delete_fn = remove_safely; // during spawning, watch what you remove!
 767
 768         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 769
 770         // default to RACE_RECORD, can be overwritten by gamemodes
 771         record_type = RACE_RECORD;
 772
 773         // needs to be done so early because of the constants they create
 774         static_init();
 775
 776         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 777
 778         TemporaryDB = db_create();
 779
 780         // 0 normal
 781         lightstyle(0, "m");
 782
 783         // 1 FLICKER (first variety)
 784         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 785
 786         // 2 SLOW STRONG PULSE
 787         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 788
 789         // 3 CANDLE (first variety)
 790         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 791
 792         // 4 FAST STROBE
 793         lightstyle(4, "mamamamamama");
 794
 795         // 5 GENTLE PULSE 1
 796         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 797
 798         // 6 FLICKER (second variety)
 799         lightstyle(6, "nmonqnmomnmomomno");
 800
 801         // 7 CANDLE (second variety)
 802         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 803
 804         // 8 CANDLE (third variety)
 805         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 806
 807         // 9 SLOW STROBE (fourth variety)
 808         lightstyle(9, "aaaaaaaazzzzzzzz");
 809
 810         // 10 FLUORESCENT FLICKER
 811         lightstyle(10, "mmamammmmammamamaaamammma");
 812
 813         // 11 SLOW PULSE NOT FADE TO BLACK
 814         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 815
 816         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 817
 818         // 63 testing
 819         lightstyle(63, "a");
 820
 821         if(autocvar_g_campaign)
 822                 CampaignPreInit();
 823
 824         Map_MarkAsRecent(mapname);
 825
 826         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 827
 828         InitGameplayMode();
 829         static_init_late();
 830         static_init_precache();
 831         readlevelcvars();
 832
 833         GameRules_limit_fallbacks();
 834
 835         if(warmup_limit == 0)
 836                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 837
 838         player_count = 0;
 839         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 840         if(bot_waypoints_for_items == 1)
 841                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 842                         bot_waypoints_for_items = 0;
 843
 844         WaypointSprite_Init();
 845
 846         GameLogInit(); // prepare everything
 847         // NOTE for matchid:
 848         // changing the logic generating it is okay. But:
 849         // it HAS to stay <= 64 chars
 850         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 851         if(autocvar_sv_eventlog)
 852         {
 853                 string num = strftime_s(); // strftime(false, "%s") isn't reliable, see strftime_s description
 854                 string s = sprintf("%s.%s.%06d", itos(autocvar_sv_eventlog_files_counter), num, floor(random() * 1000000));
 855                 matchid = strzone(s);
 856
 857                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 858                 s = ":gameinfo:mutators:LIST";
 859
 860                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 861                 s = M_ARGV(0, string);
 862
 863                 // initialiation stuff, not good in the mutator system
 864                 if(!autocvar_g_use_ammunition)
 865                         s = strcat(s, ":no_use_ammunition");
 866
 867                 // initialiation stuff, not good in the mutator system
 868                 if(autocvar_g_pickup_items == 0)
 869                         s = strcat(s, ":no_pickup_items");
 870                 if(autocvar_g_pickup_items > 0)
 871                         s = strcat(s, ":pickup_items");
 872
 873                 // initialiation stuff, not good in the mutator system
 874                 if(autocvar_g_weaponarena != "0")
 875                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 876
 877                 // TODO to mutator system
 878                 if(autocvar_g_norecoil)
 879                         s = strcat(s, ":norecoil");
 880
 881                 GameLogEcho(s);
 882                 GameLogEcho(":gameinfo:end");
 883         }
 884         else
 885                 matchid = strzone(ftos(random()));
 886
 887         cvar_set("nextmap", "");
 888
 889         SetDefaultAlpha();
 890
 891         if(autocvar_g_campaign)
 892                 CampaignPostInit();
 893
 894         Ban_LoadBans();
 895
 896         MapInfo_Enumerate();
 897         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 898
 899         q3compat = BITSET(q3compat, Q3COMPAT_ARENA, fexists(strcat("scripts/", mapname, ".arena")));
 900         q3compat = BITSET(q3compat, Q3COMPAT_DEFI, fexists(strcat("scripts/", mapname, ".defi")));
 901
 902         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 903         {
 904                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 905                 if(fd != -1)
 906                 {
 907                         string s;
 908                         while((s = fgets(fd)))
 909                         {
 910                                 int l = tokenize_console(s);
 911                                 if(l < 2)
 912                                         continue;
 913                                 if(argv(0) == "cd")
 914                                 {
 915                                         string trackname = argv(2);
 916                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 917                                         LOG_INFO("  cdtrack ", trackname);
 918                                         if (cvar_value_issafe(trackname))
 919                                         {
 920                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 921                                                 strcpy(clientstuff, newstuff);
 922                                         }
 923                                 }
 924                                 else if(argv(0) == "fog")
 925                                 {
 926                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 927                                         LOG_INFO("  \"fog\" \"", s, "\"");
 928                                 }
 929                                 else if(argv(0) == "set")
 930                                 {
 931                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 932                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 933                                 }
 934                                 else if(argv(0) != "//")
 935                                 {
 936                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 937                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 938                                 }
 939                         }
 940                         fclose(fd);
 941                 }
 942         }
 943
 944         WeaponStats_Init();
 945
 946         Nagger_Init();
 947
 948         // set up information replies for clients and server to use
 949         maplist_reply = strzone(getmaplist());
 950         lsmaps_reply = strzone(getlsmaps());
 951         monsterlist_reply = strzone(getmonsterlist());
 952         bool records_available = false;
 953         for(int i = 0; i < 10; ++i)
 954         {
 955                 string s = getrecords(i);
 956                 if (s != "")
 957                 {
 958                         records_reply[i] = strzone(s);
 959                         records_available = true;
 960                 }
 961         }
 962         if (!records_available)
 963                 records_reply[0] = "No records available for the current game mode.\n";
 964         ladder_reply = strzone(getladder());
 965         rankings_reply = strzone(getrankings());
 966
 967         // begin other init
 968         ClientInit_Spawn();
 969         RandomSeed_Spawn();
 970         PingPLReport_Spawn();
 971
 972         CheatInit();
 973
 974         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 975
 976         // fill sv_curl_serverpackages from .serverpackage files
 977         if (autocvar_sv_curl_serverpackages_auto)
 978         {
 979                 string s = "csprogs-" WATERMARK ".dat";
 980                 // remove automatically managed files from the list to prevent duplicates
 981                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 982                 {
 983                         string pkg = argv(i);
 984                         if (startsWith(pkg, "csprogs-")) continue;
 985                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 986                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 987                         s = cons(s, pkg);
 988                 }
 989                 // add automatically managed files to the list
 990                 #define X(match) MACRO_BEGIN \
 991                         int fd = search_begin(match, true, false); \
 992                         if (fd >= 0) \
 993                         { \
 994                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 995                                 { \
 996                                         s = cons(s, search_getfilename(fd, i)); \
 997                                 } \
 998                                 search_end(fd); \
 999                         } \
1000                 MACRO_END
1001                 X("*-serverpackage.txt");
1002                 X("*.serverpackage");
1003                 #undef X
1004                 cvar_set("sv_curl_serverpackages", s);
1005         }
1006
1007         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
1008         modname = "Xonotic";
1009         // physics/balance/config changes that count as mod
1010         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
1011                 modname = cvar_string("g_mod_physics");
1012         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
1013                 modname = cvar_string("g_mod_balance");
1014         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
1015                 modname = cvar_string("g_mod_config");
1016         // extra mutators that deserve to count as mod
1017         MUTATOR_CALLHOOK(SetModname, modname);
1018         modname = M_ARGV(0, string);
1019
1020         // save it for later
1021         modname = strzone(modname);
1022
1023         WinningConditionHelper(this); // set worldstatus
1024
1025         world_initialized = 1;
1026         __spawnfunc_spawn_all();
1027 }
1028
1029 spawnfunc(light)
1030 {
1031         //makestatic (this); // Who the f___ did that?
1032         delete(this);
1033 }
1034
1035 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance)
1036 {
1037     float m = e.dphitcontentsmask;
1038     e.dphitcontentsmask = goodcontents | badcontents;
1039
1040     vector org = boundmin;
1041     vector delta = boundmax - boundmin;
1042
1043     vector start, end;
1044     start = end = org;
1045     int j; // used after the loop
1046     for(j = 0; j < attempts; ++j)
1047     {
1048         start.x = org.x + random() * delta.x;
1049         start.y = org.y + random() * delta.y;
1050         start.z = org.z + random() * delta.z;
1051
1052         // rule 1: start inside world bounds, and outside
1053         // solid, and don't start from somewhere where you can
1054         // fall down to evil
1055         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1056         if (trace_fraction >= 1)
1057             continue;
1058         if (trace_startsolid)
1059             continue;
1060         if (trace_dphitcontents & badcontents)
1061             continue;
1062         if (trace_dphitq3surfaceflags & badsurfaceflags)
1063             continue;
1064
1065         // rule 2: if we are too high, lower the point
1066         if (trace_fraction * delta.z > maxaboveground)
1067             start = trace_endpos + '0 0 1' * maxaboveground;
1068         vector enddown = trace_endpos;
1069
1070         // rule 3: make sure we aren't outside the map. This only works
1071         // for somewhat well formed maps. A good rule of thumb is that
1072         // the map should have a convex outside hull.
1073         // these can be traceLINES as we already verified the starting box
1074         vector mstart = start + 0.5 * (e.mins + e.maxs);
1075         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1076         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1077             continue;
1078         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1079         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1080             continue;
1081         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1082         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1083             continue;
1084         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1085         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1086             continue;
1087         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1088         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1089             continue;
1090
1091                 // rule 4: we must "see" some spawnpoint or item
1092             entity sp = NULL;
1093             IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1094             {
1095                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1096                 {
1097                         sp = it;
1098                         break;
1099                 }
1100             });
1101                 if(!sp)
1102                 {
1103                         int items_checked = 0;
1104                         IL_EACH(g_items, checkpvs(mstart, it),
1105                         {
1106                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1107                                 {
1108                                         sp = it;
1109                                         break;
1110                                 }
1111
1112                                 ++items_checked;
1113                                 if(items_checked >= attempts)
1114                                         break; // sanity
1115                         });
1116
1117                         if(!sp)
1118                                 continue;
1119                 }
1120
1121         // find a random vector to "look at"
1122         end.x = org.x + random() * delta.x;
1123         end.y = org.y + random() * delta.y;
1124         end.z = org.z + random() * delta.z;
1125         end = start + normalize(end - start) * vlen(delta);
1126
1127         // rule 4: start TO end must not be too short
1128         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1129         if(trace_startsolid)
1130             continue;
1131         if(trace_fraction < minviewdistance / vlen(delta))
1132             continue;
1133
1134         // rule 5: don't want to look at sky
1135         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1136             continue;
1137
1138         // rule 6: we must not end up in trigger_hurt
1139         if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1140             continue;
1141
1142         break;
1143     }
1144
1145     e.dphitcontentsmask = m;
1146
1147     if(j < attempts)
1148     {
1149         setorigin(e, start);
1150         e.angles = vectoangles(end - start);
1151         LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1152         return true;
1153     }
1154     return false;
1155 }
1156
1157 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1158 {
1159         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1160 }
1161
1162 /*
1163 ===============================================================================
1164
1165 RULES
1166
1167 ===============================================================================
1168 */
1169
1170 void DumpStats(float final)
1171 {
1172         float file;
1173         string s;
1174         float to_console;
1175         float to_eventlog;
1176         float to_file;
1177         float i;
1178
1179         to_console = autocvar_sv_logscores_console;
1180         to_eventlog = autocvar_sv_eventlog;
1181         to_file = autocvar_sv_logscores_file;
1182
1183         if(!final)
1184         {
1185                 to_console = true; // always print printstats replies
1186                 to_eventlog = false; // but never print them to the event log
1187         }
1188
1189         if(to_eventlog)
1190                 if(autocvar_sv_eventlog_console)
1191                         to_console = false; // otherwise we get the output twice
1192
1193         if(final)
1194                 s = ":scores:";
1195         else
1196                 s = ":status:";
1197         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1198
1199         if(to_console)
1200                 LOG_HELP(s);
1201         if(to_eventlog)
1202                 GameLogEcho(s);
1203
1204         file = -1;
1205         if(to_file)
1206         {
1207                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1208                 if(file == -1)
1209                         to_file = false;
1210                 else
1211                         fputs(file, strcat(s, "\n"));
1212         }
1213
1214         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1215         if(to_console)
1216                 LOG_HELP(s);
1217         if(to_eventlog)
1218                 GameLogEcho(s);
1219         if(to_file)
1220                 fputs(file, strcat(s, "\n"));
1221
1222         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1223                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1224                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1225                 if(IS_PLAYER(it) || INGAME_JOINED(it))
1226                         s = strcat(s, ftos(it.team), ":");
1227                 else
1228                         s = strcat(s, "spectator:");
1229
1230                 if(to_console)
1231                         LOG_HELP(s, playername(it.netname, it.team, false));
1232                 if(to_eventlog)
1233                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it.netname, it.team, false)));
1234                 if(to_file)
1235                         fputs(file, strcat(s, playername(it.netname, it.team, false), "\n"));
1236         });
1237
1238         if(teamplay)
1239         {
1240                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1241                 if(to_console)
1242                         LOG_HELP(s);
1243                 if(to_eventlog)
1244                         GameLogEcho(s);
1245                 if(to_file)
1246                         fputs(file, strcat(s, "\n"));
1247
1248                 for(i = 1; i < 16; ++i)
1249                 {
1250                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1251                         s = strcat(s, ":", ftos(i));
1252                         if(to_console)
1253                                 LOG_HELP(s);
1254                         if(to_eventlog)
1255                                 GameLogEcho(s);
1256                         if(to_file)
1257                                 fputs(file, strcat(s, "\n"));
1258                 }
1259         }
1260
1261         if(to_console)
1262                 LOG_HELP(":end");
1263         if(to_eventlog)
1264                 GameLogEcho(":end");
1265         if(to_file)
1266         {
1267                 fputs(file, ":end\n");
1268                 fclose(file);
1269         }
1270 }
1271
1272 /*
1273 go to the next level for deathmatch
1274 only called if a time or frag limit has expired
1275 */
1276 void NextLevel()
1277 {
1278         cvar_set("_endmatch", "0");
1279         game_stopped = true;
1280         intermission_running = true; // game over
1281
1282         // enforce a wait time before allowing changelevel
1283         if(player_count > 0)
1284                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1285         else
1286                 intermission_exittime = -1;
1287
1288         /*
1289         WriteByte (MSG_ALL, SVC_CDTRACK);
1290         WriteByte (MSG_ALL, 3);
1291         WriteByte (MSG_ALL, 3);
1292         // done in FixIntermission
1293         */
1294
1295         //pos = FindIntermission ();
1296
1297         VoteReset();
1298
1299         DumpStats(true);
1300
1301         // send statistics
1302         PlayerStats_GameReport(true);
1303         WeaponStats_Shutdown();
1304
1305         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1306
1307         if(autocvar_sv_eventlog)
1308                 GameLogEcho(":gameover");
1309
1310         GameLogClose();
1311
1312         int winner_team = 0;
1313         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1314                 FixIntermissionClient(it);
1315                 if(it.winning)
1316                 {
1317                         if (teamplay && !winner_team)
1318                         {
1319                                 winner_team = it.team;
1320                                 bprint(Team_ColorCode(winner_team), Team_ColorName_Upper(winner_team), "^7 team wins the match\n");
1321                         }
1322                         bprint(playername(it.netname, it.team, false), " ^7wins\n");
1323                 }
1324         });
1325
1326         target_music_kill();
1327
1328         if(autocvar_g_campaign)
1329                 CampaignPreIntermission();
1330
1331         MUTATOR_CALLHOOK(MatchEnd);
1332
1333         localcmd("\nsv_hook_gameend\n");
1334 }
1335
1336
1337 float InitiateSuddenDeath()
1338 {
1339         // Check first whether normal overtimes could be added before initiating suddendeath mode
1340         // - for this timelimit_overtime needs to be >0 of course
1341         // - also check the winning condition calculated in the previous frame and only add normal overtime
1342         //   again, if at the point at which timelimit would be extended again, still no winner was found
1343         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1344                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1345                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1346         {
1347                 return 1; // need to call InitiateOvertime later
1348         }
1349         else
1350         {
1351                 if(!checkrules_suddendeathend)
1352                 {
1353                         if(autocvar_g_campaign)
1354                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1355                         else
1356                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1357                         if(g_race && !g_race_qualifying)
1358                                 race_StartCompleting();
1359                 }
1360                 return 0;
1361         }
1362 }
1363
1364 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1365 {
1366         ++checkrules_overtimesadded;
1367         //add one more overtime by simply extending the timelimit
1368         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1369         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1370 }
1371
1372 float GetWinningCode(float fraglimitreached, float equality)
1373 {
1374         if(autocvar_g_campaign == 1)
1375         {
1376                 if(fraglimitreached)
1377                         return WINNING_YES;
1378                 else
1379                         return WINNING_NO;
1380         }
1381         else
1382         {
1383                 if(equality)
1384                 {
1385                         if(fraglimitreached)
1386                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1387                         else
1388                                 return WINNING_NEVER;
1389                 }
1390                 else
1391                 {
1392                         if(fraglimitreached)
1393                                 return WINNING_YES;
1394                         else
1395                                 return WINNING_NO;
1396                 }
1397         }
1398 }
1399
1400 // set the .winning flag for exactly those players with a given field value
1401 void SetWinners(.float field, float value)
1402 {
1403         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = (it.(field) == value); });
1404 }
1405
1406 // set the .winning flag for those players with a given field value
1407 void AddWinners(.float field, float value)
1408 {
1409         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1410                 if(it.(field) == value)
1411                         it.winning = 1;
1412         });
1413 }
1414
1415 // clear the .winning flags
1416 void ClearWinners()
1417 {
1418         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = 0; });
1419 }
1420
1421 int fragsleft_last;
1422 float WinningCondition_Scores(float limit, float leadlimit)
1423 {
1424         // TODO make everything use THIS winning condition (except LMS)
1425         WinningConditionHelper(NULL);
1426
1427         if(teamplay)
1428         {
1429                 for (int i = 1; i < 5; ++i)
1430                 {
1431                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1432                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1433                 }
1434         }
1435
1436         ClearWinners();
1437         if(WinningConditionHelper_winner)
1438                 WinningConditionHelper_winner.winning = 1;
1439         if(WinningConditionHelper_winnerteam >= 0)
1440                 SetWinners(team, WinningConditionHelper_winnerteam);
1441
1442         if(WinningConditionHelper_lowerisbetter)
1443         {
1444                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1445                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1446                 limit = -limit;
1447         }
1448
1449         if(WinningConditionHelper_zeroisworst)
1450                 leadlimit = 0; // not supported in this mode
1451
1452         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1453         {
1454                 float fragsleft;
1455                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1456                 {
1457                         fragsleft = 1;
1458                 }
1459                 else
1460                 {
1461                         fragsleft = FLOAT_MAX;
1462                         float leadingfragsleft = FLOAT_MAX;
1463                         if (limit)
1464                                 fragsleft = limit - WinningConditionHelper_topscore;
1465                         if (leadlimit)
1466                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1467
1468                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1469                                 fragsleft = max(fragsleft, leadingfragsleft);
1470                         else
1471                                 fragsleft = min(fragsleft, leadingfragsleft);
1472                 }
1473
1474                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1475                 {
1476                         if (fragsleft == 1)
1477                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1478                         else if (fragsleft == 2)
1479                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1480                         else if (fragsleft == 3)
1481                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1482
1483                         fragsleft_last = fragsleft;
1484                 }
1485         }
1486
1487         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1488         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1489
1490         bool limit_reached;
1491         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1492         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1493                 limit_reached = (fraglimit_reached && leadlimit_reached);
1494         else
1495                 limit_reached = (fraglimit_reached || leadlimit_reached);
1496
1497         return GetWinningCode(
1498                 WinningConditionHelper_topscore && limit_reached,
1499                 WinningConditionHelper_equality
1500         );
1501 }
1502
1503 float WinningCondition_RanOutOfSpawns()
1504 {
1505         if(have_team_spawns <= 0)
1506                 return WINNING_NO;
1507
1508         if(!autocvar_g_spawn_useallspawns)
1509                 return WINNING_NO;
1510
1511         if(!some_spawn_has_been_used)
1512                 return WINNING_NO;
1513
1514         for (int i = 1; i < 5; ++i)
1515         {
1516                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1517         }
1518
1519         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1520         {
1521                 if (Team_IsValidTeam(it.team))
1522                 {
1523                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1524                 }
1525         });
1526
1527         IL_EACH(g_spawnpoints, true,
1528         {
1529                 if (Team_IsValidTeam(it.team))
1530                 {
1531                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1532                 }
1533         });
1534
1535         ClearWinners();
1536         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1537         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1538         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1539         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1540         if(team1_score + team2_score + team3_score + team4_score == 0)
1541         {
1542                 checkrules_equality = true;
1543                 return WINNING_YES;
1544         }
1545         else if(team1_score + team2_score + team3_score + team4_score == 1)
1546         {
1547                 float t, i;
1548                 if(team1_score)
1549                         t = 1;
1550                 else if(team2_score)
1551                         t = 2;
1552                 else if(team3_score)
1553                         t = 3;
1554                 else // if(team4_score)
1555                         t = 4;
1556                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1557                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1558                 {
1559                         for (int j = 1; j <= NUM_TEAMS; ++j)
1560                         {
1561                                 if (t == j)
1562                                 {
1563                                         continue;
1564                                 }
1565                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1566                                 {
1567                                         continue;
1568                                 }
1569                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1570                         }
1571                 }
1572
1573                 AddWinners(team, t);
1574                 return WINNING_YES;
1575         }
1576         else
1577                 return WINNING_NO;
1578 }
1579
1580 /*
1581 ============
1582 CheckRules_World
1583
1584 Exit deathmatch games upon conditions
1585 ============
1586 */
1587 void CheckRules_World()
1588 {
1589         VoteThink();
1590         MapVote_Think();
1591
1592         SetDefaultAlpha();
1593
1594         if (intermission_running) // someone else quit the game already
1595         {
1596                 if(player_count == 0) // Nobody there? Then let's go to the next map
1597                         MapVote_Start();
1598                         // this will actually check the player count in the next frame
1599                         // again, but this shouldn't hurt
1600                 return;
1601         }
1602
1603         float timelimit = autocvar_timelimit * 60;
1604         float fraglimit = autocvar_fraglimit;
1605         float leadlimit = autocvar_leadlimit;
1606         if (leadlimit < 0) leadlimit = 0;
1607
1608         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1609         {
1610                 if(timelimit > 0)
1611                         timelimit = 0; // timelimit is not made for warmup
1612                 if(fraglimit > 0)
1613                         fraglimit = 0; // no fraglimit for now
1614                 leadlimit = 0; // no leadlimit for now
1615         }
1616
1617         if (autocvar__endmatch || timelimit < 0)
1618         {
1619                 // endmatch
1620                 NextLevel();
1621                 return;
1622         }
1623
1624         if(timelimit > 0)
1625                 timelimit += game_starttime;
1626
1627         float wantovertime;
1628         wantovertime = 0;
1629
1630         if(checkrules_suddendeathend)
1631         {
1632                 if(!checkrules_suddendeathwarning)
1633                 {
1634                         checkrules_suddendeathwarning = true;
1635                         if(g_race && !g_race_qualifying)
1636                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1637                         else
1638                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1639                 }
1640         }
1641         else
1642         {
1643                 if (timelimit && time >= timelimit)
1644                 {
1645                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1646                         {
1647                                 float totalplayers;
1648                                 float playerswithlaps;
1649                                 float readyplayers;
1650                                 totalplayers = playerswithlaps = readyplayers = 0;
1651                                 FOREACH_CLIENT(IS_PLAYER(it), {
1652                                         ++totalplayers;
1653                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1654                                                 ++playerswithlaps;
1655                                         if(it.ready)
1656                                                 ++readyplayers;
1657                                 });
1658
1659                                 // at least 2 of the players have completed a lap: start the RACE
1660                                 // otherwise, the players should end the qualifying on their own
1661                                 if(readyplayers || playerswithlaps >= 2)
1662                                 {
1663                                         checkrules_suddendeathend = 0;
1664                                         ReadyRestart(true); // go to race
1665                                         return;
1666                                 }
1667                                 else
1668                                         wantovertime |= InitiateSuddenDeath();
1669                         }
1670                         else
1671                                 wantovertime |= InitiateSuddenDeath();
1672                 }
1673         }
1674
1675         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1676         {
1677                 NextLevel();
1678                 return;
1679         }
1680
1681         int checkrules_status = WinningCondition_RanOutOfSpawns();
1682         if(checkrules_status == WINNING_YES)
1683                 bprint("Hey! Someone ran out of spawns!\n");
1684         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1685                 checkrules_status = M_ARGV(0, float);
1686         else
1687                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1688
1689         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1690         {
1691                 checkrules_status = WINNING_NEVER;
1692                 checkrules_overtimesadded = -1;
1693                 wantovertime |= InitiateSuddenDeath();
1694         }
1695
1696         if(checkrules_status == WINNING_NEVER)
1697                 // equality cases! Nobody wins if the overtime ends in a draw.
1698                 ClearWinners();
1699
1700         if(wantovertime)
1701         {
1702                 if(checkrules_status == WINNING_NEVER)
1703                         InitiateOvertime();
1704                 else
1705                         checkrules_status = WINNING_YES;
1706         }
1707
1708         if(checkrules_suddendeathend)
1709                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1710                         checkrules_status = WINNING_YES;
1711
1712         if(checkrules_status == WINNING_YES)
1713         {
1714                 //print("WINNING\n");
1715                 NextLevel();
1716         }
1717 }
1718
1719 float want_weapon(entity weaponinfo, float allguns)
1720 {
1721         int d = 0;
1722         bool allow_mutatorblocked = false;
1723
1724         if(!weaponinfo.m_id)
1725                 return 0;
1726
1727         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
1728         d = M_ARGV(1, float);
1729         allguns = M_ARGV(2, bool);
1730         allow_mutatorblocked = M_ARGV(3, bool);
1731
1732         if(allguns)
1733                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
1734         else if(!mutator_returnvalue)
1735                 d = !(!weaponinfo.weaponstart);
1736
1737         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
1738                 d = 0;
1739
1740         float t = weaponinfo.weaponstartoverride;
1741
1742         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
1743
1744         // bit order in t:
1745         // 1: want or not
1746         // 2: is default?
1747         // 4: is set by default?
1748         if(t < 0)
1749                 t = 4 | (3 * d);
1750         else
1751                 t |= (2 * d);
1752
1753         return t;
1754 }
1755
1756 /// Weapons the player normally starts with outside weapon arena.
1757 WepSet weapons_start()
1758 {
1759         WepSet ret = '0 0 0';
1760         FOREACH(Weapons, it != WEP_Null, {
1761                 int w = want_weapon(it, false);
1762                 if (w & 1)
1763                         ret |= it.m_wepset;
1764         });
1765         return ret;
1766 }
1767
1768 WepSet weapons_all()
1769 {
1770         WepSet ret = '0 0 0';
1771         FOREACH(Weapons, it != WEP_Null, {
1772                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
1773                         ret |= it.m_wepset;
1774         });
1775         return ret;
1776 }
1777
1778 WepSet weapons_devall()
1779 {
1780         WepSet ret = '0 0 0';
1781         FOREACH(Weapons, it != WEP_Null,
1782         {
1783                 ret |= it.m_wepset;
1784         });
1785         return ret;
1786 }
1787
1788 WepSet weapons_most()
1789 {
1790         WepSet ret = '0 0 0';
1791         FOREACH(Weapons, it != WEP_Null, {
1792                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
1793                         ret |= it.m_wepset;
1794         });
1795         return ret;
1796 }
1797
1798 void weaponarena_available_all_update(entity this)
1799 {
1800         if (weaponsInMapAll)
1801         {
1802                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
1803         }
1804         else
1805         {
1806                 // if no weapons are available on the map, just fall back to all weapons arena
1807                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
1808         }
1809 }
1810
1811 void weaponarena_available_devall_update(entity this)
1812 {
1813         if (weaponsInMapAll)
1814         {
1815                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
1816         }
1817         else
1818         {
1819                 // if no weapons are available on the map, just fall back to devall weapons arena
1820                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
1821         }
1822 }
1823
1824 void weaponarena_available_most_update(entity this)
1825 {
1826         if (weaponsInMapAll)
1827         {
1828                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
1829         }
1830         else
1831         {
1832                 // if no weapons are available on the map, just fall back to most weapons arena
1833                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
1834         }
1835 }
1836
1837 void readplayerstartcvars()
1838 {
1839         // initialize starting values for players
1840         start_weapons = '0 0 0';
1841         start_weapons_default = '0 0 0';
1842         start_weapons_defaultmask = '0 0 0';
1843         start_items = 0;
1844         start_ammo_shells = 0;
1845         start_ammo_nails = 0;
1846         start_ammo_rockets = 0;
1847         start_ammo_cells = 0;
1848         start_ammo_plasma = 0;
1849         if (random_start_ammo == NULL)
1850         {
1851                 random_start_ammo = new_pure(random_start_ammo);
1852         }
1853         start_health = cvar("g_balance_health_start");
1854         start_armorvalue = cvar("g_balance_armor_start");
1855
1856         g_weaponarena = 0;
1857         g_weaponarena_weapons = '0 0 0';
1858
1859         string s = cvar_string("g_weaponarena");
1860
1861         MUTATOR_CALLHOOK(SetWeaponArena, s);
1862         s = M_ARGV(0, string);
1863
1864         if (s == "0" || s == "")
1865         {
1866                 // no arena
1867         }
1868         else if (s == "off")
1869         {
1870                 // forcibly turn off weaponarena
1871         }
1872         else if (s == "all" || s == "1")
1873         {
1874                 g_weaponarena = 1;
1875                 g_weaponarena_list = "All Weapons";
1876                 g_weaponarena_weapons = weapons_all();
1877         }
1878         else if (s == "devall")
1879         {
1880                 g_weaponarena = 1;
1881                 g_weaponarena_list = "Dev All Weapons";
1882                 g_weaponarena_weapons = weapons_devall();
1883         }
1884         else if (s == "most")
1885         {
1886                 g_weaponarena = 1;
1887                 g_weaponarena_list = "Most Weapons";
1888                 g_weaponarena_weapons = weapons_most();
1889         }
1890         else if (s == "all_available")
1891         {
1892                 g_weaponarena = 1;
1893                 g_weaponarena_list = "All Available Weapons";
1894
1895                 // this needs to run after weaponsInMapAll is initialized
1896                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
1897         }
1898         else if (s == "devall_available")
1899         {
1900                 g_weaponarena = 1;
1901                 g_weaponarena_list = "Dev All Available Weapons";
1902
1903                 // this needs to run after weaponsInMapAll is initialized
1904                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
1905         }
1906         else if (s == "most_available")
1907         {
1908                 g_weaponarena = 1;
1909                 g_weaponarena_list = "Most Available Weapons";
1910
1911                 // this needs to run after weaponsInMapAll is initialized
1912                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
1913         }
1914         else if (s == "none")
1915         {
1916                 g_weaponarena = 1;
1917                 g_weaponarena_list = "No Weapons";
1918         }
1919         else
1920         {
1921                 g_weaponarena = 1;
1922                 float t = tokenize_console(s);
1923                 g_weaponarena_list = "";
1924                 for (int j = 0; j < t; ++j)
1925                 {
1926                         s = argv(j);
1927                         Weapon wep = Weapon_from_name(s);
1928                         if(wep != WEP_Null)
1929                         {
1930                                 g_weaponarena_weapons |= (wep.m_wepset);
1931                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
1932                         }
1933                 }
1934                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
1935         }
1936
1937         if (g_weaponarena)
1938         {
1939                 g_weapon_stay = 0; // incompatible
1940                 start_weapons = g_weaponarena_weapons;
1941                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1942         }
1943         else
1944         {
1945                 FOREACH(Weapons, it != WEP_Null, {
1946                         int w = want_weapon(it, false);
1947                         WepSet s = it.m_wepset;
1948                         if(w & 1)
1949                                 start_weapons |= s;
1950                         if(w & 2)
1951                                 start_weapons_default |= s;
1952                         if(w & 4)
1953                                 start_weapons_defaultmask |= s;
1954                 });
1955         }
1956
1957         if(cvar("g_balance_superweapons_time") < 0)
1958                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
1959
1960         if(!cvar("g_use_ammunition"))
1961                 start_items |= IT_UNLIMITED_AMMO;
1962
1963         if(start_items & IT_UNLIMITED_AMMO)
1964         {
1965                 start_ammo_shells = 999;
1966                 start_ammo_nails = 999;
1967                 start_ammo_rockets = 999;
1968                 start_ammo_cells = 999;
1969                 start_ammo_plasma = 999;
1970                 start_ammo_fuel = 999;
1971         }
1972         else
1973         {
1974                 start_ammo_shells = cvar("g_start_ammo_shells");
1975                 start_ammo_nails = cvar("g_start_ammo_nails");
1976                 start_ammo_rockets = cvar("g_start_ammo_rockets");
1977                 start_ammo_cells = cvar("g_start_ammo_cells");
1978                 start_ammo_plasma = cvar("g_start_ammo_plasma");
1979                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1980                 random_start_weapons_count = cvar("g_random_start_weapons_count");
1981                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
1982                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
1983                 SetResource(random_start_ammo, RES_ROCKETS, cvar("g_random_start_rockets"));
1984                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
1985                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
1986         }
1987
1988         warmup_start_ammo_shells = start_ammo_shells;
1989         warmup_start_ammo_nails = start_ammo_nails;
1990         warmup_start_ammo_rockets = start_ammo_rockets;
1991         warmup_start_ammo_cells = start_ammo_cells;
1992         warmup_start_ammo_plasma = start_ammo_plasma;
1993         warmup_start_ammo_fuel = start_ammo_fuel;
1994         warmup_start_health = start_health;
1995         warmup_start_armorvalue = start_armorvalue;
1996         warmup_start_weapons = start_weapons;
1997         warmup_start_weapons_default = start_weapons_default;
1998         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
1999
2000         if (!g_weaponarena)
2001         {
2002                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
2003                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
2004                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
2005                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
2006                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
2007                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
2008                 warmup_start_health = cvar("g_warmup_start_health");
2009                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
2010                 warmup_start_weapons = '0 0 0';
2011                 warmup_start_weapons_default = '0 0 0';
2012                 warmup_start_weapons_defaultmask = '0 0 0';
2013                 FOREACH(Weapons, it != WEP_Null, {
2014                         int w = want_weapon(it, autocvar_g_warmup_allguns);
2015                         WepSet s = it.m_wepset;
2016                         if(w & 1)
2017                                 warmup_start_weapons |= s;
2018                         if(w & 2)
2019                                 warmup_start_weapons_default |= s;
2020                         if(w & 4)
2021                                 warmup_start_weapons_defaultmask |= s;
2022                 });
2023         }
2024
2025         if (autocvar_g_jetpack)
2026                 start_items |= ITEM_Jetpack.m_itemid;
2027
2028         MUTATOR_CALLHOOK(SetStartItems);
2029
2030         if (start_items & ITEM_Jetpack.m_itemid)
2031         {
2032                 start_items |= ITEM_JetpackRegen.m_itemid;
2033                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2034                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2035         }
2036
2037         start_ammo_shells = max(0, start_ammo_shells);
2038         start_ammo_nails = max(0, start_ammo_nails);
2039         start_ammo_rockets = max(0, start_ammo_rockets);
2040         start_ammo_cells = max(0, start_ammo_cells);
2041         start_ammo_plasma = max(0, start_ammo_plasma);
2042         start_ammo_fuel = max(0, start_ammo_fuel);
2043         SetResource(random_start_ammo, RES_SHELLS, max(0, GetResource(random_start_ammo, RES_SHELLS)));
2044         SetResource(random_start_ammo, RES_BULLETS, max(0, GetResource(random_start_ammo, RES_BULLETS)));
2045         SetResource(random_start_ammo, RES_ROCKETS, max(0, GetResource(random_start_ammo, RES_ROCKETS)));
2046         SetResource(random_start_ammo, RES_CELLS, max(0, GetResource(random_start_ammo, RES_CELLS)));
2047         SetResource(random_start_ammo, RES_PLASMA, max(0, GetResource(random_start_ammo, RES_PLASMA)));
2048
2049         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
2050         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
2051         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
2052         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
2053         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
2054         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
2055 }
2056
2057 void readlevelcvars()
2058 {
2059         if(cvar("sv_allow_fullbright"))
2060                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
2061
2062         sv_ready_restart_after_countdown = cvar("sv_ready_restart_after_countdown");
2063
2064         warmup_stage = cvar("g_warmup");
2065         warmup_limit = cvar("g_warmup_limit");
2066
2067         if(cvar("g_campaign"))
2068                 warmup_stage = 0; // no warmup during campaign
2069
2070         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
2071         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
2072         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
2073         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
2074         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
2075         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
2076         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
2077         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
2078         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
2079         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
2080         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
2081         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
2082         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
2083         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
2084
2085         g_pickup_shells = cvar("g_pickup_shells");
2086         g_pickup_shells_max = cvar("g_pickup_shells_max");
2087         g_pickup_nails = cvar("g_pickup_nails");
2088         g_pickup_nails_max = cvar("g_pickup_nails_max");
2089         g_pickup_rockets = cvar("g_pickup_rockets");
2090         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
2091         g_pickup_cells = cvar("g_pickup_cells");
2092         g_pickup_cells_max = cvar("g_pickup_cells_max");
2093         g_pickup_plasma = cvar("g_pickup_plasma");
2094         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
2095         g_pickup_fuel = cvar("g_pickup_fuel");
2096         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
2097         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
2098         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
2099         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
2100         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
2101         g_pickup_armormedium = cvar("g_pickup_armormedium");
2102         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
2103         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
2104         g_pickup_armorbig = cvar("g_pickup_armorbig");
2105         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
2106         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
2107         g_pickup_armormega = cvar("g_pickup_armormega");
2108         g_pickup_armormega_max = cvar("g_pickup_armormega_max");
2109         g_pickup_armormega_anyway = cvar("g_pickup_armormega_anyway");
2110         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
2111         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
2112         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
2113         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
2114         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
2115         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
2116         g_pickup_healthbig = cvar("g_pickup_healthbig");
2117         g_pickup_healthbig_max = cvar("g_pickup_healthbig_max");
2118         g_pickup_healthbig_anyway = cvar("g_pickup_healthbig_anyway");
2119         g_pickup_healthmega = cvar("g_pickup_healthmega");
2120         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
2121         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
2122
2123         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
2124         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
2125
2126     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
2127     if(!g_weapon_stay)
2128         g_weapon_stay = cvar("g_weapon_stay");
2129
2130     MUTATOR_CALLHOOK(ReadLevelCvars);
2131
2132         if (!warmup_stage)
2133                 game_starttime = time + cvar("g_start_delay");
2134
2135         FOREACH(Weapons, it != WEP_Null, { it.wr_init(it); });
2136
2137         readplayerstartcvars();
2138 }
2139
2140 void InitializeEntity(entity e, void(entity this) func, int order)
2141 {
2142     entity prev, cur;
2143
2144     if (!e || e.initialize_entity)
2145     {
2146         // make a proxy initializer entity
2147         entity e_old = e;
2148         e = new(initialize_entity);
2149         e.enemy = e_old;
2150     }
2151
2152     e.initialize_entity = func;
2153     e.initialize_entity_order = order;
2154
2155     cur = initialize_entity_first;
2156     prev = NULL;
2157     for (;;)
2158     {
2159         if (!cur || cur.initialize_entity_order > order)
2160         {
2161             // insert between prev and cur
2162             if (prev)
2163                 prev.initialize_entity_next = e;
2164             else
2165                 initialize_entity_first = e;
2166             e.initialize_entity_next = cur;
2167             return;
2168         }
2169         prev = cur;
2170         cur = cur.initialize_entity_next;
2171     }
2172 }
2173 void InitializeEntitiesRun()
2174 {
2175     entity startoflist = initialize_entity_first;
2176     initialize_entity_first = NULL;
2177     delete_fn = remove_except_protected;
2178     for (entity e = startoflist; e; e = e.initialize_entity_next)
2179     {
2180                 e.remove_except_protected_forbidden = 1;
2181     }
2182     for (entity e = startoflist; e; )
2183     {
2184                 e.remove_except_protected_forbidden = 0;
2185         e.initialize_entity_order = 0;
2186         entity next = e.initialize_entity_next;
2187         e.initialize_entity_next = NULL;
2188         var void(entity this) func = e.initialize_entity;
2189         e.initialize_entity = func_null;
2190         if (e.classname == "initialize_entity")
2191         {
2192             entity wrappee = e.enemy;
2193             builtin_remove(e);
2194             e = wrappee;
2195         }
2196         //dprint("Delayed initialization: ", e.classname, "\n");
2197         if (func)
2198         {
2199                 func(e);
2200         }
2201         else
2202         {
2203             eprint(e);
2204             backtrace(strcat("Null function in: ", e.classname, "\n"));
2205         }
2206         e = next;
2207     }
2208     delete_fn = remove_unsafely;
2209 }
2210
2211 // deferred dropping
2212 void DropToFloor_Handler(entity this)
2213 {
2214         WITHSELF(this, builtin_droptofloor());
2215         this.dropped_origin = this.origin;
2216 }
2217
2218 void droptofloor(entity this)
2219 {
2220         InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
2221 }
2222
2223 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2224 void RunThink(entity this, float dt)
2225 {
2226         // don't let things stay in the past.
2227         // it is possible to start that way by a trigger with a local time.
2228         if(this.nextthink <= 0 || this.nextthink > time + dt)
2229                 return;
2230
2231         float oldtime = time; // do we need to save this?
2232
2233         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2234         {
2235                 time = max(oldtime, this.nextthink);
2236                 this.nextthink = 0;
2237
2238                 if(getthink(this))
2239                         getthink(this)(this);
2240                 // mods often set nextthink to time to cause a think every frame,
2241                 // we don't want to loop in that case, so exit if the new nextthink is
2242                 // <= the time the qc was told, also exit if it is past the end of the
2243                 // frame
2244                 if(this.nextthink <= time || this.nextthink > oldtime + dt || !autocvar_sv_gameplayfix_multiplethinksperframe)
2245                         break;
2246         }
2247
2248         time = oldtime;
2249 }
2250
2251 bool autocvar_sv_freezenonclients;
2252 void Physics_Frame()
2253 {
2254         if(autocvar_sv_freezenonclients)
2255                 return;
2256
2257         IL_EACH(g_moveables, true,
2258         {
2259                 if(IS_CLIENT(it) || it.move_movetype == MOVETYPE_PHYSICS)
2260                         continue;
2261
2262                 //set_movetype(it, it.move_movetype);
2263                 // inline the set_movetype function, since this is called a lot
2264                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2265
2266                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2267                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2268
2269                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2270                 {
2271                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2272                                 continue; // these movetypes have no regular think function
2273                         // handle thinking here
2274                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + PHYS_INPUT_TIMELENGTH)
2275                                 RunThink(it, PHYS_INPUT_TIMELENGTH);
2276                 }
2277         });
2278
2279         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2280                 return;
2281
2282         // make a second pass to see if any ents spawned this frame and make
2283         // sure they run their move/think. this is verified by checking .move_time, which will never be 0 if the entity has moved
2284         // MOVETYPE_NONE is also checked as .move_time WILL be 0 with that movetype
2285         IL_EACH(g_moveables, it.move_qcphysics,
2286         {
2287                 if(IS_CLIENT(it) || it.move_time || it.move_movetype == MOVETYPE_NONE || it.move_movetype == MOVETYPE_PHYSICS)
2288                         continue;
2289                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2290         });
2291 }
2292
2293 void systems_update();
2294 void EndFrame()
2295 {
2296         anticheat_endframe();
2297
2298         Physics_Frame();
2299
2300         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2301                 entity e = IS_SPEC(it) ? it.enemy : it;
2302                 if (e.typehitsound) {
2303                         STAT(TYPEHIT_TIME, it) = time;
2304                 } else if (e.killsound) {
2305                         STAT(KILL_TIME, it) = time;
2306                 } else if (e.hitsound_damage_dealt) {
2307                         STAT(HIT_TIME, it) = time;
2308                         // NOTE: this is not accurate as client code doesn't need so much accuracy for its purposes
2309                         STAT(HITSOUND_DAMAGE_DEALT_TOTAL, it) += ceil(e.hitsound_damage_dealt);
2310                 }
2311         });
2312         // add 1 frametime because after this, engine SV_Physics
2313         // increases time by a frametime and then networks the frame
2314         // add another frametime because client shows everything with
2315         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2316         // needed!
2317         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2318         FOREACH_CLIENT(true, {
2319                 it.typehitsound = false;
2320                 it.hitsound_damage_dealt = 0;
2321                 it.killsound = false;
2322                 antilag_record(it, CS(it), altime);
2323         });
2324         IL_EACH(g_monsters, true,
2325         {
2326                 antilag_record(it, it, altime);
2327         });
2328         IL_EACH(g_projectiles, it.classname == "nade",
2329         {
2330                 antilag_record(it, it, altime);
2331         });
2332         systems_update();
2333         IL_ENDFRAME();
2334 }
2335
2336
2337 /*
2338  * RedirectionThink:
2339  * returns true if redirecting
2340  */
2341 float redirection_timeout;
2342 float redirection_nextthink;
2343 float RedirectionThink()
2344 {
2345         float clients_found;
2346
2347         if(redirection_target == "")
2348                 return false;
2349
2350         if(!redirection_timeout)
2351         {
2352                 cvar_set("sv_public", "-2");
2353                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2354                 if(redirection_target == "self")
2355                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2356                 else
2357                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2358         }
2359
2360         if(time < redirection_nextthink)
2361                 return true;
2362
2363         redirection_nextthink = time + 1;
2364
2365         clients_found = 0;
2366         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2367                 // TODO add timer
2368                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2369                 if(redirection_target == "self")
2370                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2371                 else
2372                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2373                 ++clients_found;
2374         });
2375
2376         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2377
2378         if(time > redirection_timeout || clients_found == 0)
2379                 localcmd("\nwait; wait; wait; quit\n");
2380
2381         return true;
2382 }
2383
2384 void RestoreGame()
2385 {
2386         // Loaded from a save game
2387         // some things then break, so let's work around them...
2388
2389         // Progs DB (capture records)
2390         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2391
2392         // Mapinfo
2393         MapInfo_Shutdown();
2394         MapInfo_Enumerate();
2395         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2396         WeaponStats_Init();
2397
2398         TargetMusic_RestoreGame();
2399 }
2400
2401 void Shutdown()
2402 {
2403         game_stopped = 2;
2404
2405         if(world_initialized > 0)
2406         {
2407                 world_initialized = 0;
2408
2409                 // if a timeout is active, reset the slowmo value to normal
2410                 if(timeout_status == TIMEOUT_ACTIVE)
2411                         cvar_set("slowmo", ftos(orig_slowmo));
2412
2413                 LOG_TRACE("Saving persistent data...");
2414                 Ban_SaveBans();
2415
2416                 // playerstats with unfinished match
2417                 PlayerStats_GameReport(false);
2418
2419                 if(!cheatcount_total)
2420                 {
2421                         if(autocvar_sv_db_saveasdump)
2422                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2423                         else
2424                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2425                 }
2426                 if(autocvar_developer > 0)
2427                 {
2428                         if(autocvar_sv_db_saveasdump)
2429                                 db_dump(TemporaryDB, "server-temp.db");
2430                         else
2431                                 db_save(TemporaryDB, "server-temp.db");
2432                 }
2433                 CheatShutdown(); // must be after cheatcount check
2434                 db_close(ServerProgsDB);
2435                 db_close(TemporaryDB);
2436                 LOG_TRACE("Saving persistent data... done!");
2437                 // tell the bot system the game is ending now
2438                 bot_endgame();
2439
2440                 WeaponStats_Shutdown();
2441                 MapInfo_Shutdown();
2442
2443                 strfree(sv_termsofservice_url_escaped);
2444         }
2445         else if(world_initialized == 0)
2446         {
2447                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2448         }
2449         else
2450         {
2451                 __init_dedicated_server_shutdown();
2452         }
2453 }