qcsrc/server/world.qc

   1 #include "world.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/gamemodes/sv_rules.qh>
   7 #include <common/items/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/target/music.qh>
  10 #include <common/mapobjects/trigger/hurt.qh>
  11 #include <common/mapobjects/trigger/secret.qh>
  12 #include <common/mapobjects/triggers.qh>
  13 #include <common/monsters/_mod.qh>
  14 #include <common/monsters/sv_monsters.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/notifications/all.qh>
  17 #include <common/physics/player.qh>
  18 #include <common/playerstats.qh>
  19 #include <common/state.qh>
  20 #include <common/stats.qh>
  21 #include <common/teams.qh>
  22 #include <common/util.qh>
  23 #include <common/vehicles/all.qh>
  24 #include <common/weapons/_all.qh>
  25 #include <server/anticheat.qh>
  26 #include <server/antilag.qh>
  27 #include <server/bot/api.qh>
  28 #include <server/campaign.qh>
  29 #include <server/cheats.qh>
  30 #include <server/client.qh>
  31 #include <server/command/common.qh>
  32 #include <server/command/getreplies.qh>
  33 #include <server/command/sv_cmd.qh>
  34 #include <server/command/vote.qh>
  35 #include <server/damage.qh>
  36 #include <server/gamelog.qh>
  37 #include <server/hook.qh>
  38 #include <server/intermission.qh>
  39 #include <server/ipban.qh>
  40 #include <server/items/items.qh>
  41 #include <server/main.qh>
  42 #include <server/mapvoting.qh>
  43 #include <server/mutators/_mod.qh>
  44 #include <server/race.qh>
  45 #include <server/scores.qh>
  46 #include <server/scores_rules.qh>
  47 #include <server/spawnpoints.qh>
  48 #include <server/teamplay.qh>
  49 #include <server/weapons/common.qh>
  50 #include <server/weapons/weaponstats.qh>
  51
  52 const float LATENCY_THINKRATE = 10;
  53 .float latency_sum;
  54 .float latency_cnt;
  55 .float latency_time;
  56 entity pingplreport;
  57 void PingPLReport_Think(entity this)
  58 {
  59         float delta;
  60         entity e;
  61
  62         delta = 3 / maxclients;
  63         if(delta < sys_frametime)
  64                 delta = 0;
  65         this.nextthink = time + delta;
  66
  67         e = edict_num(this.cnt + 1);
  68         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  69         {
  70                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  71                 WriteByte(MSG_BROADCAST, this.cnt);
  72                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 32767));
  73                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  74                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  75
  76                 // record latency times for clients throughout the match so we can report it to playerstats
  77                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  78                 {
  79                         CS(e).latency_sum += CS(e).ping;
  80                         CS(e).latency_cnt += 1;
  81                         CS(e).latency_time = time;
  82                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  83                 }
  84         }
  85         else
  86         {
  87                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  88                 WriteByte(MSG_BROADCAST, this.cnt);
  89                 WriteShort(MSG_BROADCAST, 0);
  90                 WriteByte(MSG_BROADCAST, 0);
  91                 WriteByte(MSG_BROADCAST, 0);
  92         }
  93         this.cnt = (this.cnt + 1) % maxclients;
  94 }
  95 void PingPLReport_Spawn()
  96 {
  97         pingplreport = new_pure(pingplreport);
  98         setthink(pingplreport, PingPLReport_Think);
  99         pingplreport.nextthink = time;
 100 }
 101
 102 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
 103
 104 void SetDefaultAlpha()
 105 {
 106         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 107         {
 108                 default_player_alpha = autocvar_g_player_alpha;
 109                 if(default_player_alpha == 0)
 110                         default_player_alpha = 1;
 111                 default_weapon_alpha = default_player_alpha;
 112         }
 113 }
 114
 115 void GotoFirstMap(entity this)
 116 {
 117         float n;
 118         if(autocvar__sv_init)
 119         {
 120                 // cvar_set("_sv_init", "0");
 121                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 122                 // to this "init" map on a dedicated server will cause no permanent
 123                 // harm
 124                 if(autocvar_g_maplist_shuffle)
 125                         ShuffleMaplist();
 126                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 127                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 128
 129                 MapInfo_Enumerate();
 130                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 131
 132                 if(!DoNextMapOverride(1))
 133                         GotoNextMap(1);
 134
 135                 return;
 136         }
 137
 138         if(time < 5)
 139         {
 140                 this.nextthink = time;
 141         }
 142         else
 143         {
 144                 this.nextthink = time + 1;
 145                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 146         }
 147 }
 148
 149 void cvar_changes_init()
 150 {
 151         float h;
 152         string k, v, d;
 153         float n, i, adding, pureadding;
 154
 155         strfree(cvar_changes);
 156         strfree(cvar_purechanges);
 157         cvar_purechanges_count = 0;
 158
 159         h = buf_create();
 160         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 161         n = buf_getsize(h);
 162
 163         adding = true;
 164         pureadding = true;
 165
 166         for(i = 0; i < n; ++i)
 167         {
 168                 k = bufstr_get(h, i);
 169
 170 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 171 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 172 #define BADCVAR(p) if(k == p) continue
 173 #define BADVALUE(p, val) if (k == p && v == val) continue
 174
 175                 // general excludes and namespaces for server admin used cvars
 176                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 177
 178                 // internal
 179                 BADPREFIX("csqc_");
 180                 BADPREFIX("cvar_check_");
 181                 BADCVAR("gamecfg");
 182                 BADCVAR("g_configversion");
 183                 BADCVAR("halflifebsp");
 184                 BADCVAR("sv_mapformat_is_quake2");
 185                 BADCVAR("sv_mapformat_is_quake3");
 186                 BADPREFIX("sv_world");
 187
 188                 // client
 189                 BADPREFIX("chase_");
 190                 BADPREFIX("cl_");
 191                 BADPREFIX("con_");
 192                 BADPREFIX("scoreboard_");
 193                 BADPREFIX("g_campaign");
 194                 BADPREFIX("g_waypointsprite_");
 195                 BADPREFIX("gl_");
 196                 BADPREFIX("joy");
 197                 BADPREFIX("hud_");
 198                 BADPREFIX("m_");
 199                 BADPREFIX("menu_");
 200                 BADPREFIX("net_slist_");
 201                 BADPREFIX("r_");
 202                 BADPREFIX("sbar_");
 203                 BADPREFIX("scr_");
 204                 BADPREFIX("snd_");
 205                 BADPREFIX("show");
 206                 BADPREFIX("sensitivity");
 207                 BADPREFIX("userbind");
 208                 BADPREFIX("v_");
 209                 BADPREFIX("vid_");
 210                 BADPREFIX("crosshair");
 211                 BADCVAR("mod_q3bsp_lightmapmergepower");
 212                 BADCVAR("mod_q3bsp_nolightmaps");
 213                 BADCVAR("fov");
 214                 BADCVAR("mastervolume");
 215                 BADCVAR("volume");
 216                 BADCVAR("bgmvolume");
 217                 BADCVAR("in_pitch_min");
 218                 BADCVAR("in_pitch_max");
 219
 220                 // private
 221                 BADCVAR("developer");
 222                 BADCVAR("log_dest_udp");
 223                 BADCVAR("net_address");
 224                 BADCVAR("net_address_ipv6");
 225                 BADCVAR("port");
 226                 BADCVAR("savedgamecfg");
 227                 BADCVAR("serverconfig");
 228                 BADCVAR("sv_autoscreenshot");
 229                 BADCVAR("sv_heartbeatperiod");
 230                 BADCVAR("sv_vote_master_password");
 231                 BADCVAR("sys_colortranslation");
 232                 BADCVAR("sys_specialcharactertranslation");
 233                 BADCVAR("timeformat");
 234                 BADCVAR("timestamps");
 235                 BADCVAR("g_require_stats");
 236                 BADPREFIX("developer_");
 237                 BADPREFIX("g_ban_");
 238                 BADPREFIX("g_banned_list");
 239                 BADPREFIX("g_require_stats_");
 240                 BADPREFIX("g_chat_flood_");
 241                 BADPREFIX("g_ghost_items");
 242                 BADPREFIX("g_playerstats_");
 243                 BADPREFIX("g_voice_flood_");
 244                 BADPREFIX("log_file");
 245                 BADPREFIX("quit_");
 246                 BADPREFIX("rcon_");
 247                 BADPREFIX("sv_allowdownloads");
 248                 BADPREFIX("sv_autodemo");
 249                 BADPREFIX("sv_curl_");
 250                 BADPREFIX("sv_eventlog");
 251                 BADPREFIX("sv_logscores_");
 252                 BADPREFIX("sv_master");
 253                 BADPREFIX("sv_weaponstats_");
 254                 BADPREFIX("sv_waypointsprite_");
 255                 BADCVAR("rescan_pending");
 256
 257                 // these can contain player IDs, so better hide
 258                 BADPREFIX("g_forced_team_");
 259                 BADCVAR("sv_muteban_list");
 260                 BADCVAR("sv_voteban_list");
 261                 BADCVAR("sv_allow_customplayermodels_idlist");
 262                 BADCVAR("sv_allow_customplayermodels_speciallist");
 263
 264                 // mapinfo
 265                 BADCVAR("fraglimit");
 266                 BADCVAR("g_arena");
 267                 BADCVAR("g_assault");
 268                 BADCVAR("g_ca");
 269                 BADCVAR("g_ca_teams");
 270                 BADCVAR("g_conquest");
 271                 BADCVAR("g_conquest_teams");
 272                 BADCVAR("g_ctf");
 273                 BADCVAR("g_cts");
 274                 BADCVAR("g_dotc");
 275                 BADCVAR("g_dm");
 276                 BADCVAR("g_domination");
 277                 BADCVAR("g_domination_default_teams");
 278                 BADCVAR("g_duel");
 279                 BADCVAR("g_duel_not_dm_maps");
 280                 BADCVAR("g_freezetag");
 281                 BADCVAR("g_freezetag_teams");
 282                 BADCVAR("g_invasion_teams");
 283                 BADCVAR("g_invasion_type");
 284                 BADCVAR("g_jailbreak");
 285                 BADCVAR("g_jailbreak_teams");
 286                 BADCVAR("g_keepaway");
 287                 BADCVAR("g_keyhunt");
 288                 BADCVAR("g_keyhunt_teams");
 289                 BADCVAR("g_lms");
 290                 BADCVAR("g_nexball");
 291                 BADCVAR("g_onslaught");
 292                 BADCVAR("g_race");
 293                 BADCVAR("g_race_laps_limit");
 294                 BADCVAR("g_race_qualifying_timelimit");
 295                 BADCVAR("g_race_qualifying_timelimit_override");
 296                 BADCVAR("g_runematch");
 297                 BADCVAR("g_shootfromeye");
 298                 BADCVAR("g_snafu");
 299                 BADCVAR("g_survival");
 300                 BADCVAR("g_survival_not_dm_maps");
 301                 BADCVAR("g_tdm");
 302                 BADCVAR("g_tdm_on_dm_maps");
 303                 BADCVAR("g_tdm_teams");
 304                 BADCVAR("g_vip");
 305                 BADCVAR("leadlimit");
 306                 BADCVAR("nextmap");
 307                 BADCVAR("teamplay");
 308                 BADCVAR("timelimit");
 309                 BADCVAR("g_mapinfo_settemp_acl");
 310                 BADCVAR("g_mapinfo_ignore_warnings");
 311                 BADCVAR("g_maplist_ignore_sizes");
 312                 BADCVAR("g_maplist_sizes_count_bots");
 313
 314                 // long
 315                 BADCVAR("hostname");
 316                 BADCVAR("g_maplist");
 317                 BADCVAR("g_maplist_mostrecent");
 318                 BADCVAR("sv_motd");
 319
 320                 v = cvar_string(k);
 321                 d = cvar_defstring(k);
 322                 if(v == d)
 323                         continue;
 324
 325                 if(adding)
 326                 {
 327                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 328                         if(strlen(cvar_changes) > 16384)
 329                         {
 330                                 cvar_changes = "// too many settings have been changed to show them here\n";
 331                                 adding = 0;
 332                         }
 333                 }
 334
 335                 // now check if the changes are actually gameplay relevant
 336
 337                 // does nothing gameplay relevant
 338                 BADCVAR("captureleadlimit_override");
 339                 BADCVAR("condump_stripcolors");
 340                 BADCVAR("gameversion");
 341                 BADCVAR("fs_gamedir");
 342                 BADCVAR("g_allow_oldvortexbeam");
 343                 BADCVAR("g_balance_kill_delay");
 344                 BADCVAR("g_buffs_pickup_anyway");
 345                 BADCVAR("g_buffs_randomize");
 346                 BADCVAR("g_buffs_randomize_teamplay");
 347                 BADCVAR("g_campcheck_distance");
 348                 BADCVAR("g_chatsounds");
 349                 BADCVAR("g_ca_point_leadlimit");
 350                 BADCVAR("g_ca_point_limit");
 351                 BADCVAR("g_ca_spectate_enemies");
 352                 BADCVAR("g_ctf_captimerecord_always");
 353                 BADCVAR("g_ctf_flag_glowtrails");
 354                 BADCVAR("g_ctf_dynamiclights");
 355                 BADCVAR("g_ctf_flag_pickup_verbosename");
 356                 BADCVAR("g_ctf_flagcarrier_auto_helpme_damage");
 357                 BADPRESUFFIX("g_ctf_flag_", "_model");
 358                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 359                 BADCVAR("g_domination_point_leadlimit");
 360                 BADCVAR("g_forced_respawn");
 361                 BADCVAR("g_freezetag_point_leadlimit");
 362                 BADCVAR("g_freezetag_point_limit");
 363                 BADCVAR("g_glowtrails");
 364                 BADCVAR("g_hats");
 365                 BADCVAR("g_casings");
 366                 BADCVAR("g_invasion_point_limit");
 367                 BADCVAR("g_jump_grunt");
 368                 BADCVAR("g_keepaway_ballcarrier_effects");
 369                 BADCVAR("g_keepawayball_effects");
 370                 BADCVAR("g_keyhunt_point_leadlimit");
 371                 BADCVAR("g_nexball_goalleadlimit");
 372                 BADCVAR("g_new_toys_autoreplace");
 373                 BADCVAR("g_new_toys_use_pickupsound");
 374                 BADCVAR("g_physics_predictall");
 375                 BADCVAR("g_piggyback");
 376                 BADCVAR("g_playerclip_collisions");
 377                 BADCVAR("g_spawn_alloweffects");
 378                 BADCVAR("g_tdm_point_leadlimit");
 379                 BADCVAR("g_tdm_point_limit");
 380                 BADCVAR("leadlimit_and_fraglimit");
 381                 BADCVAR("leadlimit_override");
 382                 BADCVAR("pausable");
 383                 BADCVAR("sv_announcer");
 384                 BADCVAR("sv_checkforpacketsduringsleep");
 385                 BADCVAR("sv_damagetext");
 386                 BADCVAR("sv_db_saveasdump");
 387                 BADCVAR("sv_intermission_cdtrack");
 388                 BADCVAR("sv_mapchange_delay");
 389                 BADCVAR("sv_minigames");
 390                 BADCVAR("sv_namechangetimer");
 391                 BADCVAR("sv_precacheplayermodels");
 392                 BADCVAR("sv_radio");
 393                 BADCVAR("sv_stepheight");
 394                 BADCVAR("sv_timeout");
 395                 BADCVAR("sv_weapons_modeloverride");
 396                 BADCVAR("w_prop_interval");
 397                 BADPREFIX("chat_");
 398                 BADPREFIX("crypto_");
 399                 BADPREFIX("gameversion_");
 400                 BADPREFIX("g_chat_");
 401                 BADPREFIX("g_ctf_captimerecord_");
 402                 BADPREFIX("g_hats_");
 403                 BADPREFIX("g_maplist_");
 404                 BADPREFIX("g_mod_");
 405                 BADPREFIX("g_respawn_");
 406                 BADPREFIX("net_");
 407                 BADPREFIX("notification_");
 408                 BADPREFIX("prvm_");
 409                 BADPREFIX("skill_");
 410                 BADPREFIX("sv_allow_");
 411                 BADPREFIX("sv_cullentities_");
 412                 BADPREFIX("sv_maxidle");
 413                 BADPREFIX("sv_minigames_");
 414                 BADPREFIX("sv_radio_");
 415                 BADPREFIX("sv_timeout_");
 416                 BADPREFIX("sv_vote_");
 417                 BADPREFIX("timelimit_");
 418
 419                 // allowed changes to server admins (please sync this to server.cfg)
 420                 // vi commands:
 421                 //   :/"impure"/,$d
 422                 //   :g!,^\/\/[^ /],d
 423                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 424                 //   :%!sort
 425                 // yes, this does contain some redundant stuff, don't really care
 426                 BADPREFIX("bot_ai_");
 427                 BADCVAR("bot_config_file");
 428                 BADCVAR("bot_number");
 429                 BADCVAR("bot_prefix");
 430                 BADCVAR("bot_suffix");
 431                 BADCVAR("capturelimit_override");
 432                 BADCVAR("fraglimit_override");
 433                 BADCVAR("gametype");
 434                 BADCVAR("g_antilag");
 435                 BADCVAR("g_balance_teams");
 436                 BADCVAR("g_balance_teams_prevent_imbalance");
 437                 BADCVAR("g_balance_teams_scorefactor");
 438                 BADCVAR("g_ban_sync_trusted_servers");
 439                 BADCVAR("g_ban_sync_uri");
 440                 BADCVAR("g_buffs");
 441                 BADCVAR("g_ca_teams_override");
 442                 BADCVAR("g_ctf_fullbrightflags");
 443                 BADCVAR("g_ctf_ignore_frags");
 444                 BADCVAR("g_ctf_leaderboard");
 445                 BADCVAR("g_domination_point_limit");
 446                 BADCVAR("g_domination_teams_override");
 447                 BADCVAR("g_freezetag_teams_override");
 448                 BADCVAR("g_friendlyfire");
 449                 BADCVAR("g_fullbrightitems");
 450                 BADCVAR("g_fullbrightplayers");
 451                 BADCVAR("g_keyhunt_point_limit");
 452                 BADCVAR("g_keyhunt_teams_override");
 453                 BADCVAR("g_lms_lives_override");
 454                 BADCVAR("g_maplist");
 455                 BADCVAR("g_maxplayers");
 456                 BADCVAR("g_mirrordamage");
 457                 BADCVAR("g_nexball_goallimit");
 458                 BADCVAR("g_norecoil");
 459                 BADCVAR("g_physics_clientselect");
 460                 BADCVAR("g_pinata");
 461                 BADCVAR("g_powerups");
 462                 BADCVAR("g_player_brightness");
 463                 BADCVAR("g_rocket_flying");
 464                 BADCVAR("g_rocket_flying_disabledelays");
 465                 BADCVAR("g_spawnshieldtime");
 466                 BADCVAR("g_start_delay");
 467                 BADCVAR("g_superspectate");
 468                 BADCVAR("g_tdm_teams_override");
 469                 BADCVAR("g_warmup");
 470                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 471                 BADCVAR("hostname");
 472                 BADCVAR("log_file");
 473                 BADCVAR("maxplayers");
 474                 BADCVAR("minplayers");
 475                 BADCVAR("minplayers_per_team");
 476                 BADCVAR("net_address");
 477                 BADCVAR("port");
 478                 BADCVAR("rcon_password");
 479                 BADCVAR("rcon_restricted_commands");
 480                 BADCVAR("rcon_restricted_password");
 481                 BADCVAR("skill");
 482                 BADCVAR("sv_adminnick");
 483                 BADCVAR("sv_autoscreenshot");
 484                 BADCVAR("sv_autotaunt");
 485                 BADCVAR("sv_curl_defaulturl");
 486                 BADCVAR("sv_defaultcharacter");
 487                 BADCVAR("sv_defaultcharacterskin");
 488                 BADCVAR("sv_defaultplayercolors");
 489                 BADCVAR("sv_defaultplayermodel");
 490                 BADCVAR("sv_defaultplayerskin");
 491                 BADCVAR("sv_maxrate");
 492                 BADCVAR("sv_motd");
 493                 BADCVAR("sv_public");
 494                 BADCVAR("sv_ready_restart");
 495                 BADCVAR("sv_showfps");
 496                 BADCVAR("sv_status_privacy");
 497                 BADCVAR("sv_taunt");
 498                 BADCVAR("sv_vote_call");
 499                 BADCVAR("sv_vote_commands");
 500                 BADCVAR("sv_vote_majority_factor");
 501                 BADCVAR("sv_vote_master");
 502                 BADCVAR("sv_vote_master_commands");
 503                 BADCVAR("sv_vote_master_password");
 504                 BADCVAR("sv_vote_simple_majority_factor");
 505                 BADVALUE("sys_ticrate", "0.0166667");
 506                 BADVALUE("sys_ticrate", "0.0333333");
 507                 BADCVAR("teamplay_mode");
 508                 BADCVAR("timelimit_override");
 509                 BADPREFIX("g_warmup_");
 510                 BADPREFIX("sv_info_");
 511                 BADPREFIX("sv_ready_restart_");
 512
 513                 // mutators that announce themselves properly to the server browser
 514                 BADCVAR("g_instagib");
 515                 BADCVAR("g_new_toys");
 516                 BADCVAR("g_nix");
 517                 BADCVAR("g_grappling_hook");
 518                 BADCVAR("g_jetpack");
 519
 520                 // temporary for testing
 521                 // TODO remove before 0.8.3 release
 522                 BADCVAR("g_ca_weaponarena");
 523                 BADCVAR("g_freezetag_weaponarena");
 524                 BADCVAR("g_lms_weaponarena");
 525                 BADCVAR("g_ctf_stalemate_time");
 526
 527 #undef BADPRESUFFIX
 528 #undef BADPREFIX
 529 #undef BADCVAR
 530 #undef BADVALUE
 531
 532                 if(pureadding)
 533                 {
 534                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 535                         if(strlen(cvar_purechanges) > 16384)
 536                         {
 537                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 538                                 pureadding = 0;
 539                         }
 540                 }
 541                 ++cvar_purechanges_count;
 542                 // WARNING: this variable is used for the server list
 543                 // NEVER dare to skip this code!
 544                 // Hacks to intentionally appearing as "pure server" even though you DO have
 545                 // modified settings may be punished by removal from the server list.
 546                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 547                 // though.
 548         }
 549         buf_del(h);
 550         if(cvar_changes == "")
 551                 cvar_changes = "// this server runs at default server settings\n";
 552         else
 553                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 554         cvar_changes = strzone(cvar_changes);
 555         if(cvar_purechanges == "")
 556                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 557         else
 558                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 559         cvar_purechanges = strzone(cvar_purechanges);
 560 }
 561
 562 entity randomseed;
 563 bool RandomSeed_Send(entity this, entity to, int sf)
 564 {
 565         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 566         WriteShort(MSG_ENTITY, this.cnt);
 567         return true;
 568 }
 569 void RandomSeed_Think(entity this)
 570 {
 571         this.cnt = bound(0, floor(random() * 65536), 65535);
 572         this.nextthink = time + 5;
 573
 574         this.SendFlags |= 1;
 575 }
 576 void RandomSeed_Spawn()
 577 {
 578         randomseed = new_pure(randomseed);
 579         setthink(randomseed, RandomSeed_Think);
 580         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 581
 582         getthink(randomseed)(randomseed); // sets random seed and nextthink
 583 }
 584
 585 spawnfunc(__init_dedicated_server)
 586 {
 587         // handler for _init/_init map (only for dedicated server initialization)
 588
 589         world_initialized = -1; // don't complain
 590
 591         delete_fn = remove_unsafely;
 592
 593         entity e = new(GotoFirstMap);
 594         setthink(e, GotoFirstMap);
 595         e.nextthink = time; // this is usually 1 at this point
 596
 597         e = new(info_player_deathmatch);  // safeguard against player joining
 598
 599     // assign reflectively to avoid "assignment to world" warning
 600     for (int i = 0, n = numentityfields(); i < n; ++i) {
 601         string k = entityfieldname(i);
 602         if (k == "classname") {
 603             // safeguard against various stuff ;)
 604             putentityfieldstring(i, this, "worldspawn");
 605             break;
 606         }
 607     }
 608
 609         // needs to be done so early because of the constants they create
 610         static_init();
 611         static_init_late();
 612         static_init_precache();
 613
 614         IL_PUSH(g_spawnpoints, e); // just incase
 615
 616         MapInfo_Enumerate();
 617         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 618 }
 619
 620 void __init_dedicated_server_shutdown() {
 621         MapInfo_Shutdown();
 622 }
 623
 624 STATIC_INIT_EARLY(maxclients)
 625 {
 626         maxclients = 0;
 627         for (entity head = nextent(NULL); head; head = nextent(head)) {
 628                 ++maxclients;
 629         }
 630 }
 631
 632 void GameplayMode_DelayedInit(entity this)
 633 {
 634         if(!scores_initialized)
 635                 ScoreRules_generic();
 636 }
 637
 638 void InitGameplayMode()
 639 {
 640         VoteReset();
 641
 642         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 643         get_mi_min_max(1);
 644         // assign reflectively to avoid "assignment to world" warning
 645         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 646             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 647             if (v) {
 648             putentityfieldstring(i, world, sprintf("%v", v));
 649             if (++done == 2) break;
 650         }
 651         }
 652         // currently, NetRadiant's limit is 131072 qu for each side
 653         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 654         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 655         // in case somebody makes extremely large maps
 656         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 657
 658         MapInfo_LoadMapSettings(mapname);
 659         GameRules_teams(false);
 660
 661         if (!cvar_value_issafe(world.fog))
 662         {
 663                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 664                 world.fog = string_null;
 665         }
 666         if(MapInfo_Map_fog != "")
 667         {
 668                 if(MapInfo_Map_fog == "none")
 669                         world.fog = string_null;
 670                 else
 671                         world.fog = strzone(MapInfo_Map_fog);
 672         }
 673         clientstuff = strzone(MapInfo_Map_clientstuff);
 674
 675         MapInfo_ClearTemps();
 676
 677         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 678
 679         cache_mutatormsg = strzone("");
 680         cache_lastmutatormsg = strzone("");
 681
 682         InitializeEntity(NULL, GameplayMode_DelayedInit, INITPRIO_GAMETYPE_FALLBACK);
 683 }
 684
 685 bool world_already_spawned;
 686 spawnfunc(worldspawn)
 687 {
 688         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 689
 690         bool wantrestart = false;
 691         {
 692                 if (!server_is_dedicated)
 693                 {
 694                         // force unloading of server pk3 files when starting a listen server
 695                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 696                         // restore csqc_progname too
 697                         string expect = "csprogs.dat";
 698                         wantrestart = cvar_string("csqc_progname") != expect;
 699                         cvar_set("csqc_progname", expect);
 700                 }
 701                 else
 702                 {
 703                         // Try to use versioned csprogs from pk3
 704                         // Only ever use versioned csprogs.dat files on dedicated servers;
 705                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 706                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 707                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 708                         string select = "csprogs.dat";
 709                         if (fexists(pk3csprogs)) select = pk3csprogs;
 710                         if (cvar_string("csqc_progname") != select)
 711                         {
 712                                 cvar_set("csqc_progname", select);
 713                                 wantrestart = true;
 714                         }
 715                         // Check for updates on startup
 716                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 717                         int sentinel = fopen("progs.txt", FILE_READ);
 718                         if (sentinel >= 0)
 719                         {
 720                                 string switchversion = fgets(sentinel);
 721                                 fclose(sentinel);
 722                                 if (switchversion != "" && switchversion != WATERMARK)
 723                                 {
 724                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 725                                         // if it doesn't exist, assume either:
 726                                         //   a) the current program was overwritten
 727                                         //   b) this is a client only update
 728                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 729                                         if (fexists(newprogs))
 730                                         {
 731                                                 cvar_set("sv_progs", newprogs);
 732                                                 wantrestart = true;
 733                                         }
 734                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 735                                         if (fexists(newcsprogs))
 736                                         {
 737                                                 cvar_set("csqc_progname", newcsprogs);
 738                                                 wantrestart = true;
 739                                         }
 740                                 }
 741                         }
 742                 }
 743                 if (wantrestart)
 744                 {
 745                         LOG_INFO("Restart requested");
 746                         changelevel(mapname);
 747                         // let initialization continue, shutdown depends on it
 748                 }
 749         }
 750
 751         if(world_already_spawned)
 752                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 753         world_already_spawned = true;
 754
 755         delete_fn = remove_safely; // during spawning, watch what you remove!
 756
 757         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 758
 759         // default to RACE_RECORD, can be overwritten by gamemodes
 760         record_type = RACE_RECORD;
 761
 762         // needs to be done so early because of the constants they create
 763         static_init();
 764
 765         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 766
 767         TemporaryDB = db_create();
 768
 769         // 0 normal
 770         lightstyle(0, "m");
 771
 772         // 1 FLICKER (first variety)
 773         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 774
 775         // 2 SLOW STRONG PULSE
 776         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 777
 778         // 3 CANDLE (first variety)
 779         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 780
 781         // 4 FAST STROBE
 782         lightstyle(4, "mamamamamama");
 783
 784         // 5 GENTLE PULSE 1
 785         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 786
 787         // 6 FLICKER (second variety)
 788         lightstyle(6, "nmonqnmomnmomomno");
 789
 790         // 7 CANDLE (second variety)
 791         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 792
 793         // 8 CANDLE (third variety)
 794         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 795
 796         // 9 SLOW STROBE (fourth variety)
 797         lightstyle(9, "aaaaaaaazzzzzzzz");
 798
 799         // 10 FLUORESCENT FLICKER
 800         lightstyle(10, "mmamammmmammamamaaamammma");
 801
 802         // 11 SLOW PULSE NOT FADE TO BLACK
 803         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 804
 805         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 806
 807         // 63 testing
 808         lightstyle(63, "a");
 809
 810         if(autocvar_g_campaign)
 811                 CampaignPreInit();
 812
 813         Map_MarkAsRecent(mapname);
 814
 815         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 816
 817         InitGameplayMode();
 818         static_init_late();
 819         static_init_precache();
 820         readlevelcvars();
 821
 822         GameRules_limit_fallbacks();
 823
 824         if(warmup_limit == 0)
 825                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 826
 827         player_count = 0;
 828         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 829         if(bot_waypoints_for_items == 1)
 830                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 831                         bot_waypoints_for_items = 0;
 832
 833         WaypointSprite_Init();
 834
 835         GameLogInit(); // prepare everything
 836         // NOTE for matchid:
 837         // changing the logic generating it is okay. But:
 838         // it HAS to stay <= 64 chars
 839         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 840         if(autocvar_sv_eventlog)
 841         {
 842                 string s = sprintf("%s.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 843                 matchid = strzone(s);
 844
 845                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 846                 s = ":gameinfo:mutators:LIST";
 847
 848                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 849                 s = M_ARGV(0, string);
 850
 851                 // initialiation stuff, not good in the mutator system
 852                 if(!autocvar_g_use_ammunition)
 853                         s = strcat(s, ":no_use_ammunition");
 854
 855                 // initialiation stuff, not good in the mutator system
 856                 if(autocvar_g_pickup_items == 0)
 857                         s = strcat(s, ":no_pickup_items");
 858                 if(autocvar_g_pickup_items > 0)
 859                         s = strcat(s, ":pickup_items");
 860
 861                 // initialiation stuff, not good in the mutator system
 862                 if(autocvar_g_weaponarena != "0")
 863                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 864
 865                 // TODO to mutator system
 866                 if(autocvar_g_norecoil)
 867                         s = strcat(s, ":norecoil");
 868
 869                 // TODO to mutator system
 870                 if(autocvar_g_powerups == 0)
 871                         s = strcat(s, ":no_powerups");
 872                 if(autocvar_g_powerups > 0)
 873                         s = strcat(s, ":powerups");
 874
 875                 GameLogEcho(s);
 876                 GameLogEcho(":gameinfo:end");
 877         }
 878         else
 879                 matchid = strzone(ftos(random()));
 880
 881         cvar_set("nextmap", "");
 882
 883         SetDefaultAlpha();
 884
 885         if(autocvar_g_campaign)
 886                 CampaignPostInit();
 887
 888         Ban_LoadBans();
 889
 890         MapInfo_Enumerate();
 891         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 892
 893         if(fexists(strcat("scripts/", mapname, ".arena")))
 894                 cvar_settemp("sv_q3acompat_machineshotgunswap", "1");
 895
 896         if(fexists(strcat("scripts/", mapname, ".defi")))
 897                 cvar_settemp("sv_q3defragcompat", "1");
 898
 899         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 900         {
 901                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 902                 if(fd != -1)
 903                 {
 904                         string s;
 905                         while((s = fgets(fd)))
 906                         {
 907                                 int l = tokenize_console(s);
 908                                 if(l < 2)
 909                                         continue;
 910                                 if(argv(0) == "cd")
 911                                 {
 912                                         string trackname = argv(2);
 913                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 914                                         LOG_INFO("  cdtrack ", trackname);
 915                                         if (cvar_value_issafe(trackname))
 916                                         {
 917                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 918                                                 strcpy(clientstuff, newstuff);
 919                                         }
 920                                 }
 921                                 else if(argv(0) == "fog")
 922                                 {
 923                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 924                                         LOG_INFO("  \"fog\" \"", s, "\"");
 925                                 }
 926                                 else if(argv(0) == "set")
 927                                 {
 928                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 929                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 930                                 }
 931                                 else if(argv(0) != "//")
 932                                 {
 933                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 934                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 935                                 }
 936                         }
 937                         fclose(fd);
 938                 }
 939         }
 940
 941         WeaponStats_Init();
 942
 943         Nagger_Init();
 944
 945         // set up information replies for clients and server to use
 946         maplist_reply = strzone(getmaplist());
 947         lsmaps_reply = strzone(getlsmaps());
 948         monsterlist_reply = strzone(getmonsterlist());
 949         bool records_available = false;
 950         for(int i = 0; i < 10; ++i)
 951         {
 952                 string s = getrecords(i);
 953                 if (s != "")
 954                 {
 955                         records_reply[i] = strzone(s);
 956                         records_available = true;
 957                 }
 958         }
 959         if (!records_available)
 960                 records_reply[0] = "No records available for the current game mode.\n";
 961         ladder_reply = strzone(getladder());
 962         rankings_reply = strzone(getrankings());
 963
 964         // begin other init
 965         ClientInit_Spawn();
 966         RandomSeed_Spawn();
 967         PingPLReport_Spawn();
 968
 969         CheatInit();
 970
 971         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 972
 973         // fill sv_curl_serverpackages from .serverpackage files
 974         if (autocvar_sv_curl_serverpackages_auto)
 975         {
 976                 string s = "csprogs-" WATERMARK ".dat";
 977                 // remove automatically managed files from the list to prevent duplicates
 978                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 979                 {
 980                         string pkg = argv(i);
 981                         if (startsWith(pkg, "csprogs-")) continue;
 982                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 983                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 984                         s = cons(s, pkg);
 985                 }
 986                 // add automatically managed files to the list
 987                 #define X(match) MACRO_BEGIN \
 988                         int fd = search_begin(match, true, false); \
 989                         if (fd >= 0) \
 990                         { \
 991                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 992                                 { \
 993                                         s = cons(s, search_getfilename(fd, i)); \
 994                                 } \
 995                                 search_end(fd); \
 996                         } \
 997                 MACRO_END
 998                 X("*-serverpackage.txt");
 999                 X("*.serverpackage");
1000                 #undef X
1001                 cvar_set("sv_curl_serverpackages", s);
1002         }
1003
1004         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
1005         modname = "Xonotic";
1006         // physics/balance/config changes that count as mod
1007         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
1008                 modname = cvar_string("g_mod_physics");
1009         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
1010                 modname = cvar_string("g_mod_balance");
1011         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
1012                 modname = cvar_string("g_mod_config");
1013         // extra mutators that deserve to count as mod
1014         MUTATOR_CALLHOOK(SetModname, modname);
1015         modname = M_ARGV(0, string);
1016
1017         // save it for later
1018         modname = strzone(modname);
1019
1020         WinningConditionHelper(this); // set worldstatus
1021
1022         world_initialized = 1;
1023         __spawnfunc_spawn_all();
1024 }
1025
1026 spawnfunc(light)
1027 {
1028         //makestatic (this); // Who the f___ did that?
1029         delete(this);
1030 }
1031
1032 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance)
1033 {
1034     float m = e.dphitcontentsmask;
1035     e.dphitcontentsmask = goodcontents | badcontents;
1036
1037     vector org = boundmin;
1038     vector delta = boundmax - boundmin;
1039
1040     vector start, end;
1041     start = end = org;
1042     int j; // used after the loop
1043     for(j = 0; j < attempts; ++j)
1044     {
1045         start.x = org.x + random() * delta.x;
1046         start.y = org.y + random() * delta.y;
1047         start.z = org.z + random() * delta.z;
1048
1049         // rule 1: start inside world bounds, and outside
1050         // solid, and don't start from somewhere where you can
1051         // fall down to evil
1052         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1053         if (trace_fraction >= 1)
1054             continue;
1055         if (trace_startsolid)
1056             continue;
1057         if (trace_dphitcontents & badcontents)
1058             continue;
1059         if (trace_dphitq3surfaceflags & badsurfaceflags)
1060             continue;
1061
1062         // rule 2: if we are too high, lower the point
1063         if (trace_fraction * delta.z > maxaboveground)
1064             start = trace_endpos + '0 0 1' * maxaboveground;
1065         vector enddown = trace_endpos;
1066
1067         // rule 3: make sure we aren't outside the map. This only works
1068         // for somewhat well formed maps. A good rule of thumb is that
1069         // the map should have a convex outside hull.
1070         // these can be traceLINES as we already verified the starting box
1071         vector mstart = start + 0.5 * (e.mins + e.maxs);
1072         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1073         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1074             continue;
1075         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1076         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1077             continue;
1078         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1079         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1080             continue;
1081         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1082         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1083             continue;
1084         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1085         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1086             continue;
1087
1088                 // rule 4: we must "see" some spawnpoint or item
1089             entity sp = NULL;
1090             IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1091             {
1092                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1093                 {
1094                         sp = it;
1095                         break;
1096                 }
1097             });
1098                 if(!sp)
1099                 {
1100                         int items_checked = 0;
1101                         IL_EACH(g_items, checkpvs(mstart, it),
1102                         {
1103                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1104                                 {
1105                                         sp = it;
1106                                         break;
1107                                 }
1108
1109                                 ++items_checked;
1110                                 if(items_checked >= attempts)
1111                                         break; // sanity
1112                         });
1113
1114                         if(!sp)
1115                                 continue;
1116                 }
1117
1118         // find a random vector to "look at"
1119         end.x = org.x + random() * delta.x;
1120         end.y = org.y + random() * delta.y;
1121         end.z = org.z + random() * delta.z;
1122         end = start + normalize(end - start) * vlen(delta);
1123
1124         // rule 4: start TO end must not be too short
1125         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1126         if(trace_startsolid)
1127             continue;
1128         if(trace_fraction < minviewdistance / vlen(delta))
1129             continue;
1130
1131         // rule 5: don't want to look at sky
1132         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1133             continue;
1134
1135         // rule 6: we must not end up in trigger_hurt
1136         if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1137             continue;
1138
1139         break;
1140     }
1141
1142     e.dphitcontentsmask = m;
1143
1144     if(j < attempts)
1145     {
1146         setorigin(e, start);
1147         e.angles = vectoangles(end - start);
1148         LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1149         return true;
1150     }
1151     return false;
1152 }
1153
1154 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1155 {
1156         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1157 }
1158
1159 /*
1160 ===============================================================================
1161
1162 RULES
1163
1164 ===============================================================================
1165 */
1166
1167 void DumpStats(float final)
1168 {
1169         float file;
1170         string s;
1171         float to_console;
1172         float to_eventlog;
1173         float to_file;
1174         float i;
1175
1176         to_console = autocvar_sv_logscores_console;
1177         to_eventlog = autocvar_sv_eventlog;
1178         to_file = autocvar_sv_logscores_file;
1179
1180         if(!final)
1181         {
1182                 to_console = true; // always print printstats replies
1183                 to_eventlog = false; // but never print them to the event log
1184         }
1185
1186         if(to_eventlog)
1187                 if(autocvar_sv_eventlog_console)
1188                         to_console = false; // otherwise we get the output twice
1189
1190         if(final)
1191                 s = ":scores:";
1192         else
1193                 s = ":status:";
1194         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1195
1196         if(to_console)
1197                 LOG_HELP(s);
1198         if(to_eventlog)
1199                 GameLogEcho(s);
1200
1201         file = -1;
1202         if(to_file)
1203         {
1204                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1205                 if(file == -1)
1206                         to_file = false;
1207                 else
1208                         fputs(file, strcat(s, "\n"));
1209         }
1210
1211         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1212         if(to_console)
1213                 LOG_HELP(s);
1214         if(to_eventlog)
1215                 GameLogEcho(s);
1216         if(to_file)
1217                 fputs(file, strcat(s, "\n"));
1218
1219         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1220                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1221                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1222                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1223                         s = strcat(s, ftos(it.team), ":");
1224                 else
1225                         s = strcat(s, "spectator:");
1226
1227                 if(to_console)
1228                         LOG_HELP(s, playername(it.netname, it.team, false));
1229                 if(to_eventlog)
1230                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it.netname, it.team, false)));
1231                 if(to_file)
1232                         fputs(file, strcat(s, playername(it.netname, it.team, false), "\n"));
1233         });
1234
1235         if(teamplay)
1236         {
1237                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1238                 if(to_console)
1239                         LOG_HELP(s);
1240                 if(to_eventlog)
1241                         GameLogEcho(s);
1242                 if(to_file)
1243                         fputs(file, strcat(s, "\n"));
1244
1245                 for(i = 1; i < 16; ++i)
1246                 {
1247                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1248                         s = strcat(s, ":", ftos(i));
1249                         if(to_console)
1250                                 LOG_HELP(s);
1251                         if(to_eventlog)
1252                                 GameLogEcho(s);
1253                         if(to_file)
1254                                 fputs(file, strcat(s, "\n"));
1255                 }
1256         }
1257
1258         if(to_console)
1259                 LOG_HELP(":end");
1260         if(to_eventlog)
1261                 GameLogEcho(":end");
1262         if(to_file)
1263         {
1264                 fputs(file, ":end\n");
1265                 fclose(file);
1266         }
1267 }
1268
1269 /*
1270 go to the next level for deathmatch
1271 only called if a time or frag limit has expired
1272 */
1273 void NextLevel()
1274 {
1275         game_stopped = true;
1276         intermission_running = true; // game over
1277
1278         // enforce a wait time before allowing changelevel
1279         if(player_count > 0)
1280                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1281         else
1282                 intermission_exittime = -1;
1283
1284         /*
1285         WriteByte (MSG_ALL, SVC_CDTRACK);
1286         WriteByte (MSG_ALL, 3);
1287         WriteByte (MSG_ALL, 3);
1288         // done in FixIntermission
1289         */
1290
1291         //pos = FindIntermission ();
1292
1293         VoteReset();
1294
1295         DumpStats(true);
1296
1297         // send statistics
1298         PlayerStats_GameReport(true);
1299         WeaponStats_Shutdown();
1300
1301         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1302
1303         if(autocvar_sv_eventlog)
1304                 GameLogEcho(":gameover");
1305
1306         GameLogClose();
1307
1308         FOREACH_CLIENT(IS_PLAYER(it), {
1309                 FixIntermissionClient(it);
1310                 if(it.winning)
1311                         bprint(playername(it.netname, it.team, false), " ^7wins.\n");
1312         });
1313
1314         target_music_kill();
1315
1316         if(autocvar_g_campaign)
1317                 CampaignPreIntermission();
1318
1319         MUTATOR_CALLHOOK(MatchEnd);
1320
1321         localcmd("\nsv_hook_gameend\n");
1322 }
1323
1324
1325 float InitiateSuddenDeath()
1326 {
1327         // Check first whether normal overtimes could be added before initiating suddendeath mode
1328         // - for this timelimit_overtime needs to be >0 of course
1329         // - also check the winning condition calculated in the previous frame and only add normal overtime
1330         //   again, if at the point at which timelimit would be extended again, still no winner was found
1331         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1332                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1333                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1334         {
1335                 return 1; // need to call InitiateOvertime later
1336         }
1337         else
1338         {
1339                 if(!checkrules_suddendeathend)
1340                 {
1341                         if(autocvar_g_campaign)
1342                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1343                         else
1344                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1345                         if(g_race && !g_race_qualifying)
1346                                 race_StartCompleting();
1347                 }
1348                 return 0;
1349         }
1350 }
1351
1352 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1353 {
1354         ++checkrules_overtimesadded;
1355         //add one more overtime by simply extending the timelimit
1356         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1357         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1358 }
1359
1360 float GetWinningCode(float fraglimitreached, float equality)
1361 {
1362         if(autocvar_g_campaign == 1)
1363         {
1364                 if(fraglimitreached)
1365                         return WINNING_YES;
1366                 else
1367                         return WINNING_NO;
1368         }
1369         else
1370         {
1371                 if(equality)
1372                 {
1373                         if(fraglimitreached)
1374                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1375                         else
1376                                 return WINNING_NEVER;
1377                 }
1378                 else
1379                 {
1380                         if(fraglimitreached)
1381                                 return WINNING_YES;
1382                         else
1383                                 return WINNING_NO;
1384                 }
1385         }
1386 }
1387
1388 // set the .winning flag for exactly those players with a given field value
1389 void SetWinners(.float field, float value)
1390 {
1391         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1392 }
1393
1394 // set the .winning flag for those players with a given field value
1395 void AddWinners(.float field, float value)
1396 {
1397         FOREACH_CLIENT(IS_PLAYER(it), {
1398                 if(it.(field) == value)
1399                         it.winning = 1;
1400         });
1401 }
1402
1403 // clear the .winning flags
1404 void ClearWinners()
1405 {
1406         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1407 }
1408
1409 int fragsleft_last;
1410 float WinningCondition_Scores(float limit, float leadlimit)
1411 {
1412         // TODO make everything use THIS winning condition (except LMS)
1413         WinningConditionHelper(NULL);
1414
1415         if(teamplay)
1416         {
1417                 for (int i = 1; i < 5; ++i)
1418                 {
1419                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1420                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1421                 }
1422         }
1423
1424         ClearWinners();
1425         if(WinningConditionHelper_winner)
1426                 WinningConditionHelper_winner.winning = 1;
1427         if(WinningConditionHelper_winnerteam >= 0)
1428                 SetWinners(team, WinningConditionHelper_winnerteam);
1429
1430         if(WinningConditionHelper_lowerisbetter)
1431         {
1432                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1433                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1434                 limit = -limit;
1435         }
1436
1437         if(WinningConditionHelper_zeroisworst)
1438                 leadlimit = 0; // not supported in this mode
1439
1440         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1441         {
1442                 float fragsleft;
1443                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1444                 {
1445                         fragsleft = 1;
1446                 }
1447                 else
1448                 {
1449                         fragsleft = FLOAT_MAX;
1450                         float leadingfragsleft = FLOAT_MAX;
1451                         if (limit)
1452                                 fragsleft = limit - WinningConditionHelper_topscore;
1453                         if (leadlimit)
1454                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1455
1456                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1457                                 fragsleft = max(fragsleft, leadingfragsleft);
1458                         else
1459                                 fragsleft = min(fragsleft, leadingfragsleft);
1460                 }
1461
1462                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1463                 {
1464                         if (fragsleft == 1)
1465                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1466                         else if (fragsleft == 2)
1467                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1468                         else if (fragsleft == 3)
1469                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1470
1471                         fragsleft_last = fragsleft;
1472                 }
1473         }
1474
1475         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1476         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1477
1478         bool limit_reached;
1479         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1480         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1481                 limit_reached = (fraglimit_reached && leadlimit_reached);
1482         else
1483                 limit_reached = (fraglimit_reached || leadlimit_reached);
1484
1485         return GetWinningCode(
1486                 WinningConditionHelper_topscore && limit_reached,
1487                 WinningConditionHelper_equality
1488         );
1489 }
1490
1491 float WinningCondition_RanOutOfSpawns()
1492 {
1493         if(have_team_spawns <= 0)
1494                 return WINNING_NO;
1495
1496         if(!autocvar_g_spawn_useallspawns)
1497                 return WINNING_NO;
1498
1499         if(!some_spawn_has_been_used)
1500                 return WINNING_NO;
1501
1502         for (int i = 1; i < 5; ++i)
1503         {
1504                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1505         }
1506
1507         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1508         {
1509                 if (Team_IsValidTeam(it.team))
1510                 {
1511                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1512                 }
1513         });
1514
1515         IL_EACH(g_spawnpoints, true,
1516         {
1517                 if (Team_IsValidTeam(it.team))
1518                 {
1519                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1520                 }
1521         });
1522
1523         ClearWinners();
1524         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1525         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1526         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1527         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1528         if(team1_score + team2_score + team3_score + team4_score == 0)
1529         {
1530                 checkrules_equality = true;
1531                 return WINNING_YES;
1532         }
1533         else if(team1_score + team2_score + team3_score + team4_score == 1)
1534         {
1535                 float t, i;
1536                 if(team1_score)
1537                         t = 1;
1538                 else if(team2_score)
1539                         t = 2;
1540                 else if(team3_score)
1541                         t = 3;
1542                 else // if(team4_score)
1543                         t = 4;
1544                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1545                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1546                 {
1547                         for (int j = 1; j <= NUM_TEAMS; ++j)
1548                         {
1549                                 if (t == j)
1550                                 {
1551                                         continue;
1552                                 }
1553                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1554                                 {
1555                                         continue;
1556                                 }
1557                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1558                         }
1559                 }
1560
1561                 AddWinners(team, t);
1562                 return WINNING_YES;
1563         }
1564         else
1565                 return WINNING_NO;
1566 }
1567
1568 /*
1569 ============
1570 CheckRules_World
1571
1572 Exit deathmatch games upon conditions
1573 ============
1574 */
1575 void CheckRules_World()
1576 {
1577         VoteThink();
1578         MapVote_Think();
1579
1580         SetDefaultAlpha();
1581
1582         if (intermission_running) // someone else quit the game already
1583         {
1584                 if(player_count == 0) // Nobody there? Then let's go to the next map
1585                         MapVote_Start();
1586                         // this will actually check the player count in the next frame
1587                         // again, but this shouldn't hurt
1588                 return;
1589         }
1590
1591         float timelimit = autocvar_timelimit * 60;
1592         float fraglimit = autocvar_fraglimit;
1593         float leadlimit = autocvar_leadlimit;
1594         if (leadlimit < 0) leadlimit = 0;
1595
1596         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1597         {
1598                 if(timelimit > 0)
1599                         timelimit = 0; // timelimit is not made for warmup
1600                 if(fraglimit > 0)
1601                         fraglimit = 0; // no fraglimit for now
1602                 leadlimit = 0; // no leadlimit for now
1603         }
1604
1605         if(timelimit > 0)
1606         {
1607                 timelimit += game_starttime;
1608         }
1609         else if (timelimit < 0)
1610         {
1611                 // endmatch
1612                 NextLevel();
1613                 return;
1614         }
1615
1616         float wantovertime;
1617         wantovertime = 0;
1618
1619         if(checkrules_suddendeathend)
1620         {
1621                 if(!checkrules_suddendeathwarning)
1622                 {
1623                         checkrules_suddendeathwarning = true;
1624                         if(g_race && !g_race_qualifying)
1625                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1626                         else
1627                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1628                 }
1629         }
1630         else
1631         {
1632                 if (timelimit && time >= timelimit)
1633                 {
1634                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1635                         {
1636                                 float totalplayers;
1637                                 float playerswithlaps;
1638                                 float readyplayers;
1639                                 totalplayers = playerswithlaps = readyplayers = 0;
1640                                 FOREACH_CLIENT(IS_PLAYER(it), {
1641                                         ++totalplayers;
1642                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1643                                                 ++playerswithlaps;
1644                                         if(it.ready)
1645                                                 ++readyplayers;
1646                                 });
1647
1648                                 // at least 2 of the players have completed a lap: start the RACE
1649                                 // otherwise, the players should end the qualifying on their own
1650                                 if(readyplayers || playerswithlaps >= 2)
1651                                 {
1652                                         checkrules_suddendeathend = 0;
1653                                         ReadyRestart(); // go to race
1654                                         return;
1655                                 }
1656                                 else
1657                                         wantovertime |= InitiateSuddenDeath();
1658                         }
1659                         else
1660                                 wantovertime |= InitiateSuddenDeath();
1661                 }
1662         }
1663
1664         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1665         {
1666                 NextLevel();
1667                 return;
1668         }
1669
1670         int checkrules_status = WinningCondition_RanOutOfSpawns();
1671         if(checkrules_status == WINNING_YES)
1672                 bprint("Hey! Someone ran out of spawns!\n");
1673         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1674                 checkrules_status = M_ARGV(0, float);
1675         else
1676                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1677
1678         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1679         {
1680                 checkrules_status = WINNING_NEVER;
1681                 checkrules_overtimesadded = -1;
1682                 wantovertime |= InitiateSuddenDeath();
1683         }
1684
1685         if(checkrules_status == WINNING_NEVER)
1686                 // equality cases! Nobody wins if the overtime ends in a draw.
1687                 ClearWinners();
1688
1689         if(wantovertime)
1690         {
1691                 if(checkrules_status == WINNING_NEVER)
1692                         InitiateOvertime();
1693                 else
1694                         checkrules_status = WINNING_YES;
1695         }
1696
1697         if(checkrules_suddendeathend)
1698                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1699                         checkrules_status = WINNING_YES;
1700
1701         if(checkrules_status == WINNING_YES)
1702         {
1703                 //print("WINNING\n");
1704                 NextLevel();
1705         }
1706 }
1707
1708 float want_weapon(entity weaponinfo, float allguns)
1709 {
1710         int d = 0;
1711         bool allow_mutatorblocked = false;
1712
1713         if(!weaponinfo.m_id)
1714                 return 0;
1715
1716         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
1717         d = M_ARGV(1, float);
1718         allguns = M_ARGV(2, bool);
1719         allow_mutatorblocked = M_ARGV(3, bool);
1720
1721         if(allguns)
1722                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
1723         else if(!mutator_returnvalue)
1724                 d = !(!weaponinfo.weaponstart);
1725
1726         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
1727                 d = 0;
1728
1729         float t = weaponinfo.weaponstartoverride;
1730
1731         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
1732
1733         // bit order in t:
1734         // 1: want or not
1735         // 2: is default?
1736         // 4: is set by default?
1737         if(t < 0)
1738                 t = 4 | (3 * d);
1739         else
1740                 t |= (2 * d);
1741
1742         return t;
1743 }
1744
1745 /// Weapons the player normally starts with outside weapon arena.
1746 WepSet weapons_start()
1747 {
1748         WepSet ret = '0 0 0';
1749         FOREACH(Weapons, it != WEP_Null, {
1750                 int w = want_weapon(it, false);
1751                 if (w & 1)
1752                         ret |= it.m_wepset;
1753         });
1754         return ret;
1755 }
1756
1757 WepSet weapons_all()
1758 {
1759         WepSet ret = '0 0 0';
1760         FOREACH(Weapons, it != WEP_Null, {
1761                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
1762                         ret |= it.m_wepset;
1763         });
1764         return ret;
1765 }
1766
1767 WepSet weapons_devall()
1768 {
1769         WepSet ret = '0 0 0';
1770         FOREACH(Weapons, it != WEP_Null,
1771         {
1772                 ret |= it.m_wepset;
1773         });
1774         return ret;
1775 }
1776
1777 WepSet weapons_most()
1778 {
1779         WepSet ret = '0 0 0';
1780         FOREACH(Weapons, it != WEP_Null, {
1781                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
1782                         ret |= it.m_wepset;
1783         });
1784         return ret;
1785 }
1786
1787 void weaponarena_available_all_update(entity this)
1788 {
1789         if (weaponsInMapAll)
1790         {
1791                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
1792         }
1793         else
1794         {
1795                 // if no weapons are available on the map, just fall back to all weapons arena
1796                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
1797         }
1798 }
1799
1800 void weaponarena_available_devall_update(entity this)
1801 {
1802         if (weaponsInMapAll)
1803         {
1804                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
1805         }
1806         else
1807         {
1808                 // if no weapons are available on the map, just fall back to devall weapons arena
1809                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
1810         }
1811 }
1812
1813 void weaponarena_available_most_update(entity this)
1814 {
1815         if (weaponsInMapAll)
1816         {
1817                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
1818         }
1819         else
1820         {
1821                 // if no weapons are available on the map, just fall back to most weapons arena
1822                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
1823         }
1824 }
1825
1826 void readplayerstartcvars()
1827 {
1828         // initialize starting values for players
1829         start_weapons = '0 0 0';
1830         start_weapons_default = '0 0 0';
1831         start_weapons_defaultmask = '0 0 0';
1832         start_items = 0;
1833         start_ammo_shells = 0;
1834         start_ammo_nails = 0;
1835         start_ammo_rockets = 0;
1836         start_ammo_cells = 0;
1837         start_ammo_plasma = 0;
1838         if (random_start_ammo == NULL)
1839         {
1840                 random_start_ammo = new_pure(random_start_ammo);
1841         }
1842         start_health = cvar("g_balance_health_start");
1843         start_armorvalue = cvar("g_balance_armor_start");
1844
1845         g_weaponarena = 0;
1846         g_weaponarena_weapons = '0 0 0';
1847
1848         string s = cvar_string("g_weaponarena");
1849
1850         MUTATOR_CALLHOOK(SetWeaponArena, s);
1851         s = M_ARGV(0, string);
1852
1853         if (s == "0" || s == "")
1854         {
1855                 // no arena
1856         }
1857         else if (s == "off")
1858         {
1859                 // forcibly turn off weaponarena
1860         }
1861         else if (s == "all" || s == "1")
1862         {
1863                 g_weaponarena = 1;
1864                 g_weaponarena_list = "All Weapons";
1865                 g_weaponarena_weapons = weapons_all();
1866         }
1867         else if (s == "devall")
1868         {
1869                 g_weaponarena = 1;
1870                 g_weaponarena_list = "Dev All Weapons";
1871                 g_weaponarena_weapons = weapons_devall();
1872         }
1873         else if (s == "most")
1874         {
1875                 g_weaponarena = 1;
1876                 g_weaponarena_list = "Most Weapons";
1877                 g_weaponarena_weapons = weapons_most();
1878         }
1879         else if (s == "all_available")
1880         {
1881                 g_weaponarena = 1;
1882                 g_weaponarena_list = "All Available Weapons";
1883
1884                 // this needs to run after weaponsInMapAll is initialized
1885                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
1886         }
1887         else if (s == "devall_available")
1888         {
1889                 g_weaponarena = 1;
1890                 g_weaponarena_list = "Dev All Available Weapons";
1891
1892                 // this needs to run after weaponsInMapAll is initialized
1893                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
1894         }
1895         else if (s == "most_available")
1896         {
1897                 g_weaponarena = 1;
1898                 g_weaponarena_list = "Most Available Weapons";
1899
1900                 // this needs to run after weaponsInMapAll is initialized
1901                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
1902         }
1903         else if (s == "none")
1904         {
1905                 g_weaponarena = 1;
1906                 g_weaponarena_list = "No Weapons";
1907         }
1908         else
1909         {
1910                 g_weaponarena = 1;
1911                 float t = tokenize_console(s);
1912                 g_weaponarena_list = "";
1913                 for (int j = 0; j < t; ++j)
1914                 {
1915                         s = argv(j);
1916                         Weapon wep = Weapon_from_name(s);
1917                         if(wep != WEP_Null)
1918                         {
1919                                 g_weaponarena_weapons |= (wep.m_wepset);
1920                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
1921                         }
1922                 }
1923                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
1924         }
1925
1926         if (g_weaponarena)
1927         {
1928                 g_weapon_stay = 0; // incompatible
1929                 start_weapons = g_weaponarena_weapons;
1930                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1931         }
1932         else
1933         {
1934                 FOREACH(Weapons, it != WEP_Null, {
1935                         int w = want_weapon(it, false);
1936                         WepSet s = it.m_wepset;
1937                         if(w & 1)
1938                                 start_weapons |= s;
1939                         if(w & 2)
1940                                 start_weapons_default |= s;
1941                         if(w & 4)
1942                                 start_weapons_defaultmask |= s;
1943                 });
1944         }
1945
1946         if(cvar("g_balance_superweapons_time") < 0)
1947                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
1948
1949         if(!cvar("g_use_ammunition"))
1950                 start_items |= IT_UNLIMITED_AMMO;
1951
1952         if(start_items & IT_UNLIMITED_AMMO)
1953         {
1954                 start_ammo_shells = 999;
1955                 start_ammo_nails = 999;
1956                 start_ammo_rockets = 999;
1957                 start_ammo_cells = 999;
1958                 start_ammo_plasma = 999;
1959                 start_ammo_fuel = 999;
1960         }
1961         else
1962         {
1963                 start_ammo_shells = cvar("g_start_ammo_shells");
1964                 start_ammo_nails = cvar("g_start_ammo_nails");
1965                 start_ammo_rockets = cvar("g_start_ammo_rockets");
1966                 start_ammo_cells = cvar("g_start_ammo_cells");
1967                 start_ammo_plasma = cvar("g_start_ammo_plasma");
1968                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1969                 random_start_weapons_count = cvar("g_random_start_weapons_count");
1970                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
1971                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
1972                 SetResource(random_start_ammo, RES_ROCKETS, cvar("g_random_start_rockets"));
1973                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
1974                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
1975         }
1976
1977         warmup_start_ammo_shells = start_ammo_shells;
1978         warmup_start_ammo_nails = start_ammo_nails;
1979         warmup_start_ammo_rockets = start_ammo_rockets;
1980         warmup_start_ammo_cells = start_ammo_cells;
1981         warmup_start_ammo_plasma = start_ammo_plasma;
1982         warmup_start_ammo_fuel = start_ammo_fuel;
1983         warmup_start_health = start_health;
1984         warmup_start_armorvalue = start_armorvalue;
1985         warmup_start_weapons = start_weapons;
1986         warmup_start_weapons_default = start_weapons_default;
1987         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
1988
1989         if (!g_weaponarena)
1990         {
1991                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1992                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1993                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1994                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1995                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
1996                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1997                 warmup_start_health = cvar("g_warmup_start_health");
1998                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
1999                 warmup_start_weapons = '0 0 0';
2000                 warmup_start_weapons_default = '0 0 0';
2001                 warmup_start_weapons_defaultmask = '0 0 0';
2002                 FOREACH(Weapons, it != WEP_Null, {
2003                         int w = want_weapon(it, autocvar_g_warmup_allguns);
2004                         WepSet s = it.m_wepset;
2005                         if(w & 1)
2006                                 warmup_start_weapons |= s;
2007                         if(w & 2)
2008                                 warmup_start_weapons_default |= s;
2009                         if(w & 4)
2010                                 warmup_start_weapons_defaultmask |= s;
2011                 });
2012         }
2013
2014         if (autocvar_g_jetpack)
2015                 start_items |= ITEM_Jetpack.m_itemid;
2016
2017         MUTATOR_CALLHOOK(SetStartItems);
2018
2019         if (start_items & ITEM_Jetpack.m_itemid)
2020         {
2021                 start_items |= ITEM_JetpackRegen.m_itemid;
2022                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2023                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2024         }
2025
2026         start_ammo_shells = max(0, start_ammo_shells);
2027         start_ammo_nails = max(0, start_ammo_nails);
2028         start_ammo_rockets = max(0, start_ammo_rockets);
2029         start_ammo_cells = max(0, start_ammo_cells);
2030         start_ammo_plasma = max(0, start_ammo_plasma);
2031         start_ammo_fuel = max(0, start_ammo_fuel);
2032         SetResource(random_start_ammo, RES_SHELLS, max(0, GetResource(random_start_ammo, RES_SHELLS)));
2033         SetResource(random_start_ammo, RES_BULLETS, max(0, GetResource(random_start_ammo, RES_BULLETS)));
2034         SetResource(random_start_ammo, RES_ROCKETS, max(0, GetResource(random_start_ammo, RES_ROCKETS)));
2035         SetResource(random_start_ammo, RES_CELLS, max(0, GetResource(random_start_ammo, RES_CELLS)));
2036         SetResource(random_start_ammo, RES_PLASMA, max(0, GetResource(random_start_ammo, RES_PLASMA)));
2037
2038         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
2039         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
2040         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
2041         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
2042         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
2043         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
2044 }
2045
2046 void readlevelcvars()
2047 {
2048         if(cvar("sv_allow_fullbright"))
2049                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
2050
2051         sv_ready_restart_after_countdown = cvar("sv_ready_restart_after_countdown");
2052
2053         warmup_stage = cvar("g_warmup");
2054         warmup_limit = cvar("g_warmup_limit");
2055
2056         if(cvar("g_campaign"))
2057                 warmup_stage = 0; // no warmup during campaign
2058
2059         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
2060         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
2061         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
2062         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
2063         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
2064         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
2065         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
2066         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
2067         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
2068         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
2069         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
2070         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
2071         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
2072         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
2073
2074         g_pickup_shells = cvar("g_pickup_shells");
2075         g_pickup_shells_max = cvar("g_pickup_shells_max");
2076         g_pickup_nails = cvar("g_pickup_nails");
2077         g_pickup_nails_max = cvar("g_pickup_nails_max");
2078         g_pickup_rockets = cvar("g_pickup_rockets");
2079         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
2080         g_pickup_cells = cvar("g_pickup_cells");
2081         g_pickup_cells_max = cvar("g_pickup_cells_max");
2082         g_pickup_plasma = cvar("g_pickup_plasma");
2083         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
2084         g_pickup_fuel = cvar("g_pickup_fuel");
2085         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
2086         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
2087         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
2088         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
2089         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
2090         g_pickup_armormedium = cvar("g_pickup_armormedium");
2091         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
2092         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
2093         g_pickup_armorbig = cvar("g_pickup_armorbig");
2094         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
2095         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
2096         g_pickup_armormega = cvar("g_pickup_armormega");
2097         g_pickup_armormega_max = cvar("g_pickup_armormega_max");
2098         g_pickup_armormega_anyway = cvar("g_pickup_armormega_anyway");
2099         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
2100         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
2101         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
2102         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
2103         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
2104         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
2105         g_pickup_healthbig = cvar("g_pickup_healthbig");
2106         g_pickup_healthbig_max = cvar("g_pickup_healthbig_max");
2107         g_pickup_healthbig_anyway = cvar("g_pickup_healthbig_anyway");
2108         g_pickup_healthmega = cvar("g_pickup_healthmega");
2109         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
2110         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
2111
2112         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
2113         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
2114
2115     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
2116     if(!g_weapon_stay)
2117         g_weapon_stay = cvar("g_weapon_stay");
2118
2119     MUTATOR_CALLHOOK(ReadLevelCvars);
2120
2121         if (!warmup_stage)
2122                 game_starttime = time + cvar("g_start_delay");
2123
2124         FOREACH(Weapons, it != WEP_Null, { it.wr_init(it); });
2125
2126         readplayerstartcvars();
2127 }
2128
2129 void InitializeEntity(entity e, void(entity this) func, int order)
2130 {
2131     entity prev, cur;
2132
2133     if (!e || e.initialize_entity)
2134     {
2135         // make a proxy initializer entity
2136         entity e_old = e;
2137         e = new(initialize_entity);
2138         e.enemy = e_old;
2139     }
2140
2141     e.initialize_entity = func;
2142     e.initialize_entity_order = order;
2143
2144     cur = initialize_entity_first;
2145     prev = NULL;
2146     for (;;)
2147     {
2148         if (!cur || cur.initialize_entity_order > order)
2149         {
2150             // insert between prev and cur
2151             if (prev)
2152                 prev.initialize_entity_next = e;
2153             else
2154                 initialize_entity_first = e;
2155             e.initialize_entity_next = cur;
2156             return;
2157         }
2158         prev = cur;
2159         cur = cur.initialize_entity_next;
2160     }
2161 }
2162 void InitializeEntitiesRun()
2163 {
2164     entity startoflist = initialize_entity_first;
2165     initialize_entity_first = NULL;
2166     delete_fn = remove_except_protected;
2167     for (entity e = startoflist; e; e = e.initialize_entity_next)
2168     {
2169                 e.remove_except_protected_forbidden = 1;
2170     }
2171     for (entity e = startoflist; e; )
2172     {
2173                 e.remove_except_protected_forbidden = 0;
2174         e.initialize_entity_order = 0;
2175         entity next = e.initialize_entity_next;
2176         e.initialize_entity_next = NULL;
2177         var void(entity this) func = e.initialize_entity;
2178         e.initialize_entity = func_null;
2179         if (e.classname == "initialize_entity")
2180         {
2181             entity wrappee = e.enemy;
2182             builtin_remove(e);
2183             e = wrappee;
2184         }
2185         //dprint("Delayed initialization: ", e.classname, "\n");
2186         if (func)
2187         {
2188                 func(e);
2189         }
2190         else
2191         {
2192             eprint(e);
2193             backtrace(strcat("Null function in: ", e.classname, "\n"));
2194         }
2195         e = next;
2196     }
2197     delete_fn = remove_unsafely;
2198 }
2199
2200 // deferred dropping
2201 void DropToFloor_Handler(entity this)
2202 {
2203         WITHSELF(this, builtin_droptofloor());
2204         this.dropped_origin = this.origin;
2205 }
2206
2207 void droptofloor(entity this)
2208 {
2209         InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
2210 }
2211
2212 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2213 void RunThink(entity this)
2214 {
2215         // don't let things stay in the past.
2216         // it is possible to start that way by a trigger with a local time.
2217         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2218                 return;
2219
2220         float oldtime = time; // do we need to save this?
2221
2222         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2223         {
2224                 time = max(oldtime, this.nextthink);
2225                 this.nextthink = 0;
2226
2227                 if(getthink(this))
2228                         getthink(this)(this);
2229                 // mods often set nextthink to time to cause a think every frame,
2230                 // we don't want to loop in that case, so exit if the new nextthink is
2231                 // <= the time the qc was told, also exit if it is past the end of the
2232                 // frame
2233                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2234                         break;
2235         }
2236
2237         time = oldtime;
2238 }
2239
2240 bool autocvar_sv_freezenonclients;
2241 void Physics_Frame()
2242 {
2243         if(autocvar_sv_freezenonclients)
2244                 return;
2245
2246         IL_EACH(g_moveables, true,
2247         {
2248                 if(IS_CLIENT(it) || it.move_movetype == MOVETYPE_PHYSICS)
2249                         continue;
2250
2251                 //set_movetype(it, it.move_movetype);
2252                 // inline the set_movetype function, since this is called a lot
2253                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2254
2255                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2256                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2257
2258                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2259                 {
2260                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2261                                 continue; // these movetypes have no regular think function
2262                         // handle thinking here
2263                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2264                                 RunThink(it);
2265                 }
2266         });
2267
2268         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2269                 return;
2270
2271         // make a second pass to see if any ents spawned this frame and make
2272         // sure they run their move/think. this is verified by checking .move_time, which will never be 0 if the entity has moved
2273         // MOVETYPE_NONE is also checked as .move_time WILL be 0 with that movetype
2274         IL_EACH(g_moveables, it.move_qcphysics,
2275         {
2276                 if(IS_CLIENT(it) || it.move_time || it.move_movetype == MOVETYPE_NONE || it.move_movetype == MOVETYPE_PHYSICS)
2277                         continue;
2278                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2279         });
2280 }
2281
2282 void systems_update();
2283 void EndFrame()
2284 {
2285         anticheat_endframe();
2286
2287         Physics_Frame();
2288
2289         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2290                 entity e = IS_SPEC(it) ? it.enemy : it;
2291                 if (e.typehitsound) {
2292                         STAT(TYPEHIT_TIME, it) = time;
2293                 } else if (e.killsound) {
2294                         STAT(KILL_TIME, it) = time;
2295                 } else if (e.damage_dealt) {
2296                         STAT(HIT_TIME, it) = time;
2297                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2298                 }
2299         });
2300         // add 1 frametime because after this, engine SV_Physics
2301         // increases time by a frametime and then networks the frame
2302         // add another frametime because client shows everything with
2303         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2304         // needed!
2305         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2306         FOREACH_CLIENT(true, {
2307                 it.typehitsound = false;
2308                 it.damage_dealt = 0;
2309                 it.killsound = false;
2310                 antilag_record(it, CS(it), altime);
2311         });
2312         IL_EACH(g_monsters, true,
2313         {
2314                 antilag_record(it, it, altime);
2315         });
2316         IL_EACH(g_projectiles, it.classname == "nade",
2317         {
2318                 antilag_record(it, it, altime);
2319         });
2320         systems_update();
2321         IL_ENDFRAME();
2322 }
2323
2324
2325 /*
2326  * RedirectionThink:
2327  * returns true if redirecting
2328  */
2329 float redirection_timeout;
2330 float redirection_nextthink;
2331 float RedirectionThink()
2332 {
2333         float clients_found;
2334
2335         if(redirection_target == "")
2336                 return false;
2337
2338         if(!redirection_timeout)
2339         {
2340                 cvar_set("sv_public", "-2");
2341                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2342                 if(redirection_target == "self")
2343                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2344                 else
2345                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2346         }
2347
2348         if(time < redirection_nextthink)
2349                 return true;
2350
2351         redirection_nextthink = time + 1;
2352
2353         clients_found = 0;
2354         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2355                 // TODO add timer
2356                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2357                 if(redirection_target == "self")
2358                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2359                 else
2360                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2361                 ++clients_found;
2362         });
2363
2364         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2365
2366         if(time > redirection_timeout || clients_found == 0)
2367                 localcmd("\nwait; wait; wait; quit\n");
2368
2369         return true;
2370 }
2371
2372 void RestoreGame()
2373 {
2374         // Loaded from a save game
2375         // some things then break, so let's work around them...
2376
2377         // Progs DB (capture records)
2378         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2379
2380         // Mapinfo
2381         MapInfo_Shutdown();
2382         MapInfo_Enumerate();
2383         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2384         WeaponStats_Init();
2385
2386         TargetMusic_RestoreGame();
2387 }
2388
2389 void Shutdown()
2390 {
2391         game_stopped = 2;
2392
2393         if(world_initialized > 0)
2394         {
2395                 world_initialized = 0;
2396
2397                 // if a timeout is active, reset the slowmo value to normal
2398                 if(timeout_status == TIMEOUT_ACTIVE)
2399                         cvar_set("slowmo", ftos(orig_slowmo));
2400
2401                 LOG_TRACE("Saving persistent data...");
2402                 Ban_SaveBans();
2403
2404                 // playerstats with unfinished match
2405                 PlayerStats_GameReport(false);
2406
2407                 if(!cheatcount_total)
2408                 {
2409                         if(autocvar_sv_db_saveasdump)
2410                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2411                         else
2412                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2413                 }
2414                 if(autocvar_developer > 0)
2415                 {
2416                         if(autocvar_sv_db_saveasdump)
2417                                 db_dump(TemporaryDB, "server-temp.db");
2418                         else
2419                                 db_save(TemporaryDB, "server-temp.db");
2420                 }
2421                 CheatShutdown(); // must be after cheatcount check
2422                 db_close(ServerProgsDB);
2423                 db_close(TemporaryDB);
2424                 LOG_TRACE("Saving persistent data... done!");
2425                 // tell the bot system the game is ending now
2426                 bot_endgame();
2427
2428                 WeaponStats_Shutdown();
2429                 MapInfo_Shutdown();
2430         }
2431         else if(world_initialized == 0)
2432         {
2433                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2434         }
2435         else
2436         {
2437                 __init_dedicated_server_shutdown();
2438         }
2439 }